ext/B/B/Deparse.pm

   1 # B::Deparse.pm
   2 # Copyright (c) 1998-2000, 2002, 2003 Stephen McCamant. All rights reserved.
   3 # This module is free software; you can redistribute and/or modify
   4 # it under the same terms as Perl itself.
   5
   6 # This is based on the module of the same name by Malcolm Beattie,
   7 # but essentially none of his code remains.
   8
   9 package B::Deparse;
  10 use Carp;
  11 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
  12          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
  13          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
  14          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
  15          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
  16          OPpCONST_ARYBASE OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
  17          OPpSORT_REVERSE
  18          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
  19          CVf_METHOD CVf_LOCKED CVf_LVALUE CVf_ASSERTION
  20          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE PMf_SKIPWHITE
  21          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
  22 $VERSION = 0.65;
  23 use strict;
  24 use vars qw/$AUTOLOAD/;
  25 use warnings ();
  26
  27 # Changes between 0.50 and 0.51:
  28 # - fixed nulled leave with live enter in sort { }
  29 # - fixed reference constants (\"str")
  30 # - handle empty programs gracefully
  31 # - handle infinte loops (for (;;) {}, while (1) {})
  32 # - differentiate between `for my $x ...' and `my $x; for $x ...'
  33 # - various minor cleanups
  34 # - moved globals into an object
  35 # - added `-u', like B::C
  36 # - package declarations using cop_stash
  37 # - subs, formats and code sorted by cop_seq
  38 # Changes between 0.51 and 0.52:
  39 # - added pp_threadsv (special variables under USE_5005THREADS)
  40 # - added documentation
  41 # Changes between 0.52 and 0.53:
  42 # - many changes adding precedence contexts and associativity
  43 # - added `-p' and `-s' output style options
  44 # - various other minor fixes
  45 # Changes between 0.53 and 0.54:
  46 # - added support for new `for (1..100)' optimization,
  47 #   thanks to Gisle Aas
  48 # Changes between 0.54 and 0.55:
  49 # - added support for new qr// construct
  50 # - added support for new pp_regcreset OP
  51 # Changes between 0.55 and 0.56:
  52 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
  53 # - fixed $# on non-lexicals broken in last big rewrite
  54 # - added temporary fix for change in opcode of OP_STRINGIFY
  55 # - fixed problem in 0.54's for() patch in `for (@ary)'
  56 # - fixed precedence in conditional of ?:
  57 # - tweaked list paren elimination in `my($x) = @_'
  58 # - made continue-block detection trickier wrt. null ops
  59 # - fixed various prototype problems in pp_entersub
  60 # - added support for sub prototypes that never get GVs
  61 # - added unquoting for special filehandle first arg in truncate
  62 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
  63 # - added semicolons at the ends of blocks
  64 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
  65 # Changes between 0.56 and 0.561:
  66 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
  67 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
  68 # Changes between 0.561 and 0.57:
  69 # - stylistic changes to symbolic constant stuff
  70 # - handled scope in s///e replacement code
  71 # - added unquote option for expanding "" into concats, etc.
  72 # - split method and proto parts of pp_entersub into separate functions
  73 # - various minor cleanups
  74 # Changes after 0.57:
  75 # - added parens in \&foo (patch by Albert Dvornik)
  76 # Changes between 0.57 and 0.58:
  77 # - fixed `0' statements that weren't being printed
  78 # - added methods for use from other programs
  79 #   (based on patches from James Duncan and Hugo van der Sanden)
  80 # - added -si and -sT to control indenting (also based on a patch from Hugo)
  81 # - added -sv to print something else instead of '???'
  82 # - preliminary version of utf8 tr/// handling
  83 # Changes after 0.58:
  84 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
  85 # - added support for Hugo's new OP_SETSTATE (like nextstate)
  86 # Changes between 0.58 and 0.59
  87 # - added support for Chip's OP_METHOD_NAMED
  88 # - added support for Ilya's OPpTARGET_MY optimization
  89 # - elided arrows before `()' subscripts when possible
  90 # Changes between 0.59 and 0.60
  91 # - support for method attribues was added
  92 # - some warnings fixed
  93 # - separate recognition of constant subs
  94 # - rewrote continue block handling, now recoginizing for loops
  95 # - added more control of expanding control structures
  96 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
  97 # - many bug-fixes
  98 # - support for pragmas and 'use'
  99 # - support for the little-used $[ variable
 100 # - support for __DATA__ sections
 101 # - UTF8 support
 102 # - BEGIN, CHECK, INIT and END blocks
 103 # - scoping of subroutine declarations fixed
 104 # - compile-time output from the input program can be suppressed, so that the
 105 #   output is just the deparsed code. (a change to O.pm in fact)
 106 # - our() declarations
 107 # - *all* the known bugs are now listed in the BUGS section
 108 # - comprehensive test mechanism (TEST -deparse)
 109 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
 110 # - bug-fixes
 111 # - new switch -P
 112 # - support for command-line switches (-l, -0, etc.)
 113 # Changes between 0.63 and 0.64
 114 # - support for //, CHECK blocks, and assertions
 115 # - improved handling of foreach loops and lexicals
 116 # - option to use Data::Dumper for constants
 117 # - more bug fixes
 118 # - discovered lots more bugs not yet fixed
 119
 120 # Todo:
 121 #  (See also BUGS section at the end of this file)
 122 #
 123 # - finish tr/// changes
 124 # - add option for even more parens (generalize \&foo change)
 125 # - left/right context
 126 # - copy comments (look at real text with $^P?)
 127 # - avoid semis in one-statement blocks
 128 # - associativity of &&=, ||=, ?:
 129 # - ',' => '=>' (auto-unquote?)
 130 # - break long lines ("\r" as discretionary break?)
 131 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
 132 # - more style options: brace style, hex vs. octal, quotes, ...
 133 # - print big ints as hex/octal instead of decimal (heuristic?)
 134 # - handle `my $x if 0'?
 135 # - version using op_next instead of op_first/sibling?
 136 # - avoid string copies (pass arrays, one big join?)
 137 # - here-docs?
 138
 139 # Current test.deparse failures
 140 # comp/assertions 38 - disabled assertions should be like "my($x) if 0"
 141 #    'sub f : assertion {}; no assertions; my $x=1; {f(my $x=2); print "$x\n"}'
 142 # comp/hints 6 - location of BEGIN blocks wrt. block openings
 143 # run/switchI 1 - missing -I switches entirely
 144 #    perl -Ifoo -e 'print @INC'
 145 # op/caller 2 - warning mask propagates backwards before warnings::register
 146 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
 147 # op/getpid 2 - can't assign to shared my() declaration (threads only)
 148 #    'my $x : shared = 5'
 149 # op/override 7 - parens on overriden require change v-string interpretation
 150 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
 151 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
 152 # op/pat 774 - losing Unicode-ness of Latin1-only strings
 153 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
 154 # op/recurse 12 - missing parens on recursive call makes it look like method
 155 #    'sub f { f($x) }'
 156 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
 157 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
 158 # op/tiehandle compile - "use strict" deparsed in the wrong place
 159 # uni/tr_ several
 160 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
 161 # ext/Data/Dumper/t/dumper compile
 162 # ext/DB_file/several
 163 # ext/Encode/several
 164 # ext/Ernno/Errno warnings
 165 # ext/IO/lib/IO/t/io_sel 23
 166 # ext/PerlIO/t/encoding compile
 167 # ext/POSIX/t/posix 6
 168 # ext/Socket/Socket 8
 169 # ext/Storable/t/croak compile
 170 # lib/Attribute/Handlers/t/multi compile
 171 # lib/bignum/ several
 172 # lib/charnames 35
 173 # lib/constant 32
 174 # lib/English 40
 175 # lib/ExtUtils/t/bytes 4
 176 # lib/File/DosGlob compile
 177 # lib/Filter/Simple/t/data 1
 178 # lib/Math/BigInt/t/constant 1
 179 # lib/Net/t/config Deparse-warning
 180 # lib/overload compile
 181 # lib/Switch/ several
 182 # lib/Symbol 4
 183 # lib/Test/Simple several
 184 # lib/Term/Complete
 185 # lib/Tie/File/t/29_downcopy 5
 186 # lib/vars 22
 187
 188 # Object fields (were globals):
 189 #
 190 # avoid_local:
 191 # (local($a), local($b)) and local($a, $b) have the same internal
 192 # representation but the short form looks better. We notice we can
 193 # use a large-scale local when checking the list, but need to prevent
 194 # individual locals too. This hash holds the addresses of OPs that
 195 # have already had their local-ness accounted for. The same thing
 196 # is done with my().
 197 #
 198 # curcv:
 199 # CV for current sub (or main program) being deparsed
 200 #
 201 # curcvlex:
 202 # Cached hash of lexical variables for curcv: keys are names,
 203 # each value is an array of pairs, indicating the cop_seq of scopes
 204 # in which a var of that name is valid.
 205 #
 206 # curcop:
 207 # COP for statement being deparsed
 208 #
 209 # curstash:
 210 # name of the current package for deparsed code
 211 #
 212 # subs_todo:
 213 # array of [cop_seq, CV, is_format?] for subs and formats we still
 214 # want to deparse
 215 #
 216 # protos_todo:
 217 # as above, but [name, prototype] for subs that never got a GV
 218 #
 219 # subs_done, forms_done:
 220 # keys are addresses of GVs for subs and formats we've already
 221 # deparsed (or at least put into subs_todo)
 222 #
 223 # subs_declared
 224 # keys are names of subs for which we've printed declarations.
 225 # That means we can omit parentheses from the arguments.
 226 #
 227 # subs_deparsed
 228 # Keeps track of fully qualified names of all deparsed subs.
 229 #
 230 # parens: -p
 231 # linenums: -l
 232 # unquote: -q
 233 # cuddle: ` ' or `\n', depending on -sC
 234 # indent_size: -si
 235 # use_tabs: -sT
 236 # ex_const: -sv
 237
 238 # A little explanation of how precedence contexts and associativity
 239 # work:
 240 #
 241 # deparse() calls each per-op subroutine with an argument $cx (short
 242 # for context, but not the same as the cx* in the perl core), which is
 243 # a number describing the op's parents in terms of precedence, whether
 244 # they're inside an expression or at statement level, etc.  (see
 245 # chart below). When ops with children call deparse on them, they pass
 246 # along their precedence. Fractional values are used to implement
 247 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
 248 # parentheses hacks. The major disadvantage of this scheme is that
 249 # it doesn't know about right sides and left sides, so say if you
 250 # assign a listop to a variable, it can't tell it's allowed to leave
 251 # the parens off the listop.
 252
 253 # Precedences:
 254 # 26             [TODO] inside interpolation context ("")
 255 # 25 left        terms and list operators (leftward)
 256 # 24 left        ->
 257 # 23 nonassoc    ++ --
 258 # 22 right       **
 259 # 21 right       ! ~ \ and unary + and -
 260 # 20 left        =~ !~
 261 # 19 left        * / % x
 262 # 18 left        + - .
 263 # 17 left        << >>
 264 # 16 nonassoc    named unary operators
 265 # 15 nonassoc    < > <= >= lt gt le ge
 266 # 14 nonassoc    == != <=> eq ne cmp
 267 # 13 left        &
 268 # 12 left        | ^
 269 # 11 left        &&
 270 # 10 left        ||
 271 #  9 nonassoc    ..  ...
 272 #  8 right       ?:
 273 #  7 right       = += -= *= etc.
 274 #  6 left        , =>
 275 #  5 nonassoc    list operators (rightward)
 276 #  4 right       not
 277 #  3 left        and
 278 #  2 left        or xor
 279 #  1             statement modifiers
 280 #  0.5           statements, but still print scopes as do { ... }
 281 #  0             statement level
 282
 283 # Nonprinting characters with special meaning:
 284 # \cS - steal parens (see maybe_parens_unop)
 285 # \n - newline and indent
 286 # \t - increase indent
 287 # \b - decrease indent (`outdent')
 288 # \f - flush left (no indent)
 289 # \cK - kill following semicolon, if any
 290
 291 sub null {
 292     my $op = shift;
 293     return class($op) eq "NULL";
 294 }
 295
 296 sub todo {
 297     my $self = shift;
 298     my($cv, $is_form) = @_;
 299     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
 300     my $seq;
 301     if ($cv->OUTSIDE_SEQ) {
 302         $seq = $cv->OUTSIDE_SEQ;
 303     } elsif (!null($cv->START) and is_state($cv->START)) {
 304         $seq = $cv->START->cop_seq;
 305     } else {
 306         $seq = 0;
 307     }
 308     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
 309     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
 310         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
 311     }
 312 }
 313
 314 sub next_todo {
 315     my $self = shift;
 316     my $ent = shift @{$self->{'subs_todo'}};
 317     my $cv = $ent->[1];
 318     my $gv = $cv->GV;
 319     my $name = $self->gv_name($gv);
 320     if ($ent->[2]) {
 321         return "format $name =\n"
 322             . $self->deparse_format($ent->[1]). "\n";
 323     } else {
 324         $self->{'subs_declared'}{$name} = 1;
 325         if ($name eq "BEGIN") {
 326             my $use_dec = $self->begin_is_use($cv);
 327             if (defined ($use_dec) and $self->{'expand'} < 5) {
 328                 return () if 0 == length($use_dec);
 329                 return $use_dec;
 330             }
 331         }
 332         my $l = '';
 333         if ($self->{'linenums'}) {
 334             my $line = $gv->LINE;
 335             my $file = $gv->FILE;
 336             $l = "\n\f#line $line \"$file\"\n";
 337         }
 338         my $p = '';
 339         if (class($cv->STASH) ne "SPECIAL") {
 340             my $stash = $cv->STASH->NAME;
 341             if ($stash ne $self->{'curstash'}) {
 342                 $p = "package $stash;\n";
 343                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
 344                 $self->{'curstash'} = $stash;
 345             }
 346             $name =~ s/^\Q$stash\E:://;
 347         }
 348         return "${p}${l}sub $name " . $self->deparse_sub($cv);
 349     }
 350 }
 351
 352 # Return a "use" declaration for this BEGIN block, if appropriate
 353 sub begin_is_use {
 354     my ($self, $cv) = @_;
 355     my $root = $cv->ROOT;
 356     local @$self{qw'curcv curcvlex'} = ($cv);
 357 #require B::Debug;
 358 #B::walkoptree($cv->ROOT, "debug");
 359     my $lineseq = $root->first;
 360     return if $lineseq->name ne "lineseq";
 361
 362     my $req_op = $lineseq->first->sibling;
 363     return if $req_op->name ne "require";
 364
 365     my $module;
 366     if ($req_op->first->private & OPpCONST_BARE) {
 367         # Actually it should always be a bareword
 368         $module = $self->const_sv($req_op->first)->PV;
 369         $module =~ s[/][::]g;
 370         $module =~ s/.pm$//;
 371     }
 372     else {
 373         $module = $self->const($self->const_sv($req_op->first), 6);
 374     }
 375
 376     my $version;
 377     my $version_op = $req_op->sibling;
 378     return if class($version_op) eq "NULL";
 379     if ($version_op->name eq "lineseq") {
 380         # We have a version parameter; skip nextstate & pushmark
 381         my $constop = $version_op->first->next->next;
 382
 383         return unless $self->const_sv($constop)->PV eq $module;
 384         $constop = $constop->sibling;
 385         $version = $self->const_sv($constop);
 386         if (class($version) eq "IV") {
 387             $version = $version->int_value;
 388         } elsif (class($version) eq "NV") {
 389             $version = $version->NV;
 390         } elsif (class($version) ne "PVMG") {
 391             # Includes PVIV and PVNV
 392             $version = $version->PV;
 393         } else {
 394             # version specified as a v-string
 395             $version = 'v'.join '.', map ord, split //, $version->PV;
 396         }
 397         $constop = $constop->sibling;
 398         return if $constop->name ne "method_named";
 399         return if $self->const_sv($constop)->PV ne "VERSION";
 400     }
 401
 402     $lineseq = $version_op->sibling;
 403     return if $lineseq->name ne "lineseq";
 404     my $entersub = $lineseq->first->sibling;
 405     if ($entersub->name eq "stub") {
 406         return "use $module $version ();\n" if defined $version;
 407         return "use $module ();\n";
 408     }
 409     return if $entersub->name ne "entersub";
 410
 411     # See if there are import arguments
 412     my $args = '';
 413
 414     my $svop = $entersub->first->sibling; # Skip over pushmark
 415     return unless $self->const_sv($svop)->PV eq $module;
 416
 417     # Pull out the arguments
 418     for ($svop=$svop->sibling; $svop->name ne "method_named";
 419                 $svop = $svop->sibling) {
 420         $args .= ", " if length($args);
 421         $args .= $self->deparse($svop, 6);
 422     }
 423
 424     my $use = 'use';
 425     my $method_named = $svop;
 426     return if $method_named->name ne "method_named";
 427     my $method_name = $self->const_sv($method_named)->PV;
 428
 429     if ($method_name eq "unimport") {
 430         $use = 'no';
 431     }
 432
 433     # Certain pragmas are dealt with using hint bits,
 434     # so we ignore them here
 435     if ($module eq 'strict' || $module eq 'integer'
 436         || $module eq 'bytes' || $module eq 'warnings') {
 437         return "";
 438     }
 439
 440     if (defined $version && length $args) {
 441         return "$use $module $version ($args);\n";
 442     } elsif (defined $version) {
 443         return "$use $module $version;\n";
 444     } elsif (length $args) {
 445         return "$use $module ($args);\n";
 446     } else {
 447         return "$use $module;\n";
 448     }
 449 }
 450
 451 sub stash_subs {
 452     my ($self, $pack) = @_;
 453     my (@ret, $stash);
 454     if (!defined $pack) {
 455         $pack = '';
 456         $stash = \%::;
 457     }
 458     else {
 459         $pack =~ s/(::)?$/::/;
 460         no strict 'refs';
 461         $stash = \%$pack;
 462     }
 463     my %stash = svref_2object($stash)->ARRAY;
 464     while (my ($key, $val) = each %stash) {
 465         next if $key eq 'main::';       # avoid infinite recursion
 466         my $class = class($val);
 467         if ($class eq "PV") {
 468             # Just a prototype. As an ugly but fairly effective way
 469             # to find out if it belongs here is to see if the AUTOLOAD
 470             # (if any) for the stash was defined in one of our files.
 471             my $A = $stash{"AUTOLOAD"};
 472             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 473                 && class($A->CV) eq "CV") {
 474                 my $AF = $A->FILE;
 475                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 476             }
 477             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
 478         } elsif ($class eq "IV") {
 479             # Just a name. As above.
 480             my $A = $stash{"AUTOLOAD"};
 481             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 482                 && class($A->CV) eq "CV") {
 483                 my $AF = $A->FILE;
 484                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 485             }
 486             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
 487         } elsif ($class eq "GV") {
 488             if (class(my $cv = $val->CV) ne "SPECIAL") {
 489                 next if $self->{'subs_done'}{$$val}++;
 490                 next if $$val != ${$cv->GV};   # Ignore imposters
 491                 $self->todo($cv, 0);
 492             }
 493             if (class(my $cv = $val->FORM) ne "SPECIAL") {
 494                 next if $self->{'forms_done'}{$$val}++;
 495                 next if $$val != ${$cv->GV};   # Ignore imposters
 496                 $self->todo($cv, 1);
 497             }
 498             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
 499                 $self->stash_subs($pack . $key);
 500             }
 501         }
 502     }
 503 }
 504
 505 sub print_protos {
 506     my $self = shift;
 507     my $ar;
 508     my @ret;
 509     foreach $ar (@{$self->{'protos_todo'}}) {
 510         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
 511         push @ret, "sub " . $ar->[0] .  "$proto;\n";
 512     }
 513     delete $self->{'protos_todo'};
 514     return @ret;
 515 }
 516
 517 sub style_opts {
 518     my $self = shift;
 519     my $opts = shift;
 520     my $opt;
 521     while (length($opt = substr($opts, 0, 1))) {
 522         if ($opt eq "C") {
 523             $self->{'cuddle'} = " ";
 524             $opts = substr($opts, 1);
 525         } elsif ($opt eq "i") {
 526             $opts =~ s/^i(\d+)//;
 527             $self->{'indent_size'} = $1;
 528         } elsif ($opt eq "T") {
 529             $self->{'use_tabs'} = 1;
 530             $opts = substr($opts, 1);
 531         } elsif ($opt eq "v") {
 532             $opts =~ s/^v([^.]*)(.|$)//;
 533             $self->{'ex_const'} = $1;
 534         }
 535     }
 536 }
 537
 538 sub new {
 539     my $class = shift;
 540     my $self = bless {}, $class;
 541     $self->{'cuddle'} = "\n";
 542     $self->{'curcop'} = undef;
 543     $self->{'curstash'} = "main";
 544     $self->{'ex_const'} = "'???'";
 545     $self->{'expand'} = 0;
 546     $self->{'files'} = {};
 547     $self->{'indent_size'} = 4;
 548     $self->{'linenums'} = 0;
 549     $self->{'parens'} = 0;
 550     $self->{'subs_todo'} = [];
 551     $self->{'unquote'} = 0;
 552     $self->{'use_dumper'} = 0;
 553     $self->{'use_tabs'} = 0;
 554
 555     $self->{'ambient_arybase'} = 0;
 556     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
 557     $self->{'ambient_hints'} = 0;
 558     $self->init();
 559
 560     while (my $arg = shift @_) {
 561         if ($arg eq "-d") {
 562             $self->{'use_dumper'} = 1;
 563             require Data::Dumper;
 564         } elsif ($arg =~ /^-f(.*)/) {
 565             $self->{'files'}{$1} = 1;
 566         } elsif ($arg eq "-l") {
 567             $self->{'linenums'} = 1;
 568         } elsif ($arg eq "-p") {
 569             $self->{'parens'} = 1;
 570         } elsif ($arg eq "-P") {
 571             $self->{'noproto'} = 1;
 572         } elsif ($arg eq "-q") {
 573             $self->{'unquote'} = 1;
 574         } elsif (substr($arg, 0, 2) eq "-s") {
 575             $self->style_opts(substr $arg, 2);
 576         } elsif ($arg =~ /^-x(\d)$/) {
 577             $self->{'expand'} = $1;
 578         }
 579     }
 580     return $self;
 581 }
 582
 583 {
 584     # Mask out the bits that L<warnings::register> uses
 585     my $WARN_MASK;
 586     BEGIN {
 587         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
 588     }
 589     sub WARN_MASK () {
 590         return $WARN_MASK;
 591     }
 592 }
 593
 594 # Initialise the contextual information, either from
 595 # defaults provided with the ambient_pragmas method,
 596 # or from perl's own defaults otherwise.
 597 sub init {
 598     my $self = shift;
 599
 600     $self->{'arybase'}  = $self->{'ambient_arybase'};
 601     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
 602                                 ? $self->{'ambient_warnings'} & WARN_MASK
 603                                 : undef;
 604     $self->{'hints'}    = $self->{'ambient_hints'} & 0xFF;
 605
 606     # also a convenient place to clear out subs_declared
 607     delete $self->{'subs_declared'};
 608 }
 609
 610 sub compile {
 611     my(@args) = @_;
 612     return sub {
 613         my $self = B::Deparse->new(@args);
 614         # First deparse command-line args
 615         if (defined $^I) { # deparse -i
 616             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
 617         }
 618         if ($^W) { # deparse -w
 619             print qq(BEGIN { \$^W = $^W; }\n);
 620         }
 621         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
 622             my $fs = perlstring($/) || 'undef';
 623             my $bs = perlstring($O::savebackslash) || 'undef';
 624             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
 625         }
 626         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
 627         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
 628         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
 629         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
 630         for my $block (@BEGINs, @CHECKs, @INITs, @ENDs) {
 631             $self->todo($block, 0);
 632         }
 633         $self->stash_subs();
 634         local($SIG{"__DIE__"}) =
 635           sub {
 636               if ($self->{'curcop'}) {
 637                   my $cop = $self->{'curcop'};
 638                   my($line, $file) = ($cop->line, $cop->file);
 639                   print STDERR "While deparsing $file near line $line,\n";
 640               }
 641             };
 642         $self->{'curcv'} = main_cv;
 643         $self->{'curcvlex'} = undef;
 644         print $self->print_protos;
 645         @{$self->{'subs_todo'}} =
 646           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
 647         print $self->indent($self->deparse_root(main_root)), "\n"
 648           unless null main_root;
 649         my @text;
 650         while (scalar(@{$self->{'subs_todo'}})) {
 651             push @text, $self->next_todo;
 652         }
 653         print $self->indent(join("", @text)), "\n" if @text;
 654
 655         # Print __DATA__ section, if necessary
 656         no strict 'refs';
 657         my $laststash = defined $self->{'curcop'}
 658             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
 659         if (defined *{$laststash."::DATA"}{IO}) {
 660             print "package $laststash;\n"
 661                 unless $laststash eq $self->{'curstash'};
 662             print "__DATA__\n";
 663             print readline(*{$laststash."::DATA"});
 664         }
 665     }
 666 }
 667
 668 sub coderef2text {
 669     my $self = shift;
 670     my $sub = shift;
 671     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
 672
 673     $self->init();
 674     return $self->indent($self->deparse_sub(svref_2object($sub)));
 675 }
 676
 677 sub ambient_pragmas {
 678     my $self = shift;
 679     my ($arybase, $hint_bits, $warning_bits) = (0, 0);
 680
 681     while (@_ > 1) {
 682         my $name = shift();
 683         my $val  = shift();
 684
 685         if ($name eq 'strict') {
 686             require strict;
 687
 688             if ($val eq 'none') {
 689                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
 690                 next();
 691             }
 692
 693             my @names;
 694             if ($val eq "all") {
 695                 @names = qw/refs subs vars/;
 696             }
 697             elsif (ref $val) {
 698                 @names = @$val;
 699             }
 700             else {
 701                 @names = split' ', $val;
 702             }
 703             $hint_bits |= strict::bits(@names);
 704         }
 705
 706         elsif ($name eq '$[') {
 707             $arybase = $val;
 708         }
 709
 710         elsif ($name eq 'integer'
 711             || $name eq 'bytes'
 712             || $name eq 'utf8') {
 713             require "$name.pm";
 714             if ($val) {
 715                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
 716             }
 717             else {
 718                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
 719             }
 720         }
 721
 722         elsif ($name eq 're') {
 723             require re;
 724             if ($val eq 'none') {
 725                 $hint_bits &= ~re::bits(qw/taint eval/);
 726                 next();
 727             }
 728
 729             my @names;
 730             if ($val eq 'all') {
 731                 @names = qw/taint eval/;
 732             }
 733             elsif (ref $val) {
 734                 @names = @$val;
 735             }
 736             else {
 737                 @names = split' ',$val;
 738             }
 739             $hint_bits |= re::bits(@names);
 740         }
 741
 742         elsif ($name eq 'warnings') {
 743             if ($val eq 'none') {
 744                 $warning_bits = $warnings::NONE;
 745                 next();
 746             }
 747
 748             my @names;
 749             if (ref $val) {
 750                 @names = @$val;
 751             }
 752             else {
 753                 @names = split/\s+/, $val;
 754             }
 755
 756             $warning_bits = $warnings::NONE if !defined ($warning_bits);
 757             $warning_bits |= warnings::bits(@names);
 758         }
 759
 760         elsif ($name eq 'warning_bits') {
 761             $warning_bits = $val;
 762         }
 763
 764         elsif ($name eq 'hint_bits') {
 765             $hint_bits = $val;
 766         }
 767
 768         else {
 769             croak "Unknown pragma type: $name";
 770         }
 771     }
 772     if (@_) {
 773         croak "The ambient_pragmas method expects an even number of args";
 774     }
 775
 776     $self->{'ambient_arybase'} = $arybase;
 777     $self->{'ambient_warnings'} = $warning_bits;
 778     $self->{'ambient_hints'} = $hint_bits;
 779 }
 780
 781 # This method is the inner loop, so try to keep it simple
 782 sub deparse {
 783     my $self = shift;
 784     my($op, $cx) = @_;
 785
 786     Carp::confess("Null op in deparse") if !defined($op)
 787                                         || class($op) eq "NULL";
 788     my $meth = "pp_" . $op->name;
 789     return $self->$meth($op, $cx);
 790 }
 791
 792 sub indent {
 793     my $self = shift;
 794     my $txt = shift;
 795     my @lines = split(/\n/, $txt);
 796     my $leader = "";
 797     my $level = 0;
 798     my $line;
 799     for $line (@lines) {
 800         my $cmd = substr($line, 0, 1);
 801         if ($cmd eq "\t" or $cmd eq "\b") {
 802             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
 803             if ($self->{'use_tabs'}) {
 804                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
 805             } else {
 806                 $leader = " " x $level;
 807             }
 808             $line = substr($line, 1);
 809         }
 810         if (substr($line, 0, 1) eq "\f") {
 811             $line = substr($line, 1); # no indent
 812         } else {
 813             $line = $leader . $line;
 814         }
 815         $line =~ s/\cK;?//g;
 816     }
 817     return join("\n", @lines);
 818 }
 819
 820 sub deparse_sub {
 821     my $self = shift;
 822     my $cv = shift;
 823     my $proto = "";
 824 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
 825 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
 826     local $self->{'curcop'} = $self->{'curcop'};
 827     if ($cv->FLAGS & SVf_POK) {
 828         $proto = "(". $cv->PV . ") ";
 829     }
 830     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE|CVf_ASSERTION)) {
 831         $proto .= ": ";
 832         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
 833         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
 834         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
 835         $proto .= "assertion " if $cv->CvFLAGS & CVf_ASSERTION;
 836     }
 837
 838     local($self->{'curcv'}) = $cv;
 839     local($self->{'curcvlex'});
 840     local(@$self{qw'curstash warnings hints'})
 841                 = @$self{qw'curstash warnings hints'};
 842     my $body;
 843     if (not null $cv->ROOT) {
 844         my $lineseq = $cv->ROOT->first;
 845         if ($lineseq->name eq "lineseq") {
 846             my @ops;
 847             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
 848                 push @ops, $o;
 849             }
 850             $body = $self->lineseq(undef, @ops).";";
 851             my $scope_en = $self->find_scope_en($lineseq);
 852             if (defined $scope_en) {
 853                 my $subs = join"", $self->seq_subs($scope_en);
 854                 $body .= ";\n$subs" if length($subs);
 855             }
 856         }
 857         else {
 858             $body = $self->deparse($cv->ROOT->first, 0);
 859         }
 860     }
 861     else {
 862         my $sv = $cv->const_sv;
 863         if ($$sv) {
 864             # uh-oh. inlinable sub... format it differently
 865             return $proto . "{ " . $self->const($sv, 0) . " }\n";
 866         } else { # XSUB? (or just a declaration)
 867             return "$proto;\n";
 868         }
 869     }
 870     return $proto ."{\n\t$body\n\b}" ."\n";
 871 }
 872
 873 sub deparse_format {
 874     my $self = shift;
 875     my $form = shift;
 876     my @text;
 877     local($self->{'curcv'}) = $form;
 878     local($self->{'curcvlex'});
 879     local($self->{'in_format'}) = 1;
 880     local(@$self{qw'curstash warnings hints'})
 881                 = @$self{qw'curstash warnings hints'};
 882     my $op = $form->ROOT;
 883     my $kid;
 884     return "\f." if $op->first->name eq 'stub'
 885                 || $op->first->name eq 'nextstate';
 886     $op = $op->first->first; # skip leavewrite, lineseq
 887     while (not null $op) {
 888         $op = $op->sibling; # skip nextstate
 889         my @exprs;
 890         $kid = $op->first->sibling; # skip pushmark
 891         push @text, "\f".$self->const_sv($kid)->PV;
 892         $kid = $kid->sibling;
 893         for (; not null $kid; $kid = $kid->sibling) {
 894             push @exprs, $self->deparse($kid, 0);
 895         }
 896         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
 897         $op = $op->sibling;
 898     }
 899     return join("", @text) . "\f.";
 900 }
 901
 902 sub is_scope {
 903     my $op = shift;
 904     return $op->name eq "leave" || $op->name eq "scope"
 905       || $op->name eq "lineseq"
 906         || ($op->name eq "null" && class($op) eq "UNOP"
 907             && (is_scope($op->first) || $op->first->name eq "enter"));
 908 }
 909
 910 sub is_state {
 911     my $name = $_[0]->name;
 912     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
 913 }
 914
 915 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
 916     my $op = shift;
 917     return (!null($op) and null($op->sibling)
 918             and $op->name eq "null" and class($op) eq "UNOP"
 919             and (($op->first->name =~ /^(and|or)$/
 920                   and $op->first->first->sibling->name eq "lineseq")
 921                  or ($op->first->name eq "lineseq"
 922                      and not null $op->first->first->sibling
 923                      and $op->first->first->sibling->name eq "unstack")
 924                  ));
 925 }
 926
 927 # Check if the op and its sibling are the initialization and the rest of a
 928 # for (..;..;..) { ... } loop
 929 sub is_for_loop {
 930     my $op = shift;
 931     # This OP might be almost anything, though it won't be a
 932     # nextstate. (It's the initialization, so in the canonical case it
 933     # will be an sassign.) The sibling is a lineseq whose first child
 934     # is a nextstate and whose second is a leaveloop.
 935     my $lseq = $op->sibling;
 936     if (!is_state $op and !null($lseq) and $lseq->name eq "lineseq") {
 937         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
 938             && (my $sib = $lseq->first->sibling)) {
 939             return (!null($sib) && $sib->name eq "leaveloop");
 940         }
 941     }
 942     return 0;
 943 }
 944
 945 sub is_scalar {
 946     my $op = shift;
 947     return ($op->name eq "rv2sv" or
 948             $op->name eq "padsv" or
 949             $op->name eq "gv" or # only in array/hash constructs
 950             $op->flags & OPf_KIDS && !null($op->first)
 951               && $op->first->name eq "gvsv");
 952 }
 953
 954 sub maybe_parens {
 955     my $self = shift;
 956     my($text, $cx, $prec) = @_;
 957     if ($prec < $cx              # unary ops nest just fine
 958         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
 959         or $self->{'parens'})
 960     {
 961         $text = "($text)";
 962         # In a unop, let parent reuse our parens; see maybe_parens_unop
 963         $text = "\cS" . $text if $cx == 16;
 964         return $text;
 965     } else {
 966         return $text;
 967     }
 968 }
 969
 970 # same as above, but get around the `if it looks like a function' rule
 971 sub maybe_parens_unop {
 972     my $self = shift;
 973     my($name, $kid, $cx) = @_;
 974     if ($cx > 16 or $self->{'parens'}) {
 975         $kid =  $self->deparse($kid, 1);
 976         if ($name eq "umask" && $kid =~ /^\d+$/) {
 977             $kid = sprintf("%#o", $kid);
 978         }
 979         return "$name($kid)";
 980     } else {
 981         $kid = $self->deparse($kid, 16);
 982         if ($name eq "umask" && $kid =~ /^\d+$/) {
 983             $kid = sprintf("%#o", $kid);
 984         }
 985         if (substr($kid, 0, 1) eq "\cS") {
 986             # use kid's parens
 987             return $name . substr($kid, 1);
 988         } elsif (substr($kid, 0, 1) eq "(") {
 989             # avoid looks-like-a-function trap with extra parens
 990             # (`+' can lead to ambiguities)
 991             return "$name(" . $kid  . ")";
 992         } else {
 993             return "$name $kid";
 994         }
 995     }
 996 }
 997
 998 sub maybe_parens_func {
 999     my $self = shift;
1000     my($func, $text, $cx, $prec) = @_;
1001     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1002         return "$func($text)";
1003     } else {
1004         return "$func $text";
1005     }
1006 }
1007
1008 sub maybe_local {
1009     my $self = shift;
1010     my($op, $cx, $text) = @_;
1011     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1012     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1013         and not $self->{'avoid_local'}{$$op}) {
1014         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1015         if( $our_local eq 'our' ) {
1016             die "Unexpected our($text)\n" unless $text =~ /^\W(\w+::)*\w+\z/;
1017             $text =~ s/(\w+::)+//;
1018         }
1019         if (want_scalar($op)) {
1020             return "$our_local $text";
1021         } else {
1022             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1023         }
1024     } else {
1025         return $text;
1026     }
1027 }
1028
1029 sub maybe_targmy {
1030     my $self = shift;
1031     my($op, $cx, $func, @args) = @_;
1032     if ($op->private & OPpTARGET_MY) {
1033         my $var = $self->padname($op->targ);
1034         my $val = $func->($self, $op, 7, @args);
1035         return $self->maybe_parens("$var = $val", $cx, 7);
1036     } else {
1037         return $func->($self, $op, $cx, @args);
1038     }
1039 }
1040
1041 sub padname_sv {
1042     my $self = shift;
1043     my $targ = shift;
1044     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1045 }
1046
1047 sub maybe_my {
1048     my $self = shift;
1049     my($op, $cx, $text) = @_;
1050     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1051         if (want_scalar($op)) {
1052             return "my $text";
1053         } else {
1054             return $self->maybe_parens_func("my", $text, $cx, 16);
1055         }
1056     } else {
1057         return $text;
1058     }
1059 }
1060
1061 # The following OPs don't have functions:
1062
1063 # pp_padany -- does not exist after parsing
1064
1065 sub AUTOLOAD {
1066     if ($AUTOLOAD =~ s/^.*::pp_//) {
1067         warn "unexpected OP_".uc $AUTOLOAD;
1068         return "XXX";
1069     } else {
1070         die "Undefined subroutine $AUTOLOAD called";
1071     }
1072 }
1073
1074 sub DESTROY {}  #       Do not AUTOLOAD
1075
1076 # $root should be the op which represents the root of whatever
1077 # we're sequencing here. If it's undefined, then we don't append
1078 # any subroutine declarations to the deparsed ops, otherwise we
1079 # append appropriate declarations.
1080 sub lineseq {
1081     my($self, $root, @ops) = @_;
1082     my($expr, @exprs);
1083
1084     my $out_cop = $self->{'curcop'};
1085     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1086     my $limit_seq;
1087     if (defined $root) {
1088         $limit_seq = $out_seq;
1089         my $nseq;
1090         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1091         $limit_seq = $nseq if !defined($limit_seq)
1092                            or defined($nseq) && $nseq < $limit_seq;
1093     }
1094     $limit_seq = $self->{'limit_seq'}
1095         if defined($self->{'limit_seq'})
1096         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1097     local $self->{'limit_seq'} = $limit_seq;
1098     for (my $i = 0; $i < @ops; $i++) {
1099         $expr = "";
1100         if (is_state $ops[$i]) {
1101             $expr = $self->deparse($ops[$i], 0);
1102             $i++;
1103             if ($i > $#ops) {
1104                 push @exprs, $expr;
1105                 last;
1106             }
1107         }
1108         if (!is_state $ops[$i] and (my $ls = $ops[$i+1]) and
1109             !null($ops[$i+1]) and $ops[$i+1]->name eq "lineseq")
1110         {
1111             if ($ls->first && !null($ls->first) && is_state($ls->first)
1112                 && (my $sib = $ls->first->sibling)) {
1113                 if (!null($sib) && $sib->name eq "leaveloop") {
1114                     push @exprs, $expr . $self->for_loop($ops[$i], 0);
1115                     $i++;
1116                     next;
1117                 }
1118             }
1119         }
1120         $expr .= $self->deparse($ops[$i], (@ops != 1)/2);
1121         $expr =~ s/;\n?\z//;
1122         push @exprs, $expr;
1123     }
1124     my $body = join(";\n", grep {length} @exprs);
1125     my $subs = "";
1126     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1127         $subs = join "\n", $self->seq_subs($limit_seq);
1128     }
1129     return join(";\n", grep {length} $body, $subs);
1130 }
1131
1132 sub scopeop {
1133     my($real_block, $self, $op, $cx) = @_;
1134     my $kid;
1135     my @kids;
1136
1137     local(@$self{qw'curstash warnings hints'})
1138                 = @$self{qw'curstash warnings hints'} if $real_block;
1139     if ($real_block) {
1140         $kid = $op->first->sibling; # skip enter
1141         if (is_miniwhile($kid)) {
1142             my $top = $kid->first;
1143             my $name = $top->name;
1144             if ($name eq "and") {
1145                 $name = "while";
1146             } elsif ($name eq "or") {
1147                 $name = "until";
1148             } else { # no conditional -> while 1 or until 0
1149                 return $self->deparse($top->first, 1) . " while 1";
1150             }
1151             my $cond = $top->first;
1152             my $body = $cond->sibling->first; # skip lineseq
1153             $cond = $self->deparse($cond, 1);
1154             $body = $self->deparse($body, 1);
1155             return "$body $name $cond";
1156         }
1157     } else {
1158         $kid = $op->first;
1159     }
1160     for (; !null($kid); $kid = $kid->sibling) {
1161         push @kids, $kid;
1162     }
1163     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1164         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1165     } else {
1166         my $lineseq = $self->lineseq($op, @kids);
1167         return (length ($lineseq) ? "$lineseq;" : "");
1168     }
1169 }
1170
1171 sub pp_scope { scopeop(0, @_); }
1172 sub pp_lineseq { scopeop(0, @_); }
1173 sub pp_leave { scopeop(1, @_); }
1174
1175 # This is a special case of scopeop and lineseq, for the case of the
1176 # main_root. The difference is that we print the output statements as
1177 # soon as we get them, for the sake of impatient users.
1178 sub deparse_root {
1179     my $self = shift;
1180     my($op) = @_;
1181     local(@$self{qw'curstash warnings hints'})
1182       = @$self{qw'curstash warnings hints'};
1183     my @kids;
1184     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1185         push @kids, $kid;
1186     }
1187     for (my $i = 0; $i < @kids; $i++) {
1188         my $expr = "";
1189         if (is_state $kids[$i]) {
1190             $expr = $self->deparse($kids[$i], 0);
1191             $i++;
1192             if ($i > $#kids) {
1193                 print $self->indent($expr);
1194                 last;
1195             }
1196         }
1197         if (is_for_loop($kids[$i])) {
1198             $expr .= $self->for_loop($kids[$i], 0);
1199             $expr .= ";\n" unless $i == $#kids;
1200             print $self->indent($expr);
1201             $i++;
1202             next;
1203         }
1204         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1205         $expr =~ s/;\n?\z//;
1206         $expr .= ";";
1207         print $self->indent($expr);
1208         print "\n" unless $i == $#kids;
1209     }
1210 }
1211
1212 # The BEGIN {} is used here because otherwise this code isn't executed
1213 # when you run B::Deparse on itself.
1214 my %globalnames;
1215 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1216             "ENV", "ARGV", "ARGVOUT", "_"); }
1217
1218 sub gv_name {
1219     my $self = shift;
1220     my $gv = shift;
1221 Carp::confess() unless ref($gv) eq "B::GV";
1222     my $stash = $gv->STASH->NAME;
1223     my $name = $gv->SAFENAME;
1224     if (($stash eq 'main' && $globalnames{$name})
1225         or ($stash eq $self->{'curstash'} && !$globalnames{$name})
1226         or $name =~ /^[^A-Za-z_]/)
1227     {
1228         $stash = "";
1229     } else {
1230         $stash = $stash . "::";
1231     }
1232     if ($name =~ /^(\^..|{)/) {
1233         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1234     }
1235     return $stash . $name;
1236 }
1237
1238 # Return the name to use for a stash variable.
1239 # If a lexical with the same name is in scope, it may need to be
1240 # fully-qualified.
1241 sub stash_variable {
1242     my ($self, $prefix, $name) = @_;
1243
1244     return "$prefix$name" if $name =~ /::/;
1245
1246     unless ($prefix eq '$' || $prefix eq '@' || #'
1247             $prefix eq '%' || $prefix eq '$#') {
1248         return "$prefix$name";
1249     }
1250
1251     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1252     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1253     return "$prefix$name";
1254 }
1255
1256 sub lex_in_scope {
1257     my ($self, $name) = @_;
1258     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1259
1260     return 0 if !defined($self->{'curcop'});
1261     my $seq = $self->{'curcop'}->cop_seq;
1262     return 0 if !exists $self->{'curcvlex'}{$name};
1263     for my $a (@{$self->{'curcvlex'}{$name}}) {
1264         my ($st, $en) = @$a;
1265         return 1 if $seq > $st && $seq <= $en;
1266     }
1267     return 0;
1268 }
1269
1270 sub populate_curcvlex {
1271     my $self = shift;
1272     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1273         my $padlist = $cv->PADLIST;
1274         # an undef CV still in lexical chain
1275         next if class($padlist) eq "SPECIAL";
1276         my @padlist = $padlist->ARRAY;
1277         my @ns = $padlist[0]->ARRAY;
1278
1279         for (my $i=0; $i<@ns; ++$i) {
1280             next if class($ns[$i]) eq "SPECIAL";
1281             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1282             if (class($ns[$i]) eq "PV") {
1283                 # Probably that pesky lexical @_
1284                 next;
1285             }
1286             my $name = $ns[$i]->PVX;
1287             my ($seq_st, $seq_en) =
1288                 ($ns[$i]->FLAGS & SVf_FAKE)
1289                     ? (0, 999999)
1290                     : ($ns[$i]->NVX, $ns[$i]->IVX);
1291
1292             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1293         }
1294     }
1295 }
1296
1297 sub find_scope_st { ((find_scope(@_))[0]); }
1298 sub find_scope_en { ((find_scope(@_))[1]); }
1299
1300 # Recurses down the tree, looking for pad variable introductions and COPs
1301 sub find_scope {
1302     my ($self, $op, $scope_st, $scope_en) = @_;
1303     carp("Undefined op in find_scope") if !defined $op;
1304     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1305
1306     for (my $o=$op->first; $$o; $o=$o->sibling) {
1307         if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1308             my $s = int($self->padname_sv($o->targ)->NVX);
1309             my $e = $self->padname_sv($o->targ)->IVX;
1310             $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1311             $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1312         }
1313         elsif (is_state($o)) {
1314             my $c = $o->cop_seq;
1315             $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1316             $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1317         }
1318         elsif ($o->flags & OPf_KIDS) {
1319             ($scope_st, $scope_en) =
1320                 $self->find_scope($o, $scope_st, $scope_en)
1321         }
1322     }
1323
1324     return ($scope_st, $scope_en);
1325 }
1326
1327 # Returns a list of subs which should be inserted before the COP
1328 sub cop_subs {
1329     my ($self, $op, $out_seq) = @_;
1330     my $seq = $op->cop_seq;
1331     # If we have nephews, then our sequence number indicates
1332     # the cop_seq of the end of some sort of scope.
1333     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1334         and my $nseq = $self->find_scope_st($op->sibling) ) {
1335         $seq = $nseq;
1336     }
1337     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1338     return $self->seq_subs($seq);
1339 }
1340
1341 sub seq_subs {
1342     my ($self, $seq) = @_;
1343     my @text;
1344 #push @text, "# ($seq)\n";
1345
1346     return "" if !defined $seq;
1347     while (scalar(@{$self->{'subs_todo'}})
1348            and $seq > $self->{'subs_todo'}[0][0]) {
1349         push @text, $self->next_todo;
1350     }
1351     return @text;
1352 }
1353
1354 # Notice how subs and formats are inserted between statements here;
1355 # also $[ assignments and pragmas.
1356 sub pp_nextstate {
1357     my $self = shift;
1358     my($op, $cx) = @_;
1359     $self->{'curcop'} = $op;
1360     my @text;
1361     push @text, $self->cop_subs($op);
1362     push @text, $op->label . ": " if $op->label;
1363     my $stash = $op->stashpv;
1364     if ($stash ne $self->{'curstash'}) {
1365         push @text, "package $stash;\n";
1366         $self->{'curstash'} = $stash;
1367     }
1368
1369     if ($self->{'arybase'} != $op->arybase) {
1370         push @text, '$[ = '. $op->arybase .";\n";
1371         $self->{'arybase'} = $op->arybase;
1372     }
1373
1374     my $warnings = $op->warnings;
1375     my $warning_bits;
1376     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1377         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1378     }
1379     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1380         $warning_bits = $warnings::NONE;
1381     }
1382     elsif ($warnings->isa("B::SPECIAL")) {
1383         $warning_bits = undef;
1384     }
1385     else {
1386         $warning_bits = $warnings->PV & WARN_MASK;
1387     }
1388
1389     if (defined ($warning_bits) and
1390        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1391         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1392         $self->{'warnings'} = $warning_bits;
1393     }
1394
1395     if ($self->{'hints'} != $op->private) {
1396         push @text, declare_hints($self->{'hints'}, $op->private);
1397         $self->{'hints'} = $op->private;
1398     }
1399
1400     # This should go after of any branches that add statements, to
1401     # increase the chances that it refers to the same line it did in
1402     # the original program.
1403     if ($self->{'linenums'}) {
1404         push @text, "\f#line " . $op->line .
1405           ' "' . $op->file, qq'"\n';
1406     }
1407
1408     return join("", @text);
1409 }
1410
1411 sub declare_warnings {
1412     my ($from, $to) = @_;
1413     if (($to & WARN_MASK) eq warnings::bits("all")) {
1414         return "use warnings;\n";
1415     }
1416     elsif (($to & WARN_MASK) eq "\0"x length($to)) {
1417         return "no warnings;\n";
1418     }
1419     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1420 }
1421
1422 sub declare_hints {
1423     my ($from, $to) = @_;
1424     my $use = $to   & ~$from;
1425     my $no  = $from & ~$to;
1426     my $decls = "";
1427     for my $pragma (hint_pragmas($use)) {
1428         $decls .= "use $pragma;\n";
1429     }
1430     for my $pragma (hint_pragmas($no)) {
1431         $decls .= "no $pragma;\n";
1432     }
1433     return $decls;
1434 }
1435
1436 sub hint_pragmas {
1437     my ($bits) = @_;
1438     my @pragmas;
1439     push @pragmas, "integer" if $bits & 0x1;
1440     push @pragmas, "strict 'refs'" if $bits & 0x2;
1441     push @pragmas, "bytes" if $bits & 0x8;
1442     return @pragmas;
1443 }
1444
1445 sub pp_dbstate { pp_nextstate(@_) }
1446 sub pp_setstate { pp_nextstate(@_) }
1447
1448 sub pp_unstack { return "" } # see also leaveloop
1449
1450 sub baseop {
1451     my $self = shift;
1452     my($op, $cx, $name) = @_;
1453     return $name;
1454 }
1455
1456 sub pp_stub {
1457     my $self = shift;
1458     my($op, $cx, $name) = @_;
1459     if ($cx >= 1) {
1460         return "()";
1461     }
1462     else {
1463         return "();";
1464     }
1465 }
1466 sub pp_wantarray { baseop(@_, "wantarray") }
1467 sub pp_fork { baseop(@_, "fork") }
1468 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1469 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1470 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1471 sub pp_tms { baseop(@_, "times") }
1472 sub pp_ghostent { baseop(@_, "gethostent") }
1473 sub pp_gnetent { baseop(@_, "getnetent") }
1474 sub pp_gprotoent { baseop(@_, "getprotoent") }
1475 sub pp_gservent { baseop(@_, "getservent") }
1476 sub pp_ehostent { baseop(@_, "endhostent") }
1477 sub pp_enetent { baseop(@_, "endnetent") }
1478 sub pp_eprotoent { baseop(@_, "endprotoent") }
1479 sub pp_eservent { baseop(@_, "endservent") }
1480 sub pp_gpwent { baseop(@_, "getpwent") }
1481 sub pp_spwent { baseop(@_, "setpwent") }
1482 sub pp_epwent { baseop(@_, "endpwent") }
1483 sub pp_ggrent { baseop(@_, "getgrent") }
1484 sub pp_sgrent { baseop(@_, "setgrent") }
1485 sub pp_egrent { baseop(@_, "endgrent") }
1486 sub pp_getlogin { baseop(@_, "getlogin") }
1487
1488 sub POSTFIX () { 1 }
1489
1490 # I couldn't think of a good short name, but this is the category of
1491 # symbolic unary operators with interesting precedence
1492
1493 sub pfixop {
1494     my $self = shift;
1495     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1496     my $kid = $op->first;
1497     $kid = $self->deparse($kid, $prec);
1498     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1499                                $cx, $prec);
1500 }
1501
1502 sub pp_preinc { pfixop(@_, "++", 23) }
1503 sub pp_predec { pfixop(@_, "--", 23) }
1504 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1505 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1506 sub pp_i_preinc { pfixop(@_, "++", 23) }
1507 sub pp_i_predec { pfixop(@_, "--", 23) }
1508 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1509 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1510 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1511
1512 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1513 sub real_negate {
1514     my $self = shift;
1515     my($op, $cx) = @_;
1516     if ($op->first->name =~ /^(i_)?negate$/) {
1517         # avoid --$x
1518         $self->pfixop($op, $cx, "-", 21.5);
1519     } else {
1520         $self->pfixop($op, $cx, "-", 21);
1521     }
1522 }
1523 sub pp_i_negate { pp_negate(@_) }
1524
1525 sub pp_not {
1526     my $self = shift;
1527     my($op, $cx) = @_;
1528     if ($cx <= 4) {
1529         $self->pfixop($op, $cx, "not ", 4);
1530     } else {
1531         $self->pfixop($op, $cx, "!", 21);
1532     }
1533 }
1534
1535 sub unop {
1536     my $self = shift;
1537     my($op, $cx, $name) = @_;
1538     my $kid;
1539     if ($op->flags & OPf_KIDS) {
1540         $kid = $op->first;
1541         if (defined prototype("CORE::$name")
1542            && prototype("CORE::$name") =~ /^;?\*/
1543            && $kid->name eq "rv2gv") {
1544             $kid = $kid->first;
1545         }
1546
1547         return $self->maybe_parens_unop($name, $kid, $cx);
1548     } else {
1549         return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1550     }
1551 }
1552
1553 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1554 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1555 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1556 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1557 sub pp_defined { unop(@_, "defined") }
1558 sub pp_undef { unop(@_, "undef") }
1559 sub pp_study { unop(@_, "study") }
1560 sub pp_ref { unop(@_, "ref") }
1561 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1562
1563 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1564 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1565 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1566 sub pp_srand { unop(@_, "srand") }
1567 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1568 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1569 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1570 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1571 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1572 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1573 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1574
1575 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1576 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1577 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1578
1579 sub pp_each { unop(@_, "each") }
1580 sub pp_values { unop(@_, "values") }
1581 sub pp_keys { unop(@_, "keys") }
1582 sub pp_pop { unop(@_, "pop") }
1583 sub pp_shift { unop(@_, "shift") }
1584
1585 sub pp_caller { unop(@_, "caller") }
1586 sub pp_reset { unop(@_, "reset") }
1587 sub pp_exit { unop(@_, "exit") }
1588 sub pp_prototype { unop(@_, "prototype") }
1589
1590 sub pp_close { unop(@_, "close") }
1591 sub pp_fileno { unop(@_, "fileno") }
1592 sub pp_umask { unop(@_, "umask") }
1593 sub pp_untie { unop(@_, "untie") }
1594 sub pp_tied { unop(@_, "tied") }
1595 sub pp_dbmclose { unop(@_, "dbmclose") }
1596 sub pp_getc { unop(@_, "getc") }
1597 sub pp_eof { unop(@_, "eof") }
1598 sub pp_tell { unop(@_, "tell") }
1599 sub pp_getsockname { unop(@_, "getsockname") }
1600 sub pp_getpeername { unop(@_, "getpeername") }
1601
1602 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1603 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1604 sub pp_readlink { unop(@_, "readlink") }
1605 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1606 sub pp_readdir { unop(@_, "readdir") }
1607 sub pp_telldir { unop(@_, "telldir") }
1608 sub pp_rewinddir { unop(@_, "rewinddir") }
1609 sub pp_closedir { unop(@_, "closedir") }
1610 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1611 sub pp_localtime { unop(@_, "localtime") }
1612 sub pp_gmtime { unop(@_, "gmtime") }
1613 sub pp_alarm { unop(@_, "alarm") }
1614 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1615
1616 sub pp_dofile { unop(@_, "do") }
1617 sub pp_entereval { unop(@_, "eval") }
1618
1619 sub pp_ghbyname { unop(@_, "gethostbyname") }
1620 sub pp_gnbyname { unop(@_, "getnetbyname") }
1621 sub pp_gpbyname { unop(@_, "getprotobyname") }
1622 sub pp_shostent { unop(@_, "sethostent") }
1623 sub pp_snetent { unop(@_, "setnetent") }
1624 sub pp_sprotoent { unop(@_, "setprotoent") }
1625 sub pp_sservent { unop(@_, "setservent") }
1626 sub pp_gpwnam { unop(@_, "getpwnam") }
1627 sub pp_gpwuid { unop(@_, "getpwuid") }
1628 sub pp_ggrnam { unop(@_, "getgrnam") }
1629 sub pp_ggrgid { unop(@_, "getgrgid") }
1630
1631 sub pp_lock { unop(@_, "lock") }
1632
1633 sub pp_exists {
1634     my $self = shift;
1635     my($op, $cx) = @_;
1636     my $arg;
1637     if ($op->private & OPpEXISTS_SUB) {
1638         # Checking for the existence of a subroutine
1639         return $self->maybe_parens_func("exists",
1640                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1641     }
1642     if ($op->flags & OPf_SPECIAL) {
1643         # Array element, not hash element
1644         return $self->maybe_parens_func("exists",
1645                                 $self->pp_aelem($op->first, 16), $cx, 16);
1646     }
1647     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1648                                     $cx, 16);
1649 }
1650
1651 sub pp_delete {
1652     my $self = shift;
1653     my($op, $cx) = @_;
1654     my $arg;
1655     if ($op->private & OPpSLICE) {
1656         if ($op->flags & OPf_SPECIAL) {
1657             # Deleting from an array, not a hash
1658             return $self->maybe_parens_func("delete",
1659                                         $self->pp_aslice($op->first, 16),
1660                                         $cx, 16);
1661         }
1662         return $self->maybe_parens_func("delete",
1663                                         $self->pp_hslice($op->first, 16),
1664                                         $cx, 16);
1665     } else {
1666         if ($op->flags & OPf_SPECIAL) {
1667             # Deleting from an array, not a hash
1668             return $self->maybe_parens_func("delete",
1669                                         $self->pp_aelem($op->first, 16),
1670                                         $cx, 16);
1671         }
1672         return $self->maybe_parens_func("delete",
1673                                         $self->pp_helem($op->first, 16),
1674                                         $cx, 16);
1675     }
1676 }
1677
1678 sub pp_require {
1679     my $self = shift;
1680     my($op, $cx) = @_;
1681     if (class($op) eq "UNOP" and $op->first->name eq "const"
1682         and $op->first->private & OPpCONST_BARE)
1683     {
1684         my $name = $self->const_sv($op->first)->PV;
1685         $name =~ s[/][::]g;
1686         $name =~ s/\.pm//g;
1687         return "require $name";
1688     } else {
1689         $self->unop($op, $cx, "require");
1690     }
1691 }
1692
1693 sub pp_scalar {
1694     my $self = shift;
1695     my($op, $cv) = @_;
1696     my $kid = $op->first;
1697     if (not null $kid->sibling) {
1698         # XXX Was a here-doc
1699         return $self->dquote($op);
1700     }
1701     $self->unop(@_, "scalar");
1702 }
1703
1704
1705 sub padval {
1706     my $self = shift;
1707     my $targ = shift;
1708     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
1709 }
1710
1711 sub pp_refgen {
1712     my $self = shift;
1713     my($op, $cx) = @_;
1714     my $kid = $op->first;
1715     if ($kid->name eq "null") {
1716         $kid = $kid->first;
1717         if ($kid->name eq "anonlist" || $kid->name eq "anonhash") {
1718             my($pre, $post) = @{{"anonlist" => ["[","]"],
1719                                  "anonhash" => ["{","}"]}->{$kid->name}};
1720             my($expr, @exprs);
1721             $kid = $kid->first->sibling; # skip pushmark
1722             for (; !null($kid); $kid = $kid->sibling) {
1723                 $expr = $self->deparse($kid, 6);
1724                 push @exprs, $expr;
1725             }
1726             return $pre . join(", ", @exprs) . $post;
1727         } elsif (!null($kid->sibling) and
1728                  $kid->sibling->name eq "anoncode") {
1729             return "sub " .
1730                 $self->deparse_sub($self->padval($kid->sibling->targ));
1731         } elsif ($kid->name eq "pushmark") {
1732             my $sib_name = $kid->sibling->name;
1733             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1734                 and not $kid->sibling->flags & OPf_REF)
1735             {
1736                 # The @a in \(@a) isn't in ref context, but only when the
1737                 # parens are there.
1738                 return "\\(" . $self->pp_list($op->first) . ")";
1739             } elsif ($sib_name eq 'entersub') {
1740                 my $text = $self->deparse($kid->sibling, 1);
1741                 # Always show parens for \(&func()), but only with -p otherwise
1742                 $text = "($text)" if $self->{'parens'}
1743                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1744                 return "\\$text";
1745             }
1746         }
1747     }
1748     $self->pfixop($op, $cx, "\\", 20);
1749 }
1750
1751 sub pp_srefgen { pp_refgen(@_) }
1752
1753 sub pp_readline {
1754     my $self = shift;
1755     my($op, $cx) = @_;
1756     my $kid = $op->first;
1757     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1758     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1759     return $self->unop($op, $cx, "readline");
1760 }
1761
1762 sub pp_rcatline {
1763     my $self = shift;
1764     my($op) = @_;
1765     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
1766 }
1767
1768 # Unary operators that can occur as pseudo-listops inside double quotes
1769 sub dq_unop {
1770     my $self = shift;
1771     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1772     my $kid;
1773     if ($op->flags & OPf_KIDS) {
1774        $kid = $op->first;
1775        # If there's more than one kid, the first is an ex-pushmark.
1776        $kid = $kid->sibling if not null $kid->sibling;
1777        return $self->maybe_parens_unop($name, $kid, $cx);
1778     } else {
1779        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1780     }
1781 }
1782
1783 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1784 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1785 sub pp_uc { dq_unop(@_, "uc") }
1786 sub pp_lc { dq_unop(@_, "lc") }
1787 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1788
1789 sub loopex {
1790     my $self = shift;
1791     my ($op, $cx, $name) = @_;
1792     if (class($op) eq "PVOP") {
1793         return "$name " . $op->pv;
1794     } elsif (class($op) eq "OP") {
1795         return $name;
1796     } elsif (class($op) eq "UNOP") {
1797         # Note -- loop exits are actually exempt from the
1798         # looks-like-a-func rule, but a few extra parens won't hurt
1799         return $self->maybe_parens_unop($name, $op->first, $cx);
1800     }
1801 }
1802
1803 sub pp_last { loopex(@_, "last") }
1804 sub pp_next { loopex(@_, "next") }
1805 sub pp_redo { loopex(@_, "redo") }
1806 sub pp_goto { loopex(@_, "goto") }
1807 sub pp_dump { loopex(@_, "dump") }
1808
1809 sub ftst {
1810     my $self = shift;
1811     my($op, $cx, $name) = @_;
1812     if (class($op) eq "UNOP") {
1813         # Genuine `-X' filetests are exempt from the LLAFR, but not
1814         # l?stat(); for the sake of clarity, give'em all parens
1815         return $self->maybe_parens_unop($name, $op->first, $cx);
1816     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
1817         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
1818     } else { # I don't think baseop filetests ever survive ck_ftst, but...
1819         return $name;
1820     }
1821 }
1822
1823 sub pp_lstat    { ftst(@_, "lstat") }
1824 sub pp_stat     { ftst(@_, "stat") }
1825 sub pp_ftrread  { ftst(@_, "-R") }
1826 sub pp_ftrwrite { ftst(@_, "-W") }
1827 sub pp_ftrexec  { ftst(@_, "-X") }
1828 sub pp_fteread  { ftst(@_, "-r") }
1829 sub pp_ftewrite { ftst(@_, "-w") }
1830 sub pp_fteexec  { ftst(@_, "-x") }
1831 sub pp_ftis     { ftst(@_, "-e") }
1832 sub pp_fteowned { ftst(@_, "-O") }
1833 sub pp_ftrowned { ftst(@_, "-o") }
1834 sub pp_ftzero   { ftst(@_, "-z") }
1835 sub pp_ftsize   { ftst(@_, "-s") }
1836 sub pp_ftmtime  { ftst(@_, "-M") }
1837 sub pp_ftatime  { ftst(@_, "-A") }
1838 sub pp_ftctime  { ftst(@_, "-C") }
1839 sub pp_ftsock   { ftst(@_, "-S") }
1840 sub pp_ftchr    { ftst(@_, "-c") }
1841 sub pp_ftblk    { ftst(@_, "-b") }
1842 sub pp_ftfile   { ftst(@_, "-f") }
1843 sub pp_ftdir    { ftst(@_, "-d") }
1844 sub pp_ftpipe   { ftst(@_, "-p") }
1845 sub pp_ftlink   { ftst(@_, "-l") }
1846 sub pp_ftsuid   { ftst(@_, "-u") }
1847 sub pp_ftsgid   { ftst(@_, "-g") }
1848 sub pp_ftsvtx   { ftst(@_, "-k") }
1849 sub pp_fttty    { ftst(@_, "-t") }
1850 sub pp_fttext   { ftst(@_, "-T") }
1851 sub pp_ftbinary { ftst(@_, "-B") }
1852
1853 sub SWAP_CHILDREN () { 1 }
1854 sub ASSIGN () { 2 } # has OP= variant
1855 sub LIST_CONTEXT () { 4 } # Assignment is in list context
1856
1857 my(%left, %right);
1858
1859 sub assoc_class {
1860     my $op = shift;
1861     my $name = $op->name;
1862     if ($name eq "concat" and $op->first->name eq "concat") {
1863         # avoid spurious `=' -- see comment in pp_concat
1864         return "concat";
1865     }
1866     if ($name eq "null" and class($op) eq "UNOP"
1867         and $op->first->name =~ /^(and|x?or)$/
1868         and null $op->first->sibling)
1869     {
1870         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
1871         # with a null that's used as the common end point of the two
1872         # flows of control. For precedence purposes, ignore it.
1873         # (COND_EXPRs have these too, but we don't bother with
1874         # their associativity).
1875         return assoc_class($op->first);
1876     }
1877     return $name . ($op->flags & OPf_STACKED ? "=" : "");
1878 }
1879
1880 # Left associative operators, like `+', for which
1881 # $a + $b + $c is equivalent to ($a + $b) + $c
1882
1883 BEGIN {
1884     %left = ('multiply' => 19, 'i_multiply' => 19,
1885              'divide' => 19, 'i_divide' => 19,
1886              'modulo' => 19, 'i_modulo' => 19,
1887              'repeat' => 19,
1888              'add' => 18, 'i_add' => 18,
1889              'subtract' => 18, 'i_subtract' => 18,
1890              'concat' => 18,
1891              'left_shift' => 17, 'right_shift' => 17,
1892              'bit_and' => 13,
1893              'bit_or' => 12, 'bit_xor' => 12,
1894              'and' => 3,
1895              'or' => 2, 'xor' => 2,
1896             );
1897 }
1898
1899 sub deparse_binop_left {
1900     my $self = shift;
1901     my($op, $left, $prec) = @_;
1902     if ($left{assoc_class($op)} && $left{assoc_class($left)}
1903         and $left{assoc_class($op)} == $left{assoc_class($left)})
1904     {
1905         return $self->deparse($left, $prec - .00001);
1906     } else {
1907         return $self->deparse($left, $prec);
1908     }
1909 }
1910
1911 # Right associative operators, like `=', for which
1912 # $a = $b = $c is equivalent to $a = ($b = $c)
1913
1914 BEGIN {
1915     %right = ('pow' => 22,
1916               'sassign=' => 7, 'aassign=' => 7,
1917               'multiply=' => 7, 'i_multiply=' => 7,
1918               'divide=' => 7, 'i_divide=' => 7,
1919               'modulo=' => 7, 'i_modulo=' => 7,
1920               'repeat=' => 7,
1921               'add=' => 7, 'i_add=' => 7,
1922               'subtract=' => 7, 'i_subtract=' => 7,
1923               'concat=' => 7,
1924               'left_shift=' => 7, 'right_shift=' => 7,
1925               'bit_and=' => 7,
1926               'bit_or=' => 7, 'bit_xor=' => 7,
1927               'andassign' => 7,
1928               'orassign' => 7,
1929              );
1930 }
1931
1932 sub deparse_binop_right {
1933     my $self = shift;
1934     my($op, $right, $prec) = @_;
1935     if ($right{assoc_class($op)} && $right{assoc_class($right)}
1936         and $right{assoc_class($op)} == $right{assoc_class($right)})
1937     {
1938         return $self->deparse($right, $prec - .00001);
1939     } else {
1940         return $self->deparse($right, $prec);
1941     }
1942 }
1943
1944 sub binop {
1945     my $self = shift;
1946     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
1947     my $left = $op->first;
1948     my $right = $op->last;
1949     my $eq = "";
1950     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
1951         $eq = "=";
1952         $prec = 7;
1953     }
1954     if ($flags & SWAP_CHILDREN) {
1955         ($left, $right) = ($right, $left);
1956     }
1957     $left = $self->deparse_binop_left($op, $left, $prec);
1958     $left = "($left)" if $flags & LIST_CONTEXT
1959                 && $left !~ /^(my|our|local|)[\@\(]/;
1960     $right = $self->deparse_binop_right($op, $right, $prec);
1961     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
1962 }
1963
1964 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
1965 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
1966 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
1967 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
1968 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
1969 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
1970 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
1971 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
1972 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
1973 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
1974 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
1975
1976 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
1977 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
1978 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
1979 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
1980 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
1981
1982 sub pp_eq { binop(@_, "==", 14) }
1983 sub pp_ne { binop(@_, "!=", 14) }
1984 sub pp_lt { binop(@_, "<", 15) }
1985 sub pp_gt { binop(@_, ">", 15) }
1986 sub pp_ge { binop(@_, ">=", 15) }
1987 sub pp_le { binop(@_, "<=", 15) }
1988 sub pp_ncmp { binop(@_, "<=>", 14) }
1989 sub pp_i_eq { binop(@_, "==", 14) }
1990 sub pp_i_ne { binop(@_, "!=", 14) }
1991 sub pp_i_lt { binop(@_, "<", 15) }
1992 sub pp_i_gt { binop(@_, ">", 15) }
1993 sub pp_i_ge { binop(@_, ">=", 15) }
1994 sub pp_i_le { binop(@_, "<=", 15) }
1995 sub pp_i_ncmp { binop(@_, "<=>", 14) }
1996
1997 sub pp_seq { binop(@_, "eq", 14) }
1998 sub pp_sne { binop(@_, "ne", 14) }
1999 sub pp_slt { binop(@_, "lt", 15) }
2000 sub pp_sgt { binop(@_, "gt", 15) }
2001 sub pp_sge { binop(@_, "ge", 15) }
2002 sub pp_sle { binop(@_, "le", 15) }
2003 sub pp_scmp { binop(@_, "cmp", 14) }
2004
2005 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2006 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2007
2008 # `.' is special because concats-of-concats are optimized to save copying
2009 # by making all but the first concat stacked. The effect is as if the
2010 # programmer had written `($a . $b) .= $c', except legal.
2011 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2012 sub real_concat {
2013     my $self = shift;
2014     my($op, $cx) = @_;
2015     my $left = $op->first;
2016     my $right = $op->last;
2017     my $eq = "";
2018     my $prec = 18;
2019     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2020         $eq = "=";
2021         $prec = 7;
2022     }
2023     $left = $self->deparse_binop_left($op, $left, $prec);
2024     $right = $self->deparse_binop_right($op, $right, $prec);
2025     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2026 }
2027
2028 # `x' is weird when the left arg is a list
2029 sub pp_repeat {
2030     my $self = shift;
2031     my($op, $cx) = @_;
2032     my $left = $op->first;
2033     my $right = $op->last;
2034     my $eq = "";
2035     my $prec = 19;
2036     if ($op->flags & OPf_STACKED) {
2037         $eq = "=";
2038         $prec = 7;
2039     }
2040     if (null($right)) { # list repeat; count is inside left-side ex-list
2041         my $kid = $left->first->sibling; # skip pushmark
2042         my @exprs;
2043         for (; !null($kid->sibling); $kid = $kid->sibling) {
2044             push @exprs, $self->deparse($kid, 6);
2045         }
2046         $right = $kid;
2047         $left = "(" . join(", ", @exprs). ")";
2048     } else {
2049         $left = $self->deparse_binop_left($op, $left, $prec);
2050     }
2051     $right = $self->deparse_binop_right($op, $right, $prec);
2052     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2053 }
2054
2055 sub range {
2056     my $self = shift;
2057     my ($op, $cx, $type) = @_;
2058     my $left = $op->first;
2059     my $right = $left->sibling;
2060     $left = $self->deparse($left, 9);
2061     $right = $self->deparse($right, 9);
2062     return $self->maybe_parens("$left $type $right", $cx, 9);
2063 }
2064
2065 sub pp_flop {
2066     my $self = shift;
2067     my($op, $cx) = @_;
2068     my $flip = $op->first;
2069     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2070     return $self->range($flip->first, $cx, $type);
2071 }
2072
2073 # one-line while/until is handled in pp_leave
2074
2075 sub logop {
2076     my $self = shift;
2077     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2078     my $left = $op->first;
2079     my $right = $op->first->sibling;
2080     if ($cx < 1 and is_scope($right) and $blockname
2081         and $self->{'expand'} < 7)
2082     { # if ($a) {$b}
2083         $left = $self->deparse($left, 1);
2084         $right = $self->deparse($right, 0);
2085         return "$blockname ($left) {\n\t$right\n\b}\cK";
2086     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2087              and $self->{'expand'} < 7) { # $b if $a
2088         $right = $self->deparse($right, 1);
2089         $left = $self->deparse($left, 1);
2090         return "$right $blockname $left";
2091     } elsif ($cx > $lowprec and $highop) { # $a && $b
2092         $left = $self->deparse_binop_left($op, $left, $highprec);
2093         $right = $self->deparse_binop_right($op, $right, $highprec);
2094         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2095     } else { # $a and $b
2096         $left = $self->deparse_binop_left($op, $left, $lowprec);
2097         $right = $self->deparse_binop_right($op, $right, $lowprec);
2098         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2099     }
2100 }
2101
2102 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2103 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2104 sub pp_dor { logop(@_, "err", 2, "//", 10, "") }
2105
2106 # xor is syntactically a logop, but it's really a binop (contrary to
2107 # old versions of opcode.pl). Syntax is what matters here.
2108 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2109
2110 sub logassignop {
2111     my $self = shift;
2112     my ($op, $cx, $opname) = @_;
2113     my $left = $op->first;
2114     my $right = $op->first->sibling->first; # skip sassign
2115     $left = $self->deparse($left, 7);
2116     $right = $self->deparse($right, 7);
2117     return $self->maybe_parens("$left $opname $right", $cx, 7);
2118 }
2119
2120 sub pp_andassign { logassignop(@_, "&&=") }
2121 sub pp_orassign  { logassignop(@_, "||=") }
2122 sub pp_dorassign { logassignop(@_, "//=") }
2123
2124 sub listop {
2125     my $self = shift;
2126     my($op, $cx, $name) = @_;
2127     my(@exprs);
2128     my $parens = ($cx >= 5) || $self->{'parens'};
2129     my $kid = $op->first->sibling;
2130     return $name if null $kid;
2131     my $first;
2132     $name = "socketpair" if $name eq "sockpair";
2133     my $proto = prototype("CORE::$name");
2134     if (defined $proto
2135         && $proto =~ /^;?\*/
2136         && $kid->name eq "rv2gv") {
2137         $first = $self->deparse($kid->first, 6);
2138     }
2139     else {
2140         $first = $self->deparse($kid, 6);
2141     }
2142     if ($name eq "chmod" && $first =~ /^\d+$/) {
2143         $first = sprintf("%#o", $first);
2144     }
2145     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
2146     push @exprs, $first;
2147     $kid = $kid->sibling;
2148     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv") {
2149         push @exprs, $self->deparse($kid->first, 6);
2150         $kid = $kid->sibling;
2151     }
2152     for (; !null($kid); $kid = $kid->sibling) {
2153         push @exprs, $self->deparse($kid, 6);
2154     }
2155     if ($parens) {
2156         return "$name(" . join(", ", @exprs) . ")";
2157     } else {
2158         return "$name " . join(", ", @exprs);
2159     }
2160 }
2161
2162 sub pp_bless { listop(@_, "bless") }
2163 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2164 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2165 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2166 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2167 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2168 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2169 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2170 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2171 sub pp_unpack { listop(@_, "unpack") }
2172 sub pp_pack { listop(@_, "pack") }
2173 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2174 sub pp_splice { listop(@_, "splice") }
2175 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2176 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2177 sub pp_reverse { listop(@_, "reverse") }
2178 sub pp_warn { listop(@_, "warn") }
2179 sub pp_die { listop(@_, "die") }
2180 # Actually, return is exempt from the LLAFR (see examples in this very
2181 # module!), but for consistency's sake, ignore that fact
2182 sub pp_return { listop(@_, "return") }
2183 sub pp_open { listop(@_, "open") }
2184 sub pp_pipe_op { listop(@_, "pipe") }
2185 sub pp_tie { listop(@_, "tie") }
2186 sub pp_binmode { listop(@_, "binmode") }
2187 sub pp_dbmopen { listop(@_, "dbmopen") }
2188 sub pp_sselect { listop(@_, "select") }
2189 sub pp_select { listop(@_, "select") }
2190 sub pp_read { listop(@_, "read") }
2191 sub pp_sysopen { listop(@_, "sysopen") }
2192 sub pp_sysseek { listop(@_, "sysseek") }
2193 sub pp_sysread { listop(@_, "sysread") }
2194 sub pp_syswrite { listop(@_, "syswrite") }
2195 sub pp_send { listop(@_, "send") }
2196 sub pp_recv { listop(@_, "recv") }
2197 sub pp_seek { listop(@_, "seek") }
2198 sub pp_fcntl { listop(@_, "fcntl") }
2199 sub pp_ioctl { listop(@_, "ioctl") }
2200 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2201 sub pp_socket { listop(@_, "socket") }
2202 sub pp_sockpair { listop(@_, "sockpair") }
2203 sub pp_bind { listop(@_, "bind") }
2204 sub pp_connect { listop(@_, "connect") }
2205 sub pp_listen { listop(@_, "listen") }
2206 sub pp_accept { listop(@_, "accept") }
2207 sub pp_shutdown { listop(@_, "shutdown") }
2208 sub pp_gsockopt { listop(@_, "getsockopt") }
2209 sub pp_ssockopt { listop(@_, "setsockopt") }
2210 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2211 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2212 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2213 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2214 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2215 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2216 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2217 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2218 sub pp_open_dir { listop(@_, "opendir") }
2219 sub pp_seekdir { listop(@_, "seekdir") }
2220 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2221 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2222 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2223 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2224 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2225 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2226 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2227 sub pp_shmget { listop(@_, "shmget") }
2228 sub pp_shmctl { listop(@_, "shmctl") }
2229 sub pp_shmread { listop(@_, "shmread") }
2230 sub pp_shmwrite { listop(@_, "shmwrite") }
2231 sub pp_msgget { listop(@_, "msgget") }
2232 sub pp_msgctl { listop(@_, "msgctl") }
2233 sub pp_msgsnd { listop(@_, "msgsnd") }
2234 sub pp_msgrcv { listop(@_, "msgrcv") }
2235 sub pp_semget { listop(@_, "semget") }
2236 sub pp_semctl { listop(@_, "semctl") }
2237 sub pp_semop { listop(@_, "semop") }
2238 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2239 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2240 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2241 sub pp_gsbyname { listop(@_, "getservbyname") }
2242 sub pp_gsbyport { listop(@_, "getservbyport") }
2243 sub pp_syscall { listop(@_, "syscall") }
2244
2245 sub pp_glob {
2246     my $self = shift;
2247     my($op, $cx) = @_;
2248     my $text = $self->dq($op->first->sibling);  # skip pushmark
2249     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2250         or $text =~ /[<>]/) {
2251         return 'glob(' . single_delim('qq', '"', $text) . ')';
2252     } else {
2253         return '<' . $text . '>';
2254     }
2255 }
2256
2257 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2258 # be a filehandle. This could probably be better fixed in the core
2259 # by moving the GV lookup into ck_truc.
2260
2261 sub pp_truncate {
2262     my $self = shift;
2263     my($op, $cx) = @_;
2264     my(@exprs);
2265     my $parens = ($cx >= 5) || $self->{'parens'};
2266     my $kid = $op->first->sibling;
2267     my $fh;
2268     if ($op->flags & OPf_SPECIAL) {
2269         # $kid is an OP_CONST
2270         $fh = $self->const_sv($kid)->PV;
2271     } else {
2272         $fh = $self->deparse($kid, 6);
2273         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2274     }
2275     my $len = $self->deparse($kid->sibling, 6);
2276     if ($parens) {
2277         return "truncate($fh, $len)";
2278     } else {
2279         return "truncate $fh, $len";
2280     }
2281 }
2282
2283 sub indirop {
2284     my $self = shift;
2285     my($op, $cx, $name) = @_;
2286     my($expr, @exprs);
2287     my $kid = $op->first->sibling;
2288     my $indir = "";
2289     if ($op->flags & OPf_STACKED) {
2290         $indir = $kid;
2291         $indir = $indir->first; # skip rv2gv
2292         if (is_scope($indir)) {
2293             $indir = "{" . $self->deparse($indir, 0) . "}";
2294             $indir = "{;}" if $indir eq "{}";
2295         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2296             $indir = $self->const_sv($indir)->PV;
2297         } else {
2298             $indir = $self->deparse($indir, 24);
2299         }
2300         $indir = $indir . " ";
2301         $kid = $kid->sibling;
2302     }
2303     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2304         $indir = ($op->private & OPpSORT_REVERSE) ? '{$b <=> $a} '
2305                                                   : '{$a <=> $b} ';
2306     }
2307     elsif ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2308         $indir = '{$b cmp $a} ';
2309     }
2310     for (; !null($kid); $kid = $kid->sibling) {
2311         $expr = $self->deparse($kid, 6);
2312         push @exprs, $expr;
2313     }
2314     my $args = $indir . join(", ", @exprs);
2315     if ($indir ne "" and $name eq "sort") {
2316         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2317         # give bareword warnings in that case. Therefore if context
2318         # requires, we'll put parens around the outside "(sort f 1, 2,
2319         # 3)". Unfortunately, we'll currently think the parens are
2320         # neccessary more often that they really are, because we don't
2321         # distinguish which side of an assignment we're on.
2322         if ($cx >= 5) {
2323             return "($name $args)";
2324         } else {
2325             return "$name $args";
2326         }
2327     } else {
2328         return $self->maybe_parens_func($name, $args, $cx, 5);
2329     }
2330
2331 }
2332
2333 sub pp_prtf { indirop(@_, "printf") }
2334 sub pp_print { indirop(@_, "print") }
2335 sub pp_sort { indirop(@_, "sort") }
2336
2337 sub mapop {
2338     my $self = shift;
2339     my($op, $cx, $name) = @_;
2340     my($expr, @exprs);
2341     my $kid = $op->first; # this is the (map|grep)start
2342     $kid = $kid->first->sibling; # skip a pushmark
2343     my $code = $kid->first; # skip a null
2344     if (is_scope $code) {
2345         $code = "{" . $self->deparse($code, 0) . "} ";
2346     } else {
2347         $code = $self->deparse($code, 24) . ", ";
2348     }
2349     $kid = $kid->sibling;
2350     for (; !null($kid); $kid = $kid->sibling) {
2351         $expr = $self->deparse($kid, 6);
2352         push @exprs, $expr if defined $expr;
2353     }
2354     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2355 }
2356
2357 sub pp_mapwhile { mapop(@_, "map") }
2358 sub pp_grepwhile { mapop(@_, "grep") }
2359
2360 sub pp_list {
2361     my $self = shift;
2362     my($op, $cx) = @_;
2363     my($expr, @exprs);
2364     my $kid = $op->first->sibling; # skip pushmark
2365     my $lop;
2366     my $local = "either"; # could be local(...), my(...) or our(...)
2367     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2368         # This assumes that no other private flags equal 128, and that
2369         # OPs that store things other than flags in their op_private,
2370         # like OP_AELEMFAST, won't be immediate children of a list.
2371         #
2372         # OP_ENTERSUB can break this logic, so check for it.
2373         # I suspect that open and exit can too.
2374
2375         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2376                 or $lop->name eq "undef")
2377             or $lop->name eq "entersub"
2378             or $lop->name eq "exit"
2379             or $lop->name eq "open")
2380         {
2381             $local = ""; # or not
2382             last;
2383         }
2384         if ($lop->name =~ /^pad[ash]v$/) { # my()
2385             ($local = "", last) if $local eq "local" || $local eq "our";
2386             $local = "my";
2387         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2388                         && $lop->private & OPpOUR_INTRO
2389                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2390                         && $lop->first->private & OPpOUR_INTRO) { # our()
2391             ($local = "", last) if $local eq "my" || $local eq "local";
2392             $local = "our";
2393         } elsif ($lop->name ne "undef") { # local()
2394             ($local = "", last) if $local eq "my" || $local eq "our";
2395             $local = "local";
2396         }
2397     }
2398     $local = "" if $local eq "either"; # no point if it's all undefs
2399     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2400     for (; !null($kid); $kid = $kid->sibling) {
2401         if ($local) {
2402             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2403                 $lop = $kid->first;
2404             } else {
2405                 $lop = $kid;
2406             }
2407             $self->{'avoid_local'}{$$lop}++;
2408             $expr = $self->deparse($kid, 6);
2409             delete $self->{'avoid_local'}{$$lop};
2410         } else {
2411             $expr = $self->deparse($kid, 6);
2412         }
2413         push @exprs, $expr;
2414     }
2415     if ($local) {
2416         return "$local(" . join(", ", @exprs) . ")";
2417     } else {
2418         return $self->maybe_parens( join(", ", @exprs), $cx, 6);
2419     }
2420 }
2421
2422 sub is_ifelse_cont {
2423     my $op = shift;
2424     return ($op->name eq "null" and class($op) eq "UNOP"
2425             and $op->first->name =~ /^(and|cond_expr)$/
2426             and is_scope($op->first->first->sibling));
2427 }
2428
2429 sub pp_cond_expr {
2430     my $self = shift;
2431     my($op, $cx) = @_;
2432     my $cond = $op->first;
2433     my $true = $cond->sibling;
2434     my $false = $true->sibling;
2435     my $cuddle = $self->{'cuddle'};
2436     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
2437             (is_scope($false) || is_ifelse_cont($false))
2438             and $self->{'expand'} < 7) {
2439         $cond = $self->deparse($cond, 8);
2440         $true = $self->deparse($true, 8);
2441         $false = $self->deparse($false, 8);
2442         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2443     }
2444
2445     $cond = $self->deparse($cond, 1);
2446     $true = $self->deparse($true, 0);
2447     my $head = "if ($cond) {\n\t$true\n\b}";
2448     my @elsifs;
2449     while (!null($false) and is_ifelse_cont($false)) {
2450         my $newop = $false->first;
2451         my $newcond = $newop->first;
2452         my $newtrue = $newcond->sibling;
2453         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2454         $newcond = $self->deparse($newcond, 1);
2455         $newtrue = $self->deparse($newtrue, 0);
2456         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2457     }
2458     if (!null($false)) {
2459         $false = $cuddle . "else {\n\t" .
2460           $self->deparse($false, 0) . "\n\b}\cK";
2461     } else {
2462         $false = "\cK";
2463     }
2464     return $head . join($cuddle, "", @elsifs) . $false;
2465 }
2466
2467 sub loop_common {
2468     my $self = shift;
2469     my($op, $cx, $init) = @_;
2470     my $enter = $op->first;
2471     my $kid = $enter->sibling;
2472     local(@$self{qw'curstash warnings hints'})
2473                 = @$self{qw'curstash warnings hints'};
2474     my $head = "";
2475     my $bare = 0;
2476     my $body;
2477     my $cond = undef;
2478     if ($kid->name eq "lineseq") { # bare or infinite loop
2479         if ($kid->last->name eq "unstack") { # infinite
2480             $head = "while (1) "; # Can't use for(;;) if there's a continue
2481             $cond = "";
2482         } else {
2483             $bare = 1;
2484         }
2485         $body = $kid;
2486     } elsif ($enter->name eq "enteriter") { # foreach
2487         my $ary = $enter->first->sibling; # first was pushmark
2488         my $var = $ary->sibling;
2489         if ($enter->flags & OPf_STACKED
2490             and not null $ary->first->sibling->sibling)
2491         {
2492             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2493               $self->deparse($ary->first->sibling->sibling, 9);
2494         } else {
2495             $ary = $self->deparse($ary, 1);
2496         }
2497         if (null $var) {
2498             if ($enter->flags & OPf_SPECIAL) { # thread special var
2499                 $var = $self->pp_threadsv($enter, 1);
2500             } else { # regular my() variable
2501                 $var = $self->pp_padsv($enter, 1);
2502             }
2503         } elsif ($var->name eq "rv2gv") {
2504             $var = $self->pp_rv2sv($var, 1);
2505             if ($enter->private & OPpOUR_INTRO) {
2506                 # our declarations don't have package names
2507                 $var =~ s/^(.).*::/$1/;
2508                 $var = "our $var";
2509             }
2510         } elsif ($var->name eq "gv") {
2511             $var = "\$" . $self->deparse($var, 1);
2512         }
2513         $head = "foreach $var ($ary) ";
2514         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2515     } elsif ($kid->name eq "null") { # while/until
2516         $kid = $kid->first;
2517         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2518         $cond = $self->deparse($kid->first, 1);
2519         $head = "$name ($cond) ";
2520         $body = $kid->first->sibling;
2521     } elsif ($kid->name eq "stub") { # bare and empty
2522         return "{;}"; # {} could be a hashref
2523     }
2524     # If there isn't a continue block, then the next pointer for the loop
2525     # will point to the unstack, which is kid's last child, except
2526     # in a bare loop, when it will point to the leaveloop. When neither of
2527     # these conditions hold, then the second-to-last child is the continue
2528     # block (or the last in a bare loop).
2529     my $cont_start = $enter->nextop;
2530     my $cont;
2531     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
2532         if ($bare) {
2533             $cont = $body->last;
2534         } else {
2535             $cont = $body->first;
2536             while (!null($cont->sibling->sibling)) {
2537                 $cont = $cont->sibling;
2538             }
2539         }
2540         my $state = $body->first;
2541         my $cuddle = $self->{'cuddle'};
2542         my @states;
2543         for (; $$state != $$cont; $state = $state->sibling) {
2544             push @states, $state;
2545         }
2546         $body = $self->lineseq(undef, @states);
2547         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2548             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2549             $cont = "\cK";
2550         } else {
2551             $cont = $cuddle . "continue {\n\t" .
2552               $self->deparse($cont, 0) . "\n\b}\cK";
2553         }
2554     } else {
2555         return "" if !defined $body;
2556         if (length $init) {
2557             $head = "for ($init; $cond;) ";
2558         }
2559         $cont = "\cK";
2560         $body = $self->deparse($body, 0);
2561     }
2562     $body =~ s/;?$/;\n/;
2563
2564     return $head . "{\n\t" . $body . "\b}" . $cont;
2565 }
2566
2567 sub pp_leaveloop { loop_common(@_, "") }
2568
2569 sub for_loop {
2570     my $self = shift;
2571     my($op, $cx) = @_;
2572     my $init = $self->deparse($op, 1);
2573     return $self->loop_common($op->sibling->first->sibling, $cx, $init);
2574 }
2575
2576 sub pp_leavetry {
2577     my $self = shift;
2578     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2579 }
2580
2581 BEGIN { eval "sub OP_CONST () {" . opnumber("const") . "}" }
2582 BEGIN { eval "sub OP_STRINGIFY () {" . opnumber("stringify") . "}" }
2583 BEGIN { eval "sub OP_RV2SV () {" . opnumber("rv2sv") . "}" }
2584 BEGIN { eval "sub OP_LIST () {" . opnumber("list") . "}" }
2585
2586 sub pp_null {
2587     my $self = shift;
2588     my($op, $cx) = @_;
2589     if (class($op) eq "OP") {
2590         # old value is lost
2591         return $self->{'ex_const'} if $op->targ == OP_CONST;
2592     } elsif ($op->first->name eq "pushmark") {
2593         return $self->pp_list($op, $cx);
2594     } elsif ($op->first->name eq "enter") {
2595         return $self->pp_leave($op, $cx);
2596     } elsif ($op->targ == OP_STRINGIFY) {
2597         return $self->dquote($op, $cx);
2598     } elsif (!null($op->first->sibling) and
2599              $op->first->sibling->name eq "readline" and
2600              $op->first->sibling->flags & OPf_STACKED) {
2601         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2602                                    . $self->deparse($op->first->sibling, 7),
2603                                    $cx, 7);
2604     } elsif (!null($op->first->sibling) and
2605              $op->first->sibling->name eq "trans" and
2606              $op->first->sibling->flags & OPf_STACKED) {
2607         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2608                                    . $self->deparse($op->first->sibling, 20),
2609                                    $cx, 20);
2610     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
2611         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2612     } elsif (!null($op->first->sibling) and
2613              $op->first->sibling->name eq "null" and
2614              class($op->first->sibling) eq "UNOP" and
2615              $op->first->sibling->first->flags & OPf_STACKED and
2616              $op->first->sibling->first->name eq "rcatline") {
2617         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2618                                    . $self->deparse($op->first->sibling, 18),
2619                                    $cx, 18);
2620     } else {
2621         return $self->deparse($op->first, $cx);
2622     }
2623 }
2624
2625 sub padname {
2626     my $self = shift;
2627     my $targ = shift;
2628     return $self->padname_sv($targ)->PVX;
2629 }
2630
2631 sub padany {
2632     my $self = shift;
2633     my $op = shift;
2634     return substr($self->padname($op->targ), 1); # skip $/@/%
2635 }
2636
2637 sub pp_padsv {
2638     my $self = shift;
2639     my($op, $cx) = @_;
2640     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2641 }
2642
2643 sub pp_padav { pp_padsv(@_) }
2644 sub pp_padhv { pp_padsv(@_) }
2645
2646 my @threadsv_names;
2647
2648 BEGIN {
2649     @threadsv_names = ("_", "1", "2", "3", "4", "5", "6", "7", "8", "9",
2650                        "&", "`", "'", "+", "/", ".", ",", "\\", '"', ";",
2651                        "^", "-", "%", "=", "|", "~", ":", "^A", "^E",
2652                        "!", "@");
2653 }
2654
2655 sub pp_threadsv {
2656     my $self = shift;
2657     my($op, $cx) = @_;
2658     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2659 }
2660
2661 sub gv_or_padgv {
2662     my $self = shift;
2663     my $op = shift;
2664     if (class($op) eq "PADOP") {
2665         return $self->padval($op->padix);
2666     } else { # class($op) eq "SVOP"
2667         return $op->gv;
2668     }
2669 }
2670
2671 sub pp_gvsv {
2672     my $self = shift;
2673     my($op, $cx) = @_;
2674     my $gv = $self->gv_or_padgv($op);
2675     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2676                                  $self->gv_name($gv)));
2677 }
2678
2679 sub pp_gv {
2680     my $self = shift;
2681     my($op, $cx) = @_;
2682     my $gv = $self->gv_or_padgv($op);
2683     return $self->gv_name($gv);
2684 }
2685
2686 sub pp_aelemfast {
2687     my $self = shift;
2688     my($op, $cx) = @_;
2689     my $gv = $self->gv_or_padgv($op);
2690     my $name = $self->gv_name($gv);
2691     $name = $self->{'curstash'}."::$name"
2692         if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2693
2694     return "\$" . $name . "[" .
2695                   ($op->private + $self->{'arybase'}) . "]";
2696 }
2697
2698 sub rv2x {
2699     my $self = shift;
2700     my($op, $cx, $type) = @_;
2701
2702     if (class($op) eq 'NULL' || !$op->can("first")) {
2703         carp("Unexpected op in pp_rv2x");
2704         return 'XXX';
2705     }
2706     my $kid = $op->first;
2707     if ($kid->name eq "gv") {
2708         return $self->stash_variable($type, $self->deparse($kid, 0));
2709     } elsif (is_scalar $kid) {
2710         my $str = $self->deparse($kid, 0);
2711         if ($str =~ /^\$([^\w\d])\z/) {
2712             # "$$+" isn't a legal way to write the scalar dereference
2713             # of $+, since the lexer can't tell you aren't trying to
2714             # do something like "$$ + 1" to get one more than your
2715             # PID. Either "${$+}" or "$${+}" are workable
2716             # disambiguations, but if the programmer did the former,
2717             # they'd be in the "else" clause below rather than here.
2718             # It's not clear if this should somehow be unified with
2719             # the code in dq and re_dq that also adds lexer
2720             # disambiguation braces.
2721             $str = '$' . "{$1}"; #'
2722         }
2723         return $type . $str;
2724     } else {
2725         return $type . "{" . $self->deparse($kid, 0) . "}";
2726     }
2727 }
2728
2729 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
2730 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
2731 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
2732
2733 # skip rv2av
2734 sub pp_av2arylen {
2735     my $self = shift;
2736     my($op, $cx) = @_;
2737     if ($op->first->name eq "padav") {
2738         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
2739     } else {
2740         return $self->maybe_local($op, $cx,
2741                                   $self->rv2x($op->first, $cx, '$#'));
2742     }
2743 }
2744
2745 # skip down to the old, ex-rv2cv
2746 sub pp_rv2cv {
2747     my ($self, $op, $cx) = @_;
2748     if (!null($op->first) && $op->first->name eq 'null' &&
2749         $op->first->targ eq OP_LIST)
2750     {
2751         return $self->rv2x($op->first->first->sibling, $cx, "&")
2752     }
2753     else {
2754         return $self->rv2x($op, $cx, "")
2755     }
2756 }
2757
2758 sub list_const {
2759     my $self = shift;
2760     my($cx, @list) = @_;
2761     my @a = map $self->const($_, 6), @list;
2762     if (@a == 0) {
2763         return "()";
2764     } elsif (@a == 1) {
2765         return $a[0];
2766     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
2767         # collapse (-1,0,1,2) into (-1..2)
2768         my ($s, $e) = @a[0,-1];
2769         my $i = $s;
2770         return $self->maybe_parens("$s..$e", $cx, 9)
2771           unless grep $i++ != $_, @a;
2772     }
2773     return $self->maybe_parens(join(", ", @a), $cx, 6);
2774 }
2775
2776 sub pp_rv2av {
2777     my $self = shift;
2778     my($op, $cx) = @_;
2779     my $kid = $op->first;
2780     if ($kid->name eq "const") { # constant list
2781         my $av = $self->const_sv($kid);
2782         return $self->list_const($cx, $av->ARRAY);
2783     } else {
2784         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
2785     }
2786  }
2787
2788 sub is_subscriptable {
2789     my $op = shift;
2790     if ($op->name =~ /^[ahg]elem/) {
2791         return 1;
2792     } elsif ($op->name eq "entersub") {
2793         my $kid = $op->first;
2794         return 0 unless null $kid->sibling;
2795         $kid = $kid->first;
2796         $kid = $kid->sibling until null $kid->sibling;
2797         return 0 if is_scope($kid);
2798         $kid = $kid->first;
2799         return 0 if $kid->name eq "gv";
2800         return 0 if is_scalar($kid);
2801         return is_subscriptable($kid);
2802     } else {
2803         return 0;
2804     }
2805 }
2806
2807 sub elem {
2808     my $self = shift;
2809     my ($op, $cx, $left, $right, $padname) = @_;
2810     my($array, $idx) = ($op->first, $op->first->sibling);
2811     unless ($array->name eq $padname) { # Maybe this has been fixed
2812         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
2813     }
2814     if ($array->name eq $padname) {
2815         $array = $self->padany($array);
2816     } elsif (is_scope($array)) { # ${expr}[0]
2817         $array = "{" . $self->deparse($array, 0) . "}";
2818     } elsif ($array->name eq "gv") {
2819         $array = $self->gv_name($self->gv_or_padgv($array));
2820         if ($array !~ /::/) {
2821             my $prefix = ($left eq '[' ? '@' : '%');
2822             $array = $self->{curstash}.'::'.$array
2823                 if $self->lex_in_scope($prefix . $array);
2824         }
2825     } elsif (is_scalar $array) { # $x[0], $$x[0], ...
2826         $array = $self->deparse($array, 24);
2827     } else {
2828         # $x[20][3]{hi} or expr->[20]
2829         my $arrow = is_subscriptable($array) ? "" : "->";
2830         return $self->deparse($array, 24) . $arrow .
2831             $left . $self->deparse($idx, 1) . $right;
2832     }
2833     $idx = $self->deparse($idx, 1);
2834
2835     # Outer parens in an array index will confuse perl
2836     # if we're interpolating in a regular expression, i.e.
2837     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
2838     #
2839     # If $self->{parens}, then an initial '(' will
2840     # definitely be paired with a final ')'. If
2841     # !$self->{parens}, the misleading parens won't
2842     # have been added in the first place.
2843     #
2844     # [You might think that we could get "(...)...(...)"
2845     # where the initial and final parens do not match
2846     # each other. But we can't, because the above would
2847     # only happen if there's an infix binop between the
2848     # two pairs of parens, and *that* means that the whole
2849     # expression would be parenthesized as well.]
2850     #
2851     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
2852
2853     # Hash-element braces will autoquote a bareword inside themselves.
2854     # We need to make sure that C<$hash{warn()}> doesn't come out as
2855     # C<$hash{warn}>, which has a quite different meaning. Currently
2856     # B::Deparse will always quote strings, even if the string was a
2857     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
2858     # for constant strings.) So we can cheat slightly here - if we see
2859     # a bareword, we know that it is supposed to be a function call.
2860     #
2861     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
2862
2863     return "\$" . $array . $left . $idx . $right;
2864 }
2865
2866 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
2867 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
2868
2869 sub pp_gelem {
2870     my $self = shift;
2871     my($op, $cx) = @_;
2872     my($glob, $part) = ($op->first, $op->last);
2873     $glob = $glob->first; # skip rv2gv
2874     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
2875     my $scope = is_scope($glob);
2876     $glob = $self->deparse($glob, 0);
2877     $part = $self->deparse($part, 1);
2878     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
2879 }
2880
2881 sub slice {
2882     my $self = shift;
2883     my ($op, $cx, $left, $right, $regname, $padname) = @_;
2884     my $last;
2885     my(@elems, $kid, $array, $list);
2886     if (class($op) eq "LISTOP") {
2887         $last = $op->last;
2888     } else { # ex-hslice inside delete()
2889         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
2890         $last = $kid;
2891     }
2892     $array = $last;
2893     $array = $array->first
2894         if $array->name eq $regname or $array->name eq "null";
2895     if (is_scope($array)) {
2896         $array = "{" . $self->deparse($array, 0) . "}";
2897     } elsif ($array->name eq $padname) {
2898         $array = $self->padany($array);
2899     } else {
2900         $array = $self->deparse($array, 24);
2901     }
2902     $kid = $op->first->sibling; # skip pushmark
2903     if ($kid->name eq "list") {
2904         $kid = $kid->first->sibling; # skip list, pushmark
2905         for (; !null $kid; $kid = $kid->sibling) {
2906             push @elems, $self->deparse($kid, 6);
2907         }
2908         $list = join(", ", @elems);
2909     } else {
2910         $list = $self->deparse($kid, 1);
2911     }
2912     return "\@" . $array . $left . $list . $right;
2913 }
2914
2915 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
2916 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
2917
2918 sub pp_lslice {
2919     my $self = shift;
2920     my($op, $cx) = @_;
2921     my $idx = $op->first;
2922     my $list = $op->last;
2923     my(@elems, $kid);
2924     $list = $self->deparse($list, 1);
2925     $idx = $self->deparse($idx, 1);
2926     return "($list)" . "[$idx]";
2927 }
2928
2929 sub want_scalar {
2930     my $op = shift;
2931     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
2932 }
2933
2934 sub want_list {
2935     my $op = shift;
2936     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
2937 }
2938
2939 sub method {
2940     my $self = shift;
2941     my($op, $cx) = @_;
2942     my $kid = $op->first->sibling; # skip pushmark
2943     my($meth, $obj, @exprs);
2944     if ($kid->name eq "list" and want_list $kid) {
2945         # When an indirect object isn't a bareword but the args are in
2946         # parens, the parens aren't part of the method syntax (the LLAFR
2947         # doesn't apply), but they make a list with OPf_PARENS set that
2948         # doesn't get flattened by the append_elem that adds the method,
2949         # making a (object, arg1, arg2, ...) list where the object
2950         # usually is. This can be distinguished from
2951         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
2952         # object) because in the later the list is in scalar context
2953         # as the left side of -> always is, while in the former
2954         # the list is in list context as method arguments always are.
2955         # (Good thing there aren't method prototypes!)
2956         $meth = $kid->sibling;
2957         $kid = $kid->first->sibling; # skip pushmark
2958         $obj = $kid;
2959         $kid = $kid->sibling;
2960         for (; not null $kid; $kid = $kid->sibling) {
2961             push @exprs, $self->deparse($kid, 6);
2962         }
2963     } else {
2964         $obj = $kid;
2965         $kid = $kid->sibling;
2966         for (; !null ($kid->sibling) && $kid->name ne "method_named";
2967               $kid = $kid->sibling) {
2968             push @exprs, $self->deparse($kid, 6);
2969         }
2970         $meth = $kid;
2971     }
2972     $obj = $self->deparse($obj, 24);
2973     if ($meth->name eq "method_named") {
2974         $meth = $self->const_sv($meth)->PV;
2975     } else {
2976         $meth = $meth->first;
2977         if ($meth->name eq "const") {
2978             # As of 5.005_58, this case is probably obsoleted by the
2979             # method_named case above
2980             $meth = $self->const_sv($meth)->PV; # needs to be bare
2981         } else {
2982             $meth = $self->deparse($meth, 1);
2983         }
2984     }
2985     my $args = join(", ", @exprs);
2986     $kid = $obj . "->" . $meth;
2987     if (length $args) {
2988         return $kid . "(" . $args . ")"; # parens mandatory
2989     } else {
2990         return $kid;
2991     }
2992 }
2993
2994 # returns "&" if the prototype doesn't match the args,
2995 # or ("", $args_after_prototype_demunging) if it does.
2996 sub check_proto {
2997     my $self = shift;
2998     return "&" if $self->{'noproto'};
2999     my($proto, @args) = @_;
3000     my($arg, $real);
3001     my $doneok = 0;
3002     my @reals;
3003     # An unbackslashed @ or % gobbles up the rest of the args
3004     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3005     while ($proto) {
3006         $proto =~ s/^(\\?[\$\@&%*]|\\\[[\$\@&%*]+\]|;)//;
3007         my $chr = $1;
3008         if ($chr eq "") {
3009             return "&" if @args;
3010         } elsif ($chr eq ";") {
3011             $doneok = 1;
3012         } elsif ($chr eq "@" or $chr eq "%") {
3013             push @reals, map($self->deparse($_, 6), @args);
3014             @args = ();
3015         } else {
3016             $arg = shift @args;
3017             last unless $arg;
3018             if ($chr eq "\$") {
3019                 if (want_scalar $arg) {
3020                     push @reals, $self->deparse($arg, 6);
3021                 } else {
3022                     return "&";
3023                 }
3024             } elsif ($chr eq "&") {
3025                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3026                     push @reals, $self->deparse($arg, 6);
3027                 } else {
3028                     return "&";
3029                 }
3030             } elsif ($chr eq "*") {
3031                 if ($arg->name =~ /^s?refgen$/
3032                     and $arg->first->first->name eq "rv2gv")
3033                   {
3034                       $real = $arg->first->first; # skip refgen, null
3035                       if ($real->first->name eq "gv") {
3036                           push @reals, $self->deparse($real, 6);
3037                       } else {
3038                           push @reals, $self->deparse($real->first, 6);
3039                       }
3040                   } else {
3041                       return "&";
3042                   }
3043             } elsif (substr($chr, 0, 1) eq "\\") {
3044                 $chr =~ tr/\\[]//d;
3045                 if ($arg->name =~ /^s?refgen$/ and
3046                     !null($real = $arg->first) and
3047                     ($chr =~ /\$/ && is_scalar($real->first)
3048                      or ($chr =~ /@/
3049                          && class($real->first->sibling) ne 'NULL'
3050                          && $real->first->sibling->name
3051                          =~ /^(rv2|pad)av$/)
3052                      or ($chr =~ /%/
3053                          && class($real->first->sibling) ne 'NULL'
3054                          && $real->first->sibling->name
3055                          =~ /^(rv2|pad)hv$/)
3056                      #or ($chr =~ /&/ # This doesn't work
3057                      #   && $real->first->name eq "rv2cv")
3058                      or ($chr =~ /\*/
3059                          && $real->first->name eq "rv2gv")))
3060                   {
3061                       push @reals, $self->deparse($real, 6);
3062                   } else {
3063                       return "&";
3064                   }
3065             }
3066        }
3067     }
3068     return "&" if $proto and !$doneok; # too few args and no `;'
3069     return "&" if @args;               # too many args
3070     return ("", join ", ", @reals);
3071 }
3072
3073 sub pp_entersub {
3074     my $self = shift;
3075     my($op, $cx) = @_;
3076     return $self->method($op, $cx) unless null $op->first->sibling;
3077     my $prefix = "";
3078     my $amper = "";
3079     my($kid, @exprs);
3080     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3081         $prefix = "do ";
3082     } elsif ($op->private & OPpENTERSUB_AMPER) {
3083         $amper = "&";
3084     }
3085     $kid = $op->first;
3086     $kid = $kid->first->sibling; # skip ex-list, pushmark
3087     for (; not null $kid->sibling; $kid = $kid->sibling) {
3088         push @exprs, $kid;
3089     }
3090     my $simple = 0;
3091     my $proto = undef;
3092     if (is_scope($kid)) {
3093         $amper = "&";
3094         $kid = "{" . $self->deparse($kid, 0) . "}";
3095     } elsif ($kid->first->name eq "gv") {
3096         my $gv = $self->gv_or_padgv($kid->first);
3097         if (class($gv->CV) ne "SPECIAL") {
3098             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3099         }
3100         $simple = 1; # only calls of named functions can be prototyped
3101         $kid = $self->deparse($kid, 24);
3102     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3103         $amper = "&";
3104         $kid = $self->deparse($kid, 24);
3105     } else {
3106         $prefix = "";
3107         my $arrow = is_subscriptable($kid->first) ? "" : "->";
3108         $kid = $self->deparse($kid, 24) . $arrow;
3109     }
3110
3111     # Doesn't matter how many prototypes there are, if
3112     # they haven't happened yet!
3113     my $declared;
3114     {
3115         no strict 'refs';
3116         no warnings 'uninitialized';
3117         $declared = exists $self->{'subs_declared'}{$kid}
3118             || (
3119                  defined &{ %{$self->{'curstash'}."::"}->{$kid} }
3120                  && !exists
3121                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3122                  && defined prototype $self->{'curstash'}."::".$kid
3123                );
3124         if (!$declared && defined($proto)) {
3125             # Avoid "too early to check prototype" warning
3126             ($amper, $proto) = ('&');
3127         }
3128     }
3129
3130     my $args;
3131     if ($declared and defined $proto and not $amper) {
3132         ($amper, $args) = $self->check_proto($proto, @exprs);
3133         if ($amper eq "&") {
3134             $args = join(", ", map($self->deparse($_, 6), @exprs));
3135         }
3136     } else {
3137         $args = join(", ", map($self->deparse($_, 6), @exprs));
3138     }
3139     if ($prefix or $amper) {
3140         if ($op->flags & OPf_STACKED) {
3141             return $prefix . $amper . $kid . "(" . $args . ")";
3142         } else {
3143             return $prefix . $amper. $kid;
3144         }
3145     } else {
3146         # glob() invocations can be translated into calls of
3147         # CORE::GLOBAL::glob with a second parameter, a number.
3148         # Reverse this.
3149         if ($kid eq "CORE::GLOBAL::glob") {
3150             $kid = "glob";
3151             $args =~ s/\s*,[^,]+$//;
3152         }
3153
3154         # It's a syntax error to call CORE::GLOBAL::foo without a prefix,
3155         # so it must have been translated from a keyword call. Translate
3156         # it back.
3157         $kid =~ s/^CORE::GLOBAL:://;
3158
3159         my $dproto = defined($proto) ? $proto : "undefined";
3160         if (!$declared) {
3161             return "$kid(" . $args . ")";
3162         } elsif ($dproto eq "") {
3163             return $kid;
3164         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3165             # is_scalar is an excessively conservative test here:
3166             # really, we should be comparing to the precedence of the
3167             # top operator of $exprs[0] (ala unop()), but that would
3168             # take some major code restructuring to do right.
3169             return $self->maybe_parens_func($kid, $args, $cx, 16);
3170         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3171             return $self->maybe_parens_func($kid, $args, $cx, 5);
3172         } else {
3173             return "$kid(" . $args . ")";
3174         }
3175     }
3176 }
3177
3178 sub pp_enterwrite { unop(@_, "write") }
3179
3180 # escape things that cause interpolation in double quotes,
3181 # but not character escapes
3182 sub uninterp {
3183     my($str) = @_;
3184     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3185     return $str;
3186 }
3187
3188 {
3189 my $bal;
3190 BEGIN {
3191     use re "eval";
3192     # Matches any string which is balanced with respect to {braces}
3193     $bal = qr(
3194       (?:
3195         [^\\{}]
3196       | \\\\
3197       | \\[{}]
3198       | \{(??{$bal})\}
3199       )*
3200     )x;
3201 }
3202
3203 # the same, but treat $|, $), $( and $ at the end of the string differently
3204 sub re_uninterp {
3205     my($str) = @_;
3206
3207     $str =~ s/
3208           ( ^|\G                  # $1
3209           | [^\\]
3210           )
3211
3212           (                       # $2
3213             (?:\\\\)*
3214           )
3215
3216           (                       # $3
3217             (\(\?\??\{$bal\}\))   # $4
3218           | [\$\@]
3219             (?!\||\)|\(|$)
3220           | \\[uUlLQE]
3221           )
3222
3223         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3224
3225     return $str;
3226 }
3227
3228 # This is for regular expressions with the /x modifier
3229 # We have to leave comments unmangled.
3230 sub re_uninterp_extended {
3231     my($str) = @_;
3232
3233     $str =~ s/
3234           ( ^|\G                  # $1
3235           | [^\\]
3236           )
3237
3238           (                       # $2
3239             (?:\\\\)*
3240           )
3241
3242           (                       # $3
3243             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3244             | \#[^\n]*            #     (skip over comments)
3245             )
3246           | [\$\@]
3247             (?!\||\)|\(|$|\s)
3248           | \\[uUlLQE]
3249           )
3250
3251         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3252
3253     return $str;
3254 }
3255 }
3256
3257 my %unctrl = # portable to to EBCDIC
3258     (
3259      "\c@" => '\c@',    # unused
3260      "\cA" => '\cA',
3261      "\cB" => '\cB',
3262      "\cC" => '\cC',
3263      "\cD" => '\cD',
3264      "\cE" => '\cE',
3265      "\cF" => '\cF',
3266      "\cG" => '\cG',
3267      "\cH" => '\cH',
3268      "\cI" => '\cI',
3269      "\cJ" => '\cJ',
3270      "\cK" => '\cK',
3271      "\cL" => '\cL',
3272      "\cM" => '\cM',
3273      "\cN" => '\cN',
3274      "\cO" => '\cO',
3275      "\cP" => '\cP',
3276      "\cQ" => '\cQ',
3277      "\cR" => '\cR',
3278      "\cS" => '\cS',
3279      "\cT" => '\cT',
3280      "\cU" => '\cU',
3281      "\cV" => '\cV',
3282      "\cW" => '\cW',
3283      "\cX" => '\cX',
3284      "\cY" => '\cY',
3285      "\cZ" => '\cZ',
3286      "\c[" => '\c[',    # unused
3287      "\c\\" => '\c\\',  # unused
3288      "\c]" => '\c]',    # unused
3289      "\c_" => '\c_',    # unused
3290     );
3291
3292 # character escapes, but not delimiters that might need to be escaped
3293 sub escape_str { # ASCII, UTF8
3294     my($str) = @_;
3295     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3296     $str =~ s/\a/\\a/g;
3297 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3298     $str =~ s/\t/\\t/g;
3299     $str =~ s/\n/\\n/g;
3300     $str =~ s/\e/\\e/g;
3301     $str =~ s/\f/\\f/g;
3302     $str =~ s/\r/\\r/g;
3303     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3304     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3305     return $str;
3306 }
3307
3308 # For regexes with the /x modifier.
3309 # Leave whitespace unmangled.
3310 sub escape_extended_re {
3311     my($str) = @_;
3312     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3313     $str =~ s/([[:^print:]])/
3314         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3315     $str =~ s/\n/\n\f/g;
3316     return $str;
3317 }
3318
3319 # Don't do this for regexen
3320 sub unback {
3321     my($str) = @_;
3322     $str =~ s/\\/\\\\/g;
3323     return $str;
3324 }
3325
3326 # Remove backslashes which precede literal control characters,
3327 # to avoid creating ambiguity when we escape the latter.
3328 sub re_unback {
3329     my($str) = @_;
3330
3331     # the insane complexity here is due to the behaviour of "\c\"
3332     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3333     return $str;
3334 }
3335
3336 sub balanced_delim {
3337     my($str) = @_;
3338     my @str = split //, $str;
3339     my($ar, $open, $close, $fail, $c, $cnt);
3340     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3341         ($open, $close) = @$ar;
3342         $fail = 0; $cnt = 0;
3343         for $c (@str) {
3344             if ($c eq $open) {
3345                 $cnt++;
3346             } elsif ($c eq $close) {
3347                 $cnt--;
3348                 if ($cnt < 0) {
3349                     # qq()() isn't ")("
3350                     $fail = 1;
3351                     last;
3352                 }
3353             }
3354         }
3355         $fail = 1 if $cnt != 0;
3356         return ($open, "$open$str$close") if not $fail;
3357     }
3358     return ("", $str);
3359 }
3360
3361 sub single_delim {
3362     my($q, $default, $str) = @_;
3363     return "$default$str$default" if $default and index($str, $default) == -1;
3364     if ($q ne 'qr') {
3365         (my $succeed, $str) = balanced_delim($str);
3366         return "$q$str" if $succeed;
3367     }
3368     for my $delim ('/', '"', '#') {
3369         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3370     }
3371     if ($default) {
3372         $str =~ s/$default/\\$default/g;
3373         return "$default$str$default";
3374     } else {
3375         $str =~ s[/][\\/]g;
3376         return "$q/$str/";
3377     }
3378 }
3379
3380 my $max_prec;
3381 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
3382
3383 # Split a floating point number into an integer mantissa and a binary
3384 # exponent. Assumes you've already made sure the number isn't zero or
3385 # some weird infinity or NaN.
3386 sub split_float {
3387     my($f) = @_;
3388     my $exponent = 0;
3389     if ($f == int($f)) {
3390         while ($f % 2 == 0) {
3391             $f /= 2;
3392             $exponent++;
3393         }
3394     } else {
3395         while ($f != int($f)) {
3396             $f *= 2;
3397             $exponent--;
3398         }
3399     }
3400     my $mantissa = sprintf("%.0f", $f);
3401     return ($mantissa, $exponent);
3402 }
3403
3404 sub const {
3405     my $self = shift;
3406     my($sv, $cx) = @_;
3407     if ($self->{'use_dumper'}) {
3408         return $self->const_dumper($sv, $cx);
3409     }
3410     if (class($sv) eq "SPECIAL") {
3411         # sv_undef, sv_yes, sv_no
3412         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
3413     } elsif (class($sv) eq "NULL") {
3414        return 'undef';
3415     }
3416     # convert a version object into the "v1.2.3" string in its V magic
3417     if ($sv->FLAGS & SVs_RMG) {
3418         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3419             return $mg->PTR if $mg->TYPE eq 'V';
3420         }
3421     }
3422
3423     if ($sv->FLAGS & SVf_IOK) {
3424         my $str = $sv->int_value;
3425         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
3426         return $str;
3427     } elsif ($sv->FLAGS & SVf_NOK) {
3428         my $nv = $sv->NV;
3429         if ($nv == 0) {
3430             if (pack("F", $nv) eq pack("F", 0)) {
3431                 # positive zero
3432                 return "0";
3433             } else {
3434                 # negative zero
3435                 return $self->maybe_parens("-.0", $cx, 21);
3436             }
3437         } elsif (1/$nv == 0) {
3438             if ($nv > 0) {
3439                 # positive infinity
3440                 return $self->maybe_parens("9**9**9", $cx, 22);
3441             } else {
3442                 # negative infinity
3443                 return $self->maybe_parens("-9**9**9", $cx, 21);
3444             }
3445         } elsif ($nv != $nv) {
3446             # NaN
3447             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
3448                 # the normal kind
3449                 return "sin(9**9**9)";
3450             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
3451                 # the inverted kind
3452                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
3453             } else {
3454                 # some other kind
3455                 my $hex = unpack("h*", pack("F", $nv));
3456                 return qq'unpack("F", pack("h*", "$hex"))';
3457             }
3458         }
3459         # first, try the default stringification
3460         my $str = "$nv";
3461         if ($str != $nv) {
3462             # failing that, try using more precision
3463             $str = sprintf("%.${max_prec}g", $nv);
3464 #           if (pack("F", $str) ne pack("F", $nv)) {
3465             if ($str != $nv) {
3466                 # not representable in decimal with whatever sprintf()
3467                 # and atof() Perl is using here.
3468                 my($mant, $exp) = split_float($nv);
3469                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
3470             }
3471         }
3472         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
3473         return $str;
3474     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3475         my $ref = $sv->RV;
3476         if (class($ref) eq "AV") {
3477             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
3478         } elsif (class($ref) eq "HV") {
3479             my %hash = $ref->ARRAY;
3480             my @elts;
3481             for my $k (sort keys %hash) {
3482                 push @elts, "$k => " . $self->const($hash{$k}, 6);
3483             }
3484             return "{" . join(", ", @elts) . "}";
3485         } elsif (class($ref) eq "CV") {
3486             return "sub " . $self->deparse_sub($ref);
3487         }
3488         if ($ref->FLAGS & SVs_SMG) {
3489             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3490                 if ($mg->TYPE eq 'r') {
3491                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
3492                     return single_delim("qr", "", $re);
3493                 }
3494             }
3495         }
3496
3497         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
3498     } elsif ($sv->FLAGS & SVf_POK) {
3499         my $str = $sv->PV;
3500         if ($str =~ /[^ -~]/) { # ASCII for non-printing
3501             return single_delim("qq", '"', uninterp escape_str unback $str);
3502         } else {
3503             return single_delim("q", "'", unback $str);
3504         }
3505     } else {
3506         return "undef";
3507     }
3508 }
3509
3510 sub const_dumper {
3511     my $self = shift;
3512     my($sv, $cx) = @_;
3513     my $ref = $sv->object_2svref();
3514     my $dumper = Data::Dumper->new([$$ref], ['$v']);
3515     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
3516     my $str = $dumper->Dump();
3517     if ($str =~ /^\$v/) {
3518         return '${my ' . $str . ' \$v}';
3519     } else {
3520         return $str;
3521     }
3522 }
3523
3524 sub const_sv {
3525     my $self = shift;
3526     my $op = shift;
3527     my $sv = $op->sv;
3528     # the constant could be in the pad (under useithreads)
3529     $sv = $self->padval($op->targ) unless $$sv;
3530     return $sv;
3531 }
3532
3533 sub pp_const {
3534     my $self = shift;
3535     my($op, $cx) = @_;
3536     if ($op->private & OPpCONST_ARYBASE) {
3537         return '$[';
3538     }
3539 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting
3540 #       return $self->const_sv($op)->PV;
3541 #    }
3542     my $sv = $self->const_sv($op);
3543     return $self->const($sv, $cx);
3544 }
3545
3546 sub dq {
3547     my $self = shift;
3548     my $op = shift;
3549     my $type = $op->name;
3550     if ($type eq "const") {
3551         return '$[' if $op->private & OPpCONST_ARYBASE;
3552         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3553     } elsif ($type eq "concat") {
3554         my $first = $self->dq($op->first);
3555         my $last  = $self->dq($op->last);
3556
3557         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
3558         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3559             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3560             || ($last =~ /^[:'{\[\w_]/ && #'
3561                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3562
3563         return $first . $last;
3564     } elsif ($type eq "uc") {
3565         return '\U' . $self->dq($op->first->sibling) . '\E';
3566     } elsif ($type eq "lc") {
3567         return '\L' . $self->dq($op->first->sibling) . '\E';
3568     } elsif ($type eq "ucfirst") {
3569         return '\u' . $self->dq($op->first->sibling);
3570     } elsif ($type eq "lcfirst") {
3571         return '\l' . $self->dq($op->first->sibling);
3572     } elsif ($type eq "quotemeta") {
3573         return '\Q' . $self->dq($op->first->sibling) . '\E';
3574     } elsif ($type eq "join") {
3575         return $self->deparse($op->last, 26); # was join($", @ary)
3576     } else {
3577         return $self->deparse($op, 26);
3578     }
3579 }
3580
3581 sub pp_backtick {
3582     my $self = shift;
3583     my($op, $cx) = @_;
3584     # skip pushmark
3585     return single_delim("qx", '`', $self->dq($op->first->sibling));
3586 }
3587
3588 sub dquote {
3589     my $self = shift;
3590     my($op, $cx) = @_;
3591     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3592     return $self->deparse($kid, $cx) if $self->{'unquote'};
3593     $self->maybe_targmy($kid, $cx,
3594                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3595 }
3596
3597 # OP_STRINGIFY is a listop, but it only ever has one arg
3598 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3599
3600 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3601 # note that tr(from)/to/ is OK, but not tr/from/(to)
3602 sub double_delim {
3603     my($from, $to) = @_;
3604     my($succeed, $delim);
3605     if ($from !~ m[/] and $to !~ m[/]) {
3606         return "/$from/$to/";
3607     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3608         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3609             return "$from$to";
3610         } else {
3611             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3612                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3613             }
3614             $to =~ s[/][\\/]g;
3615             return "$from/$to/";
3616         }
3617     } else {
3618         for $delim ('/', '"', '#') { # note no '
3619             return "$delim$from$delim$to$delim"
3620                 if index($to . $from, $delim) == -1;
3621         }
3622         $from =~ s[/][\\/]g;
3623         $to =~ s[/][\\/]g;
3624         return "/$from/$to/";
3625     }
3626 }
3627
3628 # Only used by tr///, so backslashes hyphens
3629 sub pchr { # ASCII
3630     my($n) = @_;
3631     if ($n == ord '\\') {
3632         return '\\\\';
3633     } elsif ($n == ord "-") {
3634         return "\\-";
3635     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3636         return chr($n);
3637     } elsif ($n == ord "\a") {
3638         return '\\a';
3639     } elsif ($n == ord "\b") {
3640         return '\\b';
3641     } elsif ($n == ord "\t") {
3642         return '\\t';
3643     } elsif ($n == ord "\n") {
3644         return '\\n';
3645     } elsif ($n == ord "\e") {
3646         return '\\e';
3647     } elsif ($n == ord "\f") {
3648         return '\\f';
3649     } elsif ($n == ord "\r") {
3650         return '\\r';
3651     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3652         return '\\c' . chr(ord("@") + $n);
3653     } else {
3654 #       return '\x' . sprintf("%02x", $n);
3655         return '\\' . sprintf("%03o", $n);
3656     }
3657 }
3658
3659 sub collapse {
3660     my(@chars) = @_;
3661     my($str, $c, $tr) = ("");
3662     for ($c = 0; $c < @chars; $c++) {
3663         $tr = $chars[$c];
3664         $str .= pchr($tr);
3665         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3666             $chars[$c + 2] == $tr + 2)
3667         {
3668             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3669               {}
3670             $str .= "-";
3671             $str .= pchr($chars[$c]);
3672         }
3673     }
3674     return $str;
3675 }
3676
3677 sub tr_decode_byte {
3678     my($table, $flags) = @_;
3679     my(@table) = unpack("s*", $table);
3680     splice @table, 0x100, 1;   # Number of subsequent elements
3681     my($c, $tr, @from, @to, @delfrom, $delhyphen);
3682     if ($table[ord "-"] != -1 and
3683         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
3684     {
3685         $tr = $table[ord "-"];
3686         $table[ord "-"] = -1;
3687         if ($tr >= 0) {
3688             @from = ord("-");
3689             @to = $tr;
3690         } else { # -2 ==> delete
3691             $delhyphen = 1;
3692         }
3693     }
3694     for ($c = 0; $c < @table; $c++) {
3695         $tr = $table[$c];
3696         if ($tr >= 0) {
3697             push @from, $c; push @to, $tr;
3698         } elsif ($tr == -2) {
3699             push @delfrom, $c;
3700         }
3701     }
3702     @from = (@from, @delfrom);
3703     if ($flags & OPpTRANS_COMPLEMENT) {
3704         my @newfrom = ();
3705         my %from;
3706         @from{@from} = (1) x @from;
3707         for ($c = 0; $c < 256; $c++) {
3708             push @newfrom, $c unless $from{$c};
3709         }
3710         @from = @newfrom;
3711     }
3712     unless ($flags & OPpTRANS_DELETE || !@to) {
3713         pop @to while $#to and $to[$#to] == $to[$#to -1];
3714     }
3715     my($from, $to);
3716     $from = collapse(@from);
3717     $to = collapse(@to);
3718     $from .= "-" if $delhyphen;
3719     return ($from, $to);
3720 }
3721
3722 sub tr_chr {
3723     my $x = shift;
3724     if ($x == ord "-") {
3725         return "\\-";
3726     } elsif ($x == ord "\\") {
3727         return "\\\\";
3728     } else {
3729         return chr $x;
3730     }
3731 }
3732
3733 # XXX This doesn't yet handle all cases correctly either
3734
3735 sub tr_decode_utf8 {
3736     my($swash_hv, $flags) = @_;
3737     my %swash = $swash_hv->ARRAY;
3738     my $final = undef;
3739     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
3740     my $none = $swash{"NONE"}->IV;
3741     my $extra = $none + 1;
3742     my(@from, @delfrom, @to);
3743     my $line;
3744     foreach $line (split /\n/, $swash{'LIST'}->PV) {
3745         my($min, $max, $result) = split(/\t/, $line);
3746         $min = hex $min;
3747         if (length $max) {
3748             $max = hex $max;
3749         } else {
3750             $max = $min;
3751         }
3752         $result = hex $result;
3753         if ($result == $extra) {
3754             push @delfrom, [$min, $max];
3755         } else {
3756             push @from, [$min, $max];
3757             push @to, [$result, $result + $max - $min];
3758         }
3759     }
3760     for my $i (0 .. $#from) {
3761         if ($from[$i][0] == ord '-') {
3762             unshift @from, splice(@from, $i, 1);
3763             unshift @to, splice(@to, $i, 1);
3764             last;
3765         } elsif ($from[$i][1] == ord '-') {
3766             $from[$i][1]--;
3767             $to[$i][1]--;
3768             unshift @from, ord '-';
3769             unshift @to, ord '-';
3770             last;
3771         }
3772     }
3773     for my $i (0 .. $#delfrom) {
3774         if ($delfrom[$i][0] == ord '-') {
3775             push @delfrom, splice(@delfrom, $i, 1);
3776             last;
3777         } elsif ($delfrom[$i][1] == ord '-') {
3778             $delfrom[$i][1]--;
3779             push @delfrom, ord '-';
3780             last;
3781         }
3782     }
3783     if (defined $final and $to[$#to][1] != $final) {
3784         push @to, [$final, $final];
3785     }
3786     push @from, @delfrom;
3787     if ($flags & OPpTRANS_COMPLEMENT) {
3788         my @newfrom;
3789         my $next = 0;
3790         for my $i (0 .. $#from) {
3791             push @newfrom, [$next, $from[$i][0] - 1];
3792             $next = $from[$i][1] + 1;
3793         }
3794         @from = ();
3795         for my $range (@newfrom) {
3796             if ($range->[0] <= $range->[1]) {
3797                 push @from, $range;
3798             }
3799         }
3800     }
3801     my($from, $to, $diff);
3802     for my $chunk (@from) {
3803         $diff = $chunk->[1] - $chunk->[0];
3804         if ($diff > 1) {
3805             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3806         } elsif ($diff == 1) {
3807             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3808         } else {
3809             $from .= tr_chr($chunk->[0]);
3810         }
3811     }
3812     for my $chunk (@to) {
3813         $diff = $chunk->[1] - $chunk->[0];
3814         if ($diff > 1) {
3815             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3816         } elsif ($diff == 1) {
3817             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3818         } else {
3819             $to .= tr_chr($chunk->[0]);
3820         }
3821     }
3822     #$final = sprintf("%04x", $final) if defined $final;
3823     #$none = sprintf("%04x", $none) if defined $none;
3824     #$extra = sprintf("%04x", $extra) if defined $extra;
3825     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
3826     #print STDERR $swash{'LIST'}->PV;
3827     return (escape_str($from), escape_str($to));
3828 }
3829
3830 sub pp_trans {
3831     my $self = shift;
3832     my($op, $cx) = @_;
3833     my($from, $to);
3834     if (class($op) eq "PVOP") {
3835         ($from, $to) = tr_decode_byte($op->pv, $op->private);
3836     } else { # class($op) eq "SVOP"
3837         ($from, $to) = tr_decode_utf8($op->sv->RV, $op->private);
3838     }
3839     my $flags = "";
3840     $flags .= "c" if $op->private & OPpTRANS_COMPLEMENT;
3841     $flags .= "d" if $op->private & OPpTRANS_DELETE;
3842     $to = "" if $from eq $to and $flags eq "";
3843     $flags .= "s" if $op->private & OPpTRANS_SQUASH;
3844     return "tr" . double_delim($from, $to) . $flags;
3845 }
3846
3847 # Like dq(), but different
3848 sub re_dq {
3849     my $self = shift;
3850     my ($op, $extended) = @_;
3851
3852     my $type = $op->name;
3853     if ($type eq "const") {
3854         return '$[' if $op->private & OPpCONST_ARYBASE;
3855         my $unbacked = re_unback($self->const_sv($op)->as_string);
3856         return re_uninterp_extended(escape_extended_re($unbacked))
3857             if $extended;
3858         return re_uninterp(escape_str($unbacked));
3859     } elsif ($type eq "concat") {
3860         my $first = $self->re_dq($op->first, $extended);
3861         my $last  = $self->re_dq($op->last,  $extended);
3862
3863         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
3864         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3865             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3866             || ($last =~ /^[{\[\w_]/ &&
3867                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3868
3869         return $first . $last;
3870     } elsif ($type eq "uc") {
3871         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
3872     } elsif ($type eq "lc") {
3873         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
3874     } elsif ($type eq "ucfirst") {
3875         return '\u' . $self->re_dq($op->first->sibling, $extended);
3876     } elsif ($type eq "lcfirst") {
3877         return '\l' . $self->re_dq($op->first->sibling, $extended);
3878     } elsif ($type eq "quotemeta") {
3879         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
3880     } elsif ($type eq "join") {
3881         return $self->deparse($op->last, 26); # was join($", @ary)
3882     } else {
3883         return $self->deparse($op, 26);
3884     }
3885 }
3886
3887 sub pure_string {
3888     my ($self, $op) = @_;
3889     return 0 if null $op;
3890     my $type = $op->name;
3891
3892     if ($type eq 'const') {
3893         return 1;
3894     }
3895     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
3896         return $self->pure_string($op->first->sibling);
3897     }
3898     elsif ($type eq 'join') {
3899         my $join_op = $op->first->sibling;  # Skip pushmark
3900         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
3901
3902         my $gvop = $join_op->first;
3903         return 0 unless $gvop->name eq 'gvsv';
3904         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
3905
3906         return 0 unless ${$join_op->sibling} eq ${$op->last};
3907         return 0 unless $op->last->name =~ /^(rv2|pad)av$/;
3908     }
3909     elsif ($type eq 'concat') {
3910         return $self->pure_string($op->first)
3911             && $self->pure_string($op->last);
3912     }
3913     elsif (is_scalar($op) || $type =~ /^[ah]elem$/) {
3914         return 1;
3915     }
3916     elsif ($type eq "null" and $op->can('first') and not null $op->first and
3917            $op->first->name eq "null" and $op->first->can('first')
3918            and not null $op->first->first and
3919            $op->first->first->name eq "aelemfast") {
3920         return 1;
3921     }
3922     else {
3923         return 0;
3924     }
3925
3926     return 1;
3927 }
3928
3929 sub regcomp {
3930     my $self = shift;
3931     my($op, $cx, $extended) = @_;
3932     my $kid = $op->first;
3933     $kid = $kid->first if $kid->name eq "regcmaybe";
3934     $kid = $kid->first if $kid->name eq "regcreset";
3935     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
3936     return ($self->deparse($kid, $cx), 0);
3937 }
3938
3939 sub pp_regcomp {
3940     my ($self, $op, $cx) = @_;
3941     return (($self->regcomp($op, $cx, 0))[0]);
3942 }
3943
3944 # osmic acid -- see osmium tetroxide
3945
3946 my %matchwords;
3947 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
3948     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
3949     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
3950
3951 sub matchop {
3952     my $self = shift;
3953     my($op, $cx, $name, $delim) = @_;
3954     my $kid = $op->first;
3955     my ($binop, $var, $re) = ("", "", "");
3956     if ($op->flags & OPf_STACKED) {
3957         $binop = 1;
3958         $var = $self->deparse($kid, 20);
3959         $kid = $kid->sibling;
3960     }
3961     my $quote = 1;
3962     my $extended = ($op->pmflags & PMf_EXTENDED);
3963     if (null $kid) {
3964         my $unbacked = re_unback($op->precomp);
3965         if ($extended) {
3966             $re = re_uninterp_extended(escape_extended_re($unbacked));
3967         } else {
3968             $re = re_uninterp(escape_str(re_unback($op->precomp)));
3969         }
3970     } elsif ($kid->name ne 'regcomp') {
3971         carp("found ".$kid->name." where regcomp expected");
3972     } else {
3973         ($re, $quote) = $self->regcomp($kid, 21, $extended);
3974     }
3975     my $flags = "";
3976     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
3977     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
3978     $flags .= "i" if $op->pmflags & PMf_FOLD;
3979     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
3980     $flags .= "o" if $op->pmflags & PMf_KEEP;
3981     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
3982     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
3983     $flags = $matchwords{$flags} if $matchwords{$flags};
3984     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
3985         $re =~ s/\?/\\?/g;
3986         $re = "?$re?";
3987     } elsif ($quote) {
3988         $re = single_delim($name, $delim, $re);
3989     }
3990     $re = $re . $flags if $quote;
3991     if ($binop) {
3992         return $self->maybe_parens("$var =~ $re", $cx, 20);
3993     } else {
3994         return $re;
3995     }
3996 }
3997
3998 sub pp_match { matchop(@_, "m", "/") }
3999 sub pp_pushre { matchop(@_, "m", "/") }
4000 sub pp_qr { matchop(@_, "qr", "") }
4001
4002 sub pp_split {
4003     my $self = shift;
4004     my($op, $cx) = @_;
4005     my($kid, @exprs, $ary, $expr);
4006     $kid = $op->first;
4007
4008     # For our kid (an OP_PUSHRE), pmreplroot is never actually the
4009     # root of a replacement; it's either empty, or abused to point to
4010     # the GV for an array we split into (an optimization to save
4011     # assignment overhead). Depending on whether we're using ithreads,
4012     # this OP* holds either a GV* or a PADOFFSET. Luckily, B.xs
4013     # figures out for us which it is.
4014     my $replroot = $kid->pmreplroot;
4015     my $gv = 0;
4016     if (ref($replroot) eq "B::GV") {
4017         $gv = $replroot;
4018     } elsif (!ref($replroot) and $replroot > 0) {
4019         $gv = $self->padval($replroot);
4020     }
4021     $ary = $self->stash_variable('@', $self->gv_name($gv)) if $gv;
4022
4023     for (; !null($kid); $kid = $kid->sibling) {
4024         push @exprs, $self->deparse($kid, 6);
4025     }
4026
4027     # handle special case of split(), and split(" ") that compiles to /\s+/
4028     $kid = $op->first;
4029     if ($kid->flags & OPf_SPECIAL
4030         && $exprs[0] eq '/\\s+/'
4031         && $kid->pmflags & PMf_SKIPWHITE ) {
4032             $exprs[0] = '" "';
4033     }
4034
4035     $expr = "split(" . join(", ", @exprs) . ")";
4036     if ($ary) {
4037         return $self->maybe_parens("$ary = $expr", $cx, 7);
4038     } else {
4039         return $expr;
4040     }
4041 }
4042
4043 # oxime -- any of various compounds obtained chiefly by the action of
4044 # hydroxylamine on aldehydes and ketones and characterized by the
4045 # bivalent grouping C=NOH [Webster's Tenth]
4046
4047 my %substwords;
4048 map($substwords{join "", sort split //, $_} = $_, 'ego', 'egoism', 'em',
4049     'es', 'ex', 'exes', 'gee', 'go', 'goes', 'ie', 'ism', 'iso', 'me',
4050     'meese', 'meso', 'mig', 'mix', 'os', 'ox', 'oxime', 'see', 'seem',
4051     'seg', 'sex', 'sig', 'six', 'smog', 'sog', 'some', 'xi');
4052
4053 sub pp_subst {
4054     my $self = shift;
4055     my($op, $cx) = @_;
4056     my $kid = $op->first;
4057     my($binop, $var, $re, $repl) = ("", "", "", "");
4058     if ($op->flags & OPf_STACKED) {
4059         $binop = 1;
4060         $var = $self->deparse($kid, 20);
4061         $kid = $kid->sibling;
4062     }
4063     my $flags = "";
4064     if (null($op->pmreplroot)) {
4065         $repl = $self->dq($kid);
4066         $kid = $kid->sibling;
4067     } else {
4068         $repl = $op->pmreplroot->first; # skip substcont
4069         while ($repl->name eq "entereval") {
4070             $repl = $repl->first;
4071             $flags .= "e";
4072         }
4073         if ($op->pmflags & PMf_EVAL) {
4074             $repl = $self->deparse($repl->first, 0);
4075         } else {
4076             $repl = $self->dq($repl);
4077         }
4078     }
4079     my $extended = ($op->pmflags & PMf_EXTENDED);
4080     if (null $kid) {
4081         my $unbacked = re_unback($op->precomp);
4082         if ($extended) {
4083             $re = re_uninterp_extended(escape_extended_re($unbacked));
4084         }
4085         else {
4086             $re = re_uninterp(escape_str($unbacked));
4087         }
4088     } else {
4089         ($re) = $self->regcomp($kid, 1, $extended);
4090     }
4091     $flags .= "e" if $op->pmflags & PMf_EVAL;
4092     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4093     $flags .= "i" if $op->pmflags & PMf_FOLD;
4094     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4095     $flags .= "o" if $op->pmflags & PMf_KEEP;
4096     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4097     $flags .= "x" if $extended;
4098     $flags = $substwords{$flags} if $substwords{$flags};
4099     if ($binop) {
4100         return $self->maybe_parens("$var =~ s"
4101                                    . double_delim($re, $repl) . $flags,
4102                                    $cx, 20);
4103     } else {
4104         return "s". double_delim($re, $repl) . $flags;
4105     }
4106 }
4107
4108 1;
4109 __END__
4110
4111 =head1 NAME
4112
4113 B::Deparse - Perl compiler backend to produce perl code
4114
4115 =head1 SYNOPSIS
4116
4117 B<perl> B<-MO=Deparse>[B<,-d>][B<,-f>I<FILE>][B<,-p>][B<,-q>][B<,-l>]
4118         [B<,-s>I<LETTERS>][B<,-x>I<LEVEL>] I<prog.pl>
4119
4120 =head1 DESCRIPTION
4121
4122 B::Deparse is a backend module for the Perl compiler that generates
4123 perl source code, based on the internal compiled structure that perl
4124 itself creates after parsing a program. The output of B::Deparse won't
4125 be exactly the same as the original source, since perl doesn't keep
4126 track of comments or whitespace, and there isn't a one-to-one
4127 correspondence between perl's syntactical constructions and their
4128 compiled form, but it will often be close. When you use the B<-p>
4129 option, the output also includes parentheses even when they are not
4130 required by precedence, which can make it easy to see if perl is
4131 parsing your expressions the way you intended.
4132
4133 While B::Deparse goes to some lengths to try to figure out what your
4134 original program was doing, some parts of the language can still trip
4135 it up; it still fails even on some parts of Perl's own test suite. If
4136 you encounter a failure other than the most common ones described in
4137 the BUGS section below, you can help contribute to B::Deparse's
4138 ongoing development by submitting a bug report with a small
4139 example.
4140
4141 =head1 OPTIONS
4142
4143 As with all compiler backend options, these must follow directly after
4144 the '-MO=Deparse', separated by a comma but not any white space.
4145
4146 =over 4
4147
4148 =item B<-d>
4149
4150 Output data values (when they appear as constants) using Data::Dumper.
4151 Without this option, B::Deparse will use some simple routines of its
4152 own for the same purpose. Currently, Data::Dumper is better for some
4153 kinds of data (such as complex structures with sharing and
4154 self-reference) while the built-in routines are better for others
4155 (such as odd floating-point values).
4156
4157 =item B<-f>I<FILE>
4158
4159 Normally, B::Deparse deparses the main code of a program, and all the subs
4160 defined in the same file. To include subs defined in other files, pass the
4161 B<-f> option with the filename. You can pass the B<-f> option several times, to
4162 include more than one secondary file.  (Most of the time you don't want to
4163 use it at all.)  You can also use this option to include subs which are
4164 defined in the scope of a B<#line> directive with two parameters.
4165
4166 =item B<-l>
4167
4168 Add '#line' declarations to the output based on the line and file
4169 locations of the original code.
4170
4171 =item B<-p>
4172
4173 Print extra parentheses. Without this option, B::Deparse includes
4174 parentheses in its output only when they are needed, based on the
4175 structure of your program. With B<-p>, it uses parentheses (almost)
4176 whenever they would be legal. This can be useful if you are used to
4177 LISP, or if you want to see how perl parses your input. If you say
4178
4179     if ($var & 0x7f == 65) {print "Gimme an A!"}
4180     print ($which ? $a : $b), "\n";
4181     $name = $ENV{USER} or "Bob";
4182
4183 C<B::Deparse,-p> will print
4184
4185     if (($var & 0)) {
4186         print('Gimme an A!')
4187     };
4188     (print(($which ? $a : $b)), '???');
4189     (($name = $ENV{'USER'}) or '???')
4190
4191 which probably isn't what you intended (the C<'???'> is a sign that
4192 perl optimized away a constant value).
4193
4194 =item B<-P>
4195
4196 Disable prototype checking. With this option, all function calls are
4197 deparsed as if no prototype was defined for them. In other words,
4198
4199     perl -MO=Deparse,-P -e 'sub foo (\@) { 1 } foo @x'
4200
4201 will print
4202
4203     sub foo (\@) {
4204         1;
4205     }
4206     &foo(\@x);
4207
4208 making clear how the parameters are actually passed to C<foo>.
4209
4210 =item B<-q>
4211
4212 Expand double-quoted strings into the corresponding combinations of
4213 concatenation, uc, ucfirst, lc, lcfirst, quotemeta, and join. For
4214 instance, print
4215
4216     print "Hello, $world, @ladies, \u$gentlemen\E, \u\L$me!";
4217
4218 as
4219
4220     print 'Hello, ' . $world . ', ' . join($", @ladies) . ', '
4221           . ucfirst($gentlemen) . ', ' . ucfirst(lc $me . '!');
4222
4223 Note that the expanded form represents the way perl handles such
4224 constructions internally -- this option actually turns off the reverse
4225 translation that B::Deparse usually does. On the other hand, note that
4226 C<$x = "$y"> is not the same as C<$x = $y>: the former makes the value
4227 of $y into a string before doing the assignment.
4228
4229 =item B<-s>I<LETTERS>
4230
4231 Tweak the style of B::Deparse's output. The letters should follow
4232 directly after the 's', with no space or punctuation. The following
4233 options are available:
4234
4235 =over 4
4236
4237 =item B<C>
4238
4239 Cuddle C<elsif>, C<else>, and C<continue> blocks. For example, print
4240
4241     if (...) {
4242          ...
4243     } else {
4244          ...
4245     }
4246
4247 instead of
4248
4249     if (...) {
4250          ...
4251     }
4252     else {
4253          ...
4254     }
4255
4256 The default is not to cuddle.
4257
4258 =item B<i>I<NUMBER>
4259
4260 Indent lines by multiples of I<NUMBER> columns. The default is 4 columns.
4261
4262 =item B<T>
4263
4264 Use tabs for each 8 columns of indent. The default is to use only spaces.
4265 For instance, if the style options are B<-si4T>, a line that's indented
4266 3 times will be preceded by one tab and four spaces; if the options were
4267 B<-si8T>, the same line would be preceded by three tabs.
4268
4269 =item B<v>I<STRING>B<.>
4270
4271 Print I<STRING> for the value of a constant that can't be determined
4272 because it was optimized away (mnemonic: this happens when a constant
4273 is used in B<v>oid context). The end of the string is marked by a period.
4274 The string should be a valid perl expression, generally a constant.
4275 Note that unless it's a number, it probably needs to be quoted, and on
4276 a command line quotes need to be protected from the shell. Some
4277 conventional values include 0, 1, 42, '', 'foo', and
4278 'Useless use of constant omitted' (which may need to be
4279 B<-sv"'Useless use of constant omitted'.">
4280 or something similar depending on your shell). The default is '???'.
4281 If you're using B::Deparse on a module or other file that's require'd,
4282 you shouldn't use a value that evaluates to false, since the customary
4283 true constant at the end of a module will be in void context when the
4284 file is compiled as a main program.
4285
4286 =back
4287
4288 =item B<-x>I<LEVEL>
4289
4290 Expand conventional syntax constructions into equivalent ones that expose
4291 their internal operation. I<LEVEL> should be a digit, with higher values
4292 meaning more expansion. As with B<-q>, this actually involves turning off
4293 special cases in B::Deparse's normal operations.
4294
4295 If I<LEVEL> is at least 3, C<for> loops will be translated into equivalent
4296 while loops with continue blocks; for instance
4297
4298     for ($i = 0; $i < 10; ++$i) {
4299         print $i;
4300     }
4301
4302 turns into
4303
4304     $i = 0;
4305     while ($i < 10) {
4306         print $i;
4307     } continue {
4308         ++$i
4309     }
4310
4311 Note that in a few cases this translation can't be perfectly carried back
4312 into the source code -- if the loop's initializer declares a my variable,
4313 for instance, it won't have the correct scope outside of the loop.
4314
4315 If I<LEVEL> is at least 5, C<use> declarations will be translated into
4316 C<BEGIN> blocks containing calls to C<require> and C<import>; for
4317 instance,
4318
4319     use strict 'refs';
4320
4321 turns into
4322
4323     sub BEGIN {
4324         require strict;
4325         do {
4326             'strict'->import('refs')
4327         };
4328     }
4329
4330 If I<LEVEL> is at least 7, C<if> statements will be translated into
4331 equivalent expressions using C<&&>, C<?:> and C<do {}>; for instance
4332
4333     print 'hi' if $nice;
4334     if ($nice) {
4335         print 'hi';
4336     }
4337     if ($nice) {
4338         print 'hi';
4339     } else {
4340         print 'bye';
4341     }
4342
4343 turns into
4344
4345     $nice and print 'hi';
4346     $nice and do { print 'hi' };
4347     $nice ? do { print 'hi' } : do { print 'bye' };
4348
4349 Long sequences of elsifs will turn into nested ternary operators, which
4350 B::Deparse doesn't know how to indent nicely.
4351
4352 =back
4353
4354 =head1 USING B::Deparse AS A MODULE
4355
4356 =head2 Synopsis
4357
4358     use B::Deparse;
4359     $deparse = B::Deparse->new("-p", "-sC");
4360     $body = $deparse->coderef2text(\&func);
4361     eval "sub func $body"; # the inverse operation
4362
4363 =head2 Description
4364
4365 B::Deparse can also be used on a sub-by-sub basis from other perl
4366 programs.
4367
4368 =head2 new
4369
4370     $deparse = B::Deparse->new(OPTIONS)
4371
4372 Create an object to store the state of a deparsing operation and any
4373 options. The options are the same as those that can be given on the
4374 command line (see L</OPTIONS>); options that are separated by commas
4375 after B<-MO=Deparse> should be given as separate strings. Some
4376 options, like B<-u>, don't make sense for a single subroutine, so
4377 don't pass them.
4378
4379 =head2 ambient_pragmas
4380
4381     $deparse->ambient_pragmas(strict => 'all', '$[' => $[);
4382
4383 The compilation of a subroutine can be affected by a few compiler
4384 directives, B<pragmas>. These are:
4385
4386 =over 4
4387
4388 =item *
4389
4390 use strict;
4391
4392 =item *
4393
4394 use warnings;
4395
4396 =item *
4397
4398 Assigning to the special variable $[
4399
4400 =item *
4401
4402 use integer;
4403
4404 =item *
4405
4406 use bytes;
4407
4408 =item *
4409
4410 use utf8;
4411
4412 =item *
4413
4414 use re;
4415
4416 =back
4417
4418 Ordinarily, if you use B::Deparse on a subroutine which has
4419 been compiled in the presence of one or more of these pragmas,
4420 the output will include statements to turn on the appropriate
4421 directives. So if you then compile the code returned by coderef2text,
4422 it will behave the same way as the subroutine which you deparsed.
4423
4424 However, you may know that you intend to use the results in a
4425 particular context, where some pragmas are already in scope. In
4426 this case, you use the B<ambient_pragmas> method to describe the
4427 assumptions you wish to make.
4428
4429 Not all of the options currently have any useful effect. See
4430 L</BUGS> for more details.
4431
4432 The parameters it accepts are:
4433
4434 =over 4
4435
4436 =item strict
4437
4438 Takes a string, possibly containing several values separated
4439 by whitespace. The special values "all" and "none" mean what you'd
4440 expect.
4441
4442     $deparse->ambient_pragmas(strict => 'subs refs');
4443
4444 =item $[
4445
4446 Takes a number, the value of the array base $[.
4447
4448 =item bytes
4449
4450 =item utf8
4451
4452 =item integer
4453
4454 If the value is true, then the appropriate pragma is assumed to
4455 be in the ambient scope, otherwise not.
4456
4457 =item re
4458
4459 Takes a string, possibly containing a whitespace-separated list of
4460 values. The values "all" and "none" are special. It's also permissible
4461 to pass an array reference here.
4462
4463     $deparser->ambient_pragmas(re => 'eval');
4464
4465
4466 =item warnings
4467
4468 Takes a string, possibly containing a whitespace-separated list of
4469 values. The values "all" and "none" are special, again. It's also
4470 permissible to pass an array reference here.
4471
4472     $deparser->ambient_pragmas(warnings => [qw[void io]]);
4473
4474 If one of the values is the string "FATAL", then all the warnings
4475 in that list will be considered fatal, just as with the B<warnings>
4476 pragma itself. Should you need to specify that some warnings are
4477 fatal, and others are merely enabled, you can pass the B<warnings>
4478 parameter twice:
4479
4480     $deparser->ambient_pragmas(
4481         warnings => 'all',
4482         warnings => [FATAL => qw/void io/],
4483     );
4484
4485 See L<perllexwarn> for more information about lexical warnings.
4486
4487 =item hint_bits
4488
4489 =item warning_bits
4490
4491 These two parameters are used to specify the ambient pragmas in
4492 the format used by the special variables $^H and ${^WARNING_BITS}.
4493
4494 They exist principally so that you can write code like:
4495
4496     { my ($hint_bits, $warning_bits);
4497     BEGIN {($hint_bits, $warning_bits) = ($^H, ${^WARNING_BITS})}
4498     $deparser->ambient_pragmas (
4499         hint_bits    => $hint_bits,
4500         warning_bits => $warning_bits,
4501         '$['         => 0 + $[
4502     ); }
4503
4504 which specifies that the ambient pragmas are exactly those which
4505 are in scope at the point of calling.
4506
4507 =back
4508
4509 =head2 coderef2text
4510
4511     $body = $deparse->coderef2text(\&func)
4512     $body = $deparse->coderef2text(sub ($$) { ... })
4513
4514 Return source code for the body of a subroutine (a block, optionally
4515 preceded by a prototype in parens), given a reference to the
4516 sub. Because a subroutine can have no names, or more than one name,
4517 this method doesn't return a complete subroutine definition -- if you
4518 want to eval the result, you should prepend "sub subname ", or "sub "
4519 for an anonymous function constructor. Unless the sub was defined in
4520 the main:: package, the code will include a package declaration.
4521
4522 =head1 BUGS
4523
4524 =over 4
4525
4526 =item *
4527
4528 The only pragmas to be completely supported are: C<use warnings>,
4529 C<use strict 'refs'>, C<use bytes>, and C<use integer>. (C<$[>, which
4530 behaves like a pragma, is also supported.)
4531
4532 Excepting those listed above, we're currently unable to guarantee that
4533 B::Deparse will produce a pragma at the correct point in the program.
4534 (Specifically, pragmas at the beginning of a block often appear right
4535 before the start of the block instead.)
4536 Since the effects of pragmas are often lexically scoped, this can mean
4537 that the pragma holds sway over a different portion of the program
4538 than in the input file.
4539
4540 =item *
4541
4542 In fact, the above is a specific instance of a more general problem:
4543 we can't guarantee to produce BEGIN blocks or C<use> declarations in
4544 exactly the right place. So if you use a module which affects compilation
4545 (such as by over-riding keywords, overloading constants or whatever)
4546 then the output code might not work as intended.
4547
4548 This is the most serious outstanding problem, and will require some help
4549 from the Perl core to fix.
4550
4551 =item *
4552
4553 If a keyword is over-ridden, and your program explicitly calls
4554 the built-in version by using CORE::keyword, the output of B::Deparse
4555 will not reflect this. If you run the resulting code, it will call
4556 the over-ridden version rather than the built-in one. (Maybe there
4557 should be an option to B<always> print keyword calls as C<CORE::name>.)
4558
4559 =item *
4560
4561 Some constants don't print correctly either with or without B<-d>.
4562 For instance, neither B::Deparse nor Data::Dumper know how to print
4563 dual-valued scalars correctly, as in:
4564
4565     use constant E2BIG => ($!=7); $y = E2BIG; print $y, 0+$y;
4566
4567 =item *
4568
4569 An input file that uses source filtering probably won't be deparsed into
4570 runnable code, because it will still include the B<use> declaration
4571 for the source filtering module, even though the code that is
4572 produced is already ordinary Perl which shouldn't be filtered again.
4573
4574 =item *
4575
4576 There are probably many more bugs on non-ASCII platforms (EBCDIC).
4577
4578 =back
4579
4580 =head1 AUTHOR
4581
4582 Stephen McCamant <smcc@CSUA.Berkeley.EDU>, based on an earlier version
4583 by Malcolm Beattie <mbeattie@sable.ox.ac.uk>, with contributions from
4584 Gisle Aas, James Duncan, Albert Dvornik, Robin Houston, Dave Mitchell,
4585 Hugo van der Sanden, Gurusamy Sarathy, Nick Ing-Simmons, and Rafael
4586 Garcia-Suarez.
4587
4588 =cut