ext/B/B/Concise.pm

   1 package B::Concise;
   2 # Copyright (C) 2000-2003 Stephen McCamant. All rights reserved.
   3 # This program is free software; you can redistribute and/or modify it
   4 # under the same terms as Perl itself.
   5
   6 use strict;
   7 use warnings;
   8
   9 use Exporter ();
  10
  11 our $VERSION   = "0.55";
  12 our @ISA       = qw(Exporter);
  13 our @EXPORT_OK = qw(set_style set_style_standard add_callback
  14                     concise_cv concise_main);
  15
  16 use B qw(class ppname main_start main_root main_cv cstring svref_2object
  17          SVf_IOK SVf_NOK SVf_POK SVf_IVisUV OPf_KIDS);
  18
  19 my %style =
  20   ("terse" =>
  21    ["(?(#label =>\n)?)(*(    )*)#class (#addr) #name (?([#targ])?) "
  22     . "#svclass~(?((#svaddr))?)~#svval~(?(label \"#coplabel\")?)\n",
  23     "(*(    )*)goto #class (#addr)\n",
  24     "#class pp_#name"],
  25    "concise" =>
  26    ["#hyphseq2 (*(   (x( ;)x))*)<#classsym> "
  27     . "#exname#arg(?([#targarglife])?)~#flags(?(/#private)?)(x(;~->#next)x)\n",
  28     "  (*(    )*)     goto #seq\n",
  29     "(?(<#seq>)?)#exname#arg(?([#targarglife])?)"],
  30    "linenoise" =>
  31    ["(x(;(*( )*))x)#noise#arg(?([#targarg])?)(x( ;\n)x)",
  32     "gt_#seq ",
  33     "(?(#seq)?)#noise#arg(?([#targarg])?)"],
  34    "debug" =>
  35    ["#class (#addr)\n\top_next\t\t#nextaddr\n\top_sibling\t#sibaddr\n\t"
  36     . "op_ppaddr\tPL_ppaddr[OP_#NAME]\n\top_type\t\t#typenum\n\top_seq\t\t"
  37     . "#seqnum\n\top_flags\t#flagval\n\top_private\t#privval\n"
  38     . "(?(\top_first\t#firstaddr\n)?)(?(\top_last\t\t#lastaddr\n)?)"
  39     . "(?(\top_sv\t\t#svaddr\n)?)",
  40     "    GOTO #addr\n",
  41     "#addr"],
  42    "env" => [$ENV{B_CONCISE_FORMAT}, $ENV{B_CONCISE_GOTO_FORMAT},
  43              $ENV{B_CONCISE_TREE_FORMAT}],
  44   );
  45
  46 my($format, $gotofmt, $treefmt);
  47 my $curcv;
  48 my $cop_seq_base;
  49 my @callbacks;
  50
  51 sub set_style {
  52     ($format, $gotofmt, $treefmt) = @_;
  53 }
  54
  55 sub set_style_standard {
  56     my($name) = @_;
  57     set_style(@{$style{$name}});
  58 }
  59
  60 sub add_callback {
  61     push @callbacks, @_;
  62 }
  63
  64 sub concise_cv {
  65     my ($order, $cvref) = @_;
  66     my $cv = svref_2object($cvref);
  67     $curcv = $cv;
  68     sequence($cv->START);
  69     if ($order eq "exec") {
  70         walk_exec($cv->START);
  71     } elsif ($order eq "basic") {
  72         walk_topdown($cv->ROOT, sub { $_[0]->concise($_[1]) }, 0);
  73     } else {
  74         print tree($cv->ROOT, 0)
  75     }
  76 }
  77
  78 sub concise_main {
  79     my($order) = @_;
  80     sequence(main_start);
  81     $curcv = main_cv;
  82     if ($order eq "exec") {
  83         return if class(main_start) eq "NULL";
  84         walk_exec(main_start);
  85     } elsif ($order eq "tree") {
  86         return if class(main_root) eq "NULL";
  87         print tree(main_root, 0);
  88     } elsif ($order eq "basic") {
  89         return if class(main_root) eq "NULL";
  90         walk_topdown(main_root,
  91                      sub { $_[0]->concise($_[1]) }, 0);
  92     }
  93 }
  94
  95 my $start_sym = "\e(0"; # "\cN" sometimes also works
  96 my $end_sym   = "\e(B"; # "\cO" respectively
  97
  98 my @tree_decorations =
  99   (["  ", "--", "+-", "|-", "| ", "`-", "-", 1],
 100    [" ", "-", "+", "+", "|", "`", "", 0],
 101    ["  ", map("$start_sym$_$end_sym", "qq", "wq", "tq", "x ", "mq", "q"), 1],
 102    [" ", map("$start_sym$_$end_sym", "q", "w", "t", "x", "m"), "", 0],
 103   );
 104 my $tree_style = 0;
 105
 106 my $base = 36;
 107 my $big_endian = 1;
 108
 109 my $order = "basic";
 110
 111 set_style_standard("concise");
 112
 113 sub compile {
 114     my @options = grep(/^-/, @_);
 115     my @args = grep(!/^-/, @_);
 116     my $do_main = 0;
 117     for my $o (@options) {
 118         if ($o eq "-basic") {
 119             $order = "basic";
 120         } elsif ($o eq "-exec") {
 121             $order = "exec";
 122         } elsif ($o eq "-tree") {
 123             $order = "tree";
 124         } elsif ($o eq "-compact") {
 125             $tree_style |= 1;
 126         } elsif ($o eq "-loose") {
 127             $tree_style &= ~1;
 128         } elsif ($o eq "-vt") {
 129             $tree_style |= 2;
 130         } elsif ($o eq "-ascii") {
 131             $tree_style &= ~2;
 132         } elsif ($o eq "-main") {
 133             $do_main = 1;
 134         } elsif ($o =~ /^-base(\d+)$/) {
 135             $base = $1;
 136         } elsif ($o eq "-bigendian") {
 137             $big_endian = 1;
 138         } elsif ($o eq "-littleendian") {
 139             $big_endian = 0;
 140         } elsif (exists $style{substr($o, 1)}) {
 141             set_style(@{$style{substr($o, 1)}});
 142         } else {
 143             warn "Option $o unrecognized";
 144         }
 145     }
 146     return sub {
 147         if (@args) {
 148             for my $objname (@args) {
 149                 $objname = "main::" . $objname unless $objname =~ /::/;
 150                 print "$objname:\n";
 151                 eval "concise_cv(\$order, \\&$objname)";
 152                 die "concise_cv($order, \\&$objname) failed: $@" if $@;
 153             }
 154         }
 155         if (!@args or $do_main) {
 156             print "main program:\n" if $do_main;
 157             concise_main($order);
 158         }
 159     }
 160 }
 161
 162 my %labels;
 163 my $lastnext;
 164
 165 my %opclass = ('OP' => "0", 'UNOP' => "1", 'BINOP' => "2", 'LOGOP' => "|",
 166                'LISTOP' => "@", 'PMOP' => "/", 'SVOP' => "\$", 'GVOP' => "*",
 167                'PVOP' => '"', 'LOOP' => "{", 'COP' => ";", 'PADOP' => "#");
 168
 169 no warnings 'qw'; # "Possible attempt to put comments..."
 170 my @linenoise =
 171   qw'#  () sc (  @? 1  $* gv *{ m$ m@ m% m? p/ *$ $  $# & a& pt \\ s\\ rf bl
 172      `  *? <> ?? ?/ r/ c/ // qr s/ /c y/ =  @= C  sC Cp sp df un BM po +1 +I
 173      -1 -I 1+ I+ 1- I- ** *  i* /  i/ %$ i% x  +  i+ -  i- .  "  << >> <  i<
 174      >  i> <= i, >= i. == i= != i! <? i? s< s> s, s. s= s! s? b& b^ b| -0 -i
 175      !  ~  a2 si cs rd sr e^ lg sq in %x %o ab le ss ve ix ri sf FL od ch cy
 176      uf lf uc lc qm @  [f [  @[ eh vl ky dl ex %  ${ @{ uk pk st jn )  )[ a@
 177      a% sl +] -] [- [+ so rv GS GW MS MW .. f. .f && || ^^ ?: &= |= -> s{ s}
 178      v} ca wa di rs ;; ;  ;d }{ {  }  {} f{ it {l l} rt }l }n }r dm }g }e ^o
 179      ^c ^| ^# um bm t~ u~ ~d DB db ^s se ^g ^r {w }w pf pr ^O ^K ^R ^W ^d ^v
 180      ^e ^t ^k t. fc ic fl .s .p .b .c .l .a .h g1 s1 g2 s2 ?. l? -R -W -X -r
 181      -w -x -e -o -O -z -s -M -A -C -S -c -b -f -d -p -l -u -g -k -t -T -B cd
 182      co cr u. cm ut r. l@ s@ r@ mD uD oD rD tD sD wD cD f$ w$ p$ sh e$ k$ g3
 183      g4 s4 g5 s5 T@ C@ L@ G@ A@ S@ Hg Hc Hr Hw Mg Mc Ms Mr Sg Sc So rq do {e
 184      e} {t t} g6 G6 6e g7 G7 7e g8 G8 8e g9 G9 9e 6s 7s 8s 9s 6E 7E 8E 9E Pn
 185      Pu GP SP EP Gn Gg GG SG EG g0 c$ lk t$ ;s n> // /= CO';
 186
 187 my $chars = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ";
 188
 189 sub op_flags {
 190     my($x) = @_;
 191     my(@v);
 192     push @v, "v" if ($x & 3) == 1;
 193     push @v, "s" if ($x & 3) == 2;
 194     push @v, "l" if ($x & 3) == 3;
 195     push @v, "K" if $x & 4;
 196     push @v, "P" if $x & 8;
 197     push @v, "R" if $x & 16;
 198     push @v, "M" if $x & 32;
 199     push @v, "S" if $x & 64;
 200     push @v, "*" if $x & 128;
 201     return join("", @v);
 202 }
 203
 204 sub base_n {
 205     my $x = shift;
 206     return "-" . base_n(-$x) if $x < 0;
 207     my $str = "";
 208     do { $str .= substr($chars, $x % $base, 1) } while $x = int($x / $base);
 209     $str = reverse $str if $big_endian;
 210     return $str;
 211 }
 212
 213 my %sequence_num;
 214 my $seq_max = 1;
 215
 216 sub seq {
 217     my($op) = @_;
 218     return "-" if not exists $sequence_num{$$op};
 219     return base_n($sequence_num{$$op});
 220 }
 221
 222 sub walk_topdown {
 223     my($op, $sub, $level) = @_;
 224     $sub->($op, $level);
 225     if ($op->flags & OPf_KIDS) {
 226         for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
 227             walk_topdown($kid, $sub, $level + 1);
 228         }
 229     }
 230     if (class($op) eq "PMOP" and $op->pmreplroot and $ {$op->pmreplroot}
 231         and $op->pmreplroot->isa("B::OP")) {
 232         walk_topdown($op->pmreplroot, $sub, $level + 1);
 233     }
 234 }
 235
 236 sub walklines {
 237     my($ar, $level) = @_;
 238     for my $l (@$ar) {
 239         if (ref($l) eq "ARRAY") {
 240             walklines($l, $level + 1);
 241         } else {
 242             $l->concise($level);
 243         }
 244     }
 245 }
 246
 247 sub walk_exec {
 248     my($top, $level) = @_;
 249     my %opsseen;
 250     my @lines;
 251     my @todo = ([$top, \@lines]);
 252     while (@todo and my($op, $targ) = @{shift @todo}) {
 253         for (; $$op; $op = $op->next) {
 254             last if $opsseen{$$op}++;
 255             push @$targ, $op;
 256             my $name = $op->name;
 257             if (class($op) eq "LOGOP") {
 258                 my $ar = [];
 259                 push @$targ, $ar;
 260                 push @todo, [$op->other, $ar];
 261             } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
 262                 my $ar = [];
 263                 push @$targ, $ar;
 264                 push @todo, [$op->pmreplstart, $ar];
 265             } elsif ($name =~ /^enter(loop|iter)$/) {
 266                 $labels{$op->nextop->seq} = "NEXT";
 267                 $labels{$op->lastop->seq} = "LAST";
 268                 $labels{$op->redoop->seq} = "REDO";
 269             }
 270         }
 271     }
 272     walklines(\@lines, 0);
 273 }
 274
 275 # The structure of this routine is purposely modeled after op.c's peep()
 276 sub sequence {
 277     my($op) = @_;
 278     my $oldop = 0;
 279     return if class($op) eq "NULL" or exists $sequence_num{$$op};
 280     for (; $$op; $op = $op->next) {
 281         last if exists $sequence_num{$$op};
 282         my $name = $op->name;
 283         if ($name =~ /^(null|scalar|lineseq|scope)$/) {
 284             next if $oldop and $ {$op->next};
 285         } else {
 286             $sequence_num{$$op} = $seq_max++;
 287             if (class($op) eq "LOGOP") {
 288                 my $other = $op->other;
 289                 $other = $other->next while $other->name eq "null";
 290                 sequence($other);
 291             } elsif (class($op) eq "LOOP") {
 292                 my $redoop = $op->redoop;
 293                 $redoop = $redoop->next while $redoop->name eq "null";
 294                 sequence($redoop);
 295                 my $nextop = $op->nextop;
 296                 $nextop = $nextop->next while $nextop->name eq "null";
 297                 sequence($nextop);
 298                 my $lastop = $op->lastop;
 299                 $lastop = $lastop->next while $lastop->name eq "null";
 300                 sequence($lastop);
 301             } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
 302                 my $replstart = $op->pmreplstart;
 303                 $replstart = $replstart->next while $replstart->name eq "null";
 304                 sequence($replstart);
 305             }
 306         }
 307         $oldop = $op;
 308     }
 309 }
 310
 311 sub fmt_line {
 312     my($hr, $fmt, $level) = @_;
 313     my $text = $fmt;
 314     $text =~ s/\(\?\(([^\#]*?)\#(\w+)([^\#]*?)\)\?\)/
 315       $hr->{$2} ? $1.$hr->{$2}.$3 : ""/eg;
 316     $text =~ s/\(x\((.*?);(.*?)\)x\)/$order eq "exec" ? $1 : $2/egs;
 317     $text =~ s/\(\*\(([^;]*?)\)\*\)/$1 x $level/egs;
 318     $text =~ s/\(\*\((.*?);(.*?)\)\*\)/$1 x ($level - 1) . $2 x ($level>0)/egs;
 319     $text =~ s/#([a-zA-Z]+)(\d+)/sprintf("%-$2s", $hr->{$1})/eg;
 320     $text =~ s/#([a-zA-Z]+)/$hr->{$1}/eg;
 321     $text =~ s/[ \t]*~+[ \t]*/ /g;
 322     return $text;
 323 }
 324
 325 my %priv;
 326 $priv{$_}{128} = "LVINTRO"
 327   for ("pos", "substr", "vec", "threadsv", "gvsv", "rv2sv", "rv2hv", "rv2gv",
 328        "rv2av", "rv2arylen", "aelem", "helem", "aslice", "hslice", "padsv",
 329        "padav", "padhv");
 330 $priv{$_}{64} = "REFC" for ("leave", "leavesub", "leavesublv", "leavewrite");
 331 $priv{"aassign"}{64} = "COMMON";
 332 $priv{"sassign"}{64} = "BKWARD";
 333 $priv{$_}{64} = "RTIME" for ("match", "subst", "substcont");
 334 @{$priv{"trans"}}{1,2,4,8,16,64} = ("<UTF", ">UTF", "IDENT", "SQUASH", "DEL",
 335                                     "COMPL", "GROWS");
 336 $priv{"repeat"}{64} = "DOLIST";
 337 $priv{"leaveloop"}{64} = "CONT";
 338 @{$priv{$_}}{32,64,96} = ("DREFAV", "DREFHV", "DREFSV")
 339   for ("entersub", map("rv2${_}v", "a", "s", "h", "g"), "aelem", "helem");
 340 $priv{"entersub"}{16} = "DBG";
 341 $priv{"entersub"}{32} = "TARG";
 342 @{$priv{$_}}{4,8,128} = ("INARGS","AMPER","NO()") for ("entersub", "rv2cv");
 343 $priv{"gv"}{32} = "EARLYCV";
 344 $priv{"aelem"}{16} = $priv{"helem"}{16} = "LVDEFER";
 345 $priv{$_}{16} = "OURINTR" for ("gvsv", "rv2sv", "rv2av", "rv2hv", "r2gv");
 346 $priv{$_}{16} = "TARGMY"
 347   for (map(($_,"s$_"),"chop", "chomp"),
 348        map(($_,"i_$_"), "postinc", "postdec", "multiply", "divide", "modulo",
 349            "add", "subtract", "negate"), "pow", "concat", "stringify",
 350        "left_shift", "right_shift", "bit_and", "bit_xor", "bit_or",
 351        "complement", "atan2", "sin", "cos", "rand", "exp", "log", "sqrt",
 352        "int", "hex", "oct", "abs", "length", "index", "rindex", "sprintf",
 353        "ord", "chr", "crypt", "quotemeta", "join", "push", "unshift", "flock",
 354        "chdir", "chown", "chroot", "unlink", "chmod", "utime", "rename",
 355        "link", "symlink", "mkdir", "rmdir", "wait", "waitpid", "system",
 356        "exec", "kill", "getppid", "getpgrp", "setpgrp", "getpriority",
 357        "setpriority", "time", "sleep");
 358 @{$priv{"const"}}{8,16,32,64,128} = ("STRICT","ENTERED", '$[', "BARE", "WARN");
 359 $priv{"flip"}{64} = $priv{"flop"}{64} = "LINENUM";
 360 $priv{"list"}{64} = "GUESSED";
 361 $priv{"delete"}{64} = "SLICE";
 362 $priv{"exists"}{64} = "SUB";
 363 $priv{$_}{64} = "LOCALE"
 364   for ("sort", "prtf", "sprintf", "slt", "sle", "seq", "sne", "sgt", "sge",
 365        "scmp", "lc", "uc", "lcfirst", "ucfirst");
 366 @{$priv{"sort"}}{1,2,4} = ("NUM", "INT", "REV");
 367 $priv{"threadsv"}{64} = "SVREFd";
 368 @{$priv{$_}}{16,32,64,128} = ("INBIN","INCR","OUTBIN","OUTCR")
 369   for ("open", "backtick");
 370 $priv{"exit"}{128} = "VMS";
 371
 372 sub private_flags {
 373     my($name, $x) = @_;
 374     my @s;
 375     for my $flag (128, 96, 64, 32, 16, 8, 4, 2, 1) {
 376         if ($priv{$name}{$flag} and $x & $flag and $x >= $flag) {
 377             $x -= $flag;
 378             push @s, $priv{$name}{$flag};
 379         }
 380     }
 381     push @s, $x if $x;
 382     return join(",", @s);
 383 }
 384
 385 sub concise_sv {
 386     my($sv, $hr) = @_;
 387     $hr->{svclass} = class($sv);
 388     $hr->{svclass} = "UV"
 389       if $hr->{svclass} eq "IV" and $sv->FLAGS & SVf_IVisUV;
 390     $hr->{svaddr} = sprintf("%#x", $$sv);
 391     if ($hr->{svclass} eq "GV") {
 392         my $gv = $sv;
 393         my $stash = $gv->STASH->NAME;
 394         if ($stash eq "main") {
 395             $stash = "";
 396         } else {
 397             $stash = $stash . "::";
 398         }
 399         $hr->{svval} = "*$stash" . $gv->SAFENAME;
 400         return "*$stash" . $gv->SAFENAME;
 401     } else {
 402         while (class($sv) eq "RV") {
 403             $hr->{svval} .= "\\";
 404             $sv = $sv->RV;
 405         }
 406         if (class($sv) eq "SPECIAL") {
 407             $hr->{svval} .= ["Null", "sv_undef", "sv_yes", "sv_no"]->[$$sv];
 408         } elsif ($sv->FLAGS & SVf_NOK) {
 409             $hr->{svval} .= $sv->NV;
 410         } elsif ($sv->FLAGS & SVf_IOK) {
 411             $hr->{svval} .= $sv->int_value;
 412         } elsif ($sv->FLAGS & SVf_POK) {
 413             $hr->{svval} .= cstring($sv->PV);
 414         } elsif (class($sv) eq "HV") {
 415             $hr->{svval} .= 'HASH';
 416         }
 417         return $hr->{svclass} . " " .  $hr->{svval};
 418     }
 419 }
 420
 421 sub concise_op {
 422     my ($op, $level, $format) = @_;
 423     my %h;
 424     $h{exname} = $h{name} = $op->name;
 425     $h{NAME} = uc $h{name};
 426     $h{class} = class($op);
 427     $h{extarg} = $h{targ} = $op->targ;
 428     $h{extarg} = "" unless $h{extarg};
 429     if ($h{name} eq "null" and $h{targ}) {
 430         $h{exname} = "ex-" . substr(ppname($h{targ}), 3);
 431         $h{extarg} = "";
 432     } elsif ($h{targ}) {
 433         my $padname = (($curcv->PADLIST->ARRAY)[0]->ARRAY)[$h{targ}];
 434         if (defined $padname and class($padname) ne "SPECIAL") {
 435             $h{targarg}  = $padname->PVX;
 436             my $intro = $padname->NVX - $cop_seq_base;
 437             my $finish = int($padname->IVX) - $cop_seq_base;
 438             $finish = "end" if $finish == 999999999 - $cop_seq_base;
 439             $h{targarglife} = "$h{targarg}:$intro,$finish";
 440         } else {
 441             $h{targarglife} = $h{targarg} = "t" . $h{targ};
 442         }
 443     }
 444     $h{arg} = "";
 445     $h{svclass} = $h{svaddr} = $h{svval} = "";
 446     if ($h{class} eq "PMOP") {
 447         my $precomp = $op->precomp;
 448         if (defined $precomp) {
 449             $precomp = cstring($precomp); # Escape literal control sequences
 450             $precomp = "/$precomp/";
 451         } else {
 452             $precomp = "";
 453         }
 454         my $pmreplroot = $op->pmreplroot;
 455         my $pmreplstart;
 456         if ($pmreplroot && $$pmreplroot && $pmreplroot->isa("B::GV")) {
 457             # with C<@stash_array = split(/pat/, str);>,
 458             #  *stash_array is stored in pmreplroot.
 459             $h{arg} = "($precomp => \@" . $pmreplroot->NAME . ")";
 460         } elsif ($ {$op->pmreplstart}) {
 461             undef $lastnext;
 462             $pmreplstart = "replstart->" . seq($op->pmreplstart);
 463             $h{arg} = "(" . join(" ", $precomp, $pmreplstart) . ")";
 464         } else {
 465             $h{arg} = "($precomp)";
 466         }
 467     } elsif ($h{class} eq "PVOP" and $h{name} ne "trans") {
 468         $h{arg} = '("' . $op->pv . '")';
 469         $h{svval} = '"' . $op->pv . '"';
 470     } elsif ($h{class} eq "COP") {
 471         my $label = $op->label;
 472         $h{coplabel} = $label;
 473         $label = $label ? "$label: " : "";
 474         my $loc = $op->file;
 475         $loc =~ s[.*/][];
 476         $loc .= ":" . $op->line;
 477         my($stash, $cseq) = ($op->stash->NAME, $op->cop_seq - $cop_seq_base);
 478         my $arybase = $op->arybase;
 479         $arybase = $arybase ? ' $[=' . $arybase : "";
 480         $h{arg} = "($label$stash $cseq $loc$arybase)";
 481     } elsif ($h{class} eq "LOOP") {
 482         $h{arg} = "(next->" . seq($op->nextop) . " last->" . seq($op->lastop)
 483           . " redo->" . seq($op->redoop) . ")";
 484     } elsif ($h{class} eq "LOGOP") {
 485         undef $lastnext;
 486         $h{arg} = "(other->" . seq($op->other) . ")";
 487     } elsif ($h{class} eq "SVOP") {
 488         if (! ${$op->sv}) {
 489             my $sv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$op->targ];
 490             $h{arg} = "[" . concise_sv($sv, \%h) . "]";
 491             $h{targarglife} = $h{targarg} = "";
 492         } else {
 493             $h{arg} = "(" . concise_sv($op->sv, \%h) . ")";
 494         }
 495     } elsif ($h{class} eq "PADOP") {
 496         my $sv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$op->padix];
 497         $h{arg} = "[" . concise_sv($sv, \%h) . "]";
 498     }
 499     $h{seq} = $h{hyphseq} = seq($op);
 500     $h{seq} = "" if $h{seq} eq "-";
 501     $h{seqnum} = $op->seq;
 502     $h{next} = $op->next;
 503     $h{next} = (class($h{next}) eq "NULL") ? "(end)" : seq($h{next});
 504     $h{nextaddr} = sprintf("%#x", $ {$op->next});
 505     $h{sibaddr} = sprintf("%#x", $ {$op->sibling});
 506     $h{firstaddr} = sprintf("%#x", $ {$op->first}) if $op->can("first");
 507     $h{lastaddr} = sprintf("%#x", $ {$op->last}) if $op->can("last");
 508
 509     $h{classsym} = $opclass{$h{class}};
 510     $h{flagval} = $op->flags;
 511     $h{flags} = op_flags($op->flags);
 512     $h{privval} = $op->private;
 513     $h{private} = private_flags($h{name}, $op->private);
 514     $h{addr} = sprintf("%#x", $$op);
 515     $h{label} = $labels{$op->seq};
 516     $h{typenum} = $op->type;
 517     $h{noise} = $linenoise[$op->type];
 518     $_->(\%h, $op, \$format, \$level) for @callbacks;
 519     return fmt_line(\%h, $format, $level);
 520 }
 521
 522 sub B::OP::concise {
 523     my($op, $level) = @_;
 524     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
 525         my $h = {"seq" => seq($lastnext), "class" => class($lastnext),
 526                  "addr" => sprintf("%#x", $$lastnext)};
 527         print fmt_line($h, $gotofmt, $level+1);
 528     }
 529     $lastnext = $op->next;
 530     print concise_op($op, $level, $format);
 531 }
 532
 533 # B::OP::terse (see Terse.pm) now just calls this
 534 sub b_terse {
 535     my($op, $level) = @_;
 536
 537     # This isn't necessarily right, but there's no easy way to get
 538     # from an OP to the right CV. This is a limitation of the
 539     # ->terse() interface style, and there isn't much to do about
 540     # it. In particular, we can die in concise_op if the main pad
 541     # isn't long enough, or has the wrong kind of entries, compared to
 542     # the pad a sub was compiled with. The fix for that would be to
 543     # make a backwards compatible "terse" format that never even
 544     # looked at the pad, just like the old B::Terse. I don't think
 545     # that's worth the effort, though.
 546     $curcv = main_cv unless $curcv;
 547
 548     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
 549         my $h = {"seq" => seq($lastnext), "class" => class($lastnext),
 550                  "addr" => sprintf("%#x", $$lastnext)};
 551         print fmt_line($h, $style{"terse"}[1], $level+1);
 552     }
 553     $lastnext = $op->next;
 554     print concise_op($op, $level, $style{"terse"}[0]);
 555 }
 556
 557 sub tree {
 558     my $op = shift;
 559     my $level = shift;
 560     my $style = $tree_decorations[$tree_style];
 561     my($space, $single, $kids, $kid, $nokid, $last, $lead, $size) = @$style;
 562     my $name = concise_op($op, $level, $treefmt);
 563     if (not $op->flags & OPf_KIDS) {
 564         return $name . "\n";
 565     }
 566     my @lines;
 567     for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
 568         push @lines, tree($kid, $level+1);
 569     }
 570     my $i;
 571     for ($i = $#lines; substr($lines[$i], 0, 1) eq " "; $i--) {
 572         $lines[$i] = $space . $lines[$i];
 573     }
 574     if ($i > 0) {
 575         $lines[$i] = $last . $lines[$i];
 576         while ($i-- > 1) {
 577             if (substr($lines[$i], 0, 1) eq " ") {
 578                 $lines[$i] = $nokid . $lines[$i];
 579             } else {
 580                 $lines[$i] = $kid . $lines[$i];
 581             }
 582         }
 583         $lines[$i] = $kids . $lines[$i];
 584     } else {
 585         $lines[0] = $single . $lines[0];
 586     }
 587     return("$name$lead" . shift @lines,
 588            map(" " x (length($name)+$size) . $_, @lines));
 589 }
 590
 591 # *** Warning: fragile kludge ahead ***
 592 # Because the B::* modules run in the same interpreter as the code
 593 # they're compiling, their presence tends to distort the view we have
 594 # of the code we're looking at. In particular, perl gives sequence
 595 # numbers to both OPs in general and COPs in particular. If the
 596 # program we're looking at were run on its own, these numbers would
 597 # start at 1. Because all of B::Concise and all the modules it uses
 598 # are compiled first, though, by the time we get to the user's program
 599 # the sequence numbers are alreay at pretty high numbers, which would
 600 # be distracting if you're trying to tell OPs apart. Therefore we'd
 601 # like to subtract an offset from all the sequence numbers we display,
 602 # to restore the simpler view of the world. The trick is to know what
 603 # that offset will be, when we're still compiling B::Concise!  If we
 604 # hardcoded a value, it would have to change every time B::Concise or
 605 # other modules we use do. To help a little, what we do here is
 606 # compile a little code at the end of the module, and compute the base
 607 # sequence number for the user's program as being a small offset
 608 # later, so all we have to worry about are changes in the offset.
 609 # (Note that we now only play this game with COP sequence numbers. OP
 610 # sequence numbers aren't used to refer to OPs from a distance, and
 611 # they don't have much significance, so we just generate our own
 612 # sequence numbers which are easier to control. This way we also don't
 613 # stand in the way of a possible future removal of OP sequence
 614 # numbers).
 615
 616 # When you say "perl -MO=Concise -e '$a'", the output should look like:
 617
 618 # 4  <@> leave[t1] vKP/REFC ->(end)
 619 # 1     <0> enter ->2
 620  #^ smallest OP sequence number should be 1
 621 # 2     <;> nextstate(main 1 -e:1) v ->3
 622  #                         ^ smallest COP sequence number should be 1
 623 # -     <1> ex-rv2sv vK/1 ->4
 624 # 3        <$> gvsv(*a) s ->4
 625
 626 # If the second of the marked numbers there isn't 1, it means you need
 627 # to update the corresponding magic number in the next line.
 628 # Remember, this needs to stay the last things in the module.
 629
 630 # Why is this different for MacOS?  Does it matter?
 631 my $cop_seq_mnum = $^O eq 'MacOS' ? 10 : 9;
 632 $cop_seq_base = svref_2object(eval 'sub{0;}')->START->cop_seq + $cop_seq_mnum;
 633
 634 1;
 635
 636 __END__
 637
 638 =head1 NAME
 639
 640 B::Concise - Walk Perl syntax tree, printing concise info about ops
 641
 642 =head1 SYNOPSIS
 643
 644     perl -MO=Concise[,OPTIONS] foo.pl
 645
 646     use B::Concise qw(set_style add_callback);
 647
 648 =head1 DESCRIPTION
 649
 650 This compiler backend prints the internal OPs of a Perl program's syntax
 651 tree in one of several space-efficient text formats suitable for debugging
 652 the inner workings of perl or other compiler backends. It can print OPs in
 653 the order they appear in the OP tree, in the order they will execute, or
 654 in a text approximation to their tree structure, and the format of the
 655 information displyed is customizable. Its function is similar to that of
 656 perl's B<-Dx> debugging flag or the B<B::Terse> module, but it is more
 657 sophisticated and flexible.
 658
 659 =head1 EXAMPLE
 660
 661 Here's is a short example of output, using the default formatting
 662 conventions :
 663
 664     % perl -MO=Concise -e '$a = $b + 42'
 665     8  <@> leave[t1] vKP/REFC ->(end)
 666     1     <0> enter ->2
 667     2     <;> nextstate(main 1 -e:1) v ->3
 668     7     <2> sassign vKS/2 ->8
 669     5        <2> add[t1] sK/2 ->6
 670     -           <1> ex-rv2sv sK/1 ->4
 671     3              <$> gvsv(*b) s ->4
 672     4           <$> const(IV 42) s ->5
 673     -        <1> ex-rv2sv sKRM*/1 ->7
 674     6           <$> gvsv(*a) s ->7
 675
 676 Each line corresponds to an operator. Null ops appear as C<ex-opname>,
 677 where I<opname> is the op that has been optimized away by perl.
 678
 679 The number on the first row indicates the op's sequence number. It's
 680 given in base 36 by default.
 681
 682 The symbol between angle brackets indicates the op's type : for example,
 683 <2> is a BINOP, <@> a LISTOP, etc. (see L</"OP class abbreviations">).
 684
 685 The opname may be followed by op-specific information in parentheses
 686 (e.g. C<gvsv(*b)>), and by targ information in brackets (e.g.
 687 C<leave[t1]>).
 688
 689 Next come the op flags. The common flags are listed below
 690 (L</"OP flags abbreviations">). The private flags follow, separated
 691 by a slash. For example, C<vKP/REFC> means that the leave op has
 692 public flags OPf_WANT_VOID, OPf_KIDS, and OPf_PARENS, and the private
 693 flag OPpREFCOUNTED.
 694
 695 Finally an arrow points to the sequence number of the next op.
 696
 697 =head1 OPTIONS
 698
 699 Arguments that don't start with a hyphen are taken to be the names of
 700 subroutines to print the OPs of; if no such functions are specified, the
 701 main body of the program (outside any subroutines, and not including use'd
 702 or require'd files) is printed.
 703
 704 =over 4
 705
 706 =item B<-basic>
 707
 708 Print OPs in the order they appear in the OP tree (a preorder
 709 traversal, starting at the root). The indentation of each OP shows its
 710 level in the tree.  This mode is the default, so the flag is included
 711 simply for completeness.
 712
 713 =item B<-exec>
 714
 715 Print OPs in the order they would normally execute (for the majority
 716 of constructs this is a postorder traversal of the tree, ending at the
 717 root). In most cases the OP that usually follows a given OP will
 718 appear directly below it; alternate paths are shown by indentation. In
 719 cases like loops when control jumps out of a linear path, a 'goto'
 720 line is generated.
 721
 722 =item B<-tree>
 723
 724 Print OPs in a text approximation of a tree, with the root of the tree
 725 at the left and 'left-to-right' order of children transformed into
 726 'top-to-bottom'. Because this mode grows both to the right and down,
 727 it isn't suitable for large programs (unless you have a very wide
 728 terminal).
 729
 730 =item B<-compact>
 731
 732 Use a tree format in which the minimum amount of space is used for the
 733 lines connecting nodes (one character in most cases). This squeezes out
 734 a few precious columns of screen real estate.
 735
 736 =item B<-loose>
 737
 738 Use a tree format that uses longer edges to separate OP nodes. This format
 739 tends to look better than the compact one, especially in ASCII, and is
 740 the default.
 741
 742 =item B<-vt>
 743
 744 Use tree connecting characters drawn from the VT100 line-drawing set.
 745 This looks better if your terminal supports it.
 746
 747 =item B<-ascii>
 748
 749 Draw the tree with standard ASCII characters like C<+> and C<|>. These don't
 750 look as clean as the VT100 characters, but they'll work with almost any
 751 terminal (or the horizontal scrolling mode of less(1)) and are suitable
 752 for text documentation or email. This is the default.
 753
 754 =item B<-main>
 755
 756 Include the main program in the output, even if subroutines were also
 757 specified.
 758
 759 =item B<-base>I<n>
 760
 761 Print OP sequence numbers in base I<n>. If I<n> is greater than 10, the
 762 digit for 11 will be 'a', and so on. If I<n> is greater than 36, the digit
 763 for 37 will be 'A', and so on until 62. Values greater than 62 are not
 764 currently supported. The default is 36.
 765
 766 =item B<-bigendian>
 767
 768 Print sequence numbers with the most significant digit first. This is the
 769 usual convention for Arabic numerals, and the default.
 770
 771 =item B<-littleendian>
 772
 773 Print seqence numbers with the least significant digit first.
 774
 775 =item B<-concise>
 776
 777 Use the author's favorite set of formatting conventions. This is the
 778 default, of course.
 779
 780 =item B<-terse>
 781
 782 Use formatting conventions that emulate the ouput of B<B::Terse>. The
 783 basic mode is almost indistinguishable from the real B<B::Terse>, and the
 784 exec mode looks very similar, but is in a more logical order and lacks
 785 curly brackets. B<B::Terse> doesn't have a tree mode, so the tree mode
 786 is only vaguely reminiscient of B<B::Terse>.
 787
 788 =item B<-linenoise>
 789
 790 Use formatting conventions in which the name of each OP, rather than being
 791 written out in full, is represented by a one- or two-character abbreviation.
 792 This is mainly a joke.
 793
 794 =item B<-debug>
 795
 796 Use formatting conventions reminiscient of B<B::Debug>; these aren't
 797 very concise at all.
 798
 799 =item B<-env>
 800
 801 Use formatting conventions read from the environment variables
 802 C<B_CONCISE_FORMAT>, C<B_CONCISE_GOTO_FORMAT>, and C<B_CONCISE_TREE_FORMAT>.
 803
 804 =back
 805
 806 =head1 FORMATTING SPECIFICATIONS
 807
 808 For each general style ('concise', 'terse', 'linenoise', etc.) there are
 809 three specifications: one of how OPs should appear in the basic or exec
 810 modes, one of how 'goto' lines should appear (these occur in the exec
 811 mode only), and one of how nodes should appear in tree mode. Each has the
 812 same format, described below. Any text that doesn't match a special
 813 pattern is copied verbatim.
 814
 815 =over 4
 816
 817 =item B<(x(>I<exec_text>B<;>I<basic_text>B<)x)>
 818
 819 Generates I<exec_text> in exec mode, or I<basic_text> in basic mode.
 820
 821 =item B<(*(>I<text>B<)*)>
 822
 823 Generates one copy of I<text> for each indentation level.
 824
 825 =item B<(*(>I<text1>B<;>I<text2>B<)*)>
 826
 827 Generates one fewer copies of I<text1> than the indentation level, followed
 828 by one copy of I<text2> if the indentation level is more than 0.
 829
 830 =item B<(?(>I<text1>B<#>I<var>I<Text2>B<)?)>
 831
 832 If the value of I<var> is true (not empty or zero), generates the
 833 value of I<var> surrounded by I<text1> and I<Text2>, otherwise
 834 nothing.
 835
 836 =item B<#>I<var>
 837
 838 Generates the value of the variable I<var>.
 839
 840 =item B<#>I<var>I<N>
 841
 842 Generates the value of I<var>, left jutified to fill I<N> spaces.
 843
 844 =item B<~>
 845
 846 Any number of tildes and surrounding whitespace will be collapsed to
 847 a single space.
 848
 849 =back
 850
 851 The following variables are recognized:
 852
 853 =over 4
 854
 855 =item B<#addr>
 856
 857 The address of the OP, in hexidecimal.
 858
 859 =item B<#arg>
 860
 861 The OP-specific information of the OP (such as the SV for an SVOP, the
 862 non-local exit pointers for a LOOP, etc.) enclosed in paretheses.
 863
 864 =item B<#class>
 865
 866 The B-determined class of the OP, in all caps.
 867
 868 =item B<#classsym>
 869
 870 A single symbol abbreviating the class of the OP.
 871
 872 =item B<#coplabel>
 873
 874 The label of the statement or block the OP is the start of, if any.
 875
 876 =item B<#exname>
 877
 878 The name of the OP, or 'ex-foo' if the OP is a null that used to be a foo.
 879
 880 =item B<#extarg>
 881
 882 The target of the OP, or nothing for a nulled OP.
 883
 884 =item B<#firstaddr>
 885
 886 The address of the OP's first child, in hexidecimal.
 887
 888 =item B<#flags>
 889
 890 The OP's flags, abbreviated as a series of symbols.
 891
 892 =item B<#flagval>
 893
 894 The numeric value of the OP's flags.
 895
 896 =item B<#hyphseq>
 897
 898 The sequence number of the OP, or a hyphen if it doesn't have one.
 899
 900 =item B<#label>
 901
 902 'NEXT', 'LAST', or 'REDO' if the OP is a target of one of those in exec
 903 mode, or empty otherwise.
 904
 905 =item B<#lastaddr>
 906
 907 The address of the OP's last child, in hexidecimal.
 908
 909 =item B<#name>
 910
 911 The OP's name.
 912
 913 =item B<#NAME>
 914
 915 The OP's name, in all caps.
 916
 917 =item B<#next>
 918
 919 The sequence number of the OP's next OP.
 920
 921 =item B<#nextaddr>
 922
 923 The address of the OP's next OP, in hexidecimal.
 924
 925 =item B<#noise>
 926
 927 A one- or two-character abbreviation for the OP's name.
 928
 929 =item B<#private>
 930
 931 The OP's private flags, rendered with abbreviated names if possible.
 932
 933 =item B<#privval>
 934
 935 The numeric value of the OP's private flags.
 936
 937 =item B<#seq>
 938
 939 The sequence number of the OP. Note that this is now a sequence number
 940 generated by B::Concise, rather than the real op_seq value (for which
 941 see B<#seqnum>).
 942
 943 =item B<#seqnum>
 944
 945 The real sequence number of the OP, as a regular number and not adjusted
 946 to be relative to the start of the real program. (This will generally be
 947 a fairly large number because all of B<B::Concise> is compiled before
 948 your program is).
 949
 950 =item B<#sibaddr>
 951
 952 The address of the OP's next youngest sibling, in hexidecimal.
 953
 954 =item B<#svaddr>
 955
 956 The address of the OP's SV, if it has an SV, in hexidecimal.
 957
 958 =item B<#svclass>
 959
 960 The class of the OP's SV, if it has one, in all caps (e.g., 'IV').
 961
 962 =item B<#svval>
 963
 964 The value of the OP's SV, if it has one, in a short human-readable format.
 965
 966 =item B<#targ>
 967
 968 The numeric value of the OP's targ.
 969
 970 =item B<#targarg>
 971
 972 The name of the variable the OP's targ refers to, if any, otherwise the
 973 letter t followed by the OP's targ in decimal.
 974
 975 =item B<#targarglife>
 976
 977 Same as B<#targarg>, but followed by the COP sequence numbers that delimit
 978 the variable's lifetime (or 'end' for a variable in an open scope) for a
 979 variable.
 980
 981 =item B<#typenum>
 982
 983 The numeric value of the OP's type, in decimal.
 984
 985 =back
 986
 987 =head1 ABBREVIATIONS
 988
 989 =head2 OP flags abbreviations
 990
 991     v      OPf_WANT_VOID    Want nothing (void context)
 992     s      OPf_WANT_SCALAR  Want single value (scalar context)
 993     l      OPf_WANT_LIST    Want list of any length (list context)
 994     K      OPf_KIDS         There is a firstborn child.
 995     P      OPf_PARENS       This operator was parenthesized.
 996                              (Or block needs explicit scope entry.)
 997     R      OPf_REF          Certified reference.
 998                              (Return container, not containee).
 999     M      OPf_MOD          Will modify (lvalue).
1000     S      OPf_STACKED      Some arg is arriving on the stack.
1001     *      OPf_SPECIAL      Do something weird for this op (see op.h)
1002
1003 =head2 OP class abbreviations
1004
1005     0      OP (aka BASEOP)  An OP with no children
1006     1      UNOP             An OP with one child
1007     2      BINOP            An OP with two children
1008     |      LOGOP            A control branch OP
1009     @      LISTOP           An OP that could have lots of children
1010     /      PMOP             An OP with a regular expression
1011     $      SVOP             An OP with an SV
1012     "      PVOP             An OP with a string
1013     {      LOOP             An OP that holds pointers for a loop
1014     ;      COP              An OP that marks the start of a statement
1015     #      PADOP            An OP with a GV on the pad
1016
1017 =head1 Using B::Concise outside of the O framework
1018
1019 It is possible to extend B<B::Concise> by using it outside of the B<O>
1020 framework and providing new styles and new variables.
1021
1022     use B::Concise qw(set_style add_callback);
1023     set_style($format, $gotofmt, $treefmt);
1024     add_callback
1025     (
1026         sub
1027         {
1028             my ($h, $op, $level, $format) = @_;
1029             $h->{variable} = some_func($op);
1030         }
1031     );
1032     B::Concise::compile(@options)->();
1033
1034 You can specify a style by calling the B<set_style> subroutine.  If you
1035 have a new variable in your style, or you want to change the value of an
1036 existing variable, you will need to add a callback to specify the value
1037 for that variable.
1038
1039 This is done by calling B<add_callback> passing references to any
1040 callback subroutines.  The subroutines are called in the same order as
1041 they are added.  Each subroutine is passed four parameters.  These are a
1042 reference to a hash, the keys of which are the names of the variables
1043 and the values of which are their values, the op, the level and the
1044 format.
1045
1046 To define your own variables, simply add them to the hash, or change
1047 existing values if you need to.  The level and format are passed in as
1048 references to scalars, but it is unlikely that they will need to be
1049 changed or even used.
1050
1051 To switch back to one of the standard styles like C<concise> or
1052 C<terse>, use C<set_style_standard>.
1053
1054 To see the output, call the subroutine returned by B<compile> in the
1055 same way that B<O> does.
1056
1057 =head1 AUTHOR
1058
1059 Stephen McCamant, E<lt>smcc@CSUA.Berkeley.EDUE<gt>.
1060
1061 =cut