ext/B/B/Concise.pm

   1 package B::Concise;
   2 # Copyright (C) 2000, 2001 Stephen McCamant. All rights reserved.
   3 # This program is free software; you can redistribute and/or modify it
   4 # under the same terms as Perl itself.
   5
   6 use strict;
   7 use warnings;
   8
   9 use Exporter ();
  10
  11 our $VERSION   = "0.52";
  12 our @ISA       = qw(Exporter);
  13 our @EXPORT_OK = qw(set_style add_callback);
  14
  15 use B qw(class ppname main_start main_root main_cv cstring svref_2object
  16          SVf_IOK SVf_NOK SVf_POK OPf_KIDS);
  17
  18 my %style =
  19   ("terse" =>
  20    ["(?(#label =>\n)?)(*(    )*)#class (#addr) #name (?([#targ])?) "
  21     . "#svclass~(?((#svaddr))?)~#svval~(?(label \"#coplabel\")?)\n",
  22     "(*(    )*)goto #class (#addr)\n",
  23     "#class pp_#name"],
  24    "concise" =>
  25    ["#hyphseq2 (*(   (x( ;)x))*)<#classsym> "
  26     . "#exname#arg(?([#targarglife])?)~#flags(?(/#private)?)(x(;~->#next)x)\n",
  27     "  (*(    )*)     goto #seq\n",
  28     "(?(<#seq>)?)#exname#arg(?([#targarglife])?)"],
  29    "linenoise" =>
  30    ["(x(;(*( )*))x)#noise#arg(?([#targarg])?)(x( ;\n)x)",
  31     "gt_#seq ",
  32     "(?(#seq)?)#noise#arg(?([#targarg])?)"],
  33    "debug" =>
  34    ["#class (#addr)\n\top_next\t\t#nextaddr\n\top_sibling\t#sibaddr\n\t"
  35     . "op_ppaddr\tPL_ppaddr[OP_#NAME]\n\top_type\t\t#typenum\n\top_seq\t\t"
  36     . "#seqnum\n\top_flags\t#flagval\n\top_private\t#privval\n"
  37     . "(?(\top_first\t#firstaddr\n)?)(?(\top_last\t\t#lastaddr\n)?)"
  38     . "(?(\top_sv\t\t#svaddr\n)?)",
  39     "    GOTO #addr\n",
  40     "#addr"],
  41    "env" => [$ENV{B_CONCISE_FORMAT}, $ENV{B_CONCISE_GOTO_FORMAT},
  42              $ENV{B_CONCISE_TREE_FORMAT}],
  43   );
  44
  45 my($format, $gotofmt, $treefmt);
  46 my $curcv;
  47 my($seq_base, $cop_seq_base);
  48 my @callbacks;
  49
  50 sub set_style {
  51     ($format, $gotofmt, $treefmt) = @_;
  52 }
  53
  54 sub add_callback {
  55     push @callbacks, @_;
  56 }
  57
  58 sub concise_cv {
  59     my ($order, $cvref) = @_;
  60     my $cv = svref_2object($cvref);
  61     $curcv = $cv;
  62     if ($order eq "exec") {
  63         walk_exec($cv->START);
  64     } elsif ($order eq "basic") {
  65         walk_topdown($cv->ROOT, sub { $_[0]->concise($_[1]) }, 0);
  66     } else {
  67         print tree($cv->ROOT, 0)
  68     }
  69 }
  70
  71 my $start_sym = "\e(0"; # "\cN" sometimes also works
  72 my $end_sym   = "\e(B"; # "\cO" respectively
  73
  74 my @tree_decorations =
  75   (["  ", "--", "+-", "|-", "| ", "`-", "-", 1],
  76    [" ", "-", "+", "+", "|", "`", "", 0],
  77    ["  ", map("$start_sym$_$end_sym", "qq", "wq", "tq", "x ", "mq", "q"), 1],
  78    [" ", map("$start_sym$_$end_sym", "q", "w", "t", "x", "m"), "", 0],
  79   );
  80 my $tree_style = 0;
  81
  82 my $base = 36;
  83 my $big_endian = 1;
  84
  85 my $order = "basic";
  86
  87 set_style(@{$style{concise}});
  88
  89 sub compile {
  90     my @options = grep(/^-/, @_);
  91     my @args = grep(!/^-/, @_);
  92     my $do_main = 0;
  93     for my $o (@options) {
  94         if ($o eq "-basic") {
  95             $order = "basic";
  96         } elsif ($o eq "-exec") {
  97             $order = "exec";
  98         } elsif ($o eq "-tree") {
  99             $order = "tree";
 100         } elsif ($o eq "-compact") {
 101             $tree_style |= 1;
 102         } elsif ($o eq "-loose") {
 103             $tree_style &= ~1;
 104         } elsif ($o eq "-vt") {
 105             $tree_style |= 2;
 106         } elsif ($o eq "-ascii") {
 107             $tree_style &= ~2;
 108         } elsif ($o eq "-main") {
 109             $do_main = 1;
 110         } elsif ($o =~ /^-base(\d+)$/) {
 111             $base = $1;
 112         } elsif ($o eq "-bigendian") {
 113             $big_endian = 1;
 114         } elsif ($o eq "-littleendian") {
 115             $big_endian = 0;
 116         } elsif (exists $style{substr($o, 1)}) {
 117             set_style(@{$style{substr($o, 1)}});
 118         } else {
 119             warn "Option $o unrecognized";
 120         }
 121     }
 122     if (@args) {
 123         return sub {
 124             for my $objname (@args) {
 125                 $objname = "main::" . $objname unless $objname =~ /::/;
 126                 eval "concise_cv(\$order, \\&$objname)";
 127                 die "concise_cv($order, \\&$objname) failed: $@" if $@;
 128             }
 129         }
 130     }
 131     if (!@args or $do_main) {
 132         if ($order eq "exec") {
 133             return sub { return if class(main_start) eq "NULL";
 134                          $curcv = main_cv;
 135                          walk_exec(main_start) }
 136         } elsif ($order eq "tree") {
 137             return sub { return if class(main_root) eq "NULL";
 138                          $curcv = main_cv;
 139                          print tree(main_root, 0) }
 140         } elsif ($order eq "basic") {
 141             return sub { return if class(main_root) eq "NULL";
 142                          $curcv = main_cv;
 143                          walk_topdown(main_root,
 144                                       sub { $_[0]->concise($_[1]) }, 0); }
 145         }
 146     }
 147 }
 148
 149 my %labels;
 150 my $lastnext;
 151
 152 my %opclass = ('OP' => "0", 'UNOP' => "1", 'BINOP' => "2", 'LOGOP' => "|",
 153                'LISTOP' => "@", 'PMOP' => "/", 'SVOP' => "\$", 'GVOP' => "*",
 154                'PVOP' => '"', 'LOOP' => "{", 'COP' => ";", 'PADOP' => "#");
 155
 156 no warnings 'qw'; # "Possible attempt to put comments..."
 157 my @linenoise =
 158   qw'#  () sc (  @? 1  $* gv *{ m$ m@ m% m? p/ *$ $  $# & a& pt \\ s\\ rf bl
 159      `  *? <> ?? ?/ r/ c/ // qr s/ /c y/ =  @= C  sC Cp sp df un BM po +1 +I
 160      -1 -I 1+ I+ 1- I- ** *  i* /  i/ %$ i% x  +  i+ -  i- .  "  << >> <  i<
 161      >  i> <= i, >= i. == i= != i! <? i? s< s> s, s. s= s! s? b& b^ b| -0 -i
 162      !  ~  a2 si cs rd sr e^ lg sq in %x %o ab le ss ve ix ri sf FL od ch cy
 163      uf lf uc lc qm @  [f [  @[ eh vl ky dl ex %  ${ @{ uk pk st jn )  )[ a@
 164      a% sl +] -] [- [+ so rv GS GW MS MW .. f. .f && || ^^ ?: &= |= -> s{ s}
 165      v} ca wa di rs ;; ;  ;d }{ {  }  {} f{ it {l l} rt }l }n }r dm }g }e ^o
 166      ^c ^| ^# um bm t~ u~ ~d DB db ^s se ^g ^r {w }w pf pr ^O ^K ^R ^W ^d ^v
 167      ^e ^t ^k t. fc ic fl .s .p .b .c .l .a .h g1 s1 g2 s2 ?. l? -R -W -X -r
 168      -w -x -e -o -O -z -s -M -A -C -S -c -b -f -d -p -l -u -g -k -t -T -B cd
 169      co cr u. cm ut r. l@ s@ r@ mD uD oD rD tD sD wD cD f$ w$ p$ sh e$ k$ g3
 170      g4 s4 g5 s5 T@ C@ L@ G@ A@ S@ Hg Hc Hr Hw Mg Mc Ms Mr Sg Sc So rq do {e
 171      e} {t t} g6 G6 6e g7 G7 7e g8 G8 8e g9 G9 9e 6s 7s 8s 9s 6E 7E 8E 9E Pn
 172      Pu GP SP EP Gn Gg GG SG EG g0 c$ lk t$ ;s n>';
 173
 174 my $chars = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ";
 175
 176 sub op_flags {
 177     my($x) = @_;
 178     my(@v);
 179     push @v, "v" if ($x & 3) == 1;
 180     push @v, "s" if ($x & 3) == 2;
 181     push @v, "l" if ($x & 3) == 3;
 182     push @v, "K" if $x & 4;
 183     push @v, "P" if $x & 8;
 184     push @v, "R" if $x & 16;
 185     push @v, "M" if $x & 32;
 186     push @v, "S" if $x & 64;
 187     push @v, "*" if $x & 128;
 188     return join("", @v);
 189 }
 190
 191 sub base_n {
 192     my $x = shift;
 193     return "-" . base_n(-$x) if $x < 0;
 194     my $str = "";
 195     do { $str .= substr($chars, $x % $base, 1) } while $x = int($x / $base);
 196     $str = reverse $str if $big_endian;
 197     return $str;
 198 }
 199
 200 sub seq { return $_[0]->seq ? base_n($_[0]->seq - $seq_base) : "-" }
 201
 202 sub walk_topdown {
 203     my($op, $sub, $level) = @_;
 204     $sub->($op, $level);
 205     if ($op->flags & OPf_KIDS) {
 206         for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
 207             walk_topdown($kid, $sub, $level + 1);
 208         }
 209     }
 210     if (class($op) eq "PMOP" and $ {$op->pmreplroot}
 211         and $op->pmreplroot->isa("B::OP")) {
 212         walk_topdown($op->pmreplroot, $sub, $level + 1);
 213     }
 214 }
 215
 216 sub walklines {
 217     my($ar, $level) = @_;
 218     for my $l (@$ar) {
 219         if (ref($l) eq "ARRAY") {
 220             walklines($l, $level + 1);
 221         } else {
 222             $l->concise($level);
 223         }
 224     }
 225 }
 226
 227 sub walk_exec {
 228     my($top, $level) = @_;
 229     my %opsseen;
 230     my @lines;
 231     my @todo = ([$top, \@lines]);
 232     while (@todo and my($op, $targ) = @{shift @todo}) {
 233         for (; $$op; $op = $op->next) {
 234             last if $opsseen{$$op}++;
 235             push @$targ, $op;
 236             my $name = $op->name;
 237             if ($name
 238                 =~ /^(or|and|(map|grep)while|entertry|range|cond_expr)$/) {
 239                 my $ar = [];
 240                 push @$targ, $ar;
 241                 push @todo, [$op->other, $ar];
 242             } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
 243                 my $ar = [];
 244                 push @$targ, $ar;
 245                 push @todo, [$op->pmreplstart, $ar];
 246             } elsif ($name =~ /^enter(loop|iter)$/) {
 247                 $labels{$op->nextop->seq} = "NEXT";
 248                 $labels{$op->lastop->seq} = "LAST";
 249                 $labels{$op->redoop->seq} = "REDO";
 250             }
 251         }
 252     }
 253     walklines(\@lines, 0);
 254 }
 255
 256 sub fmt_line {
 257     my($hr, $fmt, $level) = @_;
 258     my $text = $fmt;
 259     $text =~ s/\(\?\(([^\#]*?)\#(\w+)([^\#]*?)\)\?\)/
 260       $hr->{$2} ? $1.$hr->{$2}.$3 : ""/eg;
 261     $text =~ s/\(x\((.*?);(.*?)\)x\)/$order eq "exec" ? $1 : $2/egs;
 262     $text =~ s/\(\*\(([^;]*?)\)\*\)/$1 x $level/egs;
 263     $text =~ s/\(\*\((.*?);(.*?)\)\*\)/$1 x ($level - 1) . $2 x ($level>0)/egs;
 264     $text =~ s/#([a-zA-Z]+)(\d+)/sprintf("%-$2s", $hr->{$1})/eg;
 265     $text =~ s/#([a-zA-Z]+)/$hr->{$1}/eg;
 266     $text =~ s/[ \t]*~+[ \t]*/ /g;
 267     return $text;
 268 }
 269
 270 my %priv;
 271 $priv{$_}{128} = "LVINTRO"
 272   for ("pos", "substr", "vec", "threadsv", "gvsv", "rv2sv", "rv2hv", "rv2gv",
 273        "rv2av", "rv2arylen", "aelem", "helem", "aslice", "hslice", "padsv",
 274        "padav", "padhv");
 275 $priv{$_}{64} = "REFC" for ("leave", "leavesub", "leavesublv", "leavewrite");
 276 $priv{"aassign"}{64} = "COMMON";
 277 $priv{"sassign"}{64} = "BKWARD";
 278 $priv{$_}{64} = "RTIME" for ("match", "subst", "substcont");
 279 @{$priv{"trans"}}{1,2,4,8,16,64} = ("<UTF", ">UTF", "IDENT", "SQUASH", "DEL",
 280                                     "COMPL", "GROWS");
 281 $priv{"repeat"}{64} = "DOLIST";
 282 $priv{"leaveloop"}{64} = "CONT";
 283 @{$priv{$_}}{32,64,96} = ("DREFAV", "DREFHV", "DREFSV")
 284   for ("entersub", map("rv2${_}v", "a", "s", "h", "g"), "aelem", "helem");
 285 $priv{"entersub"}{16} = "DBG";
 286 $priv{"entersub"}{32} = "TARG";
 287 @{$priv{$_}}{4,8,128} = ("INARGS","AMPER","NO()") for ("entersub", "rv2cv");
 288 $priv{"gv"}{32} = "EARLYCV";
 289 $priv{"aelem"}{16} = $priv{"helem"}{16} = "LVDEFER";
 290 $priv{$_}{16} = "OURINTR" for ("gvsv", "rv2sv", "rv2av", "rv2hv", "r2gv");
 291 $priv{$_}{16} = "TARGMY"
 292   for (map(($_,"s$_"),"chop", "chomp"),
 293        map(($_,"i_$_"), "postinc", "postdec", "multiply", "divide", "modulo",
 294            "add", "subtract", "negate"), "pow", "concat", "stringify",
 295        "left_shift", "right_shift", "bit_and", "bit_xor", "bit_or",
 296        "complement", "atan2", "sin", "cos", "rand", "exp", "log", "sqrt",
 297        "int", "hex", "oct", "abs", "length", "index", "rindex", "sprintf",
 298        "ord", "chr", "crypt", "quotemeta", "join", "push", "unshift", "flock",
 299        "chdir", "chown", "chroot", "unlink", "chmod", "utime", "rename",
 300        "link", "symlink", "mkdir", "rmdir", "wait", "waitpid", "system",
 301        "exec", "kill", "getppid", "getpgrp", "setpgrp", "getpriority",
 302        "setpriority", "time", "sleep");
 303 @{$priv{"const"}}{8,16,32,64,128} = ("STRICT","ENTERED", '$[', "BARE", "WARN");
 304 $priv{"flip"}{64} = $priv{"flop"}{64} = "LINENUM";
 305 $priv{"list"}{64} = "GUESSED";
 306 $priv{"delete"}{64} = "SLICE";
 307 $priv{"exists"}{64} = "SUB";
 308 $priv{$_}{64} = "LOCALE"
 309   for ("sort", "prtf", "sprintf", "slt", "sle", "seq", "sne", "sgt", "sge",
 310        "scmp", "lc", "uc", "lcfirst", "ucfirst");
 311 @{$priv{"sort"}}{1,2,4} = ("NUM", "INT", "REV");
 312 $priv{"threadsv"}{64} = "SVREFd";
 313 $priv{$_}{16} = "INBIN" for ("open", "backtick");
 314 $priv{$_}{32} = "INCR" for ("open", "backtick");
 315 $priv{$_}{64} = "OUTBIN" for ("open", "backtick");
 316 $priv{$_}{128} = "OUTCR" for ("open", "backtick");
 317 $priv{"exit"}{128} = "VMS";
 318
 319 sub private_flags {
 320     my($name, $x) = @_;
 321     my @s;
 322     for my $flag (128, 96, 64, 32, 16, 8, 4, 2, 1) {
 323         if ($priv{$name}{$flag} and $x & $flag and $x >= $flag) {
 324             $x -= $flag;
 325             push @s, $priv{$name}{$flag};
 326         }
 327     }
 328     push @s, $x if $x;
 329     return join(",", @s);
 330 }
 331
 332 sub concise_op {
 333     my ($op, $level, $format) = @_;
 334     my %h;
 335     $h{exname} = $h{name} = $op->name;
 336     $h{NAME} = uc $h{name};
 337     $h{class} = class($op);
 338     $h{extarg} = $h{targ} = $op->targ;
 339     $h{extarg} = "" unless $h{extarg};
 340     if ($h{name} eq "null" and $h{targ}) {
 341         $h{exname} = "ex-" . substr(ppname($h{targ}), 3);
 342         $h{extarg} = "";
 343     } elsif ($h{targ}) {
 344         my $padname = (($curcv->PADLIST->ARRAY)[0]->ARRAY)[$h{targ}];
 345         if (defined $padname and class($padname) ne "SPECIAL") {
 346             $h{targarg}  = $padname->PVX;
 347             my $intro = $padname->NVX - $cop_seq_base;
 348             my $finish = int($padname->IVX) - $cop_seq_base;
 349             $finish = "end" if $finish == 999999999 - $cop_seq_base;
 350             $h{targarglife} = "$h{targarg}:$intro,$finish";
 351         } else {
 352             $h{targarglife} = $h{targarg} = "t" . $h{targ};
 353         }
 354     }
 355     $h{arg} = "";
 356     $h{svclass} = $h{svaddr} = $h{svval} = "";
 357     if ($h{class} eq "PMOP") {
 358         my $precomp = $op->precomp;
 359         if (defined $precomp) {
 360             # Escape literal control sequences
 361             for ($precomp) {
 362                 s/\t/\\t/g; s/\n/\\n/g; s/\r/\\r/g;
 363                 # How can we do the below portably?
 364                 #s/([\0-\037\177-\377])/"\\".sprintf("%03o", ord($1))/eg;
 365             }
 366             $precomp = "/$precomp/";
 367         }
 368         else { $precomp = ""; }
 369         my $pmreplroot = $op->pmreplroot;
 370         my $pmreplstart;
 371         if ($$pmreplroot && $pmreplroot->isa("B::GV")) {
 372             # with C<@stash_array = split(/pat/, str);>,
 373             #  *stash_array is stored in pmreplroot.
 374             $h{arg} = "($precomp => \@" . $pmreplroot->NAME . ")";
 375         } elsif ($ {$op->pmreplstart}) {
 376             undef $lastnext;
 377             $pmreplstart = "replstart->" . seq($op->pmreplstart);
 378             $h{arg} = "(" . join(" ", $precomp, $pmreplstart) . ")";
 379         } else {
 380             $h{arg} = "($precomp)";
 381         }
 382     } elsif ($h{class} eq "PVOP" and $h{name} ne "trans") {
 383         $h{arg} = '("' . $op->pv . '")';
 384         $h{svval} = '"' . $op->pv . '"';
 385     } elsif ($h{class} eq "COP") {
 386         my $label = $op->label;
 387         $h{coplabel} = $label;
 388         $label = $label ? "$label: " : "";
 389         my $loc = $op->file;
 390         $loc =~ s[.*/][];
 391         $loc .= ":" . $op->line;
 392         my($stash, $cseq) = ($op->stash->NAME, $op->cop_seq - $cop_seq_base);
 393         my $arybase = $op->arybase;
 394         $arybase = $arybase ? ' $[=' . $arybase : "";
 395         $h{arg} = "($label$stash $cseq $loc$arybase)";
 396     } elsif ($h{class} eq "LOOP") {
 397         $h{arg} = "(next->" . seq($op->nextop) . " last->" . seq($op->lastop)
 398           . " redo->" . seq($op->redoop) . ")";
 399     } elsif ($h{class} eq "LOGOP") {
 400         undef $lastnext;
 401         $h{arg} = "(other->" . seq($op->other) . ")";
 402     } elsif ($h{class} eq "SVOP") {
 403         my $sv = $op->sv;
 404         $h{svclass} = class($sv);
 405         $h{svaddr} = sprintf("%#x", $$sv);
 406         if ($h{svclass} eq "GV") {
 407             my $gv = $sv;
 408             my $stash = $gv->STASH->NAME;
 409             if ($stash eq "main") {
 410                 $stash = "";
 411             } else {
 412                 $stash = $stash . "::";
 413             }
 414             $h{arg} = "(*$stash" . $gv->SAFENAME . ")";
 415             $h{svval} = "*$stash" . $gv->SAFENAME;
 416         } else {
 417             while (class($sv) eq "RV") {
 418                 $h{svval} .= "\\";
 419                 $sv = $sv->RV;
 420             }
 421             if (class($sv) eq "SPECIAL") {
 422                 $h{svval} = ["Null", "sv_undef", "sv_yes", "sv_no"]->[$$sv];
 423             } elsif ($sv->FLAGS & SVf_NOK) {
 424                 $h{svval} = $sv->NV;
 425             } elsif ($sv->FLAGS & SVf_IOK) {
 426                 $h{svval} = $sv->IV;
 427             } elsif ($sv->FLAGS & SVf_POK) {
 428                 $h{svval} = cstring($sv->PV);
 429             }
 430             $h{arg} = "($h{svclass} $h{svval})";
 431         }
 432     }
 433     $h{seq} = $h{hyphseq} = seq($op);
 434     $h{seq} = "" if $h{seq} eq "-";
 435     $h{seqnum} = $op->seq;
 436     $h{next} = $op->next;
 437     $h{next} = (class($h{next}) eq "NULL") ? "(end)" : seq($h{next});
 438     $h{nextaddr} = sprintf("%#x", $ {$op->next});
 439     $h{sibaddr} = sprintf("%#x", $ {$op->sibling});
 440     $h{firstaddr} = sprintf("%#x", $ {$op->first}) if $op->can("first");
 441     $h{lastaddr} = sprintf("%#x", $ {$op->last}) if $op->can("last");
 442
 443     $h{classsym} = $opclass{$h{class}};
 444     $h{flagval} = $op->flags;
 445     $h{flags} = op_flags($op->flags);
 446     $h{privval} = $op->private;
 447     $h{private} = private_flags($h{name}, $op->private);
 448     $h{addr} = sprintf("%#x", $$op);
 449     $h{label} = $labels{$op->seq};
 450     $h{typenum} = $op->type;
 451     $h{noise} = $linenoise[$op->type];
 452     $_->(\%h, $op, \$format, \$level) for @callbacks;
 453     return fmt_line(\%h, $format, $level);
 454 }
 455
 456 sub B::OP::concise {
 457     my($op, $level) = @_;
 458     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
 459         my $h = {"seq" => seq($lastnext), "class" => class($lastnext),
 460                  "addr" => sprintf("%#x", $$lastnext)};
 461         print fmt_line($h, $gotofmt, $level+1);
 462     }
 463     $lastnext = $op->next;
 464     print concise_op($op, $level, $format);
 465 }
 466
 467 sub tree {
 468     my $op = shift;
 469     my $level = shift;
 470     my $style = $tree_decorations[$tree_style];
 471     my($space, $single, $kids, $kid, $nokid, $last, $lead, $size) = @$style;
 472     my $name = concise_op($op, $level, $treefmt);
 473     if (not $op->flags & OPf_KIDS) {
 474         return $name . "\n";
 475     }
 476     my @lines;
 477     for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
 478         push @lines, tree($kid, $level+1);
 479     }
 480     my $i;
 481     for ($i = $#lines; substr($lines[$i], 0, 1) eq " "; $i--) {
 482         $lines[$i] = $space . $lines[$i];
 483     }
 484     if ($i > 0) {
 485         $lines[$i] = $last . $lines[$i];
 486         while ($i-- > 1) {
 487             if (substr($lines[$i], 0, 1) eq " ") {
 488                 $lines[$i] = $nokid . $lines[$i];
 489             } else {
 490                 $lines[$i] = $kid . $lines[$i];
 491             }
 492         }
 493         $lines[$i] = $kids . $lines[$i];
 494     } else {
 495         $lines[0] = $single . $lines[0];
 496     }
 497     return("$name$lead" . shift @lines,
 498            map(" " x (length($name)+$size) . $_, @lines));
 499 }
 500
 501 # *** Warning: fragile kludge ahead ***
 502 # Because the B::* modules run in the same interpreter as the code
 503 # they're compiling, their presence tends to distort the view we have
 504 # of the code we're looking at. In particular, perl gives sequence
 505 # numbers to both OPs in general and COPs in particular. If the
 506 # program we're looking at were run on its own, these numbers would
 507 # start at 1. Because all of B::Concise and all the modules it uses
 508 # are compiled first, though, by the time we get to the user's program
 509 # the sequence numbers are alreay at pretty high numbers, which would
 510 # be distracting if you're trying to tell OPs apart. Therefore we'd
 511 # like to subtract an offset from all the sequence numbers we display,
 512 # to restore the simpler view of the world. The trick is to know what
 513 # that offset will be, when we're still compiling B::Concise!  If we
 514 # hardcoded a value, it would have to change every time B::Concise or
 515 # other modules we use do. To help a little, what we do here is
 516 # compile a little code at the end of the module, and compute the base
 517 # sequence number for the user's program as being a small offset
 518 # later, so all we have to worry about are changes in the offset.
 519
 520 # When you say "perl -MO=Concise -e '$a'", the output should look like:
 521
 522 # 4  <@> leave[t1] vKP/REFC ->(end)
 523 # 1     <0> enter ->2
 524  #^ smallest OP sequence number should be 1
 525 # 2     <;> nextstate(main 1 -e:1) v ->3
 526  #                         ^ smallest COP sequence number should be 1
 527 # -     <1> ex-rv2sv vK/1 ->4
 528 # 3        <$> gvsv(*a) s ->4
 529
 530 # If either of the marked numbers there aren't 1, it means you need to
 531 # update the corresponding magic number in the next two lines.
 532 # Remember, these need to stay the last things in the module.
 533
 534 # Why these are different for MacOS?  Does it matter?
 535 my $cop_seq_mnum = $^O eq 'MacOS' ? 12 : 11;
 536 my $seq_mnum = $^O eq 'MacOS' ? 100 : 84;
 537 $cop_seq_base = svref_2object(eval 'sub{0;}')->START->cop_seq + $cop_seq_mnum;
 538 $seq_base = svref_2object(eval 'sub{}')->START->seq + $seq_mnum;
 539
 540 1;
 541
 542 __END__
 543
 544 =head1 NAME
 545
 546 B::Concise - Walk Perl syntax tree, printing concise info about ops
 547
 548 =head1 SYNOPSIS
 549
 550     perl -MO=Concise[,OPTIONS] foo.pl
 551
 552     use B::Concise qw(set_style add_callback);
 553
 554 =head1 DESCRIPTION
 555
 556 This compiler backend prints the internal OPs of a Perl program's syntax
 557 tree in one of several space-efficient text formats suitable for debugging
 558 the inner workings of perl or other compiler backends. It can print OPs in
 559 the order they appear in the OP tree, in the order they will execute, or
 560 in a text approximation to their tree structure, and the format of the
 561 information displyed is customizable. Its function is similar to that of
 562 perl's B<-Dx> debugging flag or the B<B::Terse> module, but it is more
 563 sophisticated and flexible.
 564
 565 =head1 EXAMPLE
 566
 567 Here's is a short example of output, using the default formatting
 568 conventions :
 569
 570     % perl -MO=Concise -e '$a = $b + 42'
 571     8  <@> leave[t1] vKP/REFC ->(end)
 572     1     <0> enter ->2
 573     2     <;> nextstate(main 1 -e:1) v ->3
 574     7     <2> sassign vKS/2 ->8
 575     5        <2> add[t1] sK/2 ->6
 576     -           <1> ex-rv2sv sK/1 ->4
 577     3              <$> gvsv(*b) s ->4
 578     4           <$> const(IV 42) s ->5
 579     -        <1> ex-rv2sv sKRM*/1 ->7
 580     6           <$> gvsv(*a) s ->7
 581
 582 Each line corresponds to an operator. Null ops appear as C<ex-opname>,
 583 where I<opname> is the op that has been optimized away by perl.
 584
 585 The number on the first row indicates the op's sequence number. It's
 586 given in base 36 by default.
 587
 588 The symbol between angle brackets indicates the op's type : for example,
 589 <2> is a BINOP, <@> a LISTOP, etc. (see L</"OP class abbreviations">).
 590
 591 The opname may be followed by op-specific information in parentheses
 592 (e.g. C<gvsv(*b)>), and by targ information in brackets (e.g.
 593 C<leave[t1]>).
 594
 595 Next come the op flags. The common flags are listed below
 596 (L</"OP flags abbreviations">). The private flags follow, separated
 597 by a slash. For example, C<vKP/REFC> means that the leave op has
 598 public flags OPf_WANT_VOID, OPf_KIDS, and OPf_PARENS, and the private
 599 flag OPpREFCOUNTED.
 600
 601 Finally an arrow points to the sequence number of the next op.
 602
 603 =head1 OPTIONS
 604
 605 Arguments that don't start with a hyphen are taken to be the names of
 606 subroutines to print the OPs of; if no such functions are specified, the
 607 main body of the program (outside any subroutines, and not including use'd
 608 or require'd files) is printed.
 609
 610 =over 4
 611
 612 =item B<-basic>
 613
 614 Print OPs in the order they appear in the OP tree (a preorder
 615 traversal, starting at the root). The indentation of each OP shows its
 616 level in the tree.  This mode is the default, so the flag is included
 617 simply for completeness.
 618
 619 =item B<-exec>
 620
 621 Print OPs in the order they would normally execute (for the majority
 622 of constructs this is a postorder traversal of the tree, ending at the
 623 root). In most cases the OP that usually follows a given OP will
 624 appear directly below it; alternate paths are shown by indentation. In
 625 cases like loops when control jumps out of a linear path, a 'goto'
 626 line is generated.
 627
 628 =item B<-tree>
 629
 630 Print OPs in a text approximation of a tree, with the root of the tree
 631 at the left and 'left-to-right' order of children transformed into
 632 'top-to-bottom'. Because this mode grows both to the right and down,
 633 it isn't suitable for large programs (unless you have a very wide
 634 terminal).
 635
 636 =item B<-compact>
 637
 638 Use a tree format in which the minimum amount of space is used for the
 639 lines connecting nodes (one character in most cases). This squeezes out
 640 a few precious columns of screen real estate.
 641
 642 =item B<-loose>
 643
 644 Use a tree format that uses longer edges to separate OP nodes. This format
 645 tends to look better than the compact one, especially in ASCII, and is
 646 the default.
 647
 648 =item B<-vt>
 649
 650 Use tree connecting characters drawn from the VT100 line-drawing set.
 651 This looks better if your terminal supports it.
 652
 653 =item B<-ascii>
 654
 655 Draw the tree with standard ASCII characters like C<+> and C<|>. These don't
 656 look as clean as the VT100 characters, but they'll work with almost any
 657 terminal (or the horizontal scrolling mode of less(1)) and are suitable
 658 for text documentation or email. This is the default.
 659
 660 =item B<-main>
 661
 662 Include the main program in the output, even if subroutines were also
 663 specified.
 664
 665 =item B<-base>I<n>
 666
 667 Print OP sequence numbers in base I<n>. If I<n> is greater than 10, the
 668 digit for 11 will be 'a', and so on. If I<n> is greater than 36, the digit
 669 for 37 will be 'A', and so on until 62. Values greater than 62 are not
 670 currently supported. The default is 36.
 671
 672 =item B<-bigendian>
 673
 674 Print sequence numbers with the most significant digit first. This is the
 675 usual convention for Arabic numerals, and the default.
 676
 677 =item B<-littleendian>
 678
 679 Print seqence numbers with the least significant digit first.
 680
 681 =item B<-concise>
 682
 683 Use the author's favorite set of formatting conventions. This is the
 684 default, of course.
 685
 686 =item B<-terse>
 687
 688 Use formatting conventions that emulate the ouput of B<B::Terse>. The
 689 basic mode is almost indistinguishable from the real B<B::Terse>, and the
 690 exec mode looks very similar, but is in a more logical order and lacks
 691 curly brackets. B<B::Terse> doesn't have a tree mode, so the tree mode
 692 is only vaguely reminiscient of B<B::Terse>.
 693
 694 =item B<-linenoise>
 695
 696 Use formatting conventions in which the name of each OP, rather than being
 697 written out in full, is represented by a one- or two-character abbreviation.
 698 This is mainly a joke.
 699
 700 =item B<-debug>
 701
 702 Use formatting conventions reminiscient of B<B::Debug>; these aren't
 703 very concise at all.
 704
 705 =item B<-env>
 706
 707 Use formatting conventions read from the environment variables
 708 C<B_CONCISE_FORMAT>, C<B_CONCISE_GOTO_FORMAT>, and C<B_CONCISE_TREE_FORMAT>.
 709
 710 =back
 711
 712 =head1 FORMATTING SPECIFICATIONS
 713
 714 For each general style ('concise', 'terse', 'linenoise', etc.) there are
 715 three specifications: one of how OPs should appear in the basic or exec
 716 modes, one of how 'goto' lines should appear (these occur in the exec
 717 mode only), and one of how nodes should appear in tree mode. Each has the
 718 same format, described below. Any text that doesn't match a special
 719 pattern is copied verbatim.
 720
 721 =over 4
 722
 723 =item B<(x(>I<exec_text>B<;>I<basic_text>B<)x)>
 724
 725 Generates I<exec_text> in exec mode, or I<basic_text> in basic mode.
 726
 727 =item B<(*(>I<text>B<)*)>
 728
 729 Generates one copy of I<text> for each indentation level.
 730
 731 =item B<(*(>I<text1>B<;>I<text2>B<)*)>
 732
 733 Generates one fewer copies of I<text1> than the indentation level, followed
 734 by one copy of I<text2> if the indentation level is more than 0.
 735
 736 =item B<(?(>I<text1>B<#>I<var>I<Text2>B<)?)>
 737
 738 If the value of I<var> is true (not empty or zero), generates the
 739 value of I<var> surrounded by I<text1> and I<Text2>, otherwise
 740 nothing.
 741
 742 =item B<#>I<var>
 743
 744 Generates the value of the variable I<var>.
 745
 746 =item B<#>I<var>I<N>
 747
 748 Generates the value of I<var>, left jutified to fill I<N> spaces.
 749
 750 =item B<~>
 751
 752 Any number of tildes and surrounding whitespace will be collapsed to
 753 a single space.
 754
 755 =back
 756
 757 The following variables are recognized:
 758
 759 =over 4
 760
 761 =item B<#addr>
 762
 763 The address of the OP, in hexidecimal.
 764
 765 =item B<#arg>
 766
 767 The OP-specific information of the OP (such as the SV for an SVOP, the
 768 non-local exit pointers for a LOOP, etc.) enclosed in paretheses.
 769
 770 =item B<#class>
 771
 772 The B-determined class of the OP, in all caps.
 773
 774 =item B<#classsym>
 775
 776 A single symbol abbreviating the class of the OP.
 777
 778 =item B<#coplabel>
 779
 780 The label of the statement or block the OP is the start of, if any.
 781
 782 =item B<#exname>
 783
 784 The name of the OP, or 'ex-foo' if the OP is a null that used to be a foo.
 785
 786 =item B<#extarg>
 787
 788 The target of the OP, or nothing for a nulled OP.
 789
 790 =item B<#firstaddr>
 791
 792 The address of the OP's first child, in hexidecimal.
 793
 794 =item B<#flags>
 795
 796 The OP's flags, abbreviated as a series of symbols.
 797
 798 =item B<#flagval>
 799
 800 The numeric value of the OP's flags.
 801
 802 =item B<#hyphseq>
 803
 804 The sequence number of the OP, or a hyphen if it doesn't have one.
 805
 806 =item B<#label>
 807
 808 'NEXT', 'LAST', or 'REDO' if the OP is a target of one of those in exec
 809 mode, or empty otherwise.
 810
 811 =item B<#lastaddr>
 812
 813 The address of the OP's last child, in hexidecimal.
 814
 815 =item B<#name>
 816
 817 The OP's name.
 818
 819 =item B<#NAME>
 820
 821 The OP's name, in all caps.
 822
 823 =item B<#next>
 824
 825 The sequence number of the OP's next OP.
 826
 827 =item B<#nextaddr>
 828
 829 The address of the OP's next OP, in hexidecimal.
 830
 831 =item B<#noise>
 832
 833 The two-character abbreviation for the OP's name.
 834
 835 =item B<#private>
 836
 837 The OP's private flags, rendered with abbreviated names if possible.
 838
 839 =item B<#privval>
 840
 841 The numeric value of the OP's private flags.
 842
 843 =item B<#seq>
 844
 845 The sequence number of the OP.
 846
 847 =item B<#seqnum>
 848
 849 The real sequence number of the OP, as a regular number and not adjusted
 850 to be relative to the start of the real program. (This will generally be
 851 a fairly large number because all of B<B::Concise> is compiled before
 852 your program is).
 853
 854 =item B<#sibaddr>
 855
 856 The address of the OP's next youngest sibling, in hexidecimal.
 857
 858 =item B<#svaddr>
 859
 860 The address of the OP's SV, if it has an SV, in hexidecimal.
 861
 862 =item B<#svclass>
 863
 864 The class of the OP's SV, if it has one, in all caps (e.g., 'IV').
 865
 866 =item B<#svval>
 867
 868 The value of the OP's SV, if it has one, in a short human-readable format.
 869
 870 =item B<#targ>
 871
 872 The numeric value of the OP's targ.
 873
 874 =item B<#targarg>
 875
 876 The name of the variable the OP's targ refers to, if any, otherwise the
 877 letter t followed by the OP's targ in decimal.
 878
 879 =item B<#targarglife>
 880
 881 Same as B<#targarg>, but followed by the COP sequence numbers that delimit
 882 the variable's lifetime (or 'end' for a variable in an open scope) for a
 883 variable.
 884
 885 =item B<#typenum>
 886
 887 The numeric value of the OP's type, in decimal.
 888
 889 =back
 890
 891 =head1 ABBREVIATIONS
 892
 893 =head2 OP flags abbreviations
 894
 895     v      OPf_WANT_VOID    Want nothing (void context)
 896     s      OPf_WANT_SCALAR  Want single value (scalar context)
 897     l      OPf_WANT_LIST    Want list of any length (list context)
 898     K      OPf_KIDS         There is a firstborn child.
 899     P      OPf_PARENS       This operator was parenthesized.
 900                              (Or block needs explicit scope entry.)
 901     R      OPf_REF          Certified reference.
 902                              (Return container, not containee).
 903     M      OPf_MOD          Will modify (lvalue).
 904     S      OPf_STACKED      Some arg is arriving on the stack.
 905     *      OPf_SPECIAL      Do something weird for this op (see op.h)
 906
 907 =head2 OP class abbreviations
 908
 909     0      OP (aka BASEOP)  An OP with no children
 910     1      UNOP             An OP with one child
 911     2      BINOP            An OP with two children
 912     |      LOGOP            A control branch OP
 913     @      LISTOP           An OP that could have lots of children
 914     /      PMOP             An OP with a regular expression
 915     $      SVOP             An OP with an SV
 916     "      PVOP             An OP with a string
 917     {      LOOP             An OP that holds pointers for a loop
 918     ;      COP              An OP that marks the start of a statement
 919     #      PADOP            An OP with a GV on the pad
 920
 921 =head1 Using B::Concise outside of the O framework
 922
 923 It is possible to extend B<B::Concise> by using it outside of the B<O>
 924 framework and providing new styles and new variables.
 925
 926     use B::Concise qw(set_style add_callback);
 927     set_style($format, $gotofmt, $treefmt);
 928     add_callback
 929     (
 930         sub
 931         {
 932             my ($h, $op, $level, $format) = @_;
 933             $h->{variable} = some_func($op);
 934         }
 935     );
 936     B::Concise::compile(@options)->();
 937
 938 You can specify a style by calling the B<set_style> subroutine.  If you
 939 have a new variable in your style, or you want to change the value of an
 940 existing variable, you will need to add a callback to specify the value
 941 for that variable.
 942
 943 This is done by calling B<add_callback> passing references to any
 944 callback subroutines.  The subroutines are called in the same order as
 945 they are added.  Each subroutine is passed four parameters.  These are a
 946 reference to a hash, the keys of which are the names of the variables
 947 and the values of which are their values, the op, the level and the
 948 format.
 949
 950 To define your own variables, simply add them to the hash, or change
 951 existing values if you need to.  The level and format are passed in as
 952 references to scalars, but it is unlikely that they will need to be
 953 changed or even used.
 954
 955 To see the output, call the subroutine returned by B<compile> in the
 956 same way that B<O> does.
 957
 958 =head1 AUTHOR
 959
 960 Stephen McCamant, C<smcc@CSUA.Berkeley.EDU>
 961
 962 =cut