ext/B/B/Bytecode.pm

   1 # B::Bytecode.pm
   2 # Copyright (c) 2003 Enache Adrian. All rights reserved.
   3 # This module is free software; you can redistribute and/or modify
   4 # it under the same terms as Perl itself.
   5
   6 # Based on the original Bytecode.pm module written by Malcolm Beattie.
   7
   8 package B::Bytecode;
   9
  10 our $VERSION = '1.01';
  11
  12 use strict;
  13 use Config;
  14 use B qw(class main_cv main_root main_start cstring comppadlist
  15         defstash curstash begin_av init_av end_av inc_gv warnhook diehook
  16         dowarn SVt_PVGV SVt_PVHV OPf_SPECIAL OPf_STACKED OPf_MOD
  17         OPpLVAL_INTRO SVf_FAKE SVf_READONLY);
  18 use B::Asmdata qw(@specialsv_name);
  19 use B::Assembler qw(asm newasm endasm);
  20
  21 #################################################
  22
  23 my ($varix, $opix, $savebegins, %walked, %files, @cloop);
  24 my %strtab = (0,0);
  25 my %svtab = (0,0);
  26 my %optab = (0,0);
  27 my %spectab = (0,0);
  28 my $tix = 1;
  29 sub asm;
  30 sub nice ($) { }
  31
  32 BEGIN {
  33     my $ithreads = $Config{'useithreads'} eq 'define';
  34     eval qq{
  35         sub ITHREADS() { $ithreads }
  36         sub VERSION() { $] }
  37     }; die $@ if $@;
  38 }
  39
  40 #################################################
  41
  42 sub pvstring {
  43     my $pv = shift;
  44     defined($pv) ? cstring ($pv."\0") : "\"\"";
  45 }
  46
  47 sub pvix {
  48     my $str = pvstring shift;
  49     my $ix = $strtab{$str};
  50     defined($ix) ? $ix : do {
  51         asm "newpv", $str;
  52         asm "stpv", $strtab{$str} = $tix;
  53         $tix++;
  54     }
  55 }
  56
  57 sub B::OP::ix {
  58     my $op = shift;
  59     my $ix = $optab{$$op};
  60     defined($ix) ? $ix : do {
  61         nice "[".$op->name." $tix]";
  62         asm "newopx", $op->size | $op->type <<7;
  63         $optab{$$op} = $opix = $ix = $tix++;
  64         $op->bsave($ix);
  65         $ix;
  66     }
  67 }
  68
  69 sub B::SPECIAL::ix {
  70     my $spec = shift;
  71     my $ix = $spectab{$$spec};
  72     defined($ix) ? $ix : do {
  73         nice '['.$specialsv_name[$$spec].']';
  74         asm "ldspecsvx", $$spec;
  75         $spectab{$$spec} = $varix = $tix++;
  76     }
  77 }
  78
  79 sub B::SV::ix {
  80     my $sv = shift;
  81     my $ix = $svtab{$$sv};
  82     defined($ix) ? $ix : do {
  83         nice '['.class($sv).']';
  84         asm "newsvx", $sv->FLAGS;
  85         $svtab{$$sv} = $varix = $ix = $tix++;
  86         $sv->bsave($ix);
  87         $ix;
  88     }
  89 }
  90
  91 sub B::GV::ix {
  92     my ($gv,$desired) = @_;
  93     my $ix = $svtab{$$gv};
  94     defined($ix) ? $ix : do {
  95         if ($gv->GP) {
  96             my ($svix, $avix, $hvix, $cvix, $ioix, $formix);
  97             nice "[GV]";
  98             my $name = $gv->STASH->NAME . "::" . $gv->NAME;
  99             asm "gv_fetchpvx", cstring $name;
 100             $svtab{$$gv} = $varix = $ix = $tix++;
 101             asm "sv_flags", $gv->FLAGS;
 102             asm "sv_refcnt", $gv->REFCNT;
 103             asm "xgv_flags", $gv->GvFLAGS;
 104
 105             asm "gp_refcnt", $gv->GvREFCNT;
 106             asm "load_glob", $ix if $name eq "CORE::GLOBAL::glob";
 107             return $ix
 108                     unless $desired || desired $gv;
 109             $svix = $gv->SV->ix;
 110             $avix = $gv->AV->ix;
 111             $hvix = $gv->HV->ix;
 112
 113     # XXX {{{{
 114             my $cv = $gv->CV;
 115             $cvix = $$cv && defined $files{$cv->FILE} ? $cv->ix : 0;
 116             my $form = $gv->FORM;
 117             $formix = $$form && defined $files{$form->FILE} ? $form->ix : 0;
 118
 119             $ioix = $name !~ /STDOUT$/ ? $gv->IO->ix : 0;
 120                                                             # }}}} XXX
 121
 122             nice "-GV-",
 123             asm "ldsv", $varix = $ix unless $ix == $varix;
 124             asm "gp_sv", $svix;
 125             asm "gp_av", $avix;
 126             asm "gp_hv", $hvix;
 127             asm "gp_cv", $cvix;
 128             asm "gp_io", $ioix;
 129             asm "gp_cvgen", $gv->CVGEN;
 130             asm "gp_form", $formix;
 131             asm "gp_file", pvix $gv->FILE;
 132             asm "gp_line", $gv->LINE;
 133             asm "formfeed", $svix if $name eq "main::\cL";
 134         } else {
 135             nice "[GV]";
 136             asm "newsvx", $gv->FLAGS;
 137             $svtab{$$gv} = $varix = $ix = $tix++;
 138             my $stashix = $gv->STASH->ix;
 139             $gv->B::PVMG::bsave($ix);
 140             asm "xgv_flags", $gv->GvFLAGS;
 141             asm "xgv_stash", $stashix;
 142         }
 143         $ix;
 144     }
 145 }
 146
 147 sub B::HV::ix {
 148     my $hv = shift;
 149     my $ix = $svtab{$$hv};
 150     defined($ix) ? $ix : do {
 151         my ($ix,$i,@array);
 152         my $name = $hv->NAME;
 153         if ($name) {
 154             nice "[STASH]";
 155             asm "gv_stashpvx", cstring $name;
 156             asm "sv_flags", $hv->FLAGS;
 157             $svtab{$$hv} = $varix = $ix = $tix++;
 158             asm "xhv_name", pvix $name;
 159             # my $pmrootix = $hv->PMROOT->ix;   # XXX
 160             asm "ldsv", $varix = $ix unless $ix == $varix;
 161             # asm "xhv_pmroot", $pmrootix;      # XXX
 162         } else {
 163             nice "[HV]";
 164             asm "newsvx", $hv->FLAGS;
 165             $svtab{$$hv} = $varix = $ix = $tix++;
 166             my $stashix = $hv->SvSTASH->ix;
 167             for (@array = $hv->ARRAY) {
 168                 next if $i = not $i;
 169                 $_ = $_->ix;
 170             }
 171             nice "-HV-",
 172             asm "ldsv", $varix = $ix unless $ix == $varix;
 173             ($i = not $i) ? asm ("newpv", pvstring $_) : asm("hv_store", $_)
 174                 for @array;
 175             asm "xmg_stash", $stashix;
 176             asm "xhv_riter", $hv->RITER;
 177         }
 178         asm "sv_refcnt", $hv->REFCNT;
 179         $ix;
 180     }
 181 }
 182
 183 sub B::NULL::ix {
 184     my $sv = shift;
 185     $$sv ? $sv->B::SV::ix : 0;
 186 }
 187
 188 sub B::NULL::opwalk { 0 }
 189
 190 #################################################
 191
 192 sub B::NULL::bsave {
 193     my ($sv,$ix) = @_;
 194
 195     nice '-'.class($sv).'-',
 196     asm "ldsv", $varix = $ix unless $ix == $varix;
 197     asm "sv_refcnt", $sv->REFCNT;
 198 }
 199
 200 sub B::SV::bsave;
 201     *B::SV::bsave = *B::NULL::bsave;
 202
 203 sub B::RV::bsave {
 204     my ($sv,$ix) = @_;
 205     my $rvix = $sv->RV->ix;
 206     $sv->B::NULL::bsave($ix);
 207     asm "xrv", $rvix;
 208 }
 209
 210 sub B::PV::bsave {
 211     my ($sv,$ix) = @_;
 212     $sv->B::NULL::bsave($ix);
 213     asm "newpv", pvstring $sv->PVBM;
 214     asm "xpv";
 215 }
 216
 217 sub B::IV::bsave {
 218     my ($sv,$ix) = @_;
 219     $sv->B::NULL::bsave($ix);
 220     asm "xiv", $sv->IVX;
 221 }
 222
 223 sub B::NV::bsave {
 224     my ($sv,$ix) = @_;
 225     $sv->B::NULL::bsave($ix);
 226     asm "xnv", sprintf "%.40g", $sv->NVX;
 227 }
 228
 229 sub B::PVIV::bsave {
 230     my ($sv,$ix) = @_;
 231     $sv->POK ?
 232         $sv->B::PV::bsave($ix):
 233     $sv->ROK ?
 234         $sv->B::RV::bsave($ix):
 235         $sv->B::NULL::bsave($ix);
 236     asm "xiv", !ITHREADS && $sv->FLAGS & (SVf_FAKE|SVf_READONLY) ?
 237         "0 but true" : $sv->IVX;
 238 }
 239
 240 sub B::PVNV::bsave {
 241     my ($sv,$ix) = @_;
 242     $sv->B::PVIV::bsave($ix);
 243     asm "xnv", sprintf "%.40g", $sv->NVX;
 244 }
 245
 246 sub B::PVMG::domagic {
 247     my ($sv,$ix) = @_;
 248     nice '-MAGICAL-';
 249     my @mglist = $sv->MAGIC;
 250     my (@mgix, @namix);
 251     for (@mglist) {
 252         push @mgix, $_->OBJ->ix;
 253         push @namix, $_->PTR->ix if $_->LENGTH == B::HEf_SVKEY;
 254     }
 255
 256     nice '-'.class($sv).'-',
 257     asm "ldsv", $varix = $ix unless $ix == $varix;
 258     for (@mglist) {
 259         asm "sv_magic", cstring $_->TYPE;
 260         asm "mg_obj", shift @mgix;
 261         my $length = $_->LENGTH;
 262         if ($length == B::HEf_SVKEY) {
 263             asm "mg_namex", shift @namix;
 264         } elsif ($length) {
 265             asm "newpv", pvstring $_->PTR;
 266             asm "mg_name";
 267         }
 268     }
 269 }
 270
 271 sub B::PVMG::bsave {
 272     my ($sv,$ix) = @_;
 273     my $stashix = $sv->SvSTASH->ix;
 274     $sv->B::PVNV::bsave($ix);
 275     asm "xmg_stash", $stashix;
 276     $sv->domagic($ix) if $sv->MAGICAL;
 277 }
 278
 279 sub B::PVLV::bsave {
 280     my ($sv,$ix) = @_;
 281     my $targix = $sv->TARG->ix;
 282     $sv->B::PVMG::bsave($ix);
 283     asm "xlv_targ", $targix;
 284     asm "xlv_targoff", $sv->TARGOFF;
 285     asm "xlv_targlen", $sv->TARGLEN;
 286     asm "xlv_type", $sv->TYPE;
 287
 288 }
 289
 290 sub B::BM::bsave {
 291     my ($sv,$ix) = @_;
 292     $sv->B::PVMG::bsave($ix);
 293     asm "xpv_cur", $sv->CUR;
 294     asm "xbm_useful", $sv->USEFUL;
 295     asm "xbm_previous", $sv->PREVIOUS;
 296     asm "xbm_rare", $sv->RARE;
 297 }
 298
 299 sub B::IO::bsave {
 300     my ($io,$ix) = @_;
 301     my $topix = $io->TOP_GV->ix;
 302     my $fmtix = $io->FMT_GV->ix;
 303     my $bottomix = $io->BOTTOM_GV->ix;
 304     $io->B::PVMG::bsave($ix);
 305     asm "xio_lines", $io->LINES;
 306     asm "xio_page", $io->PAGE;
 307     asm "xio_page_len", $io->PAGE_LEN;
 308     asm "xio_lines_left", $io->LINES_LEFT;
 309     asm "xio_top_name", pvix $io->TOP_NAME;
 310     asm "xio_top_gv", $topix;
 311     asm "xio_fmt_name", pvix $io->FMT_NAME;
 312     asm "xio_fmt_gv", $fmtix;
 313     asm "xio_bottom_name", pvix $io->BOTTOM_NAME;
 314     asm "xio_bottom_gv", $bottomix;
 315     asm "xio_subprocess", $io->SUBPROCESS;
 316     asm "xio_type", ord $io->IoTYPE;
 317     # asm "xio_flags", ord($io->IoFLAGS) & ~32;         # XXX XXX
 318 }
 319
 320 sub B::CV::bsave {
 321     my ($cv,$ix) = @_;
 322     my $stashix = $cv->STASH->ix;
 323     my $gvix = $cv->GV->ix;
 324     my $padlistix = $cv->PADLIST->ix;
 325     my $outsideix = $cv->OUTSIDE->ix;
 326     my $constix = $cv->CONST ? $cv->XSUBANY->ix : 0;
 327     my $startix = $cv->START->opwalk;
 328     my $rootix = $cv->ROOT->ix;
 329
 330     $cv->B::PVMG::bsave($ix);
 331     asm "xcv_stash", $stashix;
 332     asm "xcv_start", $startix;
 333     asm "xcv_root", $rootix;
 334     asm "xcv_xsubany", $constix;
 335     asm "xcv_gv", $gvix;
 336     asm "xcv_file", pvix $cv->FILE if $cv->FILE;        # XXX AD
 337     asm "xcv_padlist", $padlistix;
 338     asm "xcv_outside", $outsideix;
 339     asm "xcv_flags", $cv->CvFLAGS;
 340     asm "xcv_outside_seq", $cv->OUTSIDE_SEQ;
 341     asm "xcv_depth", $cv->DEPTH;
 342 }
 343
 344 sub B::FM::bsave {
 345     my ($form,$ix) = @_;
 346
 347     $form->B::CV::bsave($ix);
 348     asm "xfm_lines", $form->LINES;
 349 }
 350
 351 sub B::AV::bsave {
 352     my ($av,$ix) = @_;
 353     return $av->B::PVMG::bsave($ix) if $av->MAGICAL;
 354     my @array = $av->ARRAY;
 355     $_ = $_->ix for @array;
 356     my $stashix = $av->SvSTASH->ix;
 357
 358     nice "-AV-",
 359     asm "ldsv", $varix = $ix unless $ix == $varix;
 360     asm "av_extend", $av->MAX if $av->MAX >= 0;
 361     asm "av_pushx", $_ for @array;
 362     asm "sv_refcnt", $av->REFCNT;
 363     asm "xmg_stash", $stashix;
 364 }
 365
 366 sub B::GV::desired {
 367     my $gv = shift;
 368     my ($cv, $form);
 369     $files{$gv->FILE} && $gv->LINE
 370     || ${$cv = $gv->CV} && $files{$cv->FILE}
 371     || ${$form = $gv->FORM} && $files{$form->FILE}
 372 }
 373
 374 sub B::HV::bwalk {
 375     my $hv = shift;
 376     return if $walked{$$hv}++;
 377     my %stash = $hv->ARRAY;
 378     while (my($k,$v) = each %stash) {
 379         if ($v->SvTYPE == SVt_PVGV) {
 380             my $hash = $v->HV;
 381             if ($$hash && $hash->NAME) {
 382                 $hash->bwalk;
 383             }
 384             $v->ix(1) if desired $v;
 385         } else {
 386             nice "[prototype]";
 387             asm "gv_fetchpvx", cstring $hv->NAME . "::$k";
 388             $svtab{$$v} = $varix = $tix;
 389             $v->bsave($tix++);
 390             asm "sv_flags", $v->FLAGS;
 391         }
 392     }
 393 }
 394
 395 ######################################################
 396
 397
 398 sub B::OP::bsave_thin {
 399     my ($op, $ix) = @_;
 400     my $next = $op->next;
 401     my $nextix = $optab{$$next};
 402     $nextix = 0, push @cloop, $op unless defined $nextix;
 403     if ($ix != $opix) {
 404         nice '-'.$op->name.'-',
 405         asm "ldop", $opix = $ix;
 406     }
 407     asm "op_next", $nextix;
 408     asm "op_targ", $op->targ if $op->type;              # tricky
 409     asm "op_flags", $op->flags;
 410     asm "op_private", $op->private;
 411 }
 412
 413 sub B::OP::bsave;
 414     *B::OP::bsave = *B::OP::bsave_thin;
 415
 416 sub B::UNOP::bsave {
 417     my ($op, $ix) = @_;
 418     my $name = $op->name;
 419     my $flags = $op->flags;
 420     my $first = $op->first;
 421     my $firstix =
 422         $name =~ /fl[io]p/
 423                         # that's just neat
 424     ||  (!ITHREADS && $name eq 'regcomp')
 425                         # trick for /$a/o in pp_regcomp
 426     ||  $name eq 'rv2sv'
 427             && $op->flags & OPf_MOD
 428             && $op->private & OPpLVAL_INTRO
 429                         # change #18774 made my life hard
 430     ?   $first->ix
 431     :   0;
 432
 433     $op->B::OP::bsave($ix);
 434     asm "op_first", $firstix;
 435 }
 436
 437 sub B::BINOP::bsave {
 438     my ($op, $ix) = @_;
 439     if ($op->name eq 'aassign' && $op->private & B::OPpASSIGN_HASH()) {
 440         my $last = $op->last;
 441         my $lastix = do {
 442             local *B::OP::bsave = *B::OP::bsave_fat;
 443             local *B::UNOP::bsave = *B::UNOP::bsave_fat;
 444             $last->ix;
 445         };
 446         asm "ldop", $lastix unless $lastix == $opix;
 447         asm "op_targ", $last->targ;
 448         $op->B::OP::bsave($ix);
 449         asm "op_last", $lastix;
 450     } else {
 451         $op->B::OP::bsave($ix);
 452     }
 453 }
 454
 455 # not needed if no pseudohashes
 456
 457 *B::BINOP::bsave = *B::OP::bsave if VERSION >= 5.009;
 458
 459 # deal with sort / formline
 460
 461 sub B::LISTOP::bsave {
 462     my ($op, $ix) = @_;
 463     my $name = $op->name;
 464     sub blocksort() { OPf_SPECIAL|OPf_STACKED }
 465     if ($name eq 'sort' && ($op->flags & blocksort) == blocksort) {
 466         my $first = $op->first;
 467         my $pushmark = $first->sibling;
 468         my $rvgv = $pushmark->first;
 469         my $leave = $rvgv->first;
 470
 471         my $leaveix = $leave->ix;
 472
 473         my $rvgvix = $rvgv->ix;
 474         asm "ldop", $rvgvix unless $rvgvix == $opix;
 475         asm "op_first", $leaveix;
 476
 477         my $pushmarkix = $pushmark->ix;
 478         asm "ldop", $pushmarkix unless $pushmarkix == $opix;
 479         asm "op_first", $rvgvix;
 480
 481         my $firstix = $first->ix;
 482         asm "ldop", $firstix unless $firstix == $opix;
 483         asm "op_sibling", $pushmarkix;
 484
 485         $op->B::OP::bsave($ix);
 486         asm "op_first", $firstix;
 487     } elsif ($name eq 'formline') {
 488         $op->B::UNOP::bsave_fat($ix);
 489     } else {
 490         $op->B::OP::bsave($ix);
 491     }
 492 }
 493
 494 # fat versions
 495
 496 sub B::OP::bsave_fat {
 497     my ($op, $ix) = @_;
 498     my $siblix = $op->sibling->ix;
 499
 500     $op->B::OP::bsave_thin($ix);
 501     asm "op_sibling", $siblix;
 502     # asm "op_seq", -1;                 XXX don't allocate OPs piece by piece
 503 }
 504
 505 sub B::UNOP::bsave_fat {
 506     my ($op,$ix) = @_;
 507     my $firstix = $op->first->ix;
 508
 509     $op->B::OP::bsave($ix);
 510     asm "op_first", $firstix;
 511 }
 512
 513 sub B::BINOP::bsave_fat {
 514     my ($op,$ix) = @_;
 515     my $last = $op->last;
 516     my $lastix = $op->last->ix;
 517     if (VERSION < 5.009 && $op->name eq 'aassign' && $last->name eq 'null') {
 518         asm "ldop", $lastix unless $lastix == $opix;
 519         asm "op_targ", $last->targ;
 520     }
 521
 522     $op->B::UNOP::bsave($ix);
 523     asm "op_last", $lastix;
 524 }
 525
 526 sub B::LOGOP::bsave {
 527     my ($op,$ix) = @_;
 528     my $otherix = $op->other->ix;
 529
 530     $op->B::UNOP::bsave($ix);
 531     asm "op_other", $otherix;
 532 }
 533
 534 sub B::PMOP::bsave {
 535     my ($op,$ix) = @_;
 536     my ($rrop, $rrarg, $rstart);
 537
 538     # my $pmnextix = $op->pmnext->ix;   # XXX
 539
 540     if (ITHREADS) {
 541         if ($op->name eq 'subst') {
 542             $rrop = "op_pmreplroot";
 543             $rrarg = $op->pmreplroot->ix;
 544             $rstart = $op->pmreplstart->ix;
 545         } elsif ($op->name eq 'pushre') {
 546             $rrop = "op_pmreplrootpo";
 547             $rrarg = $op->pmreplroot;
 548         }
 549         $op->B::BINOP::bsave($ix);
 550         asm "op_pmstashpv", pvix $op->pmstashpv;
 551     } else {
 552         $rrop = "op_pmreplrootgv";
 553         $rrarg = $op->pmreplroot->ix;
 554         $rstart = $op->pmreplstart->ix if $op->name eq 'subst';
 555         my $stashix = $op->pmstash->ix;
 556         $op->B::BINOP::bsave($ix);
 557         asm "op_pmstash", $stashix;
 558     }
 559
 560     asm $rrop, $rrarg if $rrop;
 561     asm "op_pmreplstart", $rstart if $rstart;
 562
 563     asm "op_pmflags", $op->pmflags;
 564     asm "op_pmpermflags", $op->pmpermflags;
 565     asm "op_pmdynflags", $op->pmdynflags;
 566     # asm "op_pmnext", $pmnextix;       # XXX
 567     asm "newpv", pvstring $op->precomp;
 568     asm "pregcomp";
 569 }
 570
 571 sub B::SVOP::bsave {
 572     my ($op,$ix) = @_;
 573     my $svix = $op->sv->ix;
 574
 575     $op->B::OP::bsave($ix);
 576     asm "op_sv", $svix;
 577 }
 578
 579 sub B::PADOP::bsave {
 580     my ($op,$ix) = @_;
 581
 582     $op->B::OP::bsave($ix);
 583     asm "op_padix", $op->padix;
 584 }
 585
 586 sub B::PVOP::bsave {
 587     my ($op,$ix) = @_;
 588     $op->B::OP::bsave($ix);
 589     return unless my $pv = $op->pv;
 590
 591     if ($op->name eq 'trans') {
 592         asm "op_pv_tr", join ',', length($pv)/2, unpack("s*", $pv);
 593     } else {
 594         asm "newpv", pvstring $pv;
 595         asm "op_pv";
 596     }
 597 }
 598
 599 sub B::LOOP::bsave {
 600     my ($op,$ix) = @_;
 601     my $nextix = $op->nextop->ix;
 602     my $lastix = $op->lastop->ix;
 603     my $redoix = $op->redoop->ix;
 604
 605     $op->B::BINOP::bsave($ix);
 606     asm "op_redoop", $redoix;
 607     asm "op_nextop", $nextix;
 608     asm "op_lastop", $lastix;
 609 }
 610
 611 sub B::COP::bsave {
 612     my ($cop,$ix) = @_;
 613     my $warnix = $cop->warnings->ix;
 614     my $ioix = $cop->io->ix;
 615     if (ITHREADS) {
 616         $cop->B::OP::bsave($ix);
 617         asm "cop_stashpv", pvix $cop->stashpv;
 618         asm "cop_file", pvix $cop->file;
 619     } else {
 620         my $stashix = $cop->stash->ix;
 621         my $fileix = $cop->filegv->ix(1);
 622         $cop->B::OP::bsave($ix);
 623         asm "cop_stash", $stashix;
 624         asm "cop_filegv", $fileix;
 625     }
 626     asm "cop_label", pvix $cop->label if $cop->label;   # XXX AD
 627     asm "cop_seq", $cop->cop_seq;
 628     asm "cop_arybase", $cop->arybase;
 629     asm "cop_line", $cop->line;
 630     asm "cop_warnings", $warnix;
 631     asm "cop_io", $ioix;
 632 }
 633
 634 sub B::OP::opwalk {
 635     my $op = shift;
 636     my $ix = $optab{$$op};
 637     defined($ix) ? $ix : do {
 638         my $ix;
 639         my @oplist = $op->oplist;
 640         push @cloop, undef;
 641         $ix = $_->ix while $_ = pop @oplist;
 642         while ($_ = pop @cloop) {
 643             asm "ldop", $optab{$$_};
 644             asm "op_next", $optab{${$_->next}};
 645         }
 646         $ix;
 647     }
 648 }
 649
 650 #################################################
 651
 652 sub save_cq {
 653     my $av;
 654     if (($av=begin_av)->isa("B::AV")) {
 655         if ($savebegins) {
 656             for ($av->ARRAY) {
 657                 next unless $_->FILE eq $0;
 658                 asm "push_begin", $_->ix;
 659             }
 660         } else {
 661             for ($av->ARRAY) {
 662                 next unless $_->FILE eq $0;
 663                 # XXX BEGIN { goto A while 1; A: }
 664                 for (my $op = $_->START; $$op; $op = $op->next) {
 665                     next unless $op->name eq 'require' ||
 666                         # this kludge needed for tests
 667                         $op->name eq 'gv' && do {
 668                             my $gv = class($op) eq 'SVOP' ?
 669                                 $op->gv :
 670                                 (($_->PADLIST->ARRAY)[1]->ARRAY)[$op->padix];
 671                             $$gv && $gv->NAME =~ /use_ok|plan/
 672                         };
 673                     asm "push_begin", $_->ix;
 674                     last;
 675                 }
 676             }
 677         }
 678     }
 679     if (($av=init_av)->isa("B::AV")) {
 680         for ($av->ARRAY) {
 681             next unless $_->FILE eq $0;
 682             asm "push_init", $_->ix;
 683         }
 684     }
 685     if (($av=end_av)->isa("B::AV")) {
 686         for ($av->ARRAY) {
 687             next unless $_->FILE eq $0;
 688             asm "push_end", $_->ix;
 689         }
 690     }
 691 }
 692
 693 sub compile {
 694     my ($head, $scan, $T_inhinc, $keep_syn);
 695     my $cwd = '';
 696     $files{$0} = 1;
 697     sub keep_syn {
 698         $keep_syn = 1;
 699         *B::OP::bsave = *B::OP::bsave_fat;
 700         *B::UNOP::bsave = *B::UNOP::bsave_fat;
 701         *B::BINOP::bsave = *B::BINOP::bsave_fat;
 702         *B::LISTOP::bsave = *B::LISTOP::bsave_fat;
 703     }
 704     sub bwarn { print STDERR "Bytecode.pm: @_\n" }
 705
 706     for (@_) {
 707         if (/^-S/) {
 708             *newasm = *endasm = sub { };
 709             *asm = sub { print "    @_\n" };
 710             *nice = sub ($) { print "\n@_\n" };
 711         } elsif (/^-H/) {
 712             require ByteLoader;
 713             $head = "#! $^X\nuse ByteLoader $ByteLoader::VERSION;\n";
 714         } elsif (/^-k/) {
 715             keep_syn;
 716         } elsif (/^-o(.*)$/) {
 717             open STDOUT, ">$1" or die "open $1: $!";
 718         } elsif (/^-f(.*)$/) {
 719             $files{$1} = 1;
 720         } elsif (/^-s(.*)$/) {
 721             $scan = length($1) ? $1 : $0;
 722         } elsif (/^-b/) {
 723             $savebegins = 1;
 724     # this is here for the testsuite
 725         } elsif (/^-TI/) {
 726             $T_inhinc = 1;
 727         } elsif (/^-TF(.*)/) {
 728             my $thatfile = $1;
 729             *B::COP::file = sub { $thatfile };
 730         } else {
 731             bwarn "Ignoring '$_' option";
 732         }
 733     }
 734     if ($scan) {
 735         my $f;
 736         if (open $f, $scan) {
 737             while (<$f>) {
 738                 /^#\s*line\s+\d+\s+("?)(.*)\1/ and $files{$2} = 1;
 739                 /^#/ and next;
 740                 if (/\bgoto\b\s*[^&]/ && !$keep_syn) {
 741                     bwarn "keeping the syntax tree: \"goto\" op found";
 742                     keep_syn;
 743                 }
 744             }
 745         } else {
 746             bwarn "cannot rescan '$scan'";
 747         }
 748         close $f;
 749     }
 750     binmode STDOUT;
 751     return sub {
 752         print $head if $head;
 753         newasm sub { print @_ };
 754
 755         defstash->bwalk;
 756         asm "main_start", main_start->opwalk;
 757         asm "main_root", main_root->ix;
 758         asm "main_cv", main_cv->ix;
 759         asm "curpad", (comppadlist->ARRAY)[1]->ix;
 760
 761         asm "signal", cstring "__WARN__"                # XXX
 762             if warnhook->ix;
 763         asm "incav", inc_gv->AV->ix if $T_inhinc;
 764         save_cq;
 765         asm "incav", inc_gv->AV->ix if $T_inhinc;
 766         asm "dowarn", dowarn;
 767
 768         {
 769             no strict 'refs';
 770             nice "<DATA>";
 771             my $dh = *{defstash->NAME."::DATA"};
 772             unless (eof $dh) {
 773                 local undef $/;
 774                 asm "data", ord 'D';
 775                 print <$dh>;
 776             } else {
 777                 asm "ret";
 778             }
 779         }
 780
 781         endasm;
 782     }
 783 }
 784
 785 1;
 786
 787 =head1 NAME
 788
 789 B::Bytecode - Perl compiler's bytecode backend
 790
 791 =head1 SYNOPSIS
 792
 793 B<perl -MO=Bytecode>[B<,-H>][B<,-o>I<script.plc>] I<script.pl>
 794
 795 =head1 DESCRIPTION
 796
 797 Compiles a Perl script into a bytecode format that could be loaded
 798 later by the ByteLoader module and executed as a regular Perl script.
 799
 800 =head1 EXAMPLE
 801
 802     $ perl -MO=Bytecode,-H,-ohi -e 'print "hi!\n"'
 803     $ perl hi
 804     hi!
 805
 806 =head1 OPTIONS
 807
 808 =over 4
 809
 810 =item B<-b>
 811
 812 Save all the BEGIN blocks. Normally only BEGIN blocks that C<require>
 813 other files (ex. C<use Foo;>) are saved.
 814
 815 =item B<-H>
 816
 817 prepend a C<use ByteLoader VERSION;> line to the produced bytecode.
 818
 819 =item B<-k>
 820
 821 keep the syntax tree - it is stripped by default.
 822
 823 =item B<-o>I<outfile>
 824
 825 put the bytecode in <outfile> instead of dumping it to STDOUT.
 826
 827 =item B<-s>
 828
 829 scan the script for C<# line ..> directives and for <goto LABEL>
 830 expressions. When gotos are found keep the syntax tree.
 831
 832 =back
 833
 834 =head1 KNOWN BUGS
 835
 836 =over 4
 837
 838 =item *
 839
 840 C<BEGIN { goto A: while 1; A: }> won't even compile.
 841
 842 =item *
 843
 844 C<?...?> and C<reset> do not work as expected.
 845
 846 =item *
 847
 848 variables in C<(?{ ... })> constructs are not properly scoped.
 849
 850 =item *
 851
 852 scripts that use source filters will fail miserably.
 853
 854 =back
 855
 856 =head1 NOTICE
 857
 858 There are also undocumented bugs and options.
 859
 860 THIS CODE IS HIGHLY EXPERIMENTAL. USE AT YOUR OWN RISK.
 861
 862 =head1 AUTHORS
 863
 864 Originally written by Malcolm Beattie <mbeattie@sable.ox.ac.uk> and
 865 modified by Benjamin Stuhl <sho_pi@hotmail.com>.
 866
 867 Rewritten by Enache Adrian <enache@rdslink.ro>, 2003 a.d.
 868
 869 =cut