dist/Safe/Safe.pm

   1 package Safe;
   2
   3 use 5.003_11;
   4 use strict;
   5 use Scalar::Util qw(reftype);
   6 use Config qw(%Config);
   7 use constant is_usethreads => $Config{usethreads};
   8
   9 $Safe::VERSION = "2.20";
  10
  11 # *** Don't declare any lexicals above this point ***
  12 #
  13 # This function should return a closure which contains an eval that can't
  14 # see any lexicals in scope (apart from __ExPr__ which is unavoidable)
  15
  16 sub lexless_anon_sub {
  17                  # $_[0] is package;
  18                  # $_[1] is strict flag;
  19     my $__ExPr__ = $_[2];   # must be a lexical to create the closure that
  20                             # can be used to pass the value into the safe
  21                             # world
  22
  23     # Create anon sub ref in root of compartment.
  24     # Uses a closure (on $__ExPr__) to pass in the code to be executed.
  25     # (eval on one line to keep line numbers as expected by caller)
  26     eval sprintf
  27     'package %s; %s strict; sub { @_=(); eval q[my $__ExPr__;] . $__ExPr__; }',
  28                 $_[0], $_[1] ? 'use' : 'no';
  29 }
  30
  31 use Carp;
  32 BEGIN { eval q{
  33     use Carp::Heavy;
  34 } }
  35
  36 use Opcode 1.01, qw(
  37     opset opset_to_ops opmask_add
  38     empty_opset full_opset invert_opset verify_opset
  39     opdesc opcodes opmask define_optag opset_to_hex
  40 );
  41
  42 *ops_to_opset = \&opset;   # Temporary alias for old Penguins
  43
  44
  45 my $default_root  = 0;
  46 # share *_ and functions defined in universal.c
  47 # Don't share stuff like *UNIVERSAL:: otherwise code from the
  48 # compartment can 0wn functions in UNIVERSAL
  49 my $default_share = [qw[
  50     *_
  51     &PerlIO::get_layers
  52     &UNIVERSAL::isa
  53     &UNIVERSAL::can
  54     &UNIVERSAL::VERSION
  55     &utf8::is_utf8
  56     &utf8::valid
  57     &utf8::encode
  58     &utf8::decode
  59     &utf8::upgrade
  60     &utf8::downgrade
  61     &utf8::native_to_unicode
  62     &utf8::unicode_to_native
  63     $version::VERSION
  64     $version::CLASS
  65     $version::STRICT
  66     $version::LAX
  67     @version::ISA
  68 ], ($] >= 5.008001 && qw[
  69     &Regexp::DESTROY
  70 ]), ($] >= 5.010 && qw[
  71     &re::is_regexp
  72     &re::regname
  73     &re::regnames
  74     &re::regnames_count
  75     &Tie::Hash::NamedCapture::FETCH
  76     &Tie::Hash::NamedCapture::STORE
  77     &Tie::Hash::NamedCapture::DELETE
  78     &Tie::Hash::NamedCapture::CLEAR
  79     &Tie::Hash::NamedCapture::EXISTS
  80     &Tie::Hash::NamedCapture::FIRSTKEY
  81     &Tie::Hash::NamedCapture::NEXTKEY
  82     &Tie::Hash::NamedCapture::SCALAR
  83     &Tie::Hash::NamedCapture::flags
  84     &UNIVERSAL::DOES
  85     &version::()
  86     &version::new
  87     &version::(""
  88     &version::stringify
  89     &version::(0+
  90     &version::numify
  91     &version::normal
  92     &version::(cmp
  93     &version::(<=>
  94     &version::vcmp
  95     &version::(bool
  96     &version::boolean
  97     &version::(nomethod
  98     &version::noop
  99     &version::is_alpha
 100     &version::qv
 101 ]), ($] >= 5.011 && qw[
 102     &re::regexp_pattern
 103 ])];
 104
 105 sub new {
 106     my($class, $root, $mask) = @_;
 107     my $obj = {};
 108     bless $obj, $class;
 109
 110     if (defined($root)) {
 111         croak "Can't use \"$root\" as root name"
 112             if $root =~ /^main\b/ or $root !~ /^\w[:\w]*$/;
 113         $obj->{Root}  = $root;
 114         $obj->{Erase} = 0;
 115     }
 116     else {
 117         $obj->{Root}  = "Safe::Root".$default_root++;
 118         $obj->{Erase} = 1;
 119     }
 120
 121     # use permit/deny methods instead till interface issues resolved
 122     # XXX perhaps new Safe 'Root', mask => $mask, foo => bar, ...;
 123     croak "Mask parameter to new no longer supported" if defined $mask;
 124     $obj->permit_only(':default');
 125
 126     # We must share $_ and @_ with the compartment or else ops such
 127     # as split, length and so on won't default to $_ properly, nor
 128     # will passing argument to subroutines work (via @_). In fact,
 129     # for reasons I don't completely understand, we need to share
 130     # the whole glob *_ rather than $_ and @_ separately, otherwise
 131     # @_ in non default packages within the compartment don't work.
 132     $obj->share_from('main', $default_share);
 133     Opcode::_safe_pkg_prep($obj->{Root}) if($Opcode::VERSION > 1.04);
 134     return $obj;
 135 }
 136
 137 sub DESTROY {
 138     my $obj = shift;
 139     $obj->erase('DESTROY') if $obj->{Erase};
 140 }
 141
 142 sub erase {
 143     my ($obj, $action) = @_;
 144     my $pkg = $obj->root();
 145     my ($stem, $leaf);
 146
 147     no strict 'refs';
 148     $pkg = "main::$pkg\::";     # expand to full symbol table name
 149     ($stem, $leaf) = $pkg =~ m/(.*::)(\w+::)$/;
 150
 151     # The 'my $foo' is needed! Without it you get an
 152     # 'Attempt to free unreferenced scalar' warning!
 153     my $stem_symtab = *{$stem}{HASH};
 154
 155     #warn "erase($pkg) stem=$stem, leaf=$leaf";
 156     #warn " stem_symtab hash ".scalar(%$stem_symtab)."\n";
 157         # ", join(', ', %$stem_symtab),"\n";
 158
 159 #    delete $stem_symtab->{$leaf};
 160
 161     my $leaf_glob   = $stem_symtab->{$leaf};
 162     my $leaf_symtab = *{$leaf_glob}{HASH};
 163 #    warn " leaf_symtab ", join(', ', %$leaf_symtab),"\n";
 164     %$leaf_symtab = ();
 165     #delete $leaf_symtab->{'__ANON__'};
 166     #delete $leaf_symtab->{'foo'};
 167     #delete $leaf_symtab->{'main::'};
 168 #    my $foo = undef ${"$stem\::"}{"$leaf\::"};
 169
 170     if ($action and $action eq 'DESTROY') {
 171         delete $stem_symtab->{$leaf};
 172     } else {
 173         $obj->share_from('main', $default_share);
 174     }
 175     1;
 176 }
 177
 178
 179 sub reinit {
 180     my $obj= shift;
 181     $obj->erase;
 182     $obj->share_redo;
 183 }
 184
 185 sub root {
 186     my $obj = shift;
 187     croak("Safe root method now read-only") if @_;
 188     return $obj->{Root};
 189 }
 190
 191
 192 sub mask {
 193     my $obj = shift;
 194     return $obj->{Mask} unless @_;
 195     $obj->deny_only(@_);
 196 }
 197
 198 # v1 compatibility methods
 199 sub trap   { shift->deny(@_)   }
 200 sub untrap { shift->permit(@_) }
 201
 202 sub deny {
 203     my $obj = shift;
 204     $obj->{Mask} |= opset(@_);
 205 }
 206 sub deny_only {
 207     my $obj = shift;
 208     $obj->{Mask} = opset(@_);
 209 }
 210
 211 sub permit {
 212     my $obj = shift;
 213     # XXX needs testing
 214     $obj->{Mask} &= invert_opset opset(@_);
 215 }
 216 sub permit_only {
 217     my $obj = shift;
 218     $obj->{Mask} = invert_opset opset(@_);
 219 }
 220
 221
 222 sub dump_mask {
 223     my $obj = shift;
 224     print opset_to_hex($obj->{Mask}),"\n";
 225 }
 226
 227
 228
 229 sub share {
 230     my($obj, @vars) = @_;
 231     $obj->share_from(scalar(caller), \@vars);
 232 }
 233
 234 sub share_from {
 235     my $obj = shift;
 236     my $pkg = shift;
 237     my $vars = shift;
 238     my $no_record = shift || 0;
 239     my $root = $obj->root();
 240     croak("vars not an array ref") unless ref $vars eq 'ARRAY';
 241     no strict 'refs';
 242     # Check that 'from' package actually exists
 243     croak("Package \"$pkg\" does not exist")
 244         unless keys %{"$pkg\::"};
 245     my $arg;
 246     foreach $arg (@$vars) {
 247         # catch some $safe->share($var) errors:
 248         my ($var, $type);
 249         $type = $1 if ($var = $arg) =~ s/^(\W)//;
 250         # warn "share_from $pkg $type $var";
 251         for (1..2) { # assign twice to avoid any 'used once' warnings
 252             *{$root."::$var"} = (!$type)       ? \&{$pkg."::$var"}
 253                           : ($type eq '&') ? \&{$pkg."::$var"}
 254                           : ($type eq '$') ? \${$pkg."::$var"}
 255                           : ($type eq '@') ? \@{$pkg."::$var"}
 256                           : ($type eq '%') ? \%{$pkg."::$var"}
 257                           : ($type eq '*') ?  *{$pkg."::$var"}
 258                           : croak(qq(Can't share "$type$var" of unknown type));
 259         }
 260     }
 261     $obj->share_record($pkg, $vars) unless $no_record or !$vars;
 262 }
 263
 264 sub share_record {
 265     my $obj = shift;
 266     my $pkg = shift;
 267     my $vars = shift;
 268     my $shares = \%{$obj->{Shares} ||= {}};
 269     # Record shares using keys of $obj->{Shares}. See reinit.
 270     @{$shares}{@$vars} = ($pkg) x @$vars if @$vars;
 271 }
 272 sub share_redo {
 273     my $obj = shift;
 274     my $shares = \%{$obj->{Shares} ||= {}};
 275     my($var, $pkg);
 276     while(($var, $pkg) = each %$shares) {
 277         # warn "share_redo $pkg\:: $var";
 278         $obj->share_from($pkg,  [ $var ], 1);
 279     }
 280 }
 281 sub share_forget {
 282     delete shift->{Shares};
 283 }
 284
 285 sub varglob {
 286     my ($obj, $var) = @_;
 287     no strict 'refs';
 288     return *{$obj->root()."::$var"};
 289 }
 290
 291
 292 sub reval {
 293     my ($obj, $expr, $strict) = @_;
 294     my $root = $obj->{Root};
 295
 296     my $evalsub = lexless_anon_sub($root, $strict, $expr);
 297     my @ret = (wantarray)
 298         ?        Opcode::_safe_call_sv($root, $obj->{Mask}, $evalsub)
 299         : scalar Opcode::_safe_call_sv($root, $obj->{Mask}, $evalsub);
 300
 301     # RT#60374: Safe.pm sort {} bug with -Dusethreads
 302     # If the Safe eval returns a code ref in a perl compiled with usethreads
 303     # then wrap code ref with _safe_call_sv so that, when called, the
 304     # execution will happen with the compartment fully 'in effect'.
 305     # Needed to fix sort blocks that reference $a & $b and
 306     # possibly other subtle issues.
 307     if (is_usethreads()) {
 308         for my $ret (@ret) { # edit (via alias) any CODE refs
 309             next unless (reftype($ret)||'') eq 'CODE';
 310             my $sub = $ret; # avoid closure problems
 311             $ret = sub { Opcode::_safe_call_sv($root, $obj->{Mask}, $sub) };
 312         }
 313     }
 314
 315     return (wantarray) ? @ret : $ret[0];
 316 }
 317
 318 sub rdo {
 319     my ($obj, $file) = @_;
 320     my $root = $obj->{Root};
 321
 322     my $evalsub = eval
 323             sprintf('package %s; sub { @_ = (); do $file }', $root);
 324     return Opcode::_safe_call_sv($root, $obj->{Mask}, $evalsub);
 325 }
 326
 327
 328 1;
 329
 330 __END__
 331
 332 =head1 NAME
 333
 334 Safe - Compile and execute code in restricted compartments
 335
 336 =head1 SYNOPSIS
 337
 338   use Safe;
 339
 340   $compartment = new Safe;
 341
 342   $compartment->permit(qw(time sort :browse));
 343
 344   $result = $compartment->reval($unsafe_code);
 345
 346 =head1 DESCRIPTION
 347
 348 The Safe extension module allows the creation of compartments
 349 in which perl code can be evaluated. Each compartment has
 350
 351 =over 8
 352
 353 =item a new namespace
 354
 355 The "root" of the namespace (i.e. "main::") is changed to a
 356 different package and code evaluated in the compartment cannot
 357 refer to variables outside this namespace, even with run-time
 358 glob lookups and other tricks.
 359
 360 Code which is compiled outside the compartment can choose to place
 361 variables into (or I<share> variables with) the compartment's namespace
 362 and only that data will be visible to code evaluated in the
 363 compartment.
 364
 365 By default, the only variables shared with compartments are the
 366 "underscore" variables $_ and @_ (and, technically, the less frequently
 367 used %_, the _ filehandle and so on). This is because otherwise perl
 368 operators which default to $_ will not work and neither will the
 369 assignment of arguments to @_ on subroutine entry.
 370
 371 =item an operator mask
 372
 373 Each compartment has an associated "operator mask". Recall that
 374 perl code is compiled into an internal format before execution.
 375 Evaluating perl code (e.g. via "eval" or "do 'file'") causes
 376 the code to be compiled into an internal format and then,
 377 provided there was no error in the compilation, executed.
 378 Code evaluated in a compartment compiles subject to the
 379 compartment's operator mask. Attempting to evaluate code in a
 380 compartment which contains a masked operator will cause the
 381 compilation to fail with an error. The code will not be executed.
 382
 383 The default operator mask for a newly created compartment is
 384 the ':default' optag.
 385
 386 It is important that you read the L<Opcode> module documentation
 387 for more information, especially for detailed definitions of opnames,
 388 optags and opsets.
 389
 390 Since it is only at the compilation stage that the operator mask
 391 applies, controlled access to potentially unsafe operations can
 392 be achieved by having a handle to a wrapper subroutine (written
 393 outside the compartment) placed into the compartment. For example,
 394
 395     $cpt = new Safe;
 396     sub wrapper {
 397         # vet arguments and perform potentially unsafe operations
 398     }
 399     $cpt->share('&wrapper');
 400
 401 =back
 402
 403
 404 =head1 WARNING
 405
 406 The authors make B<no warranty>, implied or otherwise, about the
 407 suitability of this software for safety or security purposes.
 408
 409 The authors shall not in any case be liable for special, incidental,
 410 consequential, indirect or other similar damages arising from the use
 411 of this software.
 412
 413 Your mileage will vary. If in any doubt B<do not use it>.
 414
 415
 416 =head2 RECENT CHANGES
 417
 418 The interface to the Safe module has changed quite dramatically since
 419 version 1 (as supplied with Perl5.002). Study these pages carefully if
 420 you have code written to use Safe version 1 because you will need to
 421 makes changes.
 422
 423
 424 =head2 Methods in class Safe
 425
 426 To create a new compartment, use
 427
 428     $cpt = new Safe;
 429
 430 Optional argument is (NAMESPACE), where NAMESPACE is the root namespace
 431 to use for the compartment (defaults to "Safe::Root0", incremented for
 432 each new compartment).
 433
 434 Note that version 1.00 of the Safe module supported a second optional
 435 parameter, MASK.  That functionality has been withdrawn pending deeper
 436 consideration. Use the permit and deny methods described below.
 437
 438 The following methods can then be used on the compartment
 439 object returned by the above constructor. The object argument
 440 is implicit in each case.
 441
 442
 443 =over 8
 444
 445 =item permit (OP, ...)
 446
 447 Permit the listed operators to be used when compiling code in the
 448 compartment (in I<addition> to any operators already permitted).
 449
 450 You can list opcodes by names, or use a tag name; see
 451 L<Opcode/"Predefined Opcode Tags">.
 452
 453 =item permit_only (OP, ...)
 454
 455 Permit I<only> the listed operators to be used when compiling code in
 456 the compartment (I<no> other operators are permitted).
 457
 458 =item deny (OP, ...)
 459
 460 Deny the listed operators from being used when compiling code in the
 461 compartment (other operators may still be permitted).
 462
 463 =item deny_only (OP, ...)
 464
 465 Deny I<only> the listed operators from being used when compiling code
 466 in the compartment (I<all> other operators will be permitted).
 467
 468 =item trap (OP, ...)
 469
 470 =item untrap (OP, ...)
 471
 472 The trap and untrap methods are synonyms for deny and permit
 473 respectfully.
 474
 475 =item share (NAME, ...)
 476
 477 This shares the variable(s) in the argument list with the compartment.
 478 This is almost identical to exporting variables using the L<Exporter>
 479 module.
 480
 481 Each NAME must be the B<name> of a non-lexical variable, typically
 482 with the leading type identifier included. A bareword is treated as a
 483 function name.
 484
 485 Examples of legal names are '$foo' for a scalar, '@foo' for an
 486 array, '%foo' for a hash, '&foo' or 'foo' for a subroutine and '*foo'
 487 for a glob (i.e.  all symbol table entries associated with "foo",
 488 including scalar, array, hash, sub and filehandle).
 489
 490 Each NAME is assumed to be in the calling package. See share_from
 491 for an alternative method (which share uses).
 492
 493 =item share_from (PACKAGE, ARRAYREF)
 494
 495 This method is similar to share() but allows you to explicitly name the
 496 package that symbols should be shared from. The symbol names (including
 497 type characters) are supplied as an array reference.
 498
 499     $safe->share_from('main', [ '$foo', '%bar', 'func' ]);
 500
 501
 502 =item varglob (VARNAME)
 503
 504 This returns a glob reference for the symbol table entry of VARNAME in
 505 the package of the compartment. VARNAME must be the B<name> of a
 506 variable without any leading type marker. For example,
 507
 508     $cpt = new Safe 'Root';
 509     $Root::foo = "Hello world";
 510     # Equivalent version which doesn't need to know $cpt's package name:
 511     ${$cpt->varglob('foo')} = "Hello world";
 512
 513
 514 =item reval (STRING, STRICT)
 515
 516 This evaluates STRING as perl code inside the compartment.
 517
 518 The code can only see the compartment's namespace (as returned by the
 519 B<root> method). The compartment's root package appears to be the
 520 C<main::> package to the code inside the compartment.
 521
 522 Any attempt by the code in STRING to use an operator which is not permitted
 523 by the compartment will cause an error (at run-time of the main program
 524 but at compile-time for the code in STRING).  The error is of the form
 525 "'%s' trapped by operation mask...".
 526
 527 If an operation is trapped in this way, then the code in STRING will
 528 not be executed. If such a trapped operation occurs or any other
 529 compile-time or return error, then $@ is set to the error message, just
 530 as with an eval().
 531
 532 If there is no error, then the method returns the value of the last
 533 expression evaluated, or a return statement may be used, just as with
 534 subroutines and B<eval()>. The context (list or scalar) is determined
 535 by the caller as usual.
 536
 537 This behaviour differs from the beta distribution of the Safe extension
 538 where earlier versions of perl made it hard to mimic the return
 539 behaviour of the eval() command and the context was always scalar.
 540
 541 The formerly undocumented STRICT argument sets strictness: if true
 542 'use strict;' is used, otherwise it uses 'no strict;'. B<Note>: if
 543 STRICT is omitted 'no strict;' is the default.
 544
 545 Some points to note:
 546
 547 If the entereval op is permitted then the code can use eval "..." to
 548 'hide' code which might use denied ops. This is not a major problem
 549 since when the code tries to execute the eval it will fail because the
 550 opmask is still in effect. However this technique would allow clever,
 551 and possibly harmful, code to 'probe' the boundaries of what is
 552 possible.
 553
 554 Any string eval which is executed by code executing in a compartment,
 555 or by code called from code executing in a compartment, will be eval'd
 556 in the namespace of the compartment. This is potentially a serious
 557 problem.
 558
 559 Consider a function foo() in package pkg compiled outside a compartment
 560 but shared with it. Assume the compartment has a root package called
 561 'Root'. If foo() contains an eval statement like eval '$foo = 1' then,
 562 normally, $pkg::foo will be set to 1.  If foo() is called from the
 563 compartment (by whatever means) then instead of setting $pkg::foo, the
 564 eval will actually set $Root::pkg::foo.
 565
 566 This can easily be demonstrated by using a module, such as the Socket
 567 module, which uses eval "..." as part of an AUTOLOAD function. You can
 568 'use' the module outside the compartment and share an (autoloaded)
 569 function with the compartment. If an autoload is triggered by code in
 570 the compartment, or by any code anywhere that is called by any means
 571 from the compartment, then the eval in the Socket module's AUTOLOAD
 572 function happens in the namespace of the compartment. Any variables
 573 created or used by the eval'd code are now under the control of
 574 the code in the compartment.
 575
 576 A similar effect applies to I<all> runtime symbol lookups in code
 577 called from a compartment but not compiled within it.
 578
 579
 580
 581 =item rdo (FILENAME)
 582
 583 This evaluates the contents of file FILENAME inside the compartment.
 584 See above documentation on the B<reval> method for further details.
 585
 586 =item root (NAMESPACE)
 587
 588 This method returns the name of the package that is the root of the
 589 compartment's namespace.
 590
 591 Note that this behaviour differs from version 1.00 of the Safe module
 592 where the root module could be used to change the namespace. That
 593 functionality has been withdrawn pending deeper consideration.
 594
 595 =item mask (MASK)
 596
 597 This is a get-or-set method for the compartment's operator mask.
 598
 599 With no MASK argument present, it returns the current operator mask of
 600 the compartment.
 601
 602 With the MASK argument present, it sets the operator mask for the
 603 compartment (equivalent to calling the deny_only method).
 604
 605 =back
 606
 607
 608 =head2 Some Safety Issues
 609
 610 This section is currently just an outline of some of the things code in
 611 a compartment might do (intentionally or unintentionally) which can
 612 have an effect outside the compartment.
 613
 614 =over 8
 615
 616 =item Memory
 617
 618 Consuming all (or nearly all) available memory.
 619
 620 =item CPU
 621
 622 Causing infinite loops etc.
 623
 624 =item Snooping
 625
 626 Copying private information out of your system. Even something as
 627 simple as your user name is of value to others. Much useful information
 628 could be gleaned from your environment variables for example.
 629
 630 =item Signals
 631
 632 Causing signals (especially SIGFPE and SIGALARM) to affect your process.
 633
 634 Setting up a signal handler will need to be carefully considered
 635 and controlled.  What mask is in effect when a signal handler
 636 gets called?  If a user can get an imported function to get an
 637 exception and call the user's signal handler, does that user's
 638 restricted mask get re-instated before the handler is called?
 639 Does an imported handler get called with its original mask or
 640 the user's one?
 641
 642 =item State Changes
 643
 644 Ops such as chdir obviously effect the process as a whole and not just
 645 the code in the compartment. Ops such as rand and srand have a similar
 646 but more subtle effect.
 647
 648 =back
 649
 650 =head2 AUTHOR
 651
 652 Originally designed and implemented by Malcolm Beattie.
 653
 654 Reworked to use the Opcode module and other changes added by Tim Bunce.
 655
 656 Currently maintained by the Perl 5 Porters, <perl5-porters@perl.org>.
 657
 658 =cut
 659