dist/Safe/Safe.pm

   1 package Safe;
   2
   3 use 5.003_11;
   4 use strict;
   5 use Scalar::Util qw(reftype);
   6 use Config qw(%Config);
   7 use constant is_usethreads => $Config{usethreads};
   8
   9 $Safe::VERSION = "2.21";
  10
  11 # *** Don't declare any lexicals above this point ***
  12 #
  13 # This function should return a closure which contains an eval that can't
  14 # see any lexicals in scope (apart from __ExPr__ which is unavoidable)
  15
  16 sub lexless_anon_sub {
  17                  # $_[0] is package;
  18                  # $_[1] is strict flag;
  19     my $__ExPr__ = $_[2];   # must be a lexical to create the closure that
  20                             # can be used to pass the value into the safe
  21                             # world
  22
  23     # Create anon sub ref in root of compartment.
  24     # Uses a closure (on $__ExPr__) to pass in the code to be executed.
  25     # (eval on one line to keep line numbers as expected by caller)
  26     eval sprintf
  27     'package %s; %s strict; sub { @_=(); eval q[my $__ExPr__;] . $__ExPr__; }',
  28                 $_[0], $_[1] ? 'use' : 'no';
  29 }
  30
  31 use Carp;
  32 BEGIN { eval q{
  33     use Carp::Heavy;
  34 } }
  35
  36 use Opcode 1.01, qw(
  37     opset opset_to_ops opmask_add
  38     empty_opset full_opset invert_opset verify_opset
  39     opdesc opcodes opmask define_optag opset_to_hex
  40 );
  41
  42 *ops_to_opset = \&opset;   # Temporary alias for old Penguins
  43
  44
  45 my $default_root  = 0;
  46 # share *_ and functions defined in universal.c
  47 # Don't share stuff like *UNIVERSAL:: otherwise code from the
  48 # compartment can 0wn functions in UNIVERSAL
  49 my $default_share = [qw[
  50     *_
  51     &PerlIO::get_layers
  52     &UNIVERSAL::isa
  53     &UNIVERSAL::can
  54     &UNIVERSAL::VERSION
  55     &utf8::is_utf8
  56     &utf8::valid
  57     &utf8::encode
  58     &utf8::decode
  59     &utf8::upgrade
  60     &utf8::downgrade
  61     &utf8::native_to_unicode
  62     &utf8::unicode_to_native
  63     $version::VERSION
  64     $version::CLASS
  65     $version::STRICT
  66     $version::LAX
  67     @version::ISA
  68 ], ($] >= 5.008001 && qw[
  69     &Regexp::DESTROY
  70 ]), ($] >= 5.010 && qw[
  71     &re::is_regexp
  72     &re::regname
  73     &re::regnames
  74     &re::regnames_count
  75     &Tie::Hash::NamedCapture::FETCH
  76     &Tie::Hash::NamedCapture::STORE
  77     &Tie::Hash::NamedCapture::DELETE
  78     &Tie::Hash::NamedCapture::CLEAR
  79     &Tie::Hash::NamedCapture::EXISTS
  80     &Tie::Hash::NamedCapture::FIRSTKEY
  81     &Tie::Hash::NamedCapture::NEXTKEY
  82     &Tie::Hash::NamedCapture::SCALAR
  83     &Tie::Hash::NamedCapture::flags
  84     &UNIVERSAL::DOES
  85     &version::()
  86     &version::new
  87     &version::(""
  88     &version::stringify
  89     &version::(0+
  90     &version::numify
  91     &version::normal
  92     &version::(cmp
  93     &version::(<=>
  94     &version::vcmp
  95     &version::(bool
  96     &version::boolean
  97     &version::(nomethod
  98     &version::noop
  99     &version::is_alpha
 100     &version::qv
 101 ]), ($] >= 5.011 && qw[
 102     &re::regexp_pattern
 103 ])];
 104
 105 sub new {
 106     my($class, $root, $mask) = @_;
 107     my $obj = {};
 108     bless $obj, $class;
 109
 110     if (defined($root)) {
 111         croak "Can't use \"$root\" as root name"
 112             if $root =~ /^main\b/ or $root !~ /^\w[:\w]*$/;
 113         $obj->{Root}  = $root;
 114         $obj->{Erase} = 0;
 115     }
 116     else {
 117         $obj->{Root}  = "Safe::Root".$default_root++;
 118         $obj->{Erase} = 1;
 119     }
 120
 121     # use permit/deny methods instead till interface issues resolved
 122     # XXX perhaps new Safe 'Root', mask => $mask, foo => bar, ...;
 123     croak "Mask parameter to new no longer supported" if defined $mask;
 124     $obj->permit_only(':default');
 125
 126     # We must share $_ and @_ with the compartment or else ops such
 127     # as split, length and so on won't default to $_ properly, nor
 128     # will passing argument to subroutines work (via @_). In fact,
 129     # for reasons I don't completely understand, we need to share
 130     # the whole glob *_ rather than $_ and @_ separately, otherwise
 131     # @_ in non default packages within the compartment don't work.
 132     $obj->share_from('main', $default_share);
 133     Opcode::_safe_pkg_prep($obj->{Root}) if($Opcode::VERSION > 1.04);
 134     return $obj;
 135 }
 136
 137 sub DESTROY {
 138     my $obj = shift;
 139     $obj->erase('DESTROY') if $obj->{Erase};
 140 }
 141
 142 sub erase {
 143     my ($obj, $action) = @_;
 144     my $pkg = $obj->root();
 145     my ($stem, $leaf);
 146
 147     no strict 'refs';
 148     $pkg = "main::$pkg\::";     # expand to full symbol table name
 149     ($stem, $leaf) = $pkg =~ m/(.*::)(\w+::)$/;
 150
 151     # The 'my $foo' is needed! Without it you get an
 152     # 'Attempt to free unreferenced scalar' warning!
 153     my $stem_symtab = *{$stem}{HASH};
 154
 155     #warn "erase($pkg) stem=$stem, leaf=$leaf";
 156     #warn " stem_symtab hash ".scalar(%$stem_symtab)."\n";
 157         # ", join(', ', %$stem_symtab),"\n";
 158
 159 #    delete $stem_symtab->{$leaf};
 160
 161     my $leaf_glob   = $stem_symtab->{$leaf};
 162     my $leaf_symtab = *{$leaf_glob}{HASH};
 163 #    warn " leaf_symtab ", join(', ', %$leaf_symtab),"\n";
 164     %$leaf_symtab = ();
 165     #delete $leaf_symtab->{'__ANON__'};
 166     #delete $leaf_symtab->{'foo'};
 167     #delete $leaf_symtab->{'main::'};
 168 #    my $foo = undef ${"$stem\::"}{"$leaf\::"};
 169
 170     if ($action and $action eq 'DESTROY') {
 171         delete $stem_symtab->{$leaf};
 172     } else {
 173         $obj->share_from('main', $default_share);
 174     }
 175     1;
 176 }
 177
 178
 179 sub reinit {
 180     my $obj= shift;
 181     $obj->erase;
 182     $obj->share_redo;
 183 }
 184
 185 sub root {
 186     my $obj = shift;
 187     croak("Safe root method now read-only") if @_;
 188     return $obj->{Root};
 189 }
 190
 191
 192 sub mask {
 193     my $obj = shift;
 194     return $obj->{Mask} unless @_;
 195     $obj->deny_only(@_);
 196 }
 197
 198 # v1 compatibility methods
 199 sub trap   { shift->deny(@_)   }
 200 sub untrap { shift->permit(@_) }
 201
 202 sub deny {
 203     my $obj = shift;
 204     $obj->{Mask} |= opset(@_);
 205 }
 206 sub deny_only {
 207     my $obj = shift;
 208     $obj->{Mask} = opset(@_);
 209 }
 210
 211 sub permit {
 212     my $obj = shift;
 213     # XXX needs testing
 214     $obj->{Mask} &= invert_opset opset(@_);
 215 }
 216 sub permit_only {
 217     my $obj = shift;
 218     $obj->{Mask} = invert_opset opset(@_);
 219 }
 220
 221
 222 sub dump_mask {
 223     my $obj = shift;
 224     print opset_to_hex($obj->{Mask}),"\n";
 225 }
 226
 227
 228
 229 sub share {
 230     my($obj, @vars) = @_;
 231     $obj->share_from(scalar(caller), \@vars);
 232 }
 233
 234 sub share_from {
 235     my $obj = shift;
 236     my $pkg = shift;
 237     my $vars = shift;
 238     my $no_record = shift || 0;
 239     my $root = $obj->root();
 240     croak("vars not an array ref") unless ref $vars eq 'ARRAY';
 241     no strict 'refs';
 242     # Check that 'from' package actually exists
 243     croak("Package \"$pkg\" does not exist")
 244         unless keys %{"$pkg\::"};
 245     my $arg;
 246     foreach $arg (@$vars) {
 247         # catch some $safe->share($var) errors:
 248         my ($var, $type);
 249         $type = $1 if ($var = $arg) =~ s/^(\W)//;
 250         # warn "share_from $pkg $type $var";
 251         for (1..2) { # assign twice to avoid any 'used once' warnings
 252             *{$root."::$var"} = (!$type)       ? \&{$pkg."::$var"}
 253                           : ($type eq '&') ? \&{$pkg."::$var"}
 254                           : ($type eq '$') ? \${$pkg."::$var"}
 255                           : ($type eq '@') ? \@{$pkg."::$var"}
 256                           : ($type eq '%') ? \%{$pkg."::$var"}
 257                           : ($type eq '*') ?  *{$pkg."::$var"}
 258                           : croak(qq(Can't share "$type$var" of unknown type));
 259         }
 260     }
 261     $obj->share_record($pkg, $vars) unless $no_record or !$vars;
 262 }
 263
 264 sub share_record {
 265     my $obj = shift;
 266     my $pkg = shift;
 267     my $vars = shift;
 268     my $shares = \%{$obj->{Shares} ||= {}};
 269     # Record shares using keys of $obj->{Shares}. See reinit.
 270     @{$shares}{@$vars} = ($pkg) x @$vars if @$vars;
 271 }
 272 sub share_redo {
 273     my $obj = shift;
 274     my $shares = \%{$obj->{Shares} ||= {}};
 275     my($var, $pkg);
 276     while(($var, $pkg) = each %$shares) {
 277         # warn "share_redo $pkg\:: $var";
 278         $obj->share_from($pkg,  [ $var ], 1);
 279     }
 280 }
 281 sub share_forget {
 282     delete shift->{Shares};
 283 }
 284
 285 sub varglob {
 286     my ($obj, $var) = @_;
 287     no strict 'refs';
 288     return *{$obj->root()."::$var"};
 289 }
 290
 291
 292 sub reval {
 293     my ($obj, $expr, $strict) = @_;
 294     my $root = $obj->{Root};
 295
 296     my $evalsub = lexless_anon_sub($root, $strict, $expr);
 297     my @ret = (wantarray)
 298         ?        Opcode::_safe_call_sv($root, $obj->{Mask}, $evalsub)
 299         : scalar Opcode::_safe_call_sv($root, $obj->{Mask}, $evalsub);
 300
 301     # RT#60374: Safe.pm sort {} bug with -Dusethreads
 302     # If the Safe eval returns a code ref in a perl compiled with usethreads
 303     # then wrap code ref with _safe_call_sv so that, when called, the
 304     # execution will happen with the compartment fully 'in effect'.
 305     # Needed to fix sort blocks that reference $a & $b and
 306     # possibly other subtle issues.
 307     if (is_usethreads()) {
 308         for my $ret (@ret) { # edit (via alias) any CODE refs
 309             next unless (reftype($ret)||'') eq 'CODE';
 310             my $sub = $ret; # avoid closure problems
 311             $ret = sub {
 312                 my @args = @_; # lexical to close over
 313                 my $sub_with_args = sub { $sub->(@args) };
 314                 return Opcode::_safe_call_sv($root, $obj->{Mask}, $sub_with_args)
 315             };
 316         }
 317     }
 318
 319     return (wantarray) ? @ret : $ret[0];
 320 }
 321
 322 sub rdo {
 323     my ($obj, $file) = @_;
 324     my $root = $obj->{Root};
 325
 326     my $evalsub = eval
 327             sprintf('package %s; sub { @_ = (); do $file }', $root);
 328     return Opcode::_safe_call_sv($root, $obj->{Mask}, $evalsub);
 329 }
 330
 331
 332 1;
 333
 334 __END__
 335
 336 =head1 NAME
 337
 338 Safe - Compile and execute code in restricted compartments
 339
 340 =head1 SYNOPSIS
 341
 342   use Safe;
 343
 344   $compartment = new Safe;
 345
 346   $compartment->permit(qw(time sort :browse));
 347
 348   $result = $compartment->reval($unsafe_code);
 349
 350 =head1 DESCRIPTION
 351
 352 The Safe extension module allows the creation of compartments
 353 in which perl code can be evaluated. Each compartment has
 354
 355 =over 8
 356
 357 =item a new namespace
 358
 359 The "root" of the namespace (i.e. "main::") is changed to a
 360 different package and code evaluated in the compartment cannot
 361 refer to variables outside this namespace, even with run-time
 362 glob lookups and other tricks.
 363
 364 Code which is compiled outside the compartment can choose to place
 365 variables into (or I<share> variables with) the compartment's namespace
 366 and only that data will be visible to code evaluated in the
 367 compartment.
 368
 369 By default, the only variables shared with compartments are the
 370 "underscore" variables $_ and @_ (and, technically, the less frequently
 371 used %_, the _ filehandle and so on). This is because otherwise perl
 372 operators which default to $_ will not work and neither will the
 373 assignment of arguments to @_ on subroutine entry.
 374
 375 =item an operator mask
 376
 377 Each compartment has an associated "operator mask". Recall that
 378 perl code is compiled into an internal format before execution.
 379 Evaluating perl code (e.g. via "eval" or "do 'file'") causes
 380 the code to be compiled into an internal format and then,
 381 provided there was no error in the compilation, executed.
 382 Code evaluated in a compartment compiles subject to the
 383 compartment's operator mask. Attempting to evaluate code in a
 384 compartment which contains a masked operator will cause the
 385 compilation to fail with an error. The code will not be executed.
 386
 387 The default operator mask for a newly created compartment is
 388 the ':default' optag.
 389
 390 It is important that you read the L<Opcode> module documentation
 391 for more information, especially for detailed definitions of opnames,
 392 optags and opsets.
 393
 394 Since it is only at the compilation stage that the operator mask
 395 applies, controlled access to potentially unsafe operations can
 396 be achieved by having a handle to a wrapper subroutine (written
 397 outside the compartment) placed into the compartment. For example,
 398
 399     $cpt = new Safe;
 400     sub wrapper {
 401         # vet arguments and perform potentially unsafe operations
 402     }
 403     $cpt->share('&wrapper');
 404
 405 =back
 406
 407
 408 =head1 WARNING
 409
 410 The authors make B<no warranty>, implied or otherwise, about the
 411 suitability of this software for safety or security purposes.
 412
 413 The authors shall not in any case be liable for special, incidental,
 414 consequential, indirect or other similar damages arising from the use
 415 of this software.
 416
 417 Your mileage will vary. If in any doubt B<do not use it>.
 418
 419
 420 =head2 RECENT CHANGES
 421
 422 The interface to the Safe module has changed quite dramatically since
 423 version 1 (as supplied with Perl5.002). Study these pages carefully if
 424 you have code written to use Safe version 1 because you will need to
 425 makes changes.
 426
 427
 428 =head2 Methods in class Safe
 429
 430 To create a new compartment, use
 431
 432     $cpt = new Safe;
 433
 434 Optional argument is (NAMESPACE), where NAMESPACE is the root namespace
 435 to use for the compartment (defaults to "Safe::Root0", incremented for
 436 each new compartment).
 437
 438 Note that version 1.00 of the Safe module supported a second optional
 439 parameter, MASK.  That functionality has been withdrawn pending deeper
 440 consideration. Use the permit and deny methods described below.
 441
 442 The following methods can then be used on the compartment
 443 object returned by the above constructor. The object argument
 444 is implicit in each case.
 445
 446
 447 =over 8
 448
 449 =item permit (OP, ...)
 450
 451 Permit the listed operators to be used when compiling code in the
 452 compartment (in I<addition> to any operators already permitted).
 453
 454 You can list opcodes by names, or use a tag name; see
 455 L<Opcode/"Predefined Opcode Tags">.
 456
 457 =item permit_only (OP, ...)
 458
 459 Permit I<only> the listed operators to be used when compiling code in
 460 the compartment (I<no> other operators are permitted).
 461
 462 =item deny (OP, ...)
 463
 464 Deny the listed operators from being used when compiling code in the
 465 compartment (other operators may still be permitted).
 466
 467 =item deny_only (OP, ...)
 468
 469 Deny I<only> the listed operators from being used when compiling code
 470 in the compartment (I<all> other operators will be permitted).
 471
 472 =item trap (OP, ...)
 473
 474 =item untrap (OP, ...)
 475
 476 The trap and untrap methods are synonyms for deny and permit
 477 respectfully.
 478
 479 =item share (NAME, ...)
 480
 481 This shares the variable(s) in the argument list with the compartment.
 482 This is almost identical to exporting variables using the L<Exporter>
 483 module.
 484
 485 Each NAME must be the B<name> of a non-lexical variable, typically
 486 with the leading type identifier included. A bareword is treated as a
 487 function name.
 488
 489 Examples of legal names are '$foo' for a scalar, '@foo' for an
 490 array, '%foo' for a hash, '&foo' or 'foo' for a subroutine and '*foo'
 491 for a glob (i.e.  all symbol table entries associated with "foo",
 492 including scalar, array, hash, sub and filehandle).
 493
 494 Each NAME is assumed to be in the calling package. See share_from
 495 for an alternative method (which share uses).
 496
 497 =item share_from (PACKAGE, ARRAYREF)
 498
 499 This method is similar to share() but allows you to explicitly name the
 500 package that symbols should be shared from. The symbol names (including
 501 type characters) are supplied as an array reference.
 502
 503     $safe->share_from('main', [ '$foo', '%bar', 'func' ]);
 504
 505
 506 =item varglob (VARNAME)
 507
 508 This returns a glob reference for the symbol table entry of VARNAME in
 509 the package of the compartment. VARNAME must be the B<name> of a
 510 variable without any leading type marker. For example,
 511
 512     $cpt = new Safe 'Root';
 513     $Root::foo = "Hello world";
 514     # Equivalent version which doesn't need to know $cpt's package name:
 515     ${$cpt->varglob('foo')} = "Hello world";
 516
 517
 518 =item reval (STRING, STRICT)
 519
 520 This evaluates STRING as perl code inside the compartment.
 521
 522 The code can only see the compartment's namespace (as returned by the
 523 B<root> method). The compartment's root package appears to be the
 524 C<main::> package to the code inside the compartment.
 525
 526 Any attempt by the code in STRING to use an operator which is not permitted
 527 by the compartment will cause an error (at run-time of the main program
 528 but at compile-time for the code in STRING).  The error is of the form
 529 "'%s' trapped by operation mask...".
 530
 531 If an operation is trapped in this way, then the code in STRING will
 532 not be executed. If such a trapped operation occurs or any other
 533 compile-time or return error, then $@ is set to the error message, just
 534 as with an eval().
 535
 536 If there is no error, then the method returns the value of the last
 537 expression evaluated, or a return statement may be used, just as with
 538 subroutines and B<eval()>. The context (list or scalar) is determined
 539 by the caller as usual.
 540
 541 This behaviour differs from the beta distribution of the Safe extension
 542 where earlier versions of perl made it hard to mimic the return
 543 behaviour of the eval() command and the context was always scalar.
 544
 545 The formerly undocumented STRICT argument sets strictness: if true
 546 'use strict;' is used, otherwise it uses 'no strict;'. B<Note>: if
 547 STRICT is omitted 'no strict;' is the default.
 548
 549 Some points to note:
 550
 551 If the entereval op is permitted then the code can use eval "..." to
 552 'hide' code which might use denied ops. This is not a major problem
 553 since when the code tries to execute the eval it will fail because the
 554 opmask is still in effect. However this technique would allow clever,
 555 and possibly harmful, code to 'probe' the boundaries of what is
 556 possible.
 557
 558 Any string eval which is executed by code executing in a compartment,
 559 or by code called from code executing in a compartment, will be eval'd
 560 in the namespace of the compartment. This is potentially a serious
 561 problem.
 562
 563 Consider a function foo() in package pkg compiled outside a compartment
 564 but shared with it. Assume the compartment has a root package called
 565 'Root'. If foo() contains an eval statement like eval '$foo = 1' then,
 566 normally, $pkg::foo will be set to 1.  If foo() is called from the
 567 compartment (by whatever means) then instead of setting $pkg::foo, the
 568 eval will actually set $Root::pkg::foo.
 569
 570 This can easily be demonstrated by using a module, such as the Socket
 571 module, which uses eval "..." as part of an AUTOLOAD function. You can
 572 'use' the module outside the compartment and share an (autoloaded)
 573 function with the compartment. If an autoload is triggered by code in
 574 the compartment, or by any code anywhere that is called by any means
 575 from the compartment, then the eval in the Socket module's AUTOLOAD
 576 function happens in the namespace of the compartment. Any variables
 577 created or used by the eval'd code are now under the control of
 578 the code in the compartment.
 579
 580 A similar effect applies to I<all> runtime symbol lookups in code
 581 called from a compartment but not compiled within it.
 582
 583
 584
 585 =item rdo (FILENAME)
 586
 587 This evaluates the contents of file FILENAME inside the compartment.
 588 See above documentation on the B<reval> method for further details.
 589
 590 =item root (NAMESPACE)
 591
 592 This method returns the name of the package that is the root of the
 593 compartment's namespace.
 594
 595 Note that this behaviour differs from version 1.00 of the Safe module
 596 where the root module could be used to change the namespace. That
 597 functionality has been withdrawn pending deeper consideration.
 598
 599 =item mask (MASK)
 600
 601 This is a get-or-set method for the compartment's operator mask.
 602
 603 With no MASK argument present, it returns the current operator mask of
 604 the compartment.
 605
 606 With the MASK argument present, it sets the operator mask for the
 607 compartment (equivalent to calling the deny_only method).
 608
 609 =back
 610
 611
 612 =head2 Some Safety Issues
 613
 614 This section is currently just an outline of some of the things code in
 615 a compartment might do (intentionally or unintentionally) which can
 616 have an effect outside the compartment.
 617
 618 =over 8
 619
 620 =item Memory
 621
 622 Consuming all (or nearly all) available memory.
 623
 624 =item CPU
 625
 626 Causing infinite loops etc.
 627
 628 =item Snooping
 629
 630 Copying private information out of your system. Even something as
 631 simple as your user name is of value to others. Much useful information
 632 could be gleaned from your environment variables for example.
 633
 634 =item Signals
 635
 636 Causing signals (especially SIGFPE and SIGALARM) to affect your process.
 637
 638 Setting up a signal handler will need to be carefully considered
 639 and controlled.  What mask is in effect when a signal handler
 640 gets called?  If a user can get an imported function to get an
 641 exception and call the user's signal handler, does that user's
 642 restricted mask get re-instated before the handler is called?
 643 Does an imported handler get called with its original mask or
 644 the user's one?
 645
 646 =item State Changes
 647
 648 Ops such as chdir obviously effect the process as a whole and not just
 649 the code in the compartment. Ops such as rand and srand have a similar
 650 but more subtle effect.
 651
 652 =back
 653
 654 =head2 AUTHOR
 655
 656 Originally designed and implemented by Malcolm Beattie.
 657
 658 Reworked to use the Opcode module and other changes added by Tim Bunce.
 659
 660 Currently maintained by the Perl 5 Porters, <perl5-porters@perl.org>.
 661
 662 =cut
 663