cpan/ExtUtils-MakeMaker/t/parse_version.t

   1 #!/usr/bin/perl -w
   2
   3 BEGIN {
   4     unshift @INC, 't/lib';
   5 }
   6 chdir 't';
   7
   8 use Test::More;
   9 use ExtUtils::MakeMaker;
  10
  11 my $Has_Version = eval 'require version; "version"->import; 1';
  12
  13 my %versions = (q[$VERSION = '1.00']            => '1.00',
  14                 q[*VERSION = \'1.01']           => '1.01',
  15                 q[($VERSION) = q$Revision: 32208 $ =~ /(\d+)/g;] => 32208,
  16                 q[$FOO::VERSION = '1.10';]      => '1.10',
  17                 q[*FOO::VERSION = \'1.11';]     => '1.11',
  18                 '$VERSION = 0.02'               => 0.02,
  19                 '$VERSION = 0.0'                => 0.0,
  20                 '$VERSION = -1.0'               => -1.0,
  21                 '$VERSION = undef'              => 'undef',
  22                 '$wibble  = 1.0'                => 'undef',
  23                 q[my $VERSION = '1.01']         => 'undef',
  24                 q[local $VERISON = '1.02']      => 'undef',
  25                 q[local $FOO::VERSION = '1.30'] => 'undef',
  26                 q[if( $Foo::VERSION >= 3.00 ) {]=> 'undef',
  27                 q[our $VERSION = '1.23';]       => '1.23',
  28
  29                 '$Something::VERSION == 1.0'    => 'undef',
  30                 '$Something::VERSION <= 1.0'    => 'undef',
  31                 '$Something::VERSION >= 1.0'    => 'undef',
  32                 '$Something::VERSION != 1.0'    => 'undef',
  33
  34                 qq[\$Something::VERSION == 1.0\n\$VERSION = 2.3\n]                     => '2.3',
  35                 qq[\$Something::VERSION == 1.0\n\$VERSION = 2.3\n\$VERSION = 4.5\n]    => '2.3',
  36
  37                 '$VERSION = sprintf("%d.%03d", q$Revision: 3.74 $ =~ /(\d+)\.(\d+)/);' => '3.074',
  38                 '$VERSION = substr(q$Revision: 2.8 $, 10) + 2 . "";'                   => '4.8',
  39
  40                );
  41
  42 if( $Has_Version ) {
  43     $versions{q[use version; $VERSION = qv("1.2.3");]} = qv("1.2.3");
  44     $versions{q[$VERSION = qv("1.2.3")]}               = qv("1.2.3");
  45 }
  46
  47 if( $] >= 5.011001 ) {
  48     $versions{'package Foo 1.23;'         } = '1.23';
  49     $versions{'package Foo::Bar 1.23;'    } = '1.23';
  50     $versions{'package Foo v1.2.3;'       } = 'v1.2.3';
  51     $versions{'package Foo::Bar v1.2.3;'  } = 'v1.2.3';
  52     $versions{' package Foo::Bar 1.23 ;'  } = '1.23';
  53     $versions{"package Foo'Bar 1.23;"     } = '1.23';
  54     $versions{"package Foo::Bar 1.2.3;"   } = '1.2.3';
  55     $versions{'package Foo 1.230;'        } = '1.230';
  56     $versions{'package Foo 1.23_01;'      } = '1.23_01';
  57     $versions{'package Foo v1.23_01;'     } = 'v1.23_01';
  58     $versions{q["package Foo 1.23"]}        = 'undef';
  59     $versions{<<'END'}                      = '1.23';
  60 package Foo 1.23;
  61 our $VERSION = 2.34;
  62 END
  63
  64     $versions{<<'END'}                      = '2.34';
  65 our $VERSION = 2.34;
  66 package Foo 1.23;
  67 END
  68
  69     $versions{<<'END'}                      = '2.34';
  70 package Foo::100;
  71 our $VERSION = 2.34;
  72 END
  73 }
  74
  75 plan tests => (2 * keys %versions) + 4;
  76
  77 for my $code ( sort keys %versions ) {
  78     my $expect = $versions{$code};
  79     (my $label = $code) =~ s/\n/\\n/g;
  80     is( parse_version_string($code), $expect, $label );
  81 }
  82
  83
  84 sub parse_version_string {
  85     my $code = shift;
  86
  87     open(FILE, ">VERSION.tmp") || die $!;
  88     print FILE "$code\n";
  89     close FILE;
  90
  91     $_ = 'foo';
  92     my $version = MM->parse_version('VERSION.tmp');
  93     is( $_, 'foo', '$_ not leaked by parse_version' );
  94
  95     unlink "VERSION.tmp";
  96
  97     return $version;
  98 }
  99
 100
 101 # This is a specific test to see if a version subroutine in the $VERSION
 102 # declaration confuses later calls to the version class.
 103 # [rt.cpan.org 30747]
 104 SKIP: {
 105     skip "need version.pm", 4 unless $Has_Version;
 106     is parse_version_string(q[ $VERSION = '1.00'; sub version { $VERSION } ]),
 107        '1.00', "eval 'sub version {...} in version string";
 108     is parse_version_string(q[ use version; $VERSION = version->new("1.2.3") ]),
 109        qv("1.2.3"), "version.pm not confused by version sub";
 110 }