cpan/CPANPLUS-Dist-Build/lib/CPANPLUS/Dist/Build.pm

   1 package CPANPLUS::Dist::Build;
   2
   3 use strict;
   4 use warnings;
   5 use vars    qw[@ISA $STATUS $VERSION];
   6 @ISA =      qw[CPANPLUS::Dist];
   7
   8 use CPANPLUS::Internals::Constants;
   9
  10 ### these constants were exported by CPANPLUS::Internals::Constants
  11 ### in previous versions.. they do the same though. If we want to have
  12 ### a normal 'use' here, up the dependency to CPANPLUS 0.056 or higher
  13 BEGIN {
  14     require CPANPLUS::Dist::Build::Constants;
  15     CPANPLUS::Dist::Build::Constants->import()
  16         if not __PACKAGE__->can('BUILD') && __PACKAGE__->can('BUILD_DIR');
  17 }
  18
  19 use CPANPLUS::Error;
  20
  21 use Config;
  22 use FileHandle;
  23 use Cwd;
  24 use version;
  25
  26 use IPC::Cmd                    qw[run];
  27 use Params::Check               qw[check];
  28 use Module::Load::Conditional   qw[can_load check_install];
  29 use Locale::Maketext::Simple    Class => 'CPANPLUS', Style => 'gettext';
  30
  31 local $Params::Check::VERBOSE = 1;
  32
  33 $VERSION = '0.40';
  34
  35 =pod
  36
  37 =head1 NAME
  38
  39 CPANPLUS::Dist::Build - CPANPLUS plugin to install packages that use Build.PL
  40
  41 =head1 SYNOPSIS
  42
  43     my $build = CPANPLUS::Dist->new(
  44                                 format  => 'CPANPLUS::Dist::Build',
  45                                 module  => $modobj,
  46                             );
  47
  48     $build->prepare;    # runs Build.PL
  49     $build->create;     # runs build && build test
  50     $build->install;    # runs build install
  51
  52
  53 =head1 DESCRIPTION
  54
  55 C<CPANPLUS::Dist::Build> is a distribution class for C<Module::Build>
  56 related modules.
  57 Using this package, you can create, install and uninstall perl
  58 modules. It inherits from C<CPANPLUS::Dist>.
  59
  60 Normal users won't have to worry about the interface to this module,
  61 as it functions transparently as a plug-in to C<CPANPLUS> and will
  62 just C<Do The Right Thing> when it's loaded.
  63
  64 =head1 ACCESSORS
  65
  66 =over 4
  67
  68 =item C<parent()>
  69
  70 Returns the C<CPANPLUS::Module> object that parented this object.
  71
  72 =item C<status()>
  73
  74 Returns the C<Object::Accessor> object that keeps the status for
  75 this module.
  76
  77 =back
  78
  79 =head1 STATUS ACCESSORS
  80
  81 All accessors can be accessed as follows:
  82     $build->status->ACCESSOR
  83
  84 =over 4
  85
  86 =item C<build_pl ()>
  87
  88 Location of the Build file.
  89 Set to 0 explicitly if something went wrong.
  90
  91 =item C<build ()>
  92
  93 BOOL indicating if the C<Build> command was successful.
  94
  95 =item C<test ()>
  96
  97 BOOL indicating if the C<Build test> command was successful.
  98
  99 =item C<prepared ()>
 100
 101 BOOL indicating if the C<prepare> call exited succesfully
 102 This gets set after C<perl Build.PL>
 103
 104 =item C<distdir ()>
 105
 106 Full path to the directory in which the C<prepare> call took place,
 107 set after a call to C<prepare>.
 108
 109 =item C<created ()>
 110
 111 BOOL indicating if the C<create> call exited succesfully. This gets
 112 set after C<Build> and C<Build test>.
 113
 114 =item C<installed ()>
 115
 116 BOOL indicating if the module was installed. This gets set after
 117 C<Build install> exits successfully.
 118
 119 =item uninstalled ()
 120
 121 BOOL indicating if the module was uninstalled properly.
 122
 123 =item C<_create_args ()>
 124
 125 Storage of the arguments passed to C<create> for this object. Used
 126 for recursive calls when satisfying prerequisites.
 127
 128 =item C<_install_args ()>
 129
 130 Storage of the arguments passed to C<install> for this object. Used
 131 for recursive calls when satisfying prerequisites.
 132
 133 =back
 134
 135 =cut
 136
 137 =head1 METHODS
 138
 139 =head2 $bool = CPANPLUS::Dist::Build->format_available();
 140
 141 Returns a boolean indicating whether or not you can use this package
 142 to create and install modules in your environment.
 143
 144 =cut
 145
 146 ### check if the format is available ###
 147 sub format_available {
 148     my $mod = "Module::Build";
 149     unless( can_load( modules => { $mod => '0.2611' } ) ) {
 150         error( loc( "You do not have '%1' -- '%2' not available",
 151                     $mod, __PACKAGE__ ) );
 152         return;
 153     }
 154
 155     return 1;
 156 }
 157
 158
 159 =head2 $bool = $dist->init();
 160
 161 Sets up the C<CPANPLUS::Dist::Build> object for use.
 162 Effectively creates all the needed status accessors.
 163
 164 Called automatically whenever you create a new C<CPANPLUS::Dist> object.
 165
 166 =cut
 167
 168 sub init {
 169     my $dist    = shift;
 170     my $status  = $dist->status;
 171
 172     $status->mk_accessors(qw[build_pl build test created installed uninstalled
 173                              _create_args _install_args _prepare_args
 174                              _mb_object _buildflags
 175                             ]);
 176
 177     ### just in case 'format_available' didn't get called
 178     require Module::Build;
 179
 180     return 1;
 181 }
 182
 183 =pod
 184
 185 =head2 $bool = $dist->prepare([perl => '/path/to/perl', buildflags => 'EXTRA=FLAGS', force => BOOL, verbose => BOOL])
 186
 187 C<prepare> prepares a distribution, running C<Build.PL>
 188 and establishing any prerequisites this
 189 distribution has.
 190
 191 The variable C<PERL5_CPANPLUS_IS_EXECUTING> will be set to the full path
 192 of the C<Build.PL> that is being executed. This enables any code inside
 193 the C<Build.PL> to know that it is being installed via CPANPLUS.
 194
 195 After a succcesfull C<prepare> you may call C<create> to create the
 196 distribution, followed by C<install> to actually install it.
 197
 198 Returns true on success and false on failure.
 199
 200 =cut
 201
 202 sub prepare {
 203     ### just in case you already did a create call for this module object
 204     ### just via a different dist object
 205     my $dist = shift;
 206     my $self = $dist->parent;
 207
 208     ### we're also the cpan_dist, since we don't need to have anything
 209     ### prepared from another installer
 210     $dist    = $self->status->dist_cpan if      $self->status->dist_cpan;
 211     $self->status->dist_cpan( $dist )   unless  $self->status->dist_cpan;
 212
 213     my $cb   = $self->parent;
 214     my $conf = $cb->configure_object;
 215     my %hash = @_;
 216
 217     my $dir;
 218     unless( $dir = $self->status->extract ) {
 219         error( loc( "No dir found to operate on!" ) );
 220         return;
 221     }
 222
 223     my $args;
 224     my( $force, $verbose, $buildflags, $perl, $prereq_target, $prereq_format,
 225         $prereq_build );
 226     {   local $Params::Check::ALLOW_UNKNOWN = 1;
 227         my $tmpl = {
 228             force           => {    default => $conf->get_conf('force'),
 229                                     store   => \$force },
 230             verbose         => {    default => $conf->get_conf('verbose'),
 231                                     store   => \$verbose },
 232             perl            => {    default => $^X, store => \$perl },
 233             buildflags      => {    default => $conf->get_conf('buildflags'),
 234                                     store   => \$buildflags },
 235             prereq_target   => {    default => '', store => \$prereq_target },
 236             prereq_format   => {    default => '',
 237                                     store   => \$prereq_format },
 238             prereq_build    => {    default => 0, store => \$prereq_build },
 239         };
 240
 241         $args = check( $tmpl, \%hash ) or return;
 242     }
 243
 244     return 1 if $dist->status->prepared && !$force;
 245
 246     $dist->status->_prepare_args( $args );
 247
 248     ### chdir to work directory ###
 249     my $orig = cwd();
 250     unless( $cb->_chdir( dir => $dir ) ) {
 251         error( loc( "Could not chdir to build directory '%1'", $dir ) );
 252         return;
 253     }
 254
 255     ### by now we've loaded module::build, and we're using the API, so
 256     ### it's safe to remove CPANPLUS::inc from our inc path, especially
 257     ### because it can trip up tests run under taint (just like EU::MM).
 258     ### turn off our PERL5OPT so no modules from CPANPLUS::inc get
 259     ### included in make test -- it should build without.
 260     ### also, modules that run in taint mode break if we leave
 261     ### our code ref in perl5opt
 262     ### XXX we've removed the ENV settings from cp::inc, so only need
 263     ### to reset the @INC
 264     #local $ENV{PERL5OPT} = CPANPLUS::inc->original_perl5opt;
 265     #local $ENV{PERL5LIB} = CPANPLUS::inc->original_perl5lib;
 266     #local @INC           = CPANPLUS::inc->original_inc;
 267
 268     ### this will generate warnings under anything lower than M::B 0.2606
 269     my @buildflags = $dist->_buildflags_as_list( $buildflags );
 270     $dist->status->_buildflags( $buildflags );
 271
 272     my $fail;
 273     RUN: {
 274         # 0.85_01
 275         ### we resolve 'configure requires' here, so we can run the 'perl
 276         ### Makefile.PL' command
 277         ### XXX for tests: mock f_c_r to something that *can* resolve and
 278         ### something that *doesnt* resolve. Check the error log for ok
 279         ### on this step or failure
 280         ### XXX make a seperate tarball to test for this scenario: simply
 281         ### containing a makefile.pl/build.pl for test purposes?
 282         my $safe_ver = version->new('0.85_01');
 283         if ( version->new($CPANPLUS::Internals::VERSION) >= $safe_ver )
 284         {   my $configure_requires = $dist->find_configure_requires;
 285             my $ok = $dist->_resolve_prereqs(
 286                             format          => $prereq_format,
 287                             verbose         => $verbose,
 288                             prereqs         => $configure_requires,
 289                             target          => $prereq_target,
 290                             force           => $force,
 291                             prereq_build    => $prereq_build,
 292                     );
 293
 294             unless( $ok ) {
 295
 296                 #### use $dist->flush to reset the cache ###
 297                 error( loc( "Unable to satisfy '%1' for '%2' " .
 298                             "-- aborting install",
 299                             'configure_requires', $self->module ) );
 300                 $dist->status->prepared(0);
 301                 $fail++;
 302                 last RUN;
 303             }
 304             ### end of prereq resolving ###
 305         }
 306
 307         # Wrap the exception that may be thrown here (should likely be
 308         # done at a much higher level).
 309         my $prep_output;
 310
 311         my $env = ENV_CPANPLUS_IS_EXECUTING;
 312         local $ENV{$env} = BUILD_PL->( $dir );
 313         my $run_perl    = $conf->get_program('perlwrapper');
 314         my $cmd = [$perl, $run_perl, BUILD_PL->($dir), @buildflags];
 315
 316         unless ( scalar run(    command => $cmd,
 317                                 buffer  => \$prep_output,
 318                                 verbose => $verbose )
 319         ) {
 320             error( loc( "Build.PL failed: %1", $prep_output ) );
 321             $fail++; last RUN;
 322         }
 323
 324         msg( $prep_output, 0 );
 325
 326         my $prereqs = $self->status->prereqs;
 327
 328         $prereqs ||= $dist->_find_prereqs( verbose => $verbose,
 329                                            dir => $dir,
 330                                            perl => $perl,
 331                                            buildflags => $buildflags );
 332
 333     }
 334
 335     ### send out test report? ###
 336     if( $fail and $conf->get_conf('cpantest') ) {
 337            $cb->_send_report(
 338             module  => $self,
 339             failed  => $fail,
 340             buffer  => CPANPLUS::Error->stack_as_string,
 341             verbose => $verbose,
 342             force   => $force,
 343         ) or error(loc("Failed to send test report for '%1'",
 344                     $self->module ) );
 345     }
 346
 347     unless( $cb->_chdir( dir => $orig ) ) {
 348         error( loc( "Could not chdir back to start dir '%1'", $orig ) );
 349     }
 350
 351     ### save where we wrote this stuff -- same as extract dir in normal
 352     ### installer circumstances
 353     $dist->status->distdir( $self->status->extract );
 354
 355     return $dist->status->prepared( $fail ? 0 : 1 );
 356 }
 357
 358 sub _find_prereqs {
 359     my $dist = shift;
 360     my $self = $dist->parent;
 361     my $cb   = $self->parent;
 362     my $conf = $cb->configure_object;
 363     my %hash = @_;
 364
 365     my ($verbose, $dir, $buildflags, $perl);
 366     my $tmpl = {
 367         verbose => { default => $conf->get_conf('verbose'), store => \$verbose },
 368         dir     => { default => $self->status->extract, store => \$dir },
 369         perl    => { default => $^X, store => \$perl },
 370         buildflags => { default => $conf->get_conf('buildflags'),
 371                         store   => \$buildflags },
 372     };
 373
 374     my $args = check( $tmpl, \%hash ) or return;
 375
 376     my $prereqs = {};
 377
 378     my $safe_ver = version->new('0.31_03');
 379
 380     my $content;
 381
 382     if ( version->new( $Module::Build::VERSION ) >= $safe_ver and IPC::Cmd->can_capture_buffer ) {
 383         my @buildflags = $dist->_buildflags_as_list( $buildflags );
 384
 385         # Use the new Build action 'prereq_data'
 386         my $run_perl    = $conf->get_program('perlwrapper');
 387
 388         unless ( scalar run(    command => [$perl, $run_perl, BUILD->($dir), 'prereq_data', @buildflags],
 389                                 buffer  => \$content,
 390                                 verbose => 0 )
 391         ) {
 392             error( loc( "Build 'prereq_data' failed: %1 %2", $!, $content ) );
 393             return;
 394         }
 395
 396     }
 397     else {
 398         my $file = File::Spec->catfile( $dir, '_build', 'prereqs' );
 399         return unless -f $file;
 400
 401         my $fh = FileHandle->new();
 402
 403         unless( $fh->open( $file ) ) {
 404            error( loc( "Cannot open '%1': %2", $file, $! ) );
 405            return;
 406         }
 407
 408         $content = do { local $/; <$fh> };
 409     }
 410
 411     return unless $content;
 412     my $bphash = eval $content;
 413     return unless $bphash and ref $bphash eq 'HASH';
 414     foreach my $type ('requires', 'build_requires') {
 415        next unless $bphash->{$type} and ref $bphash->{$type} eq 'HASH';
 416        $prereqs->{$_} = $bphash->{$type}->{$_} for keys %{ $bphash->{$type} };
 417     }
 418
 419     # Temporary fix
 420     delete $prereqs->{'perl'};
 421
 422     ### allows for a user defined callback to filter the prerequisite
 423     ### list as they see fit, to remove (or add) any prereqs they see
 424     ### fit. The default installed callback will return the hashref in
 425     ### an unmodified form
 426     ### this callback got added after cpanplus 0.0562, so use a 'can'
 427     ### to find out if it's supported. For older versions, we'll just
 428     ### return the hashref as is ourselves.
 429     my $href    = $cb->_callbacks->can('filter_prereqs')
 430                     ? $cb->_callbacks->filter_prereqs->( $cb, $prereqs )
 431                     : $prereqs;
 432
 433     $self->status->prereqs( $href );
 434
 435     ### make sure it's not the same ref
 436     return { %$href };
 437 }
 438
 439 =pod
 440
 441 =head2 $dist->create([perl => '/path/to/perl', buildflags => 'EXTRA=FLAGS', prereq_target => TARGET, force => BOOL, verbose => BOOL, skiptest => BOOL])
 442
 443 C<create> preps a distribution for installation. This means it will
 444 run C<Build> and C<Build test>.
 445 This will also satisfy any prerequisites the module may have.
 446
 447 If you set C<skiptest> to true, it will skip the C<Build test> stage.
 448 If you set C<force> to true, it will go over all the stages of the
 449 C<Build> process again, ignoring any previously cached results. It
 450 will also ignore a bad return value from C<Build test> and still allow
 451 the operation to return true.
 452
 453 Returns true on success and false on failure.
 454
 455 You may then call C<< $dist->install >> on the object to actually
 456 install it.
 457
 458 =cut
 459
 460 sub create {
 461     ### just in case you already did a create call for this module object
 462     ### just via a different dist object
 463     my $dist = shift;
 464     my $self = $dist->parent;
 465
 466     ### we're also the cpan_dist, since we don't need to have anything
 467     ### prepared from another installer
 468     $dist    = $self->status->dist_cpan if      $self->status->dist_cpan;
 469     $self->status->dist_cpan( $dist )   unless  $self->status->dist_cpan;
 470
 471     my $cb   = $self->parent;
 472     my $conf = $cb->configure_object;
 473     my %hash = @_;
 474
 475     my $dir;
 476     unless( $dir = $self->status->extract ) {
 477         error( loc( "No dir found to operate on!" ) );
 478         return;
 479     }
 480
 481     my $args;
 482     my( $force, $verbose, $buildflags, $skiptest, $prereq_target,
 483         $perl, $prereq_format, $prereq_build);
 484     {   local $Params::Check::ALLOW_UNKNOWN = 1;
 485         my $tmpl = {
 486             force           => {    default => $conf->get_conf('force'),
 487                                     store   => \$force },
 488             verbose         => {    default => $conf->get_conf('verbose'),
 489                                     store   => \$verbose },
 490             perl            => {    default => $^X, store => \$perl },
 491             buildflags      => {    default => $conf->get_conf('buildflags'),
 492                                     store   => \$buildflags },
 493             skiptest        => {    default => $conf->get_conf('skiptest'),
 494                                     store   => \$skiptest },
 495             prereq_target   => {    default => '', store => \$prereq_target },
 496             ### don't set the default format to 'build' -- that is wrong!
 497             prereq_format   => {    #default => $self->status->installer_type,
 498                                     default => '',
 499                                     store   => \$prereq_format },
 500             prereq_build    => {    default => 0, store => \$prereq_build },
 501         };
 502
 503         $args = check( $tmpl, \%hash ) or return;
 504     }
 505
 506     # restore the state as we have created this already.
 507     if ( $dist->status->created && !$force ) {
 508         ### add this directory to your lib ###
 509         $self->add_to_includepath();
 510         return 1;
 511     }
 512
 513     $dist->status->_create_args( $args );
 514
 515     ### is this dist prepared?
 516     unless( $dist->status->prepared ) {
 517         error( loc( "You have not successfully prepared a '%2' distribution ".
 518                     "yet -- cannot create yet", __PACKAGE__ ) );
 519         return;
 520     }
 521
 522     ### chdir to work directory ###
 523     my $orig = cwd();
 524     unless( $cb->_chdir( dir => $dir ) ) {
 525         error( loc( "Could not chdir to build directory '%1'", $dir ) );
 526         return;
 527     }
 528
 529     ### by now we've loaded module::build, and we're using the API, so
 530     ### it's safe to remove CPANPLUS::inc from our inc path, especially
 531     ### because it can trip up tests run under taint (just like EU::MM).
 532     ### turn off our PERL5OPT so no modules from CPANPLUS::inc get
 533     ### included in make test -- it should build without.
 534     ### also, modules that run in taint mode break if we leave
 535     ### our code ref in perl5opt
 536     ### XXX we've removed the ENV settings from cp::inc, so only need
 537     ### to reset the @INC
 538     #local $ENV{PERL5OPT} = CPANPLUS::inc->original_perl5opt;
 539     #local $ENV{PERL5LIB} = CPANPLUS::inc->original_perl5lib;
 540     #local @INC           = CPANPLUS::inc->original_inc;
 541
 542     ### but do it *before* the new_from_context, as M::B seems
 543     ### to be actually running the file...
 544     ### an unshift in the block seems to be ignored.. somehow...
 545     #{   my $lib = $self->best_path_to_module_build;
 546     #    unshift @INC, $lib if $lib;
 547     #}
 548     unshift @INC, $self->best_path_to_module_build
 549                 if $self->best_path_to_module_build;
 550
 551     ### this will generate warnings under anything lower than M::B 0.2606
 552     my @buildflags = $dist->_buildflags_as_list( $buildflags );
 553     $dist->status->_buildflags( $buildflags );
 554
 555     my $fail; my $prereq_fail; my $test_fail;
 556     RUN: {
 557
 558         my $run_perl    = $conf->get_program('perlwrapper');
 559
 560         ### this will set the directory back to the start
 561         ### dir, so we must chdir /again/
 562         my $ok = $dist->_resolve_prereqs(
 563                         force           => $force,
 564                         format          => $prereq_format,
 565                         verbose         => $verbose,
 566                         prereqs         => $self->status->prereqs,
 567                         target          => $prereq_target,
 568                         prereq_build    => $prereq_build,
 569                     );
 570
 571         unless( $cb->_chdir( dir => $dir ) ) {
 572             error( loc( "Could not chdir to build directory '%1'", $dir ) );
 573             return;
 574         }
 575
 576         unless( $ok ) {
 577             #### use $dist->flush to reset the cache ###
 578             error( loc( "Unable to satisfy prerequisites for '%1' " .
 579                         "-- aborting install", $self->module ) );
 580             $dist->status->build(0);
 581             $fail++; $prereq_fail++;
 582             last RUN;
 583         }
 584
 585         my ($captured, $cmd);
 586         if ( ON_VMS ) {
 587             $cmd = [$perl, BUILD->($dir), @buildflags];
 588         }
 589         else {
 590             $cmd = [$perl, $run_perl, BUILD->($dir), @buildflags];
 591         }
 592
 593         unless ( scalar run(    command => $cmd,
 594                                 buffer  => \$captured,
 595                                 verbose => $verbose )
 596         ) {
 597             error( loc( "MAKE failed:\n%1", $captured ) );
 598             $dist->status->build(0);
 599             $fail++; last RUN;
 600         }
 601
 602         msg( $captured, 0 );
 603
 604         $dist->status->build(1);
 605
 606         ### add this directory to your lib ###
 607         $self->add_to_includepath();
 608
 609         ### this buffer will not include what tests failed due to a
 610         ### M::B/Test::Harness bug. Reported as #9793 with patch
 611         ### against 0.2607 on 26/1/2005
 612         unless( $skiptest ) {
 613             my $test_output;
 614             if ( ON_VMS ) {
 615                 $cmd     = [$perl, BUILD->($dir), "test", @buildflags];
 616             }
 617             else {
 618                 $cmd     = [$perl, $run_perl, BUILD->($dir), "test", @buildflags];
 619             }
 620             unless ( scalar run(    command => $cmd,
 621                                     buffer  => \$test_output,
 622                                     verbose => $verbose )
 623             ) {
 624                 error( loc( "MAKE TEST failed:\n%1 ", $test_output ) );
 625
 626                 ### mark specifically *test* failure.. so we dont
 627                 ### send success on force...
 628                 $test_fail++;
 629
 630                 if( !$force and !$cb->_callbacks->proceed_on_test_failure->(
 631                                       $self, $@ )
 632                 ) {
 633                     $dist->status->test(0);
 634                     $fail++; last RUN;
 635                 }
 636
 637             }
 638             else {
 639                 msg( loc( "MAKE TEST passed:\n%1", $test_output ), 0 );
 640                 #msg( $test_output, 0 );
 641                 $dist->status->test(1);
 642             }
 643         }
 644         else {
 645             msg(loc("Tests skipped"), $verbose);
 646         }
 647     }
 648
 649     unless( $cb->_chdir( dir => $orig ) ) {
 650         error( loc( "Could not chdir back to start dir '%1'", $orig ) );
 651     }
 652
 653     ### send out test report? ###
 654     if( $conf->get_conf('cpantest') and not $prereq_fail ) {
 655         $cb->_send_report(
 656             module          => $self,
 657             failed          => $test_fail || $fail,
 658             buffer          => CPANPLUS::Error->stack_as_string,
 659             verbose         => $verbose,
 660             force           => $force,
 661             tests_skipped   => $skiptest,
 662         ) or error(loc("Failed to send test report for '%1'",
 663                     $self->module ) );
 664     }
 665
 666     return $dist->status->created( $fail ? 0 : 1 );
 667 }
 668
 669 =head2 $dist->install([verbose => BOOL, perl => /path/to/perl])
 670
 671 Actually installs the created dist.
 672
 673 Returns true on success and false on failure.
 674
 675 =cut
 676
 677 sub install {
 678     ### just in case you already did a create call for this module object
 679     ### just via a different dist object
 680     my $dist = shift;
 681     my $self = $dist->parent;
 682
 683     ### we're also the cpan_dist, since we don't need to have anything
 684     ### prepared from another installer
 685     $dist    = $self->status->dist_cpan if $self->status->dist_cpan;
 686
 687     my $cb   = $self->parent;
 688     my $conf = $cb->configure_object;
 689     my %hash = @_;
 690
 691
 692     my $verbose; my $perl; my $force; my $buildflags;
 693     {   local $Params::Check::ALLOW_UNKNOWN = 1;
 694         my $tmpl = {
 695             verbose => { default => $conf->get_conf('verbose'),
 696                          store   => \$verbose },
 697             force   => { default => $conf->get_conf('force'),
 698                          store   => \$force },
 699             buildflags => { default => $conf->get_conf('buildflags'),
 700                             store   => \$buildflags },
 701             perl    => { default => $^X, store   => \$perl },
 702         };
 703
 704         my $args = check( $tmpl, \%hash ) or return;
 705         $dist->status->_install_args( $args );
 706     }
 707
 708     my $dir;
 709     unless( $dir = $self->status->extract ) {
 710         error( loc( "No dir found to operate on!" ) );
 711         return;
 712     }
 713
 714     my $orig = cwd();
 715
 716     unless( $cb->_chdir( dir => $dir ) ) {
 717         error( loc( "Could not chdir to build directory '%1'", $dir ) );
 718         return;
 719     }
 720
 721     ### value set and false -- means failure ###
 722     if( defined $self->status->installed &&
 723         !$self->status->installed && !$force
 724     ) {
 725         error( loc( "Module '%1' has failed to install before this session " .
 726                     "-- aborting install", $self->module ) );
 727         return;
 728     }
 729
 730     my $fail;
 731     my @buildflags = $dist->_buildflags_as_list( $buildflags );
 732     my $run_perl    = $conf->get_program('perlwrapper');
 733
 734     ### hmm, how is this going to deal with sudo?
 735     ### for now, check effective uid, if it's not root,
 736     ### shell out, otherwise use the method
 737     if( $> ) {
 738
 739         ### don't worry about loading the right version of M::B anymore
 740         ### the 'new_from_context' already added the 'right' path to
 741         ### M::B at the top of the build.pl
 742         my $cmd;
 743         if ( ON_VMS ) {
 744             $cmd     = [$perl, BUILD->($dir), "install", @buildflags];
 745         }
 746         else {
 747             $cmd     = [$perl, $run_perl, BUILD->($dir), "install", @buildflags];
 748         }
 749         my $sudo    = $conf->get_program('sudo');
 750         unshift @$cmd, $sudo if $sudo;
 751
 752
 753         my $buffer;
 754         unless( scalar run( command => $cmd,
 755                             buffer  => \$buffer,
 756                             verbose => $verbose )
 757         ) {
 758             error(loc("Could not run '%1': %2", 'Build install', $buffer));
 759             $fail++;
 760         }
 761     } else {
 762         my ($install_output, $cmd);
 763         if ( ON_VMS ) {
 764             $cmd     = [$perl, BUILD->($dir), "install", @buildflags];
 765         }
 766         else {
 767             $cmd     = [$perl, $run_perl, BUILD->($dir), "install", @buildflags];
 768         }
 769         unless( scalar run( command => $cmd,
 770                             buffer  => \$install_output,
 771                             verbose => $verbose )
 772         ) {
 773             error(loc("Could not run '%1': %2", 'Build install', $install_output));
 774             $fail++;
 775         }
 776         else {
 777             msg( $install_output, 0 );
 778         }
 779     }
 780
 781
 782     unless( $cb->_chdir( dir => $orig ) ) {
 783         error( loc( "Could not chdir back to start dir '%1'", $orig ) );
 784     }
 785
 786     return $dist->status->installed( $fail ? 0 : 1 );
 787 }
 788
 789 ### returns the string 'foo=bar --zot quux'
 790 ###        as the list 'foo=bar', '--zot', 'qux'
 791 sub _buildflags_as_list {
 792     my $self    = shift;
 793     my $flags   = shift or return;
 794
 795     return Module::Build->split_like_shell($flags);
 796 }
 797
 798 =head1 AUTHOR
 799
 800 Originally by Jos Boumans E<lt>kane@cpan.orgE<gt>.  Brought to working
 801 condition by Ken Williams E<lt>kwilliams@cpan.orgE<gt>.
 802
 803 Other hackery and currently maintained by Chris C<BinGOs> Williams ( no relation ). E<lt>bingos@cpan.orgE<gt>.
 804
 805 =head1 LICENSE
 806
 807 The CPAN++ interface (of which this module is a part of) is
 808 copyright (c) 2001, 2002, 2003, 2004, 2005 Jos Boumans E<lt>kane@cpan.orgE<gt>.
 809 All rights reserved.
 810
 811 This library is free software;
 812 you may redistribute and/or modify it under the same
 813 terms as Perl itself.
 814
 815 =cut
 816
 817 qq[Putting the Module::Build into CPANPLUS];
 818
 819
 820 # Local variables:
 821 # c-indentation-style: bsd
 822 # c-basic-offset: 4
 823 # indent-tabs-mode: nil
 824 # End:
 825 # vim: expandtab shiftwidth=4:
 826