bin/sqlt-diff

   1 #!/usr/bin/perl -w
   2 # vim: set ft=perl:
   3
   4 # -------------------------------------------------------------------
   5 # $Id: sqlt-diff,v 1.17 2007-03-19 17:15:54 duality72 Exp $
   6 # -------------------------------------------------------------------
   7 # Copyright (C) 2002-4 The SQLFairy Authors
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License as
  11 # published by the Free Software Foundation; version 2.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  21 # 02111-1307  USA
  22 # -------------------------------------------------------------------
  23
  24 =head1 NAME
  25
  26 sqlt-diff - find the differences b/w two schemas
  27
  28 =head1 SYNOPSIS
  29
  30 For help:
  31
  32   sqlt-diff -h|--help
  33
  34 For a list of all valid parsers:
  35
  36   sqlt -l|--list
  37
  38 To diff two schemas:
  39
  40   sqlt-diff [options] file_name1=parser1 file_name2=parser2
  41
  42 Options:
  43
  44   -d|--debug   Show debugging info
  45   -t|--trace   Turn on tracing for Parse::RecDescent
  46   -c|--case-insensitive   Compare tables/columns case-insensitively
  47   --ignore-index-names    Ignore index name differences
  48   --ignore-constraint-names   Ignore constraint name differences
  49   --mysql_parser_version=<#####> Specify a target MySQL parser version
  50                                  for dealing with /*! comments
  51   --output-db=<Producer>  This Producer will be used instead of one
  52                           corresponding to parser1 to format output
  53                           for new tables
  54
  55 =head1 DESCRIPTION
  56
  57 sqlt-diff is a utility for creating a file of SQL commands necessary to
  58 transform the first schema provided to the second.  While not yet
  59 exhaustive in its ability to mutate the entire schema, it will report the
  60 following
  61
  62 =over
  63
  64 =item * New tables
  65
  66 Using the Producer class of the target (second) schema, any tables missing
  67 in the first schema will be generated in their entirety (fields, constraints,
  68 indices).
  69
  70 =item * Missing/altered fields
  71
  72 Any fields missing or altered between the two schemas will be reported
  73 as:
  74
  75   ALTER TABLE <table_name>
  76     [DROP <field_name>]
  77     [CHANGE <field_name> <datatype> (<size>)] ;
  78
  79 =item * Missing/altered indices
  80
  81 Any indices missing or of a different type or on different fields will be
  82 indicated.  Indices that should be dropped will be reported as such:
  83
  84   DROP INDEX <index_name> ON <table_name> ;
  85
  86 An index of a different type or on different fields will be reported as a
  87 new index as such:
  88
  89   CREATE [<index_type>] INDEX [<index_name>] ON <table_name>
  90     ( <field_name>[,<field_name>] ) ;
  91
  92 =back
  93
  94 "ALTER/DROP TABLE" and "CREATE INDEX" statements B<are not> generated by
  95 the Producer, unfortunately, and may require massaging before being passed to
  96 your target database.
  97
  98 =cut
  99
 100 # -------------------------------------------------------------------
 101
 102 use strict;
 103 use Pod::Usage;
 104 use Data::Dumper;
 105 use SQL::Translator;
 106 use SQL::Translator::Diff;
 107 use SQL::Translator::Schema::Constants;
 108
 109 use vars qw( $VERSION );
 110 $VERSION = sprintf "%d.%02d", q$Revision: 1.17 $ =~ /(\d+)\.(\d+)/;
 111
 112 my ( @input, $list, $help, $debug, $trace, $caseopt,$ignore_index_names,
 113         $ignore_constraint_names, $output_db, $mysql_parser_version );
 114 for my $arg ( @ARGV ) {
 115     if ( $arg =~ m/^-?-l(ist)?$/ ) {
 116         $list = 1;
 117     }
 118     elsif ( $arg =~ m/^-?-h(elp)?$/ ) {
 119         $help = 1;
 120     }
 121     elsif ( $arg =~ m/^-?-d(ebug)?$/ ) {
 122         $debug = 1;
 123     }
 124     elsif ( $arg =~ m/^-?-t(race)?$/ ) {
 125         $trace = 1;
 126     }
 127     elsif ( $arg =~ m/^-?-c(ase-insensitive)?$/ ) {
 128         $caseopt = 1;
 129     }
 130     elsif ( $arg =~ m/^--ignore-index-names$/ ) {
 131         $ignore_index_names = 1;
 132     }
 133     elsif ( $arg =~ m/^--ignore-constraint-names$/ ) {
 134         $ignore_constraint_names = 1;
 135     }
 136     elsif ( $arg =~ m/^--mysql-parser-version=(.+)$/ ) {
 137         $mysql_parser_version = $1;
 138     }
 139     elsif ( $arg =~ m/^--output-db=(.+)$/ ) {
 140         $output_db = $1;
 141     }
 142     elsif ( $arg =~ m/^([^=]+)=(.+)$/ ) {
 143         push @input, { file => $1, parser => $2 };
 144     }
 145     else {
 146         pod2usage( msg => "Unknown argument '$arg'" );
 147     }
 148 }
 149
 150 pod2usage(1) if $help || !@ARGV;
 151 pod2usage('Please specify only two schemas to diff') if scalar @input > 2;
 152
 153 my $tr            = SQL::Translator->new;
 154 my @parsers       = $tr->list_parsers;
 155 my %valid_parsers = map { $_, 1 } @parsers;
 156
 157 if ( $list ) {
 158     print "\nParsers:\n", map { "\t$_\n" } sort @parsers;
 159     print "\n";
 160     exit(0);
 161 }
 162
 163 pod2usage( msg => 'Too many file args' ) if @input > 2;
 164
 165 my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
 166     my $file   = $_->{'file'};
 167     my $parser = $_->{'parser'};
 168
 169     die "Unable to read file '$file'\n" unless -r $file;
 170     die "'$parser' is an invalid parser\n" unless $valid_parsers{ $parser };
 171
 172     my $t = SQL::Translator->new(parser_args => {mysql_parser_version => $mysql_parser_version || 0});
 173     $t->debug( $debug );
 174     $t->trace( $trace );
 175     $t->parser( $parser )            or die $tr->error;
 176     my $out = $t->translate( $file ) or die $tr->error;
 177     my $schema = $t->schema;
 178     unless ( $schema->name ) {
 179         $schema->name( $file );
 180     }
 181
 182     ($schema, $parser);
 183 } @input;
 184
 185 my $result = SQL::Translator::Diff::schema_diff($source_schema, $source_db,
 186                                                 $target_schema, $target_db,
 187                                                 { caseopt                 => $caseopt,
 188                                                   ignore_index_names      => $ignore_index_names,
 189                                                   ignore_constraint_names => $ignore_constraint_names,
 190                                                   output_db               => $output_db,
 191                                                   debug                   => $debug,
 192                                                   trace                   => $trace });
 193 if($result)
 194 {
 195     print $result;
 196 }
 197 else
 198 {
 199     print "No differences found.";
 200 }
 201
 202 # -------------------------------------------------------------------
 203 # Bring out number weight & measure in a year of dearth.
 204 # William Blake
 205 # -------------------------------------------------------------------
 206
 207 =pod
 208
 209 =head1 AUTHOR
 210
 211 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.
 212
 213 =head1 SEE ALSO
 214
 215 SQL::Translator, L<http://sqlfairy.sourceforge.net>.
 216
 217 =cut