bin/sqlt

   1 #!/usr/bin/perl -w
   2
   3 # -------------------------------------------------------------------
   4 # $Id: sqlt,v 1.1 2003-08-26 02:29:12 kycl4rk Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2002 Ken Y. Clark <kycl4rk@users.sourceforge.net>,
   7 #                    darren chamberlain <darren@cpan.org>
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License as
  11 # published by the Free Software Foundation; version 2.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  21 # 02111-1307  USA
  22 # -------------------------------------------------------------------
  23
  24 use strict;
  25 use Getopt::Long;
  26 use Pod::Usage;
  27 use SQL::Translator;
  28
  29 use Data::Dumper;
  30
  31 use vars qw( $VERSION );
  32 $VERSION = sprintf "%d.%02d", q$Revision: 1.1 $ =~ /(\d+)\.(\d+)/;
  33
  34 my $from;             # the original database
  35 my $to;               # the destination database
  36 my $help;             # show POD and bail
  37 my $stdin;            # whether to read STDIN for create script
  38 my $no_comments;      # whether to put comments in out file
  39 my $show_warnings;    # whether to show warnings from SQL::Translator
  40 my $add_drop_table;   # whether to show warnings from SQL::Translator
  41 my $debug;            # whether to print debug info
  42 my $trace;            # whether to print parser trace
  43 my $list;             # list all parsers and producers
  44 my $no_trim;          # don't trim whitespace on xSV fields
  45 my $no_scan;          # don't scan xSV fields for data types and sizes
  46 my $field_separator;  # for xSV files
  47 my $record_separator; # for xSV files
  48 my $validate;         # whether to validate the parsed document
  49 my $imap_file;        # filename where to place image map coords
  50 my $imap_url;         # URL to use in making image map
  51 my $pretty;           # use CGI::Pretty instead of CGI (HTML producer)
  52 my $template;         # template to pass to TTSchema producer
  53
  54 #
  55 # Get options, explain how to use the script if necessary.
  56 #
  57 GetOptions(
  58     'f|from|parser:s' => \$from,
  59     't|to|producer:s' => \$to,
  60     'h|help'          => \$help,
  61     'l|list'          => \$list,
  62     'd|debug'         => \$debug,
  63     'trace'           => \$trace,
  64     'no-comments'     => \$no_comments,
  65     'show-warnings'   => \$show_warnings,
  66     'add-drop-table'  => \$add_drop_table,
  67     'v|validate'      => \$validate,
  68     'no-trim'         => \$no_trim,
  69     'no-scan'         => \$no_scan,
  70     'fs:s'            => \$field_separator,
  71     'rs:s'            => \$record_separator,
  72     'imap-file:s'     => \$imap_file,
  73     'imap-url:s'      => \$imap_url,
  74     'pretty!'         => \$pretty,
  75     'template:s'      => \$template,
  76 ) or pod2usage(2);
  77
  78 my @files = @ARGV; # the create script(s) for the original db
  79
  80 pod2usage(1) if $help;
  81
  82 #
  83 # If everything is OK, translate file(s).
  84 #
  85 my $translator      =  SQL::Translator->new(
  86     debug           => $debug          ||  0,
  87     trace           => $trace          ||  0,
  88     no_comments     => $no_comments    ||  0,
  89     show_warnings   => $show_warnings  ||  0,
  90     add_drop_table  => $add_drop_table ||  0,
  91     validate        => $validate       ||  0,
  92     parser_args     => {
  93         trim_fields      => $no_trim ? 0 : 1,
  94         scan_fields      => $no_scan ? 0 : 1,
  95         field_separator  => $field_separator,
  96         record_separator => $record_separator,
  97     },
  98     producer_args   => {
  99         imap_file        => $imap_file,
 100         imap_url         => $imap_url,
 101         pretty           => $pretty,
 102         ttfile           => $template,
 103     },
 104 );
 105
 106 if ( $list ) {
 107     my @parsers   = $translator->list_parsers;
 108     my @producers = $translator->list_producers;
 109
 110     for ( @parsers, @producers ) {
 111         if ( $_ =~ m/.+::(\w+)\.pm/ ) {
 112             $_ = $1;
 113         }
 114     }
 115
 116     print "\nParsers:\n",   map { "\t$_\n" } sort @parsers;
 117     print "\nProducers:\n", map { "\t$_\n" } sort @producers;
 118     print "\n";
 119     exit(0);
 120 }
 121
 122 pod2usage(2) unless $from && $to && @files;
 123
 124 $translator->parser($from);
 125 $translator->producer($to);
 126
 127 for my $file (@files) {
 128     my $output = $translator->translate(file => $file) or die
 129         "Error: " . $translator->error;
 130     print $output;
 131 }
 132
 133 # ----------------------------------------------------
 134 # It is not all books that are as dull as their readers.
 135 # Henry David Thoreau
 136 # ----------------------------------------------------
 137
 138 =head1 NAME
 139
 140 sql_translator.pl - convert an SQL database schema
 141
 142 =head1 SYNOPSIS
 143
 144 For help:
 145
 146   ./sql_translator.pl -h|--help
 147
 148 For a list of all parsers and producers:
 149
 150   ./sql_translator.pl -l|--list
 151
 152 To translate a schema:
 153
 154   ./sql_translator.pl
 155         -f|--from|--parser MySQL
 156         -t|--to|--producer Oracle
 157         [options]
 158         file
 159
 160   Options:
 161
 162     -d|--debug         Print debug info
 163     -v|--validate      Validate the schema
 164     --trace            Print parser trace info
 165     --no-comments      Don't include comments in SQL output
 166     --show-warnings    Print to STDERR warnings of conflicts, etc.
 167     --add-drop-table   Add 'drop table' statements before creates
 168
 169   xSV Options:
 170
 171     --fs               The field separator
 172     --rs               The record separator
 173     --no-trim          Don't trim whitespace on fields
 174     --no-scan          Don't scan fields for data types and sizes
 175
 176   Diagram Options:
 177
 178     --imap-file        Filename to put image map data
 179     --imap-url         URL to use for image map
 180
 181   HTML Options:
 182
 183     --pretty           Use CGI::Pretty for the outpu
 184
 185   TTSchema Options:
 186
 187     --template         The path to the template
 188
 189 =head1 DESCRIPTION
 190
 191 This script is part of the SQL Fairy project
 192 (http://sqlfairy.sourceforge.net/).  It will try to convert any
 193 database syntax for which it has a grammar into some other format it
 194 knows about.
 195
 196 If using "show-warnings," be sure to redirect STDERR to a separate file.
 197 In bash, you could do this:
 198
 199     $ sql_translator.pl -f MySQL -t PostgreSQL --show-warnings \
 200        file.sql 1>out 2>err
 201
 202 You can specify a parser or producer located in any module that Perl
 203 knows about, allowing you to easily substitute your own.
 204
 205 =head1 AUTHOR
 206
 207 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>
 208
 209 =head1 SEE ALSO
 210
 211 SQL::Translator.
 212
 213 =cut