bin/sql_translator.pl

   1 #!/usr/bin/perl -w
   2
   3 # -------------------------------------------------------------------
   4 # $Id: sql_translator.pl,v 1.6 2002-11-26 03:59:57 kycl4rk Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2002 Ken Y. Clark <kycl4rk@users.sourceforge.net>,
   7 #                    darren chamberlain <darren@cpan.org>
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License as
  11 # published by the Free Software Foundation; version 2.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  21 # 02111-1307  USA
  22 # -------------------------------------------------------------------
  23
  24 use strict;
  25 use Getopt::Long;
  26 use Pod::Usage;
  27 use SQL::Translator;
  28
  29 use Data::Dumper;
  30
  31 use vars qw( $VERSION );
  32 $VERSION = sprintf "%d.%02d", q$Revision: 1.6 $ =~ /(\d+)\.(\d+)/;
  33
  34 my $from;           # the original database
  35 my $to;             # the destination database
  36 my $help;           # show POD and bail
  37 my $stdin;          # whether to read STDIN for create script
  38 my $no_comments;    # whether to put comments in out file
  39 my $show_warnings;  # whether to show warnings from SQL::Translator
  40 my $add_drop_table; # whether to show warnings from SQL::Translator
  41 my $xlate;          # user overrides for field translation
  42 my $debug;          # whether to print debug info
  43 my $trace;          # whether to print parser trace
  44 my $list;           # list all parsers and producers
  45
  46 #
  47 # Get options, explain how to use the script if necessary.
  48 #
  49 GetOptions(
  50     'f|from|parser:s' => \$from,
  51     't|to|producer:s' => \$to,
  52     'h|help'          => \$help,
  53     'l|list'          => \$list,
  54     'd|debug'         => \$debug,
  55     'trace'           => \$trace,
  56     'no-comments'     => \$no_comments,
  57     'show-warnings'   => \$show_warnings,
  58     'add-drop-table'  => \$add_drop_table,
  59     'xlate=s'         => \$xlate,
  60 ) or pod2usage(2);
  61
  62 my @files = @ARGV; # the create script(s) for the original db
  63
  64 pod2usage(1) if $help;
  65
  66 if ( $xlate ) {
  67     my @fields = split /,/, $xlate;
  68     $xlate     = {};
  69     for my $field ( @fields ) {
  70         my ( $from, $to ) = split(/\//, $field);
  71         $xlate->{$from} = $to;
  72     }
  73 }
  74
  75 #
  76 # If everything is OK, translate file(s).
  77 #
  78 my $translator     =  SQL::Translator->new(
  79     xlate          => $xlate          || {},
  80     debug          => $debug          ||  0,
  81     trace          => $trace          ||  0,
  82     no_comments    => $no_comments    ||  0,
  83     show_warnings  => $show_warnings  ||  0,
  84     add_drop_table => $add_drop_table ||  0,
  85 );
  86
  87 if ( $list ) {
  88     my @parsers   = $translator->list_parsers;
  89     my @producers = $translator->list_producers;
  90
  91     for ( @parsers, @producers ) {
  92         if ( $_ =~ m/.+::(\w+)\.pm/ ) {
  93             $_ = $1;
  94         }
  95     }
  96
  97     print "\nParsers:\n",   map { "\t$_\n" } sort @parsers;
  98     print "\nProducers:\n", map { "\t$_\n" } sort @producers;
  99     print "\n";
 100     exit(0);
 101 }
 102
 103 pod2usage(2) unless $from && $to && @files;
 104
 105 $translator->parser($from);
 106 $translator->producer($to);
 107
 108 for my $file (@files) {
 109     my $output = $translator->translate( $file ) or die
 110         "Error: " . $translator->error;
 111     print $output;
 112 }
 113
 114 # ----------------------------------------------------
 115 # It is not all books that are as dull as their readers.
 116 # Henry David Thoreau
 117 # ----------------------------------------------------
 118
 119 =head1 NAME
 120
 121 sql_translator.pl - convert an SQL database schema
 122
 123 =head1 SYNOPSIS
 124
 125 For help:
 126
 127   ./sql_translator.pl -h|--help
 128
 129 For a list of all parsers and producers:
 130
 131   ./sql_translator.pl -l|--list
 132
 133 To translate a schema:
 134
 135   ./sql_translator.pl
 136         -f|--from|--parser MySQL
 137         -t|--to|--producer Oracle
 138         [options]
 139         file
 140
 141   Options:
 142
 143     -d|--debug                Print debug info
 144     --trace                   Print parser trace info
 145     --no-comments             Don't include comments in SQL output
 146     --show-warnings           Print to STDERR warnings of conflicts, etc.
 147     --add-drop-table          Add 'drop table' statements before creates
 148     --xlate=foo/bar,baz/blech Overrides for field translation
 149
 150 =head1 DESCRIPTION
 151
 152 This script is part of the SQL Fairy project
 153 (http://sqlfairy.sourceforge.net/).  It will try to convert any
 154 database syntax for which it has a grammar into some other format it
 155 knows about.
 156
 157 If using "show-warnings," be sure to redirect STDERR to a separate file.
 158 In bash, you could do this:
 159
 160     $ sql_translator.pl -f MySQL -t PostgreSQL --show-warnings file.sql \
 161        1>out 2>err
 162
 163 =head1 AUTHOR
 164
 165 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>
 166
 167 =head1 SEE ALSO
 168
 169 SQL::Translator.
 170
 171 =cut