base/lib/Text/Tradition.pm

   1 package Text::Tradition;
   2
   3 use JSON qw / from_json /;
   4 use Module::Load;
   5 use Moose;
   6 use Moose::Util qw/ does_role apply_all_roles /;
   7 use Text::Tradition::Collation;
   8 use Text::Tradition::Error;
   9 use Text::Tradition::Witness;
  10 use TryCatch;
  11
  12 use vars qw( $VERSION );
  13 $VERSION = "1.1";
  14
  15 # Enable plugin(s) if available
  16 eval { with 'Text::Tradition::HasStemma'; };
  17 # Don't warn normally
  18 # if( $@ ) {
  19 #       warn "Text::Tradition::Analysis not found. Disabling stemma analysis functionality";
  20 # };
  21 eval { with 'Text::Tradition::Language'; };
  22 eval { with 'Text::Tradition::Ownership'; };
  23
  24 has 'collation' => (
  25     is => 'ro',
  26     isa => 'Text::Tradition::Collation',
  27     writer => '_save_collation',
  28     );
  29
  30 has 'witness_hash' => (
  31     traits => ['Hash'],
  32     isa => 'HashRef[Text::Tradition::Witness]',
  33     handles => {
  34         witness     => 'get',
  35         add_witness => 'set',
  36         del_witness => 'delete',
  37         has_witness => 'exists',
  38         witnesses   => 'values',
  39     },
  40     default => sub { {} },
  41     );
  42
  43 has 'name' => (
  44     is => 'rw',
  45     isa => 'Str',
  46     default => 'Tradition',
  47     );
  48
  49 has '_initialized' => (
  50         is => 'ro',
  51         isa => 'Bool',
  52         default => undef,
  53         writer => '_init_done',
  54         );
  55
  56 # Create the witness before trying to add it
  57 around 'add_witness' => sub {
  58     my $orig = shift;
  59     my $self = shift;
  60     # TODO allow add of a Witness object?
  61     my %args = @_ == 1 ? %{$_[0]} : @_;
  62     $args{'tradition'} = $self;
  63     my $new_wit = Text::Tradition::Witness->new( %args );
  64     $self->$orig( $new_wit->sigil => $new_wit );
  65     return $new_wit;
  66 };
  67
  68 # Allow deletion of witness by object as well as by sigil
  69 around 'del_witness' => sub {
  70     my $orig = shift;
  71     my $self = shift;
  72     my @key_args;
  73     foreach my $arg ( @_ ) {
  74         push( @key_args,
  75               ref( $arg ) eq 'Text::Tradition::Witness' ? $arg->sigil : $arg );
  76     }
  77     return $self->$orig( @key_args );
  78 };
  79
  80 # Don't allow an empty hash value
  81 around 'witness' => sub {
  82     my( $orig, $self, $arg ) = @_;
  83     return unless $self->has_witness( $arg );
  84     return $self->$orig( $arg );
  85 };
  86
  87 =head1 NAME
  88
  89 Text::Tradition - a software model for a set of collated texts
  90
  91 =head1 SYNOPSIS
  92
  93   use Text::Tradition;
  94   my $t = Text::Tradition->new(
  95     'name' => 'this is a text',
  96     'input' => 'TEI',
  97     'file' => '/path/to/tei_parallel_seg_file.xml' );
  98
  99   my @text_wits = $t->witnesses();
 100   my $manuscript_a = $t->witness( 'A' );
 101
 102   $t = Text::Tradition->new();
 103   $t->add_witness( 'sourcetype' => 'xmldesc',
 104     'file' => '/path/to/teitranscription.xml' );
 105   $t->add_witness( 'sourcetype => 'plaintext', 'sigil' => 'Q',
 106     'string' => 'The quick brown fox jumped over the lazy dogs' );
 107   ## TODO
 108   $t->collate_texts;
 109
 110   my $text_path_svg = $t->collation->as_svg();
 111   ## See Text::Tradition::Collation for more on text collation itself
 112
 113 =head1 DESCRIPTION
 114
 115 Text::Tradition is a library for representation and analysis of collated
 116 texts, particularly medieval ones.  A 'tradition' refers to the aggregation
 117 of surviving versions of a text, generally preserved in multiple
 118 manuscripts (or 'witnesses').  A Tradition object thus has one more more
 119 Witnesses, as well as a Collation that represents the unity of all versions
 120 of the text.
 121
 122 =head1 METHODS
 123
 124 =head2 new
 125
 126 Creates and returns a new text tradition object.  The following options are
 127 accepted.
 128
 129 General options:
 130
 131 =over 4
 132
 133 =item B<name> - The name of the text.
 134
 135 =back
 136
 137 Initialization based on a collation file:
 138
 139 =over 4
 140
 141 =item B<input> - The input format of the collation file.  Can be one of the
 142 following:
 143
 144 =over 4
 145
 146 =item * Self - a GraphML format produced by this module
 147
 148 =item * CollateX - a GraphML format produced by CollateX
 149
 150 =item * CTE - a TEI XML format produced by Classical Text Editor
 151
 152 =item * JSON - an alignment table in JSON format, as produced by CollateX and
 153 other tools
 154
 155 =item * TEI - a TEI parallel segmentation format file
 156
 157 =item * Tabular - a spreadsheet collation.  See the documentation for
 158 L<Text::Tradition::Parser::Tabular> for an explanation of additional options.
 159
 160 =back
 161
 162 =item B<file> - The name of the file that contains the data.  One of 'file'
 163 or 'string' should be specified.
 164
 165 =item B<string> - A text string that contains the data.  One of 'file' or
 166 'string' should be specified.
 167
 168 =back
 169
 170 Initialization based on a list of witnesses [NOT YET IMPLEMENTED]:
 171
 172 =over 4
 173
 174 =item B<witnesses> - A reference to an array of Text::Tradition::Witness
 175 objects that carry the text to be collated.
 176
 177 =item B<collator> - A reference to a collation program that will accept
 178 Witness objects.
 179
 180 =back
 181
 182 =head2 B<witnesses>
 183
 184 Return the Text::Tradition::Witness objects associated with this tradition,
 185 as an array.
 186
 187 =head2 B<witness>( $sigil )
 188
 189 Returns the Text::Tradition::Witness object whose sigil is $sigil, or undef
 190 if there is no such object within the tradition.
 191
 192 =head2 B<add_witness>( %opts )
 193
 194 Instantiate a new witness with the given options (see documentation for
 195 Text::Tradition::Witness) and add it to the tradition.
 196
 197 =head2 B<del_witness>( $sigil )
 198
 199 Delete the witness with the given sigil from the tradition.  Returns the
 200 witness object for the deleted witness.
 201
 202 =begin testing
 203
 204 use_ok( 'Text::Tradition', "can use module" );
 205
 206 my $t = Text::Tradition->new( 'name' => 'empty' );
 207 is( ref( $t ), 'Text::Tradition', "initialized an empty Tradition object" );
 208 is( $t->name, 'empty', "object has the right name" );
 209 is( scalar $t->witnesses, 0, "object has no witnesses" );
 210
 211 my $simple = 't/data/simple.txt';
 212 my $s = Text::Tradition->new(
 213     'name'  => 'inline',
 214     'input' => 'Tabular',
 215     'file'  => $simple,
 216     );
 217 is( ref( $s ), 'Text::Tradition', "initialized a Tradition object" );
 218 is( $s->name, 'inline', "object has the right name" );
 219 is( scalar $s->witnesses, 3, "object has three witnesses" );
 220
 221 my $wit_a = $s->witness('A');
 222 is( ref( $wit_a ), 'Text::Tradition::Witness', "Found a witness A" );
 223 if( $wit_a ) {
 224     is( $wit_a->sigil, 'A', "Witness A has the right sigil" );
 225 }
 226 is( $s->witness('X'), undef, "There is no witness X" );
 227 ok( !exists $s->{'witnesses'}->{'X'}, "Witness key X not created" );
 228
 229 my $wit_d = $s->add_witness( 'sigil' => 'D', 'sourcetype' => 'collation' );
 230 is( ref( $wit_d ), 'Text::Tradition::Witness', "new witness created" );
 231 is( $wit_d->sigil, 'D', "witness has correct sigil" );
 232 is( scalar $s->witnesses, 4, "object now has four witnesses" );
 233
 234 my $del = $s->del_witness( 'D' );
 235 is( $del, $wit_d, "Deleted correct witness" );
 236 is( scalar $s->witnesses, 3, "object has three witnesses again" );
 237
 238 # TODO test initialization by witness list when we have it
 239
 240 =end testing
 241
 242 =cut
 243
 244
 245 sub BUILD {
 246     my( $self, $init_args ) = @_;
 247
 248     # First, make a collation object. This will use only those arguments in
 249     # init_args that apply to the collation.
 250         my $collation = Text::Tradition::Collation->new( %$init_args,
 251                                                                                                         'tradition' => $self );
 252         $self->_save_collation( $collation );
 253
 254     if( exists $init_args->{'input'} ) {
 255         # Call the appropriate parser on the given data
 256         my @format_standalone = qw/ Self CollateText CollateX CTE JSON TEI Tabular /;
 257         my @format_basetext = qw/ KUL /;
 258         my $use_base;
 259         my $format = $init_args->{'input'};
 260         if( $format && !( grep { $_ eq $format } @format_standalone )
 261             && !( grep { $_ eq $format } @format_basetext ) ) {
 262             warn "Unrecognized input format $format; not parsing";
 263             return;
 264         }
 265         if( $format && grep { $_ eq $format } @format_basetext ) {
 266             $use_base = 1;
 267             if( !exists $init_args->{'base'} ) {
 268                 warn "Cannot make a collation from $format without a base text";
 269                 return;
 270             }
 271         }
 272
 273         # Now do the parsing.
 274         if( $format ) {
 275             if( $use_base ) {
 276                 $format = 'BaseText';   # Use the BaseText module for parsing,
 277                                         # but retain the original input arg.
 278             }
 279             my $mod = "Text::Tradition::Parser::$format";
 280             load( $mod );
 281             $mod->can('parse')->( $self, $init_args );
 282         }
 283     }
 284     $self->_init_done( 1 );
 285     return $self;
 286 }
 287
 288 =head2 add_json_witnesses( $jsonstring, $options )
 289
 290 Adds a set of witnesses from a JSON array specification. This is a wrapper
 291 to parse the JSON and call add_witness (with the specified $options) for
 292 each element therein.
 293
 294 =cut
 295
 296 sub add_json_witnesses {
 297         my( $self, $jsonstr, $extraopts ) = @_;
 298         my $witarray = from_json( $jsonstr );
 299         foreach my $witspec ( @{$witarray->{witnesses}} ) {
 300                 my $opts = $extraopts || {};
 301                 $opts->{'sourcetype'} = 'json';
 302                 $opts->{'object'} = $witspec;
 303                 $self->add_witness( $opts );
 304         }
 305 }
 306
 307 sub throw {
 308         Text::Tradition::Error->throw(
 309                 'ident' => 'Tradition error',
 310                 'message' => $_[0],
 311                 );
 312 }
 313
 314 no Moose;
 315 __PACKAGE__->meta->make_immutable;
 316
 317
 318 =head1 BUGS / TODO
 319
 320 =over
 321
 322 =item * Allow tradition to be initialized via passing to a collator.
 323
 324 =back
 325
 326 =head1 LICENSE
 327
 328 This package is free software and is provided "as is" without express
 329 or implied warranty.  You can redistribute it and/or modify it under
 330 the same terms as Perl itself.
 331
 332 =head1 AUTHOR
 333
 334 Tara L Andrews E<lt>aurum@cpan.orgE<gt>