base/lib/Text/Tradition/Parser/TEI.pm

   1 package Text::Tradition::Parser::TEI;
   2
   3 use strict;
   4 use warnings;
   5 use Text::Tradition::Error;
   6 use Text::Tradition::Parser::Util qw( collate_variants );
   7 use XML::LibXML;
   8 use XML::LibXML::XPathContext;
   9
  10 =head1 NAME
  11
  12 Text::Tradition::Parser::TEI
  13
  14 =head1 SYNOPSIS
  15
  16   use Text::Tradition;
  17
  18   my $t_from_file = Text::Tradition->new(
  19     'name' => 'my text',
  20     'input' => 'TEI',
  21     'file' => '/path/to/parallel_seg_file.xml'
  22     );
  23
  24   my $t_from_string = Text::Tradition->new(
  25     'name' => 'my text',
  26     'input' => 'TEI',
  27     'string' => $parallel_seg_xml,
  28     );
  29
  30
  31 =head1 DESCRIPTION
  32
  33 Parser module for Text::Tradition, given a TEI parallel-segmentation file
  34 that describes a text and its variants.  Normally called upon
  35 initialization of Text::Tradition.
  36
  37 The witnesses for the tradition are taken from the <listWit/> element
  38 within the TEI header; the readings are taken from any <p/> element that
  39 appears in the text body (including <head/> elements therein.)
  40
  41 =head1 METHODS
  42
  43 =head2 B<parse>( $tradition, $option_hash )
  44
  45 Takes an initialized tradition and a set of options; creates the
  46 appropriate nodes and edges on the graph, as well as the appropriate
  47 witness objects.  The $option_hash must contain either a 'file' or a
  48 'string' argument with the XML to be parsed.
  49
  50 =begin testing
  51
  52 use Text::Tradition;
  53 binmode STDOUT, ":utf8";
  54 binmode STDERR, ":utf8";
  55 eval { no warnings; binmode $DB::OUT, ":utf8"; };
  56
  57 my $par_seg = 't/data/florilegium_tei_ps.xml';
  58 my $t = Text::Tradition->new(
  59     'name'  => 'inline',
  60     'input' => 'TEI',
  61     'file'  => $par_seg,
  62     );
  63
  64 is( ref( $t ), 'Text::Tradition', "Parsed parallel-segmentation TEI" );
  65 if( $t ) {
  66     is( scalar $t->collation->readings, 311, "Collation has all readings" );
  67     is( scalar $t->collation->paths, 361, "Collation has all paths" );
  68 }
  69
  70 # Try to re-parse it, ensure we can use the parser twice in the same Perl
  71 # invocation
  72
  73 my $t2 = Text::Tradition->new(
  74     'name'  => 'inline',
  75     'input' => 'TEI',
  76     'file'  => $par_seg,
  77     );
  78
  79 is( ref( $t2 ), 'Text::Tradition', "Parsed parallel-segmentation TEI again" );
  80
  81 =end testing
  82
  83 =cut
  84
  85 my $text = {}; # Hash of arrays, one per eventual witness we find.
  86 my $substitutions = {}; # Keep track of merged readings
  87 my $app_anchors = {};   # Track apparatus references
  88 my $app_ac = {};        # Save a.c. readings
  89 my $app_count;          # Keep track of how many apps we have
  90
  91 # Create the package variables for tag names.
  92
  93 # Would really like to do this with varname variables, but apparently this
  94 # is considered a bad idea.  The long way round then.
  95 my( $LISTWIT, $WITNESS, $TEXT, $W, $SEG, $APP, $RDG, $LEM );
  96 sub _make_tagnames {
  97     my( $ns ) = @_;
  98     ( $LISTWIT, $WITNESS, $TEXT, $W, $SEG, $APP, $RDG, $LEM )
  99         = ( 'listWit', 'witness', 'text', 'w', 'seg', 'app', 'rdg', 'lem' );
 100     if( $ns ) {
 101         $LISTWIT = "$ns:$LISTWIT";
 102         $WITNESS = "$ns:$WITNESS";
 103         $TEXT = "$ns:$TEXT";
 104         $W = "$ns:$W";
 105         $SEG = "$ns:$SEG";
 106         $APP = "$ns:$APP";
 107         $RDG = "$ns:$RDG";
 108         $LEM = "$ns:$LEM";
 109     }
 110 }
 111
 112 # Parse the TEI file.
 113 sub parse {
 114     my( $tradition, $opts ) = @_;
 115
 116     # First, parse the XML.
 117     my $parser = XML::LibXML->new();
 118     my $doc;
 119     if( exists $opts->{'string'} ) {
 120         $doc = $parser->parse_string( $opts->{'string'} );
 121     } elsif ( exists $opts->{'file'} ) {
 122         $doc = $parser->parse_file( $opts->{'file'} );
 123     } elsif ( exists $opts->{'xmlobj'} ) {
 124         $doc = $opts->{'xmlobj'};
 125     } else {
 126         warn "Could not find string or file option to parse";
 127         return;
 128     }
 129     my $tei = $doc->documentElement();
 130         unless( $tei->nodeName =~ /^tei(corpus)?$/i ) {
 131                 throw( "Parsed document has non-TEI root element " . $tei->nodeName );
 132         }
 133     my $xpc = XML::LibXML::XPathContext->new( $tei );
 134     my $ns;
 135     if( $tei->namespaceURI ) {
 136         $ns = 'tei';
 137         $xpc->registerNs( $ns, $tei->namespaceURI );
 138     }
 139     _make_tagnames( $ns );
 140
 141     # Then get the witnesses and create the witness objects.
 142     foreach my $wit_el ( $xpc->findnodes( "//$LISTWIT/$WITNESS" ) ) {
 143         my $sig = $wit_el->getAttribute( 'xml:id' );
 144         my $source = $wit_el->toString();
 145         $tradition->add_witness( sigil => $sig, sourcetype => 'collation' );
 146     }
 147     map { $text->{$_->sigil} = [] } $tradition->witnesses;
 148
 149     # Look for all word/seg node IDs and note their pre-existence.
 150     my @attrs = $xpc->findnodes( "//$W/attribute::xml:id" );
 151     _save_preexisting_nodeids( @attrs );
 152
 153     # Count up how many apps we have.
 154     my @apps = $xpc->findnodes( "//$APP" );
 155     $app_count = scalar( @apps );
 156
 157     # Now go through the children of the text element and pull out the
 158     # actual text.
 159     foreach my $xml_el ( $xpc->findnodes( "//$TEXT" ) ) {
 160         foreach my $xn ( $xml_el->childNodes ) {
 161             _get_readings( $tradition, $xn );
 162         }
 163     }
 164     # Our $text global now has lists of readings, one per witness.
 165     # Join them up.
 166     my $c = $tradition->collation;
 167     foreach my $sig ( keys %$text ) {
 168         # Determine the list of readings for
 169         my $sequence = $text->{$sig};
 170         my @real_sequence = ( $c->start );
 171         push( @$sequence, $c->end );
 172         foreach( _clean_sequence( $sig, $sequence, 1 ) ) {
 173             push( @real_sequence, _return_rdg( $_ ) );
 174         }
 175         # See if we need to make an a.c. version of the witness.
 176         if( exists $app_ac->{$sig} ) {
 177             my @uncorrected;
 178             push( @uncorrected, @real_sequence );
 179             # Get rid of any remaining placeholders.
 180             @real_sequence = _clean_sequence( $sig, \@uncorrected );
 181             # Do the uncorrections
 182             foreach my $app ( keys %{$app_ac->{$sig}} ) {
 183                 my $start = _return_rdg( $app_anchors->{$app}->{$sig}->{'start'} );
 184                 my $end = _return_rdg( $app_anchors->{$app}->{$sig}->{'end'} );
 185                 my @new = map { _return_rdg( $_ ) } @{$app_ac->{$sig}->{$app}};
 186                 _replace_sequence( \@uncorrected, $start, $end, @new );
 187             }
 188             # and record the results.
 189             $tradition->witness( $sig )->uncorrected_path( \@uncorrected );
 190             $tradition->witness( $sig )->is_layered( 1 );
 191         }
 192         $tradition->witness( $sig )->path( \@real_sequence );
 193     }
 194     # Now make our witness paths.
 195     $tradition->collation->make_witness_paths();
 196
 197     unless( $opts->{'nocalc'} ) {
 198                 # Calculate the ranks for the nodes.
 199                 $tradition->collation->calculate_ranks();
 200
 201                 # Now that we have ranks, see if we have distinct nodes with identical
 202                 # text and identical rank that can be merged.
 203                 $tradition->collation->flatten_ranks();
 204
 205                 # And now that we've done that, calculate the common nodes.
 206                 $tradition->collation->calculate_common_readings();
 207
 208                 # Save the text for each witness so that we can ensure consistency
 209                 # later on
 210                 $tradition->collation->text_from_paths();
 211         }
 212 }
 213
 214 sub _clean_sequence {
 215     my( $wit, $sequence, $keep_ac ) = @_;
 216     my @clean_sequence;
 217     foreach my $rdg ( @$sequence ) {
 218         if( $rdg =~ /^PH-(.*)$/ ) {
 219             # It is a placeholder.  Keep it only if we need it for a later
 220             # a.c. run.
 221             my $app_id = $1;
 222             if( $keep_ac && exists $app_ac->{$wit} &&
 223                 exists $app_ac->{$wit}->{$app_id} ) {
 224                                 # print STDERR "Retaining empty placeholder for $app_id\n";
 225                                 push( @clean_sequence, $rdg );
 226             }
 227         } else {
 228             push( @clean_sequence, $rdg );
 229         }
 230     }
 231     return @clean_sequence;
 232 }
 233
 234 sub _replace_sequence {
 235     my( $arr, $start, $end, @new ) = @_;
 236     my( $start_idx, $end_idx );
 237     foreach my $i ( 0 .. $#{$arr} ) {
 238         # If $arr->[$i] is a placeholder, cope.
 239         my $iid = ref( $arr->[$i] ) ? $arr->[$i]->id : $arr->[$i];
 240         $start_idx = $i if( $iid eq $start );
 241         if( $iid eq $end ) {
 242             $end_idx = $i;
 243             last;
 244         }
 245     }
 246     unless( $start_idx && $end_idx ) {
 247         warn "Could not find start and end";
 248         return;
 249     }
 250     my $length = $end_idx - $start_idx + 1;
 251     splice( @$arr, $start_idx, $length, @new );
 252 }
 253
 254 sub _return_rdg {
 255     my( $rdg ) = @_;
 256     # If we were passed a reading name, return the name.  If we were
 257     # passed a reading object, return the object.
 258     my $wantobj = ref( $rdg ) eq 'Text::Tradition::Collation::Reading';
 259     my $real = $rdg;
 260     if( exists $substitutions->{ $wantobj ? $rdg->id : $rdg } ) {
 261         $real = $substitutions->{ $wantobj ? $rdg->id : $rdg };
 262         $real = $real->id unless $wantobj;
 263     }
 264     return $real;
 265 }
 266
 267 ## TODO test specific sorts of nodes of the parallel-seg XML.
 268
 269 ## Recursive helper function to help us navigate through nested XML,
 270 ## picking out the text.  $tradition is the tradition, needed for
 271 ## making readings; $xn is the XML node currently being looked at,
 272 ## $in_var is a flag to say that we are inside a variant, $ac is a
 273 ## flag to say that we are inside an ante-correctionem reading, and
 274 ## @cur_wits is the list of witnesses to which this XML node applies.
 275 ## Returns the list of readings, if any, created on the run.
 276
 277 {
 278     my %active_wits;
 279     my $current_app;
 280     my $seen_apps;
 281
 282     sub _get_readings {
 283         my( $tradition, $xn, $in_var, $ac, @cur_wits ) = @_;
 284         @cur_wits = grep { $active_wits{$_} } keys %active_wits unless $in_var;
 285
 286         my @new_readings;
 287         if( $xn->nodeType == XML_TEXT_NODE ) {
 288             # Some words, thus make some readings.
 289             my $str = $xn->data;
 290             return unless $str =~ /\S/; # skip whitespace-only text nodes
 291             #print STDERR "Handling text node " . $str . "\n";
 292             # Check that all the witnesses we have are active.
 293             foreach my $c ( @cur_wits ) {
 294                 warn "$c is not among active wits" unless $active_wits{$c};
 295             }
 296             $str =~ s/^\s+//;
 297             my $final = $str =~ s/\s+$//;
 298             foreach my $w ( split( /\s+/, $str ) ) {
 299                 # For now, skip punctuation.
 300                 next if $w !~ /[[:alnum:]]/;
 301                 my $rdg = _make_reading( $tradition->collation, $w );
 302                 push( @new_readings, $rdg );
 303                 foreach ( @cur_wits ) {
 304                     warn "Empty wit!" unless $_;
 305                     warn "Empty reading!" unless $rdg;
 306                     push( @{$text->{$_}}, $rdg ) unless $ac;
 307                 }
 308             }
 309         } elsif( $xn->nodeName eq 'w' ) {
 310             # Everything in this tag is one word.  Also save any original XML ID.
 311             #print STDERR "Handling word " . $xn->toString . "\n";
 312             # Check that all the witnesses we have are active.
 313             foreach my $c ( @cur_wits ) {
 314                 warn "$c is not among active wits" unless $active_wits{$c};
 315             }
 316             my $xml_id = $xn->getAttribute( 'xml:id' );
 317             my $rdg = _make_reading( $tradition->collation, $xn->textContent, $xml_id );
 318             push( @new_readings, $rdg );
 319             foreach( @cur_wits ) {
 320                 warn "Empty wit!" unless $_;
 321                 warn "Empty reading!" unless $rdg;
 322                 push( @{$text->{$_}}, $rdg ) unless $ac;
 323             }
 324         } elsif ( $xn->nodeName eq 'app' ) {
 325             $seen_apps++;
 326             $current_app = $xn->getAttribute( 'xml:id' );
 327             # print STDERR "Handling app $current_app\n";
 328             # Keep the reading sets in this app.
 329             my @sets;
 330             # Recurse through all children (i.e. rdgs) for sets of words.
 331             foreach ( $xn->childNodes ) {
 332                 my @rdg_set = _get_readings( $tradition, $_, $in_var, $ac, @cur_wits );
 333                 push( @sets, \@rdg_set ) if @rdg_set;
 334             }
 335             # Now collate these sets if we have more than one.
 336             my $subs = collate_variants( $tradition->collation, @sets ) if @sets > 1;
 337             map { $substitutions->{$_} = $subs->{$_} } keys %$subs;
 338             # Return the entire set of unique readings.
 339             my %unique;
 340             foreach my $s ( @sets ) {
 341                 map { $unique{$_->id} = $_ } @$s;
 342             }
 343             push( @new_readings, values( %unique ) );
 344             # Exit the current app.
 345             $current_app = '';
 346         } elsif ( $xn->nodeName eq 'lem' || $xn->nodeName eq 'rdg' ) {
 347             # Alter the current witnesses and recurse.
 348             #print STDERR "Handling reading for " . $xn->getAttribute( 'wit' ) . "\n";
 349             # TODO handle p.c. and s.l. designations too
 350             $ac = $xn->getAttribute( 'type' ) && $xn->getAttribute( 'type' ) eq 'a.c.';
 351             my @rdg_wits = _get_sigla( $xn );
 352             return unless @rdg_wits;  # Skip readings that appear in no witnesses
 353             my @words;
 354             foreach ( $xn->childNodes ) {
 355                 my @rdg_set = _get_readings( $tradition, $_, 1, $ac, @rdg_wits );
 356                 push( @words, @rdg_set ) if @rdg_set;
 357             }
 358             # If we have more than one word in a reading, it should become a segment.
 359             # $tradition->collation->add_segment( @words ) if @words > 1;
 360
 361             if( $ac ) {
 362                 # Add the reading set to the a.c. readings.
 363                 foreach ( @rdg_wits ) {
 364                     $app_ac->{$_}->{$current_app} = \@words;
 365                 }
 366             } else {
 367                 # Add the reading set to the app anchors for each witness
 368                 # or put in placeholders for empty p.c. readings
 369                 foreach ( @rdg_wits ) {
 370                     my $start = @words ? $words[0]->id : "PH-$current_app";
 371                     my $end = @words ? $words[-1]->id : "PH-$current_app";
 372                     $app_anchors->{$current_app}->{$_}->{'start'} = $start;
 373                     $app_anchors->{$current_app}->{$_}->{'end'} = $end;
 374                     push( @{$text->{$_}}, $start ) unless @words;
 375                 }
 376             }
 377             push( @new_readings, @words );
 378         } elsif( $xn->nodeName eq 'witStart' ) {
 379             # Add the relevant wit(s) to the active list.
 380             #print STDERR "Handling witStart\n";
 381             map { $active_wits{$_} = 1 } @cur_wits;
 382             # Record a lacuna in all non-active witnesses if this is
 383             # the first app. Get the full list from $text.
 384             if( $seen_apps == 1 ) {
 385                 my $i = 0;
 386                 foreach my $sig ( keys %$text ) {
 387                     next if $active_wits{$sig};
 388                     my $l = $tradition->collation->add_reading( {
 389                         'id' => $current_app . "_$i",
 390                         'is_lacuna' => 1 } );
 391                     $i++;
 392                     push( @{$text->{$sig}}, $l );
 393                 }
 394             }
 395         } elsif( $xn->nodeName eq 'witEnd' ) {
 396             # Take the relevant wit(s) out of the list.
 397             #print STDERR "Handling witEnd\n";
 398             map { $active_wits{$_} = undef } @cur_wits;
 399             # Record a lacuna, unless this is the last app.
 400             unless( $seen_apps == $app_count ) {
 401                 foreach my $i ( 0 .. $#cur_wits ) {
 402                     my $w = $cur_wits[$i];
 403                     my $l = $tradition->collation->add_reading( {
 404                         'id' => $current_app . "_$i",
 405                         'is_lacuna' => 1 } );
 406                     push( @{$text->{$w}}, $l );
 407                 }
 408             }
 409         } elsif( $xn->nodeName eq 'witDetail'
 410                          || $xn->nodeName eq 'note' ) {
 411             # Ignore these for now.
 412             return;
 413         } else {
 414             # Recurse as if this tag weren't there.
 415             #print STDERR "Recursing on tag " . $xn->nodeName . "\n";
 416             foreach( $xn->childNodes ) {
 417                 push( @new_readings, _get_readings( $tradition, $_, $in_var, $ac, @cur_wits ) );
 418             }
 419         }
 420         return @new_readings;
 421     }
 422
 423 }
 424
 425 =begin testing
 426
 427 use XML::LibXML;
 428 use XML::LibXML::XPathContext;
 429 use Text::Tradition::Parser::TEI;
 430
 431 my $xml_str = '<tei><rdg wit="#A #B #C #D">some text</rdg></tei>';
 432 my $el = XML::LibXML->new()->parse_string( $xml_str )->documentElement;
 433 my $xpc = XML::LibXML::XPathContext->new( $el );
 434 my $obj = $xpc->find( '//rdg' );
 435
 436 my @wits = Text::Tradition::Parser::TEI::_get_sigla( $obj );
 437 is( join( ' ', @wits) , "A B C D", "correctly parsed reading wit string" );
 438
 439 =end testing
 440
 441 =cut
 442
 443 # Helper to extract a list of witness sigla from a reading element.
 444 sub _get_sigla {
 445     my( $rdg ) = @_;
 446     # Cope if we have been handed a NodeList.  There is only
 447     # one reading here.
 448     if( ref( $rdg ) eq 'XML::LibXML::NodeList' ) {
 449         $rdg = $rdg->shift;
 450     }
 451
 452     my @wits;
 453     if( ref( $rdg ) eq 'XML::LibXML::Element' ) {
 454         my $witstr = $rdg->getAttribute( 'wit' );
 455         return () unless $witstr;
 456         $witstr =~ s/^\s+//;
 457         $witstr =~ s/\s+$//;
 458         @wits = split( /\s+/, $witstr );
 459         map { $_ =~ s/^\#// } @wits;
 460     }
 461     return @wits;
 462 }
 463
 464 # Helper with its counters to actually make the readings.
 465 {
 466     my $word_ctr = 0;
 467     my %used_nodeids;
 468
 469     sub _save_preexisting_nodeids {
 470         foreach( @_ ) {
 471             $used_nodeids{$_->getValue()} = 1;
 472         }
 473     }
 474
 475     sub _make_reading {
 476         my( $graph, $word, $xml_id ) = @_;
 477         if( $xml_id ) {
 478             if( exists $used_nodeids{$xml_id} ) {
 479                 if( $used_nodeids{$xml_id} != 1 ) {
 480                     warn "Already used assigned XML ID somewhere else!";
 481                     $xml_id = undef;
 482                 }
 483             } else {
 484                 warn "Undetected pre-existing XML ID";
 485             }
 486         }
 487         if( !$xml_id ) {
 488             until( $xml_id ) {
 489                 my $try_id = 'w'.$word_ctr++;
 490                 next if exists $used_nodeids{$try_id};
 491                 $xml_id = $try_id;
 492             }
 493         }
 494         my $rdg = $graph->add_reading(
 495                 { 'id' => $xml_id,
 496                   'text' => $word }
 497                 );
 498         $used_nodeids{$xml_id} = $rdg;
 499         return $rdg;
 500     }
 501 }
 502
 503 1;
 504
 505 sub throw {
 506         Text::Tradition::Error->throw(
 507                 'ident' => 'Parser::TEI error',
 508                 'message' => $_[0],
 509                 );
 510 }
 511
 512 =head1 BUGS / TODO
 513
 514 =over
 515
 516 =item * More unit testing
 517
 518 =item * Handle special designations apart from a.c.
 519
 520 =item * Mark common nodes within collated variants
 521
 522 =back
 523
 524 =head1 LICENSE
 525
 526 This package is free software and is provided "as is" without express
 527 or implied warranty.  You can redistribute it and/or modify it under
 528 the same terms as Perl itself.
 529
 530 =head1 AUTHOR
 531
 532 Tara L Andrews E<lt>aurum@cpan.orgE<gt>