base/lib/Text/Tradition/Parser/CTE.pm

   1 package Text::Tradition::Parser::CTE;
   2
   3 use strict;
   4 use warnings;
   5 use feature 'say';
   6 use Encode qw/ decode /;
   7 use Text::Tradition::Error;
   8 use Text::Tradition::Parser::Util qw/ collate_variants /;
   9 use XML::LibXML;
  10 use XML::LibXML::XPathContext;
  11 use TryCatch;
  12
  13 =head1 NAME
  14
  15 Text::Tradition::Parser::CTE
  16
  17 =head1 DESCRIPTION
  18
  19 Parser module for Text::Tradition, given a TEI file exported from
  20 Classical Text Editor.
  21
  22 =head1 METHODS
  23
  24 =head2 parse
  25
  26 my @apparatus = read( $xml_file );
  27
  28 Takes a Tradition object and a TEI file exported from Classical Text
  29 Editor using double-endpoint-attachment critical apparatus encoding;
  30 initializes the Tradition from the file.
  31
  32 =cut
  33
  34 my %sigil_for;  # Save the XML IDs for witnesses.
  35 my %apps;       # Save the apparatus XML for a given ID.
  36 my %has_ac;     # Keep track of witnesses that have corrections.
  37
  38 sub parse {
  39         my( $tradition, $opts ) = @_;
  40         my $c = $tradition->collation;  # Some shorthand
  41
  42         ## DEBUG/TEST
  43         $opts->{interpret_transposition} = 1;
  44
  45         # First, parse the XML.
  46     my( $tei, $xpc ) = _remove_formatting( $opts );
  47     return unless $tei; # we have already warned.
  48
  49         # CTE uses a DTD rather than any xmlns-based parsing.  Thus we
  50         # need no namespace handling.
  51         # Get the witnesses and create the witness objects.
  52         foreach my $wit_el ( $xpc->findnodes( '//sourceDesc/listWit/witness' ) ) {
  53                 # The witness xml:id is used internally, and is *not* the sigil name.
  54                 my $id= $wit_el->getAttribute( 'xml:id' );
  55                 # If the witness element has an abbr element, that is the sigil. Otherwise
  56                 # the whole thing is the sigil.
  57                 my $sig = $xpc->findvalue( 'abbr', $wit_el );
  58                 my $identifier = 'CTE witness';
  59                 if( $sig ) {
  60                         # The sigil is what is in the <abbr/> tag; the identifier is anything
  61                         # that follows.
  62                         $identifier = _tidy_identifier(
  63                                 $xpc->findvalue( 'child::text()', $wit_el ) );
  64                 } else {
  65                         my @sig_parts = $xpc->findnodes( 'descendant::text()', $wit_el );
  66                         $sig = _stringify_sigil( @sig_parts );
  67                 }
  68                 say STDERR "Adding witness $sig ($identifier)";
  69                 $tradition->add_witness( sigil => $sig, identifier => $identifier,
  70                         sourcetype => 'collation' );
  71                 $sigil_for{'#'.$id} = $sig;  # Make life easy by keying on the ID ref syntax
  72         }
  73
  74         # Now go through the text and find the base tokens, apparatus tags, and
  75         # anchors.  Make a giant array of all of these things in sequence.
  76         # TODO consider combining this with creation of graph below
  77         my @base_text;
  78         foreach my $pg_el ( $xpc->findnodes( '/TEI/text/body/p' ) ) {
  79                 foreach my $xn ( $pg_el->childNodes ) {
  80                         push( @base_text, _get_base( $xn ) );
  81                 }
  82         }
  83         # We now have to work through this array applying the alternate
  84         # apparatus readings to the base text.  Essentially we will put
  85         # everything on the graph, from which we will delete the apps and
  86         # anchors when we are done.
  87
  88         # First, put the base tokens, apps, and anchors in the graph. Save the
  89         # app siglorum separately as it has to be processed in order.
  90         my @app_sig;
  91         my @app_crit;
  92         my $counter = 0;
  93         my $last = $c->start;
  94         foreach my $item ( @base_text ) {
  95             my $r;
  96         if( $item->{'type'} eq 'token' ) {
  97             $r = $c->add_reading( { id => 'n'.$counter++,
  98                                                         text => $item->{'content'} } );
  99         } elsif ( $item->{'type'} eq 'anchor' ) {
 100             $r = $c->add_reading( { id => '__ANCHOR_' . $item->{'content'} . '__',
 101                                                         is_ph => 1 } );
 102         } elsif ( $item->{'type'} eq 'app' ) {
 103             my $tag = '__APP_' . $counter++ . '__';
 104             $r = $c->add_reading( { id => $tag, is_ph => 1 } );
 105             my $app = $item->{'content'};
 106             $apps{$tag} = $app;
 107             # Apparatus should be differentiable by type attribute; apparently
 108             # it is not. Peek at the content to categorize it.
 109             # Apparatus criticus is type a1; app siglorum is type a2
 110             my @sigtags = $xpc->findnodes( 'descendant::*[name(witStart) or name(witEnd)]', $app );
 111             if( @sigtags ) {
 112                         push( @app_sig, $tag );
 113                 } else {
 114                     push( @app_crit, $tag );
 115                 }
 116         }
 117         $c->add_path( $last, $r, $c->baselabel );
 118         $last = $r;
 119     }
 120     $c->add_path( $last, $c->end, $c->baselabel );
 121
 122     # Now we can parse the apparatus entries, and add the variant readings
 123     # to the graph.
 124     foreach my $app_id ( @app_crit ) {
 125         _add_readings( $c, $app_id, $opts );
 126     }
 127     _add_lacunae( $c, @app_sig );
 128
 129     # Finally, add explicit witness paths, remove the base paths, and remove
 130     # the app/anchor tags.
 131     try {
 132             _expand_all_paths( $c );
 133         } catch( Text::Tradition::Error $e ) {
 134                 throw( $e->message );
 135         } catch {
 136                 throw( $@ );
 137         }
 138
 139     # Save the text for each witness so that we can ensure consistency
 140     # later on
 141     unless( $opts->{'nocalc'} ) {
 142         try {
 143                         $tradition->collation->text_from_paths();
 144                         $tradition->collation->calculate_ranks();
 145                         $tradition->collation->flatten_ranks();
 146                 } catch( Text::Tradition::Error $e ) {
 147                         throw( $e->message );
 148                 } catch {
 149                         throw( $@ );
 150                 }
 151         }
 152 }
 153
 154 sub _stringify_sigil {
 155     my( @nodes ) = @_;
 156     my @parts = grep { /\w/ } map { $_->data } @nodes;
 157     my $whole = join( '', @parts );
 158     $whole =~ s/\W//g;
 159     return $whole;
 160 }
 161
 162 sub _tidy_identifier {
 163         my( $str ) = @_;
 164         $str =~ s/^\W+//;
 165         return $str;
 166 }
 167
 168 # Get rid of all the formatting elements that get in the way of tokenization.
 169 sub _remove_formatting {
 170         my( $opts ) = @_;
 171
 172         # First, parse the original XML
 173         my $parser = XML::LibXML->new();
 174     my $doc;
 175     if( exists $opts->{'string'} ) {
 176         $doc = $parser->parse_string( $opts->{'string'} );
 177     } elsif ( exists $opts->{'file'} ) {
 178         $doc = $parser->parse_file( $opts->{'file'} );
 179     } elsif ( exists $opts->{'xmlobj'} ) {
 180         $doc = $opts->{'xmlobj'};
 181     } else {
 182         warn "Could not find string or file option to parse";
 183         return;
 184     }
 185
 186     # Second, remove the formatting
 187         my $xpc = XML::LibXML::XPathContext->new( $doc->documentElement );
 188         my @useless = $xpc->findnodes( '//hi' );
 189         foreach my $n ( @useless ) {
 190                 my $parent = $n->parentNode();
 191                 my @children = $n->childNodes();
 192                 my $first = shift @children;
 193                 if( $first ) {
 194                         $parent->replaceChild( $first, $n );
 195                         foreach my $c ( @children ) {
 196                                 $parent->insertAfter( $c, $first );
 197                                 $first = $c;
 198                         }
 199                 } else {
 200                         $parent->removeChild( $n );
 201                 }
 202         }
 203
 204         # Third, write out and reparse to merge the text nodes.
 205         my $enc = $doc->encoding || 'UTF-8';
 206         my $result = decode( $enc, $doc->toString() );
 207         my $tei = $parser->parse_string( $result )->documentElement;
 208         unless( $tei->nodeName =~ /^tei(corpus)?$/i ) {
 209                 throw( "Parsed document has non-TEI root element " . $tei->nodeName );
 210         }
 211         $xpc = XML::LibXML::XPathContext->new( $tei );
 212         return( $tei, $xpc );
 213 }
 214
 215 ## Helper function to help us navigate through nested XML, picking out
 216 ## the words, the apparatus, and the anchors.
 217
 218 sub _get_base {
 219         my( $xn ) = @_;
 220         my @readings;
 221         if( $xn->nodeType == XML_TEXT_NODE ) {
 222             # Base text, just split the words on whitespace and add them
 223             # to our sequence.
 224                 my $str = $xn->data;
 225                 $str =~ s/^\s+//;
 226                 my @tokens = split( /\s+/, $str );
 227                 push( @readings, map { { type => 'token', content => $_ } } @tokens );
 228         } elsif( $xn->nodeName eq 'app' ) {
 229                 # Apparatus, just save the entire XML node.
 230                 push( @readings, { type => 'app', content => $xn } );
 231         } elsif( $xn->nodeName eq 'anchor' ) {
 232                 # Anchor to mark the end of some apparatus; save its ID.
 233                 if( $xn->hasAttribute('xml:id') ) {
 234                         push( @readings, { type => 'anchor',
 235                             content => $xn->getAttribute( 'xml:id' ) } );
 236                 } # if the anchor has no XML ID, it is not relevant to us.
 237         } elsif( $xn->nodeName !~ /^(note|seg|milestone|emph)$/ ) {  # Any tag we don't know to disregard
 238             say STDERR "Unrecognized tag " . $xn->nodeName;
 239         }
 240         return @readings;
 241 }
 242
 243 sub _append_tokens {
 244         my( $list, @tokens ) = @_;
 245         if( @$list && $list->[-1]->{'content'} =~ /\#JOIN\#$/ ) {
 246                 # The list evidently ended mid-word; join the next token onto it.
 247                 my $t = shift @tokens;
 248                 if( ref $t && $t->{'type'} eq 'token' ) {
 249                         # Join the word
 250                         $t = $t->{'content'};
 251                 } elsif( ref $t ) {
 252                         # An app or anchor intervened; end the word.
 253                         unshift( @tokens, $t );
 254                         $t = '';
 255                 }
 256                 $list->[-1]->{'content'} =~ s/\#JOIN\#$/$t/;
 257         }
 258         foreach my $t ( @tokens ) {
 259                 unless( ref( $t ) ) {
 260                         $t = { 'type' => 'token', 'content' => $t };
 261                 }
 262                 push( @$list, $t );
 263         }
 264 }
 265
 266 sub _add_readings {
 267     my( $c, $app_id, $opts ) = @_;
 268     my $xn = $apps{$app_id};
 269     my $anchor = _anchor_name( $xn->getAttribute( 'to' ) );
 270
 271     # Get the lemma, which is all the readings between app and anchor,
 272     # excluding other apps or anchors.
 273         my @lemma = _return_lemma( $c, $app_id, $anchor );
 274         my $lemma_str = join( ' ',  map { $_->text } grep { !$_->is_ph } @lemma );
 275
 276     # For each reading, send its text to 'interpret' along with the lemma,
 277     # and then save the list of witnesses that these tokens belong to.
 278     my %wit_rdgs;  # Maps from witnesses to the variant text
 279     my $ctr = 0;
 280     my $tag = $app_id;
 281     $tag =~ s/^\__APP_(.*)\__$/$1/;
 282
 283     foreach my $rdg ( $xn->getChildrenByTagName( 'rdg' ) ) {
 284         my @witlist = split( /\s+/, $rdg->getAttribute( 'wit' ) );
 285         my @text;
 286         foreach ( $rdg->childNodes ) {
 287             push( @text, _get_base( $_ ) );
 288         }
 289         my( $interpreted, $flag ) = ( '', undef );
 290         if( @text ) {
 291                 ( $interpreted, $flag ) = interpret(
 292                         join( ' ', map { $_->{'content'} } @text ), $lemma_str, $anchor, $opts );
 293         }
 294         next if( $interpreted eq $lemma_str ) && !keys %$flag;  # Reading is lemma.
 295
 296         my @rdg_nodes;
 297         if( $interpreted eq '#LACUNA#' ) {
 298                 push( @rdg_nodes, $c->add_reading( { id => 'r'.$tag.".".$ctr++,
 299                                                                                          is_lacuna => 1 } ) );
 300         } elsif( $flag->{'TR'} ) {
 301                 # Our reading is transposed to after the given string. Look
 302                 # down the collation base text and try to find it.
 303                 # The @rdg_nodes should remain blank here, so that the correct
 304                 # omission goes into the graph.
 305                 my @transp_nodes;
 306                 foreach my $w ( split(  /\s+/, $interpreted ) ) {
 307                         my $r = $c->add_reading( { id => 'r'.$tag.".".$ctr++,
 308                                                                                    text => $w } );
 309                                 push( @transp_nodes, $r );
 310                         }
 311                         if( $anchor && @lemma ) {
 312                                 my $success = _attach_transposition( $c, \@lemma, $anchor,
 313                                         \@transp_nodes, \@witlist, $flag->{'TR'} );
 314                                 unless( $success ) {
 315                                         # If we didn't manage to insert the displaced reading,
 316                                         # then restore it here rather than silently deleting it.
 317                                         push( @rdg_nodes, @transp_nodes );
 318                                 }
 319                         }
 320         } else {
 321                         foreach my $w ( split( /\s+/, $interpreted ) ) {
 322                                 my $r = $c->add_reading( { id => 'r'.$tag.".".$ctr++,
 323                                                                                    text => $w } );
 324                                 push( @rdg_nodes, $r );
 325                         }
 326         }
 327
 328         # For each listed wit, save the reading.
 329         # If an A.C. or P.C. reading is implied rather than explicitly noted,
 330         # this is where it will be dealt with.
 331         foreach my $wit ( @witlist ) {
 332                         $wit .= '_ac' if $flag->{'AC'};
 333             $wit_rdgs{$wit} = \@rdg_nodes;
 334             # If the PC flag is set, there is a corresponding AC that
 335             # follows the lemma and has to be explicitly declared.
 336             if( $flag->{'PC'} ) {
 337                 $wit_rdgs{$wit.'_ac'} = \@lemma;
 338             }
 339         }
 340
 341         # Does the reading have an ID? If so it probably has a witDetail
 342         # attached, and we need to read it. If an A.C. or P.C. reading is
 343         # declared explicity, this is where it will be dealt with.
 344         if( $rdg->hasAttribute( 'xml:id' ) ) {
 345                 warn "Witdetail on meta reading" if $flag; # this could get complicated.
 346             my $rid = $rdg->getAttribute( 'xml:id' );
 347             my $xpc = XML::LibXML::XPathContext->new( $xn );
 348             my @details = $xpc->findnodes( './witDetail[@target="'.$rid.'"]' );
 349             foreach my $d ( @details ) {
 350                 _parse_wit_detail( $d, \%wit_rdgs, \@lemma );
 351             }
 352         }
 353     }
 354
 355     # Now collate the variant readings, since it is not done for us.
 356     collate_variants( $c, \@lemma, values %wit_rdgs );
 357
 358     # Now add the witness paths for each reading. If we don't have an anchor
 359     # (e.g. with an initial witStart) there was no witness path to speak of.
 360         foreach my $wit_id ( keys %wit_rdgs ) {
 361                 my $witstr = _get_sigil( $wit_id, $c->ac_label );
 362                 my $rdg_list = $wit_rdgs{$wit_id};
 363                 _add_wit_path( $c, $rdg_list, $app_id, $anchor, $witstr );
 364         }
 365 }
 366
 367 sub _anchor_name {
 368     my $xmlid = shift;
 369     $xmlid =~ s/^\#//;
 370     return sprintf( "__ANCHOR_%s__", $xmlid );
 371 }
 372
 373 sub _return_lemma {
 374     my( $c, $app, $anchor ) = @_;
 375     my @nodes = grep { $_->id !~ /^__A(PP|NCHOR)/ }
 376         $c->reading_sequence( $c->reading( $app ), $c->reading( $anchor ),
 377                 $c->baselabel );
 378     return @nodes;
 379 }
 380
 381 # Make a best-effort attempt to attach a transposition farther down the line.
 382 # $lemmaseq contains the Reading objects of the lemma
 383 # $anchor contains the point at which we should start scanning for a match
 384 # $rdgseq contains the Reading objects of the transposed reading
 385 #       (should be identical to the lemma)
 386 # $witlist contains the list of applicable witnesses
 387 # $reftxt contains the text to match, after which the $rdgseq should go.
 388 sub _attach_transposition {
 389         my( $c, $lemmaseq, $anchor, $rdgseq, $witlist, $reftxt ) = @_;
 390         my @refwords = split( /\s+/, $reftxt );
 391         my $checked = $c->reading( $anchor );
 392         my $found;
 393         my $success;
 394         while( $checked ne $c->end && !$found ) {
 395                 my $next = $c->next_reading( $checked, $c->baselabel );
 396                 if( $next->text eq $refwords[0] ) {
 397                         # See if the entire sequence of words matches.
 398                         $found = $next;
 399                         foreach my $w ( 1..$#refwords ) {
 400                                 $found = $c->next_reading( $next, $c->baselabel );
 401                                 unless( $found->text eq $refwords[$w] ) {
 402                                         $found = undef;
 403                                         last;
 404                                 }
 405                         }
 406                 }
 407                 $checked = $next;
 408         }
 409         if( $found ) {
 410                 # The $found variable should now contain the reading after which we
 411                 # should stick the transposition.
 412                 my $fnext = $c->next_reading( $found, $c->baselabel );
 413                 my $aclabel = $c->ac_label;
 414                 foreach my $wit_id ( @$witlist ) {
 415                         my $witstr = _get_sigil( $wit_id, $aclabel );
 416                         _add_wit_path( $c, $rdgseq, $found->id, $fnext->id, $witstr );
 417                 }
 418                 # ...and add the transposition relationship between lemma and rdgseq.
 419                 if( @$lemmaseq == @$rdgseq ) {
 420                         foreach my $i ( 0..$#{$lemmaseq} ) {
 421                                 $c->add_relationship( $lemmaseq->[$i], $rdgseq->[$i],
 422                                         { type => 'transposition', annotation => 'Detected by CTE' } );
 423                         }
 424                 $success = 1;
 425                 } else {
 426                         throw( "Lemma at $found and transposed sequence different lengths?!" );
 427                 }
 428         } else {
 429                 say STDERR "WARNING: Unable to find $reftxt in base text for transposition";
 430         }
 431         return $success;
 432 }
 433
 434 =head2 interpret( $reading, $lemma )
 435
 436 Given a string in $reading and a corresponding lemma in $lemma, interpret what
 437 the actual reading should be. Used to deal with apparatus-ese shorthands for
 438 marking transpositions, prefixed or suffixed words, and the like.
 439
 440 =cut
 441
 442 sub interpret {
 443         # A utility function to change apparatus-ese into a full variant.
 444         my( $reading, $lemma, $anchor, $opts ) = @_;
 445         return $reading if $reading eq $lemma;
 446         my $oldreading = $reading;
 447         # $lemma =~ s/\s+[[:punct:]]+$//;
 448         my $flag = {};  # To pass back extra info about the interpretation
 449         my @words = split( /\s+/, $lemma );
 450         # Discard any 'sic' notation - that rather goes without saying.
 451         $reading =~ s/([[:punct:]]+)?sic([[:punct:]]+)?//g;
 452
 453         # Now look for common jargon.
 454         if( $reading =~ /^(.*) praem.$/ || $reading =~ /^praem\. (.*)$/ ) {
 455                 $reading = "$1 $lemma";
 456         } elsif( $reading =~ /^(.*) add.$/ || $reading =~ /^add\. (.*)$/ ) {
 457                 $reading = "$lemma $1";
 458         } elsif( $reading =~ /locus [uv]acuus/
 459             || $reading eq 'def.'
 460             || $reading eq 'illeg.'
 461             || $reading eq 'desunt'
 462             ) {
 463                 $reading = '#LACUNA#';
 464         } elsif( $reading eq 'om.' ) {
 465                 $reading = '';
 466         } elsif( $reading =~ /^in[uv]\.$/
 467                          || $reading =~ /^tr(ans(p)?)?\.$/ ) {
 468                 # Hope it is two words.
 469                 say STDERR "WARNING: want to invert a lemma that is not two words"
 470                         unless scalar( @words ) == 2;
 471                 $reading = join( ' ', reverse( @words ) );
 472         } elsif( $reading =~ /^iter(\.|at)$/ ) {
 473                 # Repeat the lemma
 474                 $reading = "$lemma $lemma";
 475         } elsif( $reading =~ /^(.*?)\s*\(?in marg\.\)?$/ ) {
 476                 $reading = $1;
 477                 if( $reading ) {
 478                         # The given text is a correction.
 479                         $flag->{'PC'} = 1;
 480                 } else {
 481                         # The lemma itself was the correction; the witness carried
 482                         # no reading pre-correction.
 483                         $flag->{'AC'} = 1;
 484                 }
 485         } elsif( $reading =~ /^(.*) \.\.\. (.*)$/ ) {
 486                 # The first and last N words captured should replace the first and
 487                 # last N words of the lemma.
 488                 my @begin = split( /\s+/, $1 );
 489                 my @end = split( /\s+/, $2 );
 490                 if( scalar( @begin ) + scalar ( @end ) > scalar( @words ) ) {
 491                         # Something is wrong and we can't do the splice.
 492                         throw( "$lemma is too short to accommodate $oldreading" );
 493                 } else {
 494                         splice( @words, 0, scalar @begin, @begin );
 495                         splice( @words, -(scalar @end), scalar @end, @end );
 496                         $reading = join( ' ', @words );
 497                 }
 498         } elsif( $opts->{interpret_transposition} &&
 499                          ( $reading =~ /^post\s*(?<lem>.*?)\s+tr(ans(p)?)?\.$/ ||
 500                            $reading =~ /^tr(ans(p)?)?\. post\s*(?<lem>.*)$/) ) {
 501                 # Try to deal with transposed readings
 502                 ## DEBUG
 503                 say STDERR "Will attempt transposition: $reading at $anchor";
 504                 $reading = $lemma;
 505                 $flag->{'TR'} = $+{lem};
 506         }
 507         return( $reading, $flag );
 508 }
 509
 510 sub _parse_wit_detail {
 511     my( $detail, $readings, $lemma ) = @_;
 512     my $wit = $detail->getAttribute( 'wit' );
 513     my $content = $detail->textContent;
 514     if( $content =~ /^a\.?\s*c(orr)?\.$/ ) {
 515         # Replace the key in the $readings hash
 516         my $rdg = delete $readings->{$wit};
 517         $readings->{$wit.'_ac'} = $rdg;
 518         $has_ac{$sigil_for{$wit}} = 1;
 519     } elsif( $content =~ /^p\.?\s*c(orr)?\.$/ || $content =~ /^s\.?\s*l\.$/ ) {
 520         # If no key for the wit a.c. exists, add one pointing to the lemma
 521         unless( exists $readings->{$wit.'_ac'} ) {
 522             $readings->{$wit.'_ac'} = $lemma;
 523         }
 524         $has_ac{$sigil_for{$wit}} = 1;
 525     } else {  #...not sure what it is?
 526         say STDERR "WARNING: Unrecognized sigil annotation $content";
 527     }
 528 }
 529
 530 sub _add_lacunae {
 531         my( $c, @app_id ) = @_;
 532         # Go through the apparatus entries in order, noting where to start and stop our
 533         # various witnesses.
 534         my %lacunose;
 535         my $ctr = 0;
 536         foreach my $tag ( @app_id ) {
 537                 my $app = $apps{$tag};
 538                 # Find the anchor, if any. This marks the point where the text starts
 539                 # or ends.
 540                 my $anchor = $app->getAttribute( 'to' );
 541                 my $aname;
 542                 if( $anchor ) {
 543                         $anchor =~ s/^\#//;
 544                         $aname = _anchor_name( $anchor );
 545                 }
 546
 547                 foreach my $rdg ( $app->getChildrenByTagName( 'rdg' ) ) {
 548                 my @witlist = map { _get_sigil( $_, $c->ac_label ) }
 549                         split( /\s+/, $rdg->getAttribute( 'wit' ) );
 550                         my @start = $rdg->getChildrenByTagName( 'witStart' );
 551                         my @end = $rdg->getChildrenByTagName( 'witEnd' );
 552                         if( @start && @end ) {
 553                                 throw( "App sig entry at $anchor has both witStart and witEnd!" );
 554                         }
 555                         if( @start && $anchor &&
 556                                 $c->prior_reading( $aname, $c->baselabel ) ne $c->start ) {
 557                                 # We are picking back up after a hiatus. Find the last end and
 558                                 # add a lacuna link between there and here.
 559                                 foreach my $wit ( @witlist ) {
 560                                         my $stoppoint = delete $lacunose{$wit};
 561                                         my $stopname = $stoppoint ? _anchor_name( $stoppoint ) : $c->start->id;
 562                                         say STDERR "Adding lacuna for $wit between $stopname and $anchor";
 563                                         my $lacuna = $c->add_reading( { id => "as_$anchor.".$ctr++,
 564                                         is_lacuna => 1 } );
 565                                 _add_wit_path( $c, [ $lacuna ], $stopname, $aname, $wit );
 566                                 }
 567                         } elsif( @end && $anchor &&
 568                                 $c->next_reading( $aname, $c->baselabel ) ne $c->end ) {
 569                                 # We are stopping. If we've already stopped for the given witness,
 570                                 # flag an error; otherwise record the stopping point.
 571                                 foreach my $wit ( @witlist ) {
 572                                         if( $lacunose{$wit} ) {
 573                                                 throw( "Trying to end $wit at $anchor when already ended at "
 574                                                         . $lacunose{$wit} );
 575                                         }
 576                                         $lacunose{$wit} = $anchor;
 577                                 }
 578                         }
 579                 }
 580         }
 581
 582         # For whatever remains in the %lacunose hash, add a lacuna between that spot and
 583         # $c->end for each of the witnesses.
 584         foreach my $wit ( keys %lacunose ) {
 585                 next unless $lacunose{$wit};
 586                 my $aname = _anchor_name( $lacunose{$wit} );
 587                 say STDERR "Adding lacuna for $wit from $aname to end";
 588                 my $lacuna = $c->add_reading( { id => 'as_'.$lacunose{$wit}.'.'.$ctr++,
 589                         is_lacuna => 1 } );
 590                 _add_wit_path( $c, [ $lacuna ], $aname, $c->end, $wit );
 591         }
 592 }
 593
 594 sub _get_sigil {
 595     my( $xml_id, $layerlabel ) = @_;
 596     if( $xml_id =~ /^(.*)_ac$/ ) {
 597         my $real_id = $1;
 598         return $sigil_for{$real_id} . $layerlabel;
 599     } else {
 600         return $sigil_for{$xml_id};
 601     }
 602 }
 603
 604 sub _expand_all_paths {
 605     my( $c ) = @_;
 606
 607     # Walk the collation and fish out the paths for each witness
 608     foreach my $wit ( $c->tradition->witnesses ) {
 609         my $sig = $wit->sigil;
 610         my @path = grep { !$_->is_ph }
 611             $c->reading_sequence( $c->start, $c->end, $sig );
 612         $wit->path( \@path );
 613         if( $has_ac{$sig} ) {
 614             my @ac_path = grep { !$_->is_ph }
 615                 $c->reading_sequence( $c->start, $c->end, $sig.$c->ac_label );
 616             $wit->uncorrected_path( \@ac_path );
 617         }
 618     }
 619
 620     # Delete the anchors
 621     foreach my $anchor ( grep { $_->is_ph } $c->readings ) {
 622         $c->del_reading( $anchor );
 623     }
 624     # Delete the base edges
 625     map { $c->del_path( $_, $c->baselabel ) } $c->paths;
 626
 627     # Make the path edges
 628     $c->make_witness_paths();
 629
 630     # Now remove any orphan nodes, and warn that we are doing so.
 631     my %suspect_apps;
 632     while( $c->sequence->predecessorless_vertices > 1 ) {
 633         foreach my $v ( $c->sequence->predecessorless_vertices ) {
 634                 my $r = $c->reading( $v );
 635                 next if $r->is_start;
 636                 my $tag = $r->id;
 637                 $tag =~ s/^r(\d+)\.\d+/$1/;
 638                 say STDERR "Deleting orphan reading $r / " . $r->text;
 639                 push( @{$suspect_apps{$tag}}, $r->id ) if $tag =~ /^\d+$/;
 640                 $c->del_reading( $r );
 641         }
 642     }
 643     if( $c->sequence->successorless_vertices > 1 ) {
 644         my @bad = grep { $_ ne $c->end->id } $c->sequence->successorless_vertices;
 645         foreach( @bad ) {
 646                 my $tag = $_;
 647                 next unless $tag =~ /^r/;
 648                 $tag =~ s/^r(\d+)\.\d+/$1/;
 649                 push( @{$suspect_apps{$tag}}, $_ );
 650         }
 651                 _dump_suspects( %suspect_apps );
 652         throw( "Remaining hanging readings: @bad" );
 653         }
 654         _dump_suspects( %suspect_apps ) if keys %suspect_apps;
 655 }
 656
 657 sub _add_wit_path {
 658     my( $c, $rdg, $app, $anchor, $wit ) = @_;
 659     my @nodes = @$rdg;
 660     push( @nodes, $c->reading( $anchor ) );
 661
 662     my $cur = $c->reading( $app );
 663     foreach my $n ( @nodes ) {
 664         $c->add_path( $cur, $n, $wit );
 665         $cur = $n;
 666     }
 667 }
 668
 669 sub _dump_suspects {
 670         my %list = @_;
 671         say STDERR "Suspect apparatus entries:";
 672         foreach my $suspect ( sort { $a <=> $b } keys %list ) {
 673                 my @badrdgs = @{$list{$suspect}};
 674                 say STDERR _print_apparatus( $suspect );
 675                 say STDERR "\t(Linked to readings @badrdgs)";
 676         }
 677 }
 678
 679 sub _print_apparatus {
 680         my( $appid ) = @_;
 681         my $tag = '__APP_' . $appid . '__';
 682         my $app = $apps{$tag};
 683         my $appstring = '';
 684         # Interpret the XML - get the lemma and readings and print them out.
 685         my $xpc = XML::LibXML::XPathContext->new( $app );
 686         my $anchor = $app->getAttribute('to');
 687         if( $anchor ) {
 688                 # We have a lemma, so we construct it.
 689                 $anchor =~ s/^#//;
 690                 $appstring .= "(Anchor $anchor) ";
 691                 my $curr = $app;
 692                 while( $curr ) {
 693                         last if $curr->nodeType eq XML_ELEMENT_NODE
 694                                 && $curr->hasAttribute( 'xml:id' )
 695                                 && $curr->getAttribute( 'xml:id' ) eq $anchor;
 696                         $appstring .= $curr->data if $curr->nodeType eq XML_TEXT_NODE;
 697                         $curr = $curr->nextSibling;
 698                 }
 699         }
 700         $appstring .= '] ';
 701         my @readings;
 702         foreach my $rdg_el ( $xpc->findnodes( 'child::rdg' ) ) {
 703                 my $rdgtext = '';
 704                 my $startend = '';
 705                 my %detail;
 706                 foreach my $child_el ( $rdg_el->childNodes ) {
 707                         if( $child_el->nodeType eq XML_TEXT_NODE ) {
 708                                 $rdgtext .= $child_el->data;
 709                         } elsif( $child_el->nodeName =~ /^wit(Start|End)$/ ) {
 710                                 my $startend = lc( $1 );
 711                         } elsif( $child_el->nodeName eq 'witDetail' ) {
 712                                 foreach my $wit ( map { _get_sigil( $_ ) }
 713                                         split( /\s+/, $child_el->getAttribute('wit') ) ) {
 714                                         $detail{$wit} = $child_el->textContent;
 715                                 }
 716                         }
 717                 }
 718
 719                 my @witlist;
 720                 foreach my $witrep (  map { _get_sigil( $_ ) }
 721                         split( /\s+/, $rdg_el->getAttribute('wit') ) ) {
 722                         if( exists $detail{$witrep} ) {
 723                                 $witrep .= '(' . $detail{$witrep} . ')'
 724                         }
 725                         if( $startend eq 'start' ) {
 726                                 $witrep = '*' . $witrep;
 727                         } elsif( $startend eq 'end' ) {
 728                                 $witrep .= '*';
 729                         }
 730                         push( @witlist, $witrep );
 731                 }
 732                 $rdgtext .= " @witlist";
 733                 push( @readings, $rdgtext );
 734         }
 735         $appstring .= join( '  ', @readings );
 736         return $appstring;
 737 }
 738
 739 sub throw {
 740         Text::Tradition::Error->throw(
 741                 'ident' => 'Parser::CTE error',
 742                 'message' => $_[0],
 743                 );
 744 }
 745
 746 =head1 LICENSE
 747
 748 This package is free software and is provided "as is" without express
 749 or implied warranty.  You can redistribute it and/or modify it under
 750 the same terms as Perl itself.
 751
 752 =head1 AUTHOR
 753
 754 Tara L Andrews, aurum@cpan.org
 755
 756 =cut
 757
 758 1;
 759