base/lib/Text/Tradition/Collation.pm

   1 package Text::Tradition::Collation;
   2
   3 use feature 'say';
   4 use Encode qw( decode_utf8 );
   5 use File::Temp;
   6 use File::Which;
   7 use Graph;
   8 use IPC::Run qw( run binary );
   9 use Text::CSV;
  10 use Text::Tradition::Collation::Data;
  11 use Text::Tradition::Collation::Reading;
  12 use Text::Tradition::Collation::RelationshipStore;
  13 use Text::Tradition::Error;
  14 use XML::Easy::Syntax qw( $xml10_namestartchar_rx $xml10_namechar_rx );
  15 use XML::LibXML;
  16 use XML::LibXML::XPathContext;
  17 use Moose;
  18
  19 has _data => (
  20         isa      => 'Text::Tradition::Collation::Data',
  21         is       => 'ro',
  22         required => 1,
  23         handles  => [ qw(
  24                 sequence
  25                 paths
  26                 _set_relations
  27                 relations
  28                 _set_start
  29                 _set_end
  30                 ac_label
  31                 has_cached_table
  32                 relationships
  33                 related_readings
  34                 get_relationship
  35                 del_relationship
  36                 equivalence
  37                 equivalence_graph
  38                 readings
  39                 reading
  40                 _add_reading
  41                 del_reading
  42                 has_reading
  43                 wit_list_separator
  44                 baselabel
  45                 linear
  46                 wordsep
  47                 start
  48                 end
  49                 cached_table
  50                 _graphcalc_done
  51                 has_cached_svg
  52                 wipe_table
  53         )]
  54 );
  55
  56 has 'tradition' => (
  57     is => 'ro',
  58     isa => 'Text::Tradition',
  59     writer => '_set_tradition',
  60     weak_ref => 1,
  61     );
  62
  63 =head1 NAME
  64
  65 Text::Tradition::Collation - a software model for a text collation
  66
  67 =head1 SYNOPSIS
  68
  69   use Text::Tradition;
  70   my $t = Text::Tradition->new(
  71     'name' => 'this is a text',
  72     'input' => 'TEI',
  73     'file' => '/path/to/tei_parallel_seg_file.xml' );
  74
  75   my $c = $t->collation;
  76   my @readings = $c->readings;
  77   my @paths = $c->paths;
  78   my @relationships = $c->relationships;
  79
  80   my $svg_variant_graph = $t->collation->as_svg();
  81
  82 =head1 DESCRIPTION
  83
  84 Text::Tradition is a library for representation and analysis of collated
  85 texts, particularly medieval ones.  The Collation is the central feature of
  86 a Tradition, where the text, its sequence of readings, and its relationships
  87 between readings are actually kept.
  88
  89 =head1 CONSTRUCTOR
  90
  91 =head2 new
  92
  93 The constructor.  Takes a hash or hashref of the following arguments:
  94
  95 =over
  96
  97 =item * tradition - The Text::Tradition object to which the collation
  98 belongs. Required.
  99
 100 =item * linear - Whether the collation should be linear; that is, whether
 101 transposed readings should be treated as two linked readings rather than one,
 102 and therefore whether the collation graph is acyclic.  Defaults to true.
 103
 104 =item * baselabel - The default label for the path taken by a base text
 105 (if any). Defaults to 'base text'.
 106
 107 =item * wit_list_separator - The string to join a list of witnesses for
 108 purposes of making labels in display graphs.  Defaults to ', '.
 109
 110 =item * ac_label - The extra label to tack onto a witness sigil when
 111 representing another layer of path for the given witness - that is, when
 112 a text has more than one possible reading due to scribal corrections or
 113 the like.  Defaults to ' (a.c.)'.
 114
 115 =item * wordsep - The string used to separate words in the original text.
 116 Defaults to ' '.
 117
 118 =back
 119
 120 =head1 ACCESSORS
 121
 122 =head2 tradition
 123
 124 =head2 linear
 125
 126 =head2 wit_list_separator
 127
 128 =head2 baselabel
 129
 130 =head2 ac_label
 131
 132 =head2 wordsep
 133
 134 Simple accessors for collation attributes.
 135
 136 =head2 start
 137
 138 The meta-reading at the start of every witness path.
 139
 140 =head2 end
 141
 142 The meta-reading at the end of every witness path.
 143
 144 =head2 readings
 145
 146 Returns all Reading objects in the graph.
 147
 148 =head2 reading( $id )
 149
 150 Returns the Reading object corresponding to the given ID.
 151
 152 =head2 add_reading( $reading_args )
 153
 154 Adds a new reading object to the collation.
 155 See L<Text::Tradition::Collation::Reading> for the available arguments.
 156
 157 =head2 del_reading( $object_or_id )
 158
 159 Removes the given reading from the collation, implicitly removing its
 160 paths and relationships.
 161
 162 =head2 merge_readings( $main, $second, $concatenate, $with_str )
 163
 164 Merges the $second reading into the $main one. If $concatenate is true, then
 165 the merged node will carry the text of both readings, concatenated with either
 166 $with_str (if specified) or a sensible default (the empty string if the
 167 appropriate 'join_*' flag is set on either reading, or else $self->wordsep.)
 168
 169 The first two arguments may be either readings or reading IDs.
 170
 171 =head2 has_reading( $id )
 172
 173 Predicate to see whether a given reading ID is in the graph.
 174
 175 =head2 reading_witnesses( $object_or_id )
 176
 177 Returns a list of sigils whose witnesses contain the reading.
 178
 179 =head2 paths
 180
 181 Returns all reading paths within the document - that is, all edges in the
 182 collation graph.  Each path is an arrayref of [ $source, $target ] reading IDs.
 183
 184 =head2 add_path( $source, $target, $sigil )
 185
 186 Links the given readings in the collation in sequence, under the given witness
 187 sigil.  The readings may be specified by object or ID.
 188
 189 =head2 del_path( $source, $target, $sigil )
 190
 191 Links the given readings in the collation in sequence, under the given witness
 192 sigil.  The readings may be specified by object or ID.
 193
 194 =head2 has_path( $source, $target );
 195
 196 Returns true if the two readings are linked in sequence in any witness.
 197 The readings may be specified by object or ID.
 198
 199 =head2 relationships
 200
 201 Returns all Relationship objects in the collation.
 202
 203 =head2 add_relationship( $reading, $other_reading, $options )
 204
 205 Adds a new relationship of the type given in $options between the two readings,
 206 which may be specified by object or ID.  Returns a value of ( $status, @vectors)
 207 where $status is true on success, and @vectors is a list of relationship edges
 208 that were ultimately added.
 209 See L<Text::Tradition::Collation::Relationship> for the available options.
 210
 211 =cut
 212
 213 sub BUILDARGS {
 214         my ( $class, @args ) = @_;
 215         my %args = @args == 1 ? %{ $args[0] } : @args;
 216         # TODO determine these from the Moose::Meta object
 217         my @delegate_attrs = qw(sequence relations readings wit_list_separator baselabel
 218                 linear wordsep start end cached_table _graphcalc_done);
 219         my %data_args;
 220         for my $attr (@delegate_attrs) {
 221                 $data_args{$attr} = delete $args{$attr} if exists $args{$attr};
 222         }
 223         $args{_data} = Text::Tradition::Collation::Data->new(%data_args);
 224         return \%args;
 225 }
 226
 227 sub BUILD {
 228     my $self = shift;
 229     $self->_set_relations( Text::Tradition::Collation::RelationshipStore->new( 'collation' => $self ) );
 230     $self->_set_start( $self->add_reading(
 231         { 'collation' => $self, 'is_start' => 1, 'init' => 1 } ) );
 232     $self->_set_end( $self->add_reading(
 233         { 'collation' => $self, 'is_end' => 1, 'init' => 1 } ) );
 234 }
 235
 236 ### Reading construct/destruct functions
 237
 238 sub add_reading {
 239         my( $self, $reading ) = @_;
 240         unless( ref( $reading ) eq 'Text::Tradition::Collation::Reading' ) {
 241                 my %args = %$reading;
 242                 if( $args{'init'} ) {
 243                         # If we are initializing an empty collation, don't assume that we
 244                         # have set a tradition.
 245                         delete $args{'init'};
 246                 } elsif( $self->tradition->can('language') && $self->tradition->has_language
 247                         && !exists $args{'language'} ) {
 248                         $args{'language'} = $self->tradition->language;
 249                 }
 250                 $reading = Text::Tradition::Collation::Reading->new(
 251                         'collation' => $self,
 252                         %args );
 253         }
 254         # First check to see if a reading with this ID exists.
 255         if( $self->reading( $reading->id ) ) {
 256                 throw( "Collation already has a reading with id " . $reading->id );
 257         }
 258         $self->_graphcalc_done(0);
 259         $self->_add_reading( $reading->id => $reading );
 260         # Once the reading has been added, put it in both graphs.
 261         $self->sequence->add_vertex( $reading->id );
 262         $self->relations->add_reading( $reading->id );
 263         return $reading;
 264 };
 265
 266 around del_reading => sub {
 267         my $orig = shift;
 268         my $self = shift;
 269         my $arg = shift;
 270
 271         if( ref( $arg ) eq 'Text::Tradition::Collation::Reading' ) {
 272                 $arg = $arg->id;
 273         }
 274         # Remove the reading from the graphs.
 275         $self->_graphcalc_done(0);
 276         $self->_clear_cache; # Explicitly clear caches to GC the reading
 277         $self->sequence->delete_vertex( $arg );
 278         $self->relations->delete_reading( $arg );
 279
 280         # Carry on.
 281         $self->$orig( $arg );
 282 };
 283
 284 =begin testing
 285
 286 use Text::Tradition;
 287
 288 my $cxfile = 't/data/Collatex-16.xml';
 289 my $t = Text::Tradition->new(
 290     'name'  => 'inline',
 291     'input' => 'CollateX',
 292     'file'  => $cxfile,
 293     );
 294 my $c = $t->collation;
 295
 296 my $rno = scalar $c->readings;
 297 # Split n21 for testing purposes
 298 my $new_r = $c->add_reading( { 'id' => 'n21p0', 'text' => 'un', 'join_next' => 1 } );
 299 my $old_r = $c->reading( 'n21' );
 300 $old_r->alter_text( 'to' );
 301 $c->del_path( 'n20', 'n21', 'A' );
 302 $c->add_path( 'n20', 'n21p0', 'A' );
 303 $c->add_path( 'n21p0', 'n21', 'A' );
 304 $c->flatten_ranks();
 305 ok( $c->reading( 'n21p0' ), "New reading exists" );
 306 is( scalar $c->readings, $rno, "Reading add offset by flatten_ranks" );
 307
 308 # Combine n3 and n4 ( with his )
 309 $c->merge_readings( 'n3', 'n4', 1 );
 310 ok( !$c->reading('n4'), "Reading n4 is gone" );
 311 is( $c->reading('n3')->text, 'with his', "Reading n3 has both words" );
 312
 313 # Collapse n9 and n10 ( rood / root )
 314 $c->merge_readings( 'n9', 'n10' );
 315 ok( !$c->reading('n10'), "Reading n10 is gone" );
 316 is( $c->reading('n9')->text, 'rood', "Reading n9 has an unchanged word" );
 317
 318 # Combine n21 and n21p0
 319 my $remaining = $c->reading('n21');
 320 $remaining ||= $c->reading('n22');  # one of these should still exist
 321 $c->merge_readings( 'n21p0', $remaining, 1 );
 322 ok( !$c->reading('n21'), "Reading $remaining is gone" );
 323 is( $c->reading('n21p0')->text, 'unto', "Reading n21p0 merged correctly" );
 324
 325 =end testing
 326
 327 =cut
 328
 329 sub merge_readings {
 330         my $self = shift;
 331
 332         # Sanity check
 333         my( $kept_obj, $del_obj, $combine, $combine_char ) = $self->_objectify_args( @_ );
 334         my $mergemeta = $kept_obj->is_meta;
 335         throw( "Cannot merge meta and non-meta reading" )
 336                 unless ( $mergemeta && $del_obj->is_meta )
 337                         || ( !$mergemeta && !$del_obj->is_meta );
 338         if( $mergemeta ) {
 339                 throw( "Cannot merge with start or end node" )
 340                         if( $kept_obj eq $self->start || $kept_obj eq $self->end
 341                                 || $del_obj eq $self->start || $del_obj eq $self->end );
 342                 throw( "Cannot combine text of meta readings" ) if $combine;
 343         }
 344         # We only need the IDs for adding paths to the graph, not the reading
 345         # objects themselves.
 346         my $kept = $kept_obj->id;
 347         my $deleted = $del_obj->id;
 348         $self->_graphcalc_done(0);
 349
 350     # The kept reading should inherit the paths and the relationships
 351     # of the deleted reading.
 352         foreach my $path ( $self->sequence->edges_at( $deleted ) ) {
 353                 my @vector = ( $kept );
 354                 push( @vector, $path->[1] ) if $path->[0] eq $deleted;
 355                 unshift( @vector, $path->[0] ) if $path->[1] eq $deleted;
 356                 next if $vector[0] eq $vector[1]; # Don't add a self loop
 357                 my %wits = %{$self->sequence->get_edge_attributes( @$path )};
 358                 $self->sequence->add_edge( @vector );
 359                 my $fwits = $self->sequence->get_edge_attributes( @vector );
 360                 @wits{keys %$fwits} = values %$fwits;
 361                 $self->sequence->set_edge_attributes( @vector, \%wits );
 362         }
 363         $self->relations->merge_readings( $kept, $deleted, $combine );
 364
 365         # Do the deletion deed.
 366         if( $combine ) {
 367                 # Combine the text of the readings
 368                 my $joinstr = $combine_char;
 369                 unless( defined $joinstr ) {
 370                         $joinstr = '' if $kept_obj->join_next || $del_obj->join_prior;
 371                         $joinstr = $self->wordsep unless defined $joinstr;
 372                 }
 373                 $kept_obj->_combine( $del_obj, $joinstr );
 374         }
 375         $self->del_reading( $deleted );
 376 }
 377
 378 =head2 compress_readings
 379
 380 Where possible in the graph, compresses plain sequences of readings into a
 381 single reading. The sequences must consist of readings with no
 382 relationships to other readings, with only a single witness path between
 383 them and no other witness paths from either that would skip the other. The
 384 readings must also not be marked as nonsense or bad grammar.
 385
 386 WARNING: This operation cannot be undone.
 387
 388 =cut
 389
 390 sub compress_readings {
 391         my $self = shift;
 392         # Anywhere in the graph that there is a reading that joins only to a single
 393         # successor, and neither of these have any relationships, just join the two
 394         # readings.
 395         foreach my $rdg ( sort { $a->rank <=> $b->rank } $self->readings ) {
 396                 # Now look for readings that can be joined to their successors.
 397                 next unless $rdg->is_combinable;
 398                 my %seen;
 399                 while( $self->sequence->successors( $rdg ) == 1 ) {
 400                         my( $next ) = $self->reading( $self->sequence->successors( $rdg ) );
 401                         throw( "Infinite loop" ) if $seen{$next->id};
 402                         $seen{$next->id} = 1;
 403                         last if $self->sequence->predecessors( $next ) > 1;
 404                         last unless $next->is_combinable;
 405                         say "Joining readings $rdg and $next";
 406                         $self->merge_readings( $rdg, $next, 1 );
 407                 }
 408         }
 409         # Make sure we haven't screwed anything up
 410         foreach my $wit ( $self->tradition->witnesses ) {
 411                 my $pathtext = $self->path_text( $wit->sigil );
 412                 my $origtext = join( ' ', @{$wit->text} );
 413                 throw( "Text differs for witness " . $wit->sigil )
 414                         unless $pathtext eq $origtext;
 415                 if( $wit->is_layered ) {
 416                         $pathtext = $self->path_text( $wit->sigil.$self->ac_label );
 417                         $origtext = join( ' ', @{$wit->layertext} );
 418                         throw( "Ante-corr text differs for witness " . $wit->sigil )
 419                                 unless $pathtext eq $origtext;
 420                 }
 421         }
 422
 423         $self->relations->rebuild_equivalence();
 424         $self->calculate_ranks();
 425 }
 426
 427 # Helper function for manipulating the graph.
 428 sub _stringify_args {
 429         my( $self, $first, $second, @args ) = @_;
 430     $first = $first->id
 431         if ref( $first ) eq 'Text::Tradition::Collation::Reading';
 432     $second = $second->id
 433         if ref( $second ) eq 'Text::Tradition::Collation::Reading';
 434     return( $first, $second, @args );
 435 }
 436
 437 # Helper function for manipulating the graph.
 438 sub _objectify_args {
 439         my( $self, $first, $second, $arg ) = @_;
 440     $first = $self->reading( $first )
 441         unless ref( $first ) eq 'Text::Tradition::Collation::Reading';
 442     $second = $self->reading( $second )
 443         unless ref( $second ) eq 'Text::Tradition::Collation::Reading';
 444     return( $first, $second, $arg );
 445 }
 446 ### Path logic
 447
 448 sub add_path {
 449         my $self = shift;
 450
 451         # We only need the IDs for adding paths to the graph, not the reading
 452         # objects themselves.
 453     my( $source, $target, $wit ) = $self->_stringify_args( @_ );
 454
 455         $self->_graphcalc_done(0);
 456         # Connect the readings
 457         unless( $self->sequence->has_edge( $source, $target ) ) {
 458             $self->sequence->add_edge( $source, $target );
 459             $self->relations->add_equivalence_edge( $source, $target );
 460         }
 461     # Note the witness in question
 462     $self->sequence->set_edge_attribute( $source, $target, $wit, 1 );
 463 }
 464
 465 sub del_path {
 466         my $self = shift;
 467         my @args;
 468         if( ref( $_[0] ) eq 'ARRAY' ) {
 469                 my $e = shift @_;
 470                 @args = ( @$e, @_ );
 471         } else {
 472                 @args = @_;
 473         }
 474
 475         # We only need the IDs for adding paths to the graph, not the reading
 476         # objects themselves.
 477     my( $source, $target, $wit ) = $self->_stringify_args( @args );
 478
 479         $self->_graphcalc_done(0);
 480         if( $self->sequence->has_edge_attribute( $source, $target, $wit ) ) {
 481                 $self->sequence->delete_edge_attribute( $source, $target, $wit );
 482         }
 483         unless( keys %{$self->sequence->get_edge_attributes( $source, $target )} ) {
 484                 $self->sequence->delete_edge( $source, $target );
 485                 $self->relations->delete_equivalence_edge( $source, $target );
 486         }
 487 }
 488
 489
 490 # Extra graph-alike utility
 491 sub has_path {
 492         my $self = shift;
 493     my( $source, $target, $wit ) = $self->_stringify_args( @_ );
 494         return undef unless $self->sequence->has_edge( $source, $target );
 495         return $self->sequence->has_edge_attribute( $source, $target, $wit );
 496 }
 497
 498 =head2 clear_witness( @sigil_list )
 499
 500 Clear the given witnesses out of the collation entirely, removing references
 501 to them in paths, and removing readings that belong only to them.  Should only
 502 be called via $tradition->del_witness.
 503
 504 =cut
 505
 506 sub clear_witness {
 507         my( $self, @sigils ) = @_;
 508
 509         $self->_graphcalc_done(0);
 510         # Clear the witness(es) out of the paths
 511         foreach my $e ( $self->paths ) {
 512                 foreach my $sig ( @sigils ) {
 513                         $self->del_path( $e, $sig );
 514                 }
 515         }
 516
 517         # Clear out the newly unused readings
 518         foreach my $r ( $self->readings ) {
 519                 unless( $self->reading_witnesses( $r ) ) {
 520                         $self->del_reading( $r );
 521                 }
 522         }
 523 }
 524
 525 sub add_relationship {
 526         my $self = shift;
 527     my( $source, $target, $opts ) = $self->_stringify_args( @_ );
 528     my( @vectors ) = $self->relations->add_relationship( $source, $target, $opts );
 529         $self->_graphcalc_done(0);
 530     return @vectors;
 531 }
 532
 533 around qw/ get_relationship del_relationship / => sub {
 534         my $orig = shift;
 535         my $self = shift;
 536         my @args = @_;
 537         if( @args == 1 && ref( $args[0] ) eq 'ARRAY' ) {
 538                 @args = @{$_[0]};
 539         }
 540         my( $source, $target ) = $self->_stringify_args( @args );
 541         $self->$orig( $source, $target );
 542 };
 543
 544 =head2 reading_witnesses( $reading )
 545
 546 Return a list of sigils corresponding to the witnesses in which the reading appears.
 547
 548 =cut
 549
 550 sub reading_witnesses {
 551         my( $self, $reading ) = @_;
 552         # We need only check either the incoming or the outgoing edges; I have
 553         # arbitrarily chosen "incoming".  Thus, special-case the start node.
 554         if( $reading eq $self->start ) {
 555                 return map { $_->sigil } $self->tradition->witnesses;
 556         }
 557         my %all_witnesses;
 558         foreach my $e ( $self->sequence->edges_to( $reading ) ) {
 559                 my $wits = $self->sequence->get_edge_attributes( @$e );
 560                 @all_witnesses{ keys %$wits } = 1;
 561         }
 562         my $acstr = $self->ac_label;
 563         foreach my $acwit ( grep { $_ =~ s/^(.*)\Q$acstr\E$/$1/ } keys %all_witnesses ) {
 564                 delete $all_witnesses{$acwit.$acstr} if exists $all_witnesses{$acwit};
 565         }
 566         return keys %all_witnesses;
 567 }
 568
 569 =head1 OUTPUT METHODS
 570
 571 =head2 as_svg( \%options )
 572
 573 Returns an SVG string that represents the graph, via as_dot and graphviz.
 574 See as_dot for a list of options.  Must have GraphViz (dot) installed to run.
 575
 576 =cut
 577
 578 sub as_svg {
 579     my( $self, $opts ) = @_;
 580     throw( "Need GraphViz installed to output SVG" )
 581         unless File::Which::which( 'dot' );
 582     my $want_subgraph = exists $opts->{'from'} || exists $opts->{'to'};
 583     $self->calculate_ranks()
 584         unless( $self->_graphcalc_done || $opts->{'nocalc'} || !$self->linear );
 585         my @cmd = qw/dot -Tsvg/;
 586         my( $svg, $err );
 587         my $dotfile = File::Temp->new();
 588         ## USE FOR DEBUGGING
 589         # $dotfile->unlink_on_destroy(0);
 590         binmode $dotfile, ':utf8';
 591         print $dotfile $self->as_dot( $opts );
 592         push( @cmd, $dotfile->filename );
 593         run( \@cmd, ">", binary(), \$svg );
 594         $svg = decode_utf8( $svg );
 595         return $svg;
 596 }
 597
 598
 599 =head2 as_dot( \%options )
 600
 601 Returns a string that is the collation graph expressed in dot
 602 (i.e. GraphViz) format.  Options include:
 603
 604 =over 4
 605
 606 =item * from
 607
 608 =item * to
 609
 610 =item * color_common
 611
 612 =back
 613
 614 =cut
 615
 616 sub as_dot {
 617     my( $self, $opts ) = @_;
 618     my $startrank = $opts->{'from'} if $opts;
 619     my $endrank = $opts->{'to'} if $opts;
 620     my $color_common = $opts->{'color_common'} if $opts;
 621     my $STRAIGHTENHACK = !$startrank && !$endrank && $self->end->rank
 622        && $self->end->rank > 100;
 623     $STRAIGHTENHACK = 1 if $opts->{'straight'}; # even for subgraphs or small graphs
 624
 625     # Check the arguments
 626     if( $startrank ) {
 627         return if $endrank && $startrank > $endrank;
 628         return if $startrank > $self->end->rank;
 629         }
 630         if( defined $endrank ) {
 631                 return if $endrank < 0;
 632                 $endrank = undef if $endrank == $self->end->rank;
 633         }
 634
 635     my $graph_name = $self->tradition->name;
 636     $graph_name =~ s/[^\w\s]//g;
 637     $graph_name = join( '_', split( /\s+/, $graph_name ) );
 638
 639     my %graph_attrs = (
 640         'rankdir' => 'LR',
 641         'bgcolor' => 'none',
 642         );
 643     my %node_attrs = (
 644         'fontsize' => 14,
 645         'fillcolor' => 'white',
 646         'style' => 'filled',
 647         'shape' => 'ellipse'
 648         );
 649     my %edge_attrs = (
 650         'arrowhead' => 'open',
 651         'color' => '#000000',
 652         'fontcolor' => '#000000',
 653         );
 654
 655     my $dot = sprintf( "digraph %s {\n", $graph_name );
 656     $dot .= "\tgraph " . _dot_attr_string( \%graph_attrs ) . ";\n";
 657     $dot .= "\tnode " . _dot_attr_string( \%node_attrs ) . ";\n";
 658
 659         # Output substitute start/end readings if necessary
 660         if( $startrank ) {
 661                 $dot .= "\t\"__SUBSTART__\" [ label=\"...\",id=\"__START__\" ];\n";
 662         }
 663         if( $endrank ) {
 664                 $dot .= "\t\"__SUBEND__\" [ label=\"...\",id=\"__END__\" ];\n";
 665         }
 666         if( $STRAIGHTENHACK ) {
 667                 ## HACK part 1
 668                 my $startlabel = $startrank ? '__SUBSTART__' : '__START__';
 669                 $dot .= "\tsubgraph { rank=same \"$startlabel\" \"#SILENT#\" }\n";
 670                 $dot .= "\t\"#SILENT#\" [ shape=diamond,color=white,penwidth=0,label=\"\" ];"
 671         }
 672         my %used;  # Keep track of the readings that actually appear in the graph
 673         # Sort the readings by rank if we have ranks; this speeds layout.
 674         my @all_readings = $self->end->has_rank
 675                 ? sort { $a->rank <=> $b->rank } $self->readings
 676                 : $self->readings;
 677         # TODO Refrain from outputting lacuna nodes - just grey out the edges.
 678     foreach my $reading ( @all_readings ) {
 679         # Only output readings within our rank range.
 680         next if $startrank && $reading->rank < $startrank;
 681         next if $endrank && $reading->rank > $endrank;
 682         $used{$reading->id} = 1;
 683         # Need not output nodes without separate labels
 684         next if $reading->id eq $reading->text;
 685         my $rattrs;
 686         my $label = $reading->text;
 687         $label .= '-' if $reading->join_next;
 688         $label = "-$label" if $reading->join_prior;
 689         $label =~ s/\"/\\\"/g;
 690                 $rattrs->{'label'} = $label;
 691                 $rattrs->{'id'} = $reading->id;
 692                 $rattrs->{'fillcolor'} = '#b3f36d' if $reading->is_common && $color_common;
 693         $dot .= sprintf( "\t\"%s\" %s;\n", $reading->id, _dot_attr_string( $rattrs ) );
 694     }
 695
 696         # Add the real edges. Need to weight one edge per rank jump, in a
 697         # continuous line.
 698         # my $weighted = $self->_add_edge_weights;
 699     my @edges = $self->paths;
 700         my( %substart, %subend );
 701     foreach my $edge ( @edges ) {
 702         # Do we need to output this edge?
 703         if( $used{$edge->[0]} && $used{$edge->[1]} ) {
 704                 my $label = $self->_path_display_label( $self->path_witnesses( $edge ) );
 705                         my $variables = { %edge_attrs, 'label' => $label };
 706
 707                         # Account for the rank gap if necessary
 708                         my $rank0 = $self->reading( $edge->[0] )->rank
 709                                 if $self->reading( $edge->[0] )->has_rank;
 710                         my $rank1 = $self->reading( $edge->[1] )->rank
 711                                 if $self->reading( $edge->[1] )->has_rank;
 712                         if( defined $rank0 && defined $rank1 && $rank1 - $rank0 > 1 ) {
 713                                 $variables->{'minlen'} = $rank1 - $rank0;
 714                         }
 715
 716                         # Add the calculated edge weights
 717                         # if( exists $weighted->{$edge->[0]}
 718                         #       && $weighted->{$edge->[0]} eq $edge->[1] ) {
 719                         #       # $variables->{'color'} = 'red';
 720                         #       $variables->{'weight'} = 3.0;
 721                         # }
 722
 723                         # EXPERIMENTAL: make edge width reflect no. of witnesses
 724                         my $extrawidth = scalar( $self->path_witnesses( $edge ) ) * 0.2;
 725                         $variables->{'penwidth'} = $extrawidth + 0.8; # gives 1 for a single wit
 726
 727                         my $varopts = _dot_attr_string( $variables );
 728                         $dot .= sprintf( "\t\"%s\" -> \"%s\" %s;\n",
 729                                 $edge->[0], $edge->[1], $varopts );
 730         } elsif( $used{$edge->[0]} ) {
 731                 $subend{$edge->[0]} = $edge->[1];
 732         } elsif( $used{$edge->[1]} ) {
 733                 $substart{$edge->[1]} = $edge->[0];
 734         }
 735     }
 736     # Add substitute start and end edges if necessary
 737     foreach my $node ( keys %substart ) {
 738         my $witstr = $self->_path_display_label ( $self->path_witnesses( $substart{$node}, $node ) );
 739         my $variables = { %edge_attrs, 'label' => $witstr };
 740         my $nrdg = $self->reading( $node );
 741         if( $nrdg->has_rank && $nrdg->rank > $startrank ) {
 742                 # Substart is actually one lower than $startrank
 743                 $variables->{'minlen'} = $nrdg->rank - ( $startrank - 1 );
 744         }
 745         my $varopts = _dot_attr_string( $variables );
 746         $dot .= "\t\"__SUBSTART__\" -> \"$node\" $varopts;\n";
 747         }
 748     foreach my $node ( keys %subend ) {
 749         my $witstr = $self->_path_display_label ( $self->path_witnesses( $node, $subend{$node} ) );
 750         my $variables = { %edge_attrs, 'label' => $witstr };
 751         my $varopts = _dot_attr_string( $variables );
 752         $dot .= "\t\"$node\" -> \"__SUBEND__\" $varopts;\n";
 753         }
 754         # HACK part 2
 755         if( $STRAIGHTENHACK ) {
 756                 my $endlabel = $endrank ? '__SUBEND__' : '__END__';
 757                 $dot .= "\t\"$endlabel\" -> \"#SILENT#\" [ color=white,penwidth=0 ];\n";
 758         }
 759
 760     $dot .= "}\n";
 761     return $dot;
 762 }
 763
 764 sub _dot_attr_string {
 765         my( $hash ) = @_;
 766         my @attrs;
 767         foreach my $k ( sort keys %$hash ) {
 768                 my $v = $hash->{$k};
 769                 push( @attrs, $k.'="'.$v.'"' );
 770         }
 771         return( '[ ' . join( ', ', @attrs ) . ' ]' );
 772 }
 773
 774 sub _add_edge_weights {
 775         my $self = shift;
 776         # Walk the graph from START to END, choosing the successor node with
 777         # the largest number of witness paths each time.
 778         my $weighted = {};
 779         my $curr = $self->start->id;
 780         my $ranked = $self->end->has_rank;
 781         while( $curr ne $self->end->id ) {
 782                 my $rank = $ranked ? $self->reading( $curr )->rank : 0;
 783                 my @succ = sort { $self->path_witnesses( $curr, $a )
 784                                                         <=> $self->path_witnesses( $curr, $b ) }
 785                         $self->sequence->successors( $curr );
 786                 my $next = pop @succ;
 787                 my $nextrank = $ranked ? $self->reading( $next )->rank : 0;
 788                 # Try to avoid lacunae in the weighted path.
 789                 while( @succ &&
 790                            ( $self->reading( $next )->is_lacuna ||
 791                                  $nextrank - $rank > 1 ) ){
 792                         $next = pop @succ;
 793                 }
 794                 $weighted->{$curr} = $next;
 795                 $curr = $next;
 796         }
 797         return $weighted;
 798 }
 799
 800 =head2 path_witnesses( $edge )
 801
 802 Returns the list of sigils whose witnesses are associated with the given edge.
 803 The edge can be passed as either an array or an arrayref of ( $source, $target ).
 804
 805 =cut
 806
 807 sub path_witnesses {
 808         my( $self, @edge ) = @_;
 809         # If edge is an arrayref, cope.
 810         if( @edge == 1 && ref( $edge[0] ) eq 'ARRAY' ) {
 811                 my $e = shift @edge;
 812                 @edge = @$e;
 813         }
 814         my @wits = keys %{$self->sequence->get_edge_attributes( @edge )};
 815         return @wits;
 816 }
 817
 818 # Helper function. Make a display label for the given witnesses, showing a.c.
 819 # witnesses only where the main witness is not also in the list.
 820 sub _path_display_label {
 821         my $self = shift;
 822         my %wits;
 823         map { $wits{$_} = 1 } @_;
 824
 825         # If an a.c. wit is listed, remove it if the main wit is also listed.
 826         # Otherwise keep it for explicit listing.
 827         my $aclabel = $self->ac_label;
 828         my @disp_ac;
 829         foreach my $w ( sort keys %wits ) {
 830                 if( $w =~ /^(.*)\Q$aclabel\E$/ ) {
 831                         if( exists $wits{$1} ) {
 832                                 delete $wits{$w};
 833                         } else {
 834                                 push( @disp_ac, $w );
 835                         }
 836                 }
 837         }
 838
 839         # See if we are in a majority situation.
 840         my $maj = scalar( $self->tradition->witnesses ) * 0.6;
 841         $maj = $maj > 5 ? $maj : 5;
 842         if( scalar keys %wits > $maj ) {
 843                 unshift( @disp_ac, 'majority' );
 844                 return join( ', ', @disp_ac );
 845         } else {
 846                 return join( ', ', sort keys %wits );
 847         }
 848 }
 849
 850 =head2 readings_at_rank( $rank )
 851
 852 Returns a list of readings at a given rank, taken from the alignment table.
 853
 854 =cut
 855
 856 sub readings_at_rank {
 857         my( $self, $rank ) = @_;
 858         my $table = $self->alignment_table;
 859         # Table rank is real rank - 1.
 860         my @elements = map { $_->{'tokens'}->[$rank-1] } @{$table->{'alignment'}};
 861         my %readings;
 862         foreach my $e ( @elements ) {
 863                 next unless ref( $e ) eq 'HASH';
 864                 next unless exists $e->{'t'};
 865                 $readings{$e->{'t'}->id} = $e->{'t'};
 866         }
 867         return values %readings;
 868 }
 869
 870 =head2 as_graphml
 871
 872 Returns a GraphML representation of the collation.  The GraphML will contain
 873 two graphs. The first expresses the attributes of the readings and the witness
 874 paths that link them; the second expresses the relationships that link the
 875 readings.  This is the native transfer format for a tradition.
 876
 877 =begin testing
 878
 879 use Text::Tradition;
 880 use TryCatch;
 881
 882 my $READINGS = 311;
 883 my $PATHS = 361;
 884
 885 my $datafile = 't/data/florilegium_tei_ps.xml';
 886 my $tradition = Text::Tradition->new( 'input' => 'TEI',
 887                                       'name' => 'test0',
 888                                       'file' => $datafile,
 889                                       'linear' => 1 );
 890
 891 ok( $tradition, "Got a tradition object" );
 892 is( scalar $tradition->witnesses, 13, "Found all witnesses" );
 893 ok( $tradition->collation, "Tradition has a collation" );
 894
 895 my $c = $tradition->collation;
 896 is( scalar $c->readings, $READINGS, "Collation has all readings" );
 897 is( scalar $c->paths, $PATHS, "Collation has all paths" );
 898 is( scalar $c->relationships, 0, "Collation has all relationships" );
 899
 900 # Add a few relationships
 901 $c->add_relationship( 'w123', 'w125', { 'type' => 'collated' } );
 902 $c->add_relationship( 'w193', 'w196', { 'type' => 'collated' } );
 903 $c->add_relationship( 'w257', 'w262', { 'type' => 'transposition' } );
 904
 905 # Now write it to GraphML and parse it again.
 906
 907 my $graphml = $c->as_graphml;
 908 my $st = Text::Tradition->new( 'input' => 'Self', 'string' => $graphml );
 909 is( scalar $st->collation->readings, $READINGS, "Reparsed collation has all readings" );
 910 is( scalar $st->collation->paths, $PATHS, "Reparsed collation has all paths" );
 911 is( scalar $st->collation->relationships, 3, "Reparsed collation has new relationships" );
 912
 913 # Now add a stemma, write to GraphML, and look at the output.
 914 SKIP: {
 915         skip "Analysis module not present", 3 unless $tradition->can( 'add_stemma' );
 916         my $stemma = $tradition->add_stemma( 'dotfile' => 't/data/florilegium.dot' );
 917         is( ref( $stemma ), 'Text::Tradition::Stemma', "Parsed dotfile into stemma" );
 918         is( $tradition->stemmata, 1, "Tradition now has the stemma" );
 919         $graphml = $c->as_graphml;
 920         like( $graphml, qr/digraph/, "Digraph declaration exists in GraphML" );
 921 }
 922
 923 =end testing
 924
 925 =cut
 926
 927 ## TODO MOVE this to Tradition.pm and modularize it better
 928 sub as_graphml {
 929     my( $self, $options ) = @_;
 930         $self->calculate_ranks unless $self->_graphcalc_done;
 931
 932         my $start = $options->{'from'}
 933                 ? $self->reading( $options->{'from'} ) : $self->start;
 934         my $end = $options->{'to'}
 935                 ? $self->reading( $options->{'to'} ) : $self->end;
 936         if( $start->has_rank && $end->has_rank && $end->rank < $start->rank ) {
 937                 throw( 'Start node must be before end node' );
 938         }
 939         # The readings need to be ranked for this to work.
 940         $start = $self->start unless $start->has_rank;
 941         $end = $self->end unless $end->has_rank;
 942         my $rankoffset = 0;
 943         unless( $start eq $self->start ) {
 944                 $rankoffset = $start->rank - 1;
 945         }
 946         my %use_readings;
 947
 948     # Some namespaces
 949     my $graphml_ns = 'http://graphml.graphdrawing.org/xmlns';
 950     my $xsi_ns = 'http://www.w3.org/2001/XMLSchema-instance';
 951     my $graphml_schema = 'http://graphml.graphdrawing.org/xmlns ' .
 952         'http://graphml.graphdrawing.org/xmlns/1.0/graphml.xsd';
 953
 954     # Create the document and root node
 955     require XML::LibXML;
 956     my $graphml = XML::LibXML->createDocument( "1.0", "UTF-8" );
 957     my $root = $graphml->createElementNS( $graphml_ns, 'graphml' );
 958     $graphml->setDocumentElement( $root );
 959     $root->setNamespace( $xsi_ns, 'xsi', 0 );
 960     $root->setAttributeNS( $xsi_ns, 'schemaLocation', $graphml_schema );
 961
 962     # List of attribute types to save on our objects and their corresponding
 963     # GraphML types
 964     my %save_types = (
 965         'Str' => 'string',
 966         'Int' => 'int',
 967         'Bool' => 'boolean',
 968         'ReadingID' => 'string',
 969         'RelationshipType' => 'string',
 970         'RelationshipScope' => 'string',
 971     );
 972
 973     # Add the data keys for the graph. Include an extra key 'version' for the
 974     # GraphML output version.
 975     my %graph_data_keys;
 976     my $gdi = 0;
 977     my %graph_attributes = ( 'version' => 'string' );
 978         # Graph attributes include those of Tradition and those of Collation.
 979         my %gattr_from;
 980         my $tmeta = $self->tradition->meta;
 981         my $cmeta = $self->meta;
 982         map { $gattr_from{$_->name} = 'Tradition' } $tmeta->get_all_attributes;
 983         map { $gattr_from{$_->name} = 'Collation' } $cmeta->get_all_attributes;
 984         foreach my $attr ( ( $tmeta->get_all_attributes, $cmeta->get_all_attributes ) ) {
 985                 next if $attr->name =~ /^_/;
 986                 next unless $save_types{$attr->type_constraint->name};
 987                 $graph_attributes{$attr->name} = $save_types{$attr->type_constraint->name};
 988         }
 989     # Extra custom keys for complex objects that should be saved in some form.
 990     # The subroutine should return a string, or undef/empty.
 991     if( $tmeta->has_method('stemmata') ) {
 992                 $graph_attributes{'stemmata'} = sub {
 993                         my @stemstrs;
 994                         map { push( @stemstrs, $_->editable( {linesep => ''} ) ) }
 995                                 $self->tradition->stemmata;
 996                         join( "\n", @stemstrs );
 997                 };
 998         }
 999
1000         if( $tmeta->has_method('user') ) {
1001                 $graph_attributes{'user'} = sub {
1002                         $self->tradition->user ? $self->tradition->user->id : undef
1003                 };
1004         }
1005
1006     foreach my $datum ( sort keys %graph_attributes ) {
1007         $graph_data_keys{$datum} = 'dg'.$gdi++;
1008         my $key = $root->addNewChild( $graphml_ns, 'key' );
1009         my $dtype = ref( $graph_attributes{$datum} ) ? 'string'
1010                 : $graph_attributes{$datum};
1011         $key->setAttribute( 'attr.name', $datum );
1012         $key->setAttribute( 'attr.type', $dtype );
1013         $key->setAttribute( 'for', 'graph' );
1014         $key->setAttribute( 'id', $graph_data_keys{$datum} );
1015     }
1016
1017     # Add the data keys for reading nodes
1018     my %reading_attributes;
1019     my $rmeta = Text::Tradition::Collation::Reading->meta;
1020     foreach my $attr( $rmeta->get_all_attributes ) {
1021                 next if $attr->name =~ /^_/;
1022                 next unless $save_types{$attr->type_constraint->name};
1023                 $reading_attributes{$attr->name} = $save_types{$attr->type_constraint->name};
1024         }
1025         if( $self->start->does('Text::Tradition::Morphology' ) ) {
1026                 # Extra custom key for the reading morphology
1027                 $reading_attributes{'lexemes'} = 'string';
1028         }
1029
1030     my %node_data_keys;
1031     my $ndi = 0;
1032     foreach my $datum ( sort keys %reading_attributes ) {
1033         $node_data_keys{$datum} = 'dn'.$ndi++;
1034         my $key = $root->addNewChild( $graphml_ns, 'key' );
1035         $key->setAttribute( 'attr.name', $datum );
1036         $key->setAttribute( 'attr.type', $reading_attributes{$datum} );
1037         $key->setAttribute( 'for', 'node' );
1038         $key->setAttribute( 'id', $node_data_keys{$datum} );
1039     }
1040
1041     # Add the data keys for edges, that is, paths and relationships. Path
1042     # data does not come from a Moose class so is here manually.
1043     my $edi = 0;
1044     my %edge_data_keys;
1045     my %edge_attributes = (
1046         witness => 'string',                    # ID/label for a path
1047         extra => 'boolean',                             # Path key
1048         );
1049     my @path_attributes = keys %edge_attributes; # track our manual additions
1050     my $pmeta = Text::Tradition::Collation::Relationship->meta;
1051     foreach my $attr( $pmeta->get_all_attributes ) {
1052                 next if $attr->name =~ /^_/;
1053                 next unless $save_types{$attr->type_constraint->name};
1054                 $edge_attributes{$attr->name} = $save_types{$attr->type_constraint->name};
1055         }
1056     foreach my $datum ( sort keys %edge_attributes ) {
1057         $edge_data_keys{$datum} = 'de'.$edi++;
1058         my $key = $root->addNewChild( $graphml_ns, 'key' );
1059         $key->setAttribute( 'attr.name', $datum );
1060         $key->setAttribute( 'attr.type', $edge_attributes{$datum} );
1061         $key->setAttribute( 'for', 'edge' );
1062         $key->setAttribute( 'id', $edge_data_keys{$datum} );
1063     }
1064
1065     # Add the collation graph itself. First, sanitize the name to a valid XML ID.
1066     my $xmlidname = $self->tradition->name;
1067     $xmlidname =~ s/(?!$xml10_namechar_rx)./_/g;
1068     if( $xmlidname !~ /^$xml10_namestartchar_rx/ ) {
1069         $xmlidname = '_'.$xmlidname;
1070     }
1071     my $sgraph = $root->addNewChild( $graphml_ns, 'graph' );
1072     $sgraph->setAttribute( 'edgedefault', 'directed' );
1073     $sgraph->setAttribute( 'id', $xmlidname );
1074     $sgraph->setAttribute( 'parse.edgeids', 'canonical' );
1075     $sgraph->setAttribute( 'parse.edges', 0 ); # fill in later
1076     $sgraph->setAttribute( 'parse.nodeids', 'canonical' );
1077     $sgraph->setAttribute( 'parse.nodes', 0 ); # fill in later
1078     $sgraph->setAttribute( 'parse.order', 'nodesfirst' );
1079
1080     # Tradition/collation attribute data
1081     foreach my $datum ( keys %graph_attributes ) {
1082         my $value;
1083         if( $datum eq 'version' ) {
1084                 $value = '3.2';
1085         } elsif( ref( $graph_attributes{$datum} ) ) {
1086                 my $sub = $graph_attributes{$datum};
1087                 $value = &$sub();
1088         } elsif( $gattr_from{$datum} eq 'Tradition' ) {
1089                 $value = $self->tradition->$datum;
1090         } else {
1091                 $value = $self->$datum;
1092         }
1093                 _add_graphml_data( $sgraph, $graph_data_keys{$datum}, $value );
1094         }
1095
1096     my $node_ctr = 0;
1097     my %node_hash;
1098     # Add our readings to the graph
1099     foreach my $n ( sort { $a->id cmp $b->id } $self->readings ) {
1100         next if $n->has_rank && $n ne $self->start && $n ne $self->end &&
1101                 ( $n->rank < $start->rank || $n->rank > $end->rank );
1102         $use_readings{$n->id} = 1;
1103         # Add to the main graph
1104         my $node_el = $sgraph->addNewChild( $graphml_ns, 'node' );
1105         my $node_xmlid = 'n' . $node_ctr++;
1106         $node_hash{ $n->id } = $node_xmlid;
1107         $node_el->setAttribute( 'id', $node_xmlid );
1108         foreach my $d ( keys %reading_attributes ) {
1109                 my $nval = $n->$d;
1110                 # Custom serialization
1111                 if( $d eq 'lexemes' ) {
1112                                 # If nval is a true value, we have lexemes so we need to
1113                                 # serialize them. Otherwise set nval to undef so that the
1114                                 # key is excluded from this reading.
1115                         $nval = $nval ? $n->_serialize_lexemes : undef;
1116                 } elsif( $d eq 'normal_form' && $n->normal_form eq $n->text ) {
1117                         $nval = undef;
1118                 }
1119                 if( $rankoffset && $d eq 'rank' && $n ne $self->start ) {
1120                         # Adjust the ranks within the subgraph.
1121                         $nval = $n eq $self->end ? $end->rank - $rankoffset + 1
1122                                 : $nval - $rankoffset;
1123                 }
1124                 _add_graphml_data( $node_el, $node_data_keys{$d}, $nval )
1125                         if defined $nval;
1126         }
1127     }
1128
1129     # Add the path edges to the sequence graph
1130     my $edge_ctr = 0;
1131     foreach my $e ( sort { $a->[0] cmp $b->[0] } $self->sequence->edges() ) {
1132         # We add an edge in the graphml for every witness in $e.
1133         next unless( $use_readings{$e->[0]} || $use_readings{$e->[1]} );
1134         my @edge_wits = sort $self->path_witnesses( $e );
1135         $e->[0] = $self->start->id unless $use_readings{$e->[0]};
1136         $e->[1] = $self->end->id unless $use_readings{$e->[1]};
1137         # Skip any path from start to end; that witness is not in the subgraph.
1138         next if ( $e->[0] eq $self->start->id && $e->[1] eq $self->end->id );
1139         foreach my $wit ( @edge_wits ) {
1140                         my( $id, $from, $to ) = ( 'e'.$edge_ctr++,
1141                                                                                 $node_hash{ $e->[0] },
1142                                                                                 $node_hash{ $e->[1] } );
1143                         my $edge_el = $sgraph->addNewChild( $graphml_ns, 'edge' );
1144                         $edge_el->setAttribute( 'source', $from );
1145                         $edge_el->setAttribute( 'target', $to );
1146                         $edge_el->setAttribute( 'id', $id );
1147
1148                         # It's a witness path, so add the witness
1149                         my $base = $wit;
1150                         my $key = $edge_data_keys{'witness'};
1151                         # Is this an ante-corr witness?
1152                         my $aclabel = $self->ac_label;
1153                         if( $wit =~ /^(.*)\Q$aclabel\E$/ ) {
1154                                 # Keep the base witness
1155                                 $base = $1;
1156                                 # ...and record that this is an 'extra' reading path
1157                                 _add_graphml_data( $edge_el, $edge_data_keys{'extra'}, $aclabel );
1158                         }
1159                         _add_graphml_data( $edge_el, $edge_data_keys{'witness'}, $base );
1160                 }
1161         }
1162
1163         # Report the actual number of nodes and edges that went in
1164         $sgraph->setAttribute( 'parse.edges', $edge_ctr );
1165         $sgraph->setAttribute( 'parse.nodes', $node_ctr );
1166
1167         # Add the relationship graph to the XML
1168         map { delete $edge_data_keys{$_} } @path_attributes;
1169         $self->relations->_as_graphml( $graphml_ns, $root, \%node_hash,
1170                 $node_data_keys{'id'}, \%edge_data_keys );
1171
1172     # Save and return the thing
1173     my $result = decode_utf8( $graphml->toString(1) );
1174     return $result;
1175 }
1176
1177 sub _add_graphml_data {
1178     my( $el, $key, $value ) = @_;
1179     return unless defined $value;
1180     my $data_el = $el->addNewChild( $el->namespaceURI, 'data' );
1181     $data_el->setAttribute( 'key', $key );
1182     $data_el->appendText( $value );
1183 }
1184
1185 =head2 as_csv
1186
1187 Returns a CSV alignment table representation of the collation graph, one
1188 row per witness (or witness uncorrected.)
1189
1190 =cut
1191
1192 sub as_csv {
1193     my( $self ) = @_;
1194     my $table = $self->alignment_table;
1195     my $csv = Text::CSV->new( { binary => 1, quote_null => 0 } );
1196     my @result;
1197     # Make the header row
1198     $csv->combine( map { $_->{'witness'} } @{$table->{'alignment'}} );
1199         push( @result, decode_utf8( $csv->string ) );
1200     # Make the rest of the rows
1201     foreach my $idx ( 0 .. $table->{'length'} - 1 ) {
1202         my @rowobjs = map { $_->{'tokens'}->[$idx] } @{$table->{'alignment'}};
1203         my @row = map { $_ ? $_->{'t'}->text : $_ } @rowobjs;
1204         $csv->combine( @row );
1205         push( @result, decode_utf8( $csv->string ) );
1206     }
1207     return join( "\n", @result );
1208 }
1209
1210 =head2 alignment_table( $use_refs, $include_witnesses )
1211
1212 Return a reference to an alignment table, in a slightly enhanced CollateX
1213 format which looks like this:
1214
1215  $table = { alignment => [ { witness => "SIGIL",
1216                              tokens => [ { t => "TEXT" }, ... ] },
1217                            { witness => "SIG2",
1218                              tokens => [ { t => "TEXT" }, ... ] },
1219                            ... ],
1220             length => TEXTLEN };
1221
1222 If $use_refs is set to 1, the reading object is returned in the table
1223 instead of READINGTEXT; if not, the text of the reading is returned.
1224
1225 If $include_witnesses is set to a hashref, only the witnesses whose sigil
1226 keys have a true hash value will be included.
1227
1228 =cut
1229
1230 sub alignment_table {
1231     my( $self ) = @_;
1232     $self->calculate_ranks() unless $self->_graphcalc_done;
1233     return $self->cached_table if $self->has_cached_table;
1234
1235     # Make sure we can do this
1236         throw( "Need a linear graph in order to make an alignment table" )
1237                 unless $self->linear;
1238         $self->calculate_ranks unless $self->end->has_rank;
1239
1240     my $table = { 'alignment' => [], 'length' => $self->end->rank - 1 };
1241     my @all_pos = ( 1 .. $self->end->rank - 1 );
1242     foreach my $wit ( sort { $a->sigil cmp $b->sigil } $self->tradition->witnesses ) {
1243         # say STDERR "Making witness row(s) for " . $wit->sigil;
1244         my @wit_path = $self->reading_sequence( $self->start, $self->end, $wit->sigil );
1245         my @row = _make_witness_row( \@wit_path, \@all_pos );
1246         push( @{$table->{'alignment'}},
1247                 { 'witness' => $wit->sigil, 'tokens' => \@row } );
1248         if( $wit->is_layered ) {
1249                 my @wit_ac_path = $self->reading_sequence( $self->start, $self->end,
1250                         $wit->sigil.$self->ac_label );
1251             my @ac_row = _make_witness_row( \@wit_ac_path, \@all_pos );
1252                         push( @{$table->{'alignment'}},
1253                                 { 'witness' => $wit->sigil.$self->ac_label, 'tokens' => \@ac_row } );
1254         }
1255     }
1256     $self->cached_table( $table );
1257     return $table;
1258 }
1259
1260 sub _make_witness_row {
1261     my( $path, $positions ) = @_;
1262     my %char_hash;
1263     map { $char_hash{$_} = undef } @$positions;
1264     my $debug = 0;
1265     foreach my $rdg ( @$path ) {
1266         say STDERR "rank " . $rdg->rank if $debug;
1267         # say STDERR "No rank for " . $rdg->id unless defined $rdg->rank;
1268         $char_hash{$rdg->rank} = { 't' => $rdg };
1269     }
1270     my @row = map { $char_hash{$_} } @$positions;
1271     # Fill in lacuna markers for undef spots in the row
1272     my $last_el = shift @row;
1273     my @filled_row = ( $last_el );
1274     foreach my $el ( @row ) {
1275         # If we are using node reference, make the lacuna node appear many times
1276         # in the table.  If not, use the lacuna tag.
1277         if( $last_el && $last_el->{'t'}->is_lacuna && !defined $el ) {
1278             $el = $last_el;
1279         }
1280         push( @filled_row, $el );
1281         $last_el = $el;
1282     }
1283     return @filled_row;
1284 }
1285
1286 =head1 NAVIGATION METHODS
1287
1288 =head2 reading_sequence( $first, $last, $sigil, $backup )
1289
1290 Returns the ordered list of readings, starting with $first and ending
1291 with $last, for the witness given in $sigil. If a $backup sigil is
1292 specified (e.g. when walking a layered witness), it will be used wherever
1293 no $sigil path exists.  If there is a base text reading, that will be
1294 used wherever no path exists for $sigil or $backup.
1295
1296 =cut
1297
1298 # TODO Think about returning some lazy-eval iterator.
1299 # TODO Get rid of backup; we should know from what witness is whether we need it.
1300
1301 sub reading_sequence {
1302     my( $self, $start, $end, $witness ) = @_;
1303
1304     $witness = $self->baselabel unless $witness;
1305     my @readings = ( $start );
1306     my %seen;
1307     my $n = $start;
1308     while( $n && $n->id ne $end->id ) {
1309         if( exists( $seen{$n->id} ) ) {
1310             throw( "Detected loop for $witness at " . $n->id );
1311         }
1312         $seen{$n->id} = 1;
1313
1314         my $next = $self->next_reading( $n, $witness );
1315         unless( $next ) {
1316             throw( "Did not find any path for $witness from reading " . $n->id );
1317         }
1318         push( @readings, $next );
1319         $n = $next;
1320     }
1321     # Check that the last reading is our end reading.
1322     my $last = $readings[$#readings];
1323     throw( "Last reading found from " . $start->text .
1324         " for witness $witness is not the end!" ) # TODO do we get this far?
1325         unless $last->id eq $end->id;
1326
1327     return @readings;
1328 }
1329
1330 =head2 next_reading( $reading, $sigil );
1331
1332 Returns the reading that follows the given reading along the given witness
1333 path.
1334
1335 =cut
1336
1337 sub next_reading {
1338     # Return the successor via the corresponding path.
1339     my $self = shift;
1340     my $answer = $self->_find_linked_reading( 'next', @_ );
1341         return undef unless $answer;
1342     return $self->reading( $answer );
1343 }
1344
1345 =head2 prior_reading( $reading, $sigil )
1346
1347 Returns the reading that precedes the given reading along the given witness
1348 path.
1349
1350 =cut
1351
1352 sub prior_reading {
1353     # Return the predecessor via the corresponding path.
1354     my $self = shift;
1355     my $answer = $self->_find_linked_reading( 'prior', @_ );
1356     return $self->reading( $answer );
1357 }
1358
1359 sub _find_linked_reading {
1360     my( $self, $direction, $node, $path ) = @_;
1361
1362     # Get a backup if we are dealing with a layered witness
1363     my $alt_path;
1364     my $aclabel = $self->ac_label;
1365     if( $path && $path =~ /^(.*)\Q$aclabel\E$/ ) {
1366         $alt_path = $1;
1367     }
1368
1369     my @linked_paths = $direction eq 'next'
1370         ? $self->sequence->edges_from( $node )
1371         : $self->sequence->edges_to( $node );
1372     return undef unless scalar( @linked_paths );
1373
1374     # We have to find the linked path that contains all of the
1375     # witnesses supplied in $path.
1376     my( @path_wits, @alt_path_wits );
1377     @path_wits = sort( $self->_witnesses_of_label( $path ) ) if $path;
1378     @alt_path_wits = sort( $self->_witnesses_of_label( $alt_path ) ) if $alt_path;
1379     my $base_le;
1380     my $alt_le;
1381     foreach my $le ( @linked_paths ) {
1382         if( $self->sequence->has_edge_attribute( @$le, $self->baselabel ) ) {
1383             $base_le = $le;
1384         }
1385                 my @le_wits = sort $self->path_witnesses( $le );
1386                 if( _is_within( \@path_wits, \@le_wits ) ) {
1387                         # This is the right path.
1388                         return $direction eq 'next' ? $le->[1] : $le->[0];
1389                 } elsif( _is_within( \@alt_path_wits, \@le_wits ) ) {
1390                         $alt_le = $le;
1391                 }
1392     }
1393     # Got this far? Return the alternate path if it exists.
1394     return $direction eq 'next' ? $alt_le->[1] : $alt_le->[0]
1395         if $alt_le;
1396
1397     # Got this far? Return the base path if it exists.
1398     return $direction eq 'next' ? $base_le->[1] : $base_le->[0]
1399         if $base_le;
1400
1401     # Got this far? We have no appropriate path.
1402     warn "Could not find $direction node from " . $node->id
1403         . " along path $path";
1404     return undef;
1405 }
1406
1407 # Some set logic.
1408 sub _is_within {
1409     my( $set1, $set2 ) = @_;
1410     my $ret = @$set1; # will be 0, i.e. false, if set1 is empty
1411     foreach my $el ( @$set1 ) {
1412         $ret = 0 unless grep { /^\Q$el\E$/ } @$set2;
1413     }
1414     return $ret;
1415 }
1416
1417 # Return the string that joins together a list of witnesses for
1418 # display on a single path.
1419 sub _witnesses_of_label {
1420     my( $self, $label ) = @_;
1421     my $regex = $self->wit_list_separator;
1422     my @answer = split( /\Q$regex\E/, $label );
1423     return @answer;
1424 }
1425
1426 =head2 common_readings
1427
1428 Returns the list of common readings in the graph (i.e. those readings that are
1429 shared by all non-lacunose witnesses.)
1430
1431 =cut
1432
1433 sub common_readings {
1434         my $self = shift;
1435         my @common = grep { $_->is_common } $self->readings;
1436         return @common;
1437 }
1438
1439 =head2 path_text( $sigil, [, $start, $end ] )
1440
1441 Returns the text of a witness (plus its backup, if we are using a layer)
1442 as stored in the collation.  The text is returned as a string, where the
1443 individual readings are joined with spaces and the meta-readings (e.g.
1444 lacunae) are omitted.  Optional specification of $start and $end allows
1445 the generation of a subset of the witness text.
1446
1447 =cut
1448
1449 sub path_text {
1450         my( $self, $wit, $start, $end ) = @_;
1451         $start = $self->start unless $start;
1452         $end = $self->end unless $end;
1453         my @path = grep { !$_->is_meta } $self->reading_sequence( $start, $end, $wit );
1454         my $pathtext = '';
1455         my $last;
1456         foreach my $r ( @path ) {
1457                 unless ( $r->join_prior || !$last || $last->join_next ) {
1458                         $pathtext .= ' ';
1459                 }
1460                 $pathtext .= $r->text;
1461                 $last = $r;
1462         }
1463         return $pathtext;
1464 }
1465
1466 =head1 INITIALIZATION METHODS
1467
1468 These are mostly for use by parsers.
1469
1470 =head2 make_witness_path( $witness )
1471
1472 Link the array of readings contained in $witness->path (and in
1473 $witness->uncorrected_path if it exists) into collation paths.
1474 Clear out the arrays when finished.
1475
1476 =head2 make_witness_paths
1477
1478 Call make_witness_path for all witnesses in the tradition.
1479
1480 =cut
1481
1482 # For use when a collation is constructed from a base text and an apparatus.
1483 # We have the sequences of readings and just need to add path edges.
1484 # When we are done, clear out the witness path attributes, as they are no
1485 # longer needed.
1486 # TODO Find a way to replace the witness path attributes with encapsulated functions?
1487
1488 sub make_witness_paths {
1489     my( $self ) = @_;
1490     foreach my $wit ( $self->tradition->witnesses ) {
1491         # say STDERR "Making path for " . $wit->sigil;
1492         $self->make_witness_path( $wit );
1493     }
1494 }
1495
1496 sub make_witness_path {
1497     my( $self, $wit ) = @_;
1498     my @chain = @{$wit->path};
1499     my $sig = $wit->sigil;
1500     # Add start and end if necessary
1501     unshift( @chain, $self->start ) unless $chain[0] eq $self->start;
1502     push( @chain, $self->end ) unless $chain[-1] eq $self->end;
1503     foreach my $idx ( 0 .. $#chain-1 ) {
1504         $self->add_path( $chain[$idx], $chain[$idx+1], $sig );
1505     }
1506     if( $wit->is_layered ) {
1507         @chain = @{$wit->uncorrected_path};
1508                 unshift( @chain, $self->start ) unless $chain[0] eq $self->start;
1509                 push( @chain, $self->end ) unless $chain[-1] eq $self->end;
1510         foreach my $idx( 0 .. $#chain-1 ) {
1511             my $source = $chain[$idx];
1512             my $target = $chain[$idx+1];
1513             $self->add_path( $source, $target, $sig.$self->ac_label )
1514                 unless $self->has_path( $source, $target, $sig );
1515         }
1516     }
1517     $wit->clear_path;
1518     $wit->clear_uncorrected_path;
1519 }
1520
1521 =head2 calculate_ranks
1522
1523 Calculate the reading ranks (that is, their aligned positions relative
1524 to each other) for the graph.  This can only be called on linear collations.
1525
1526 =begin testing
1527
1528 use Text::Tradition;
1529
1530 my $cxfile = 't/data/Collatex-16.xml';
1531 my $t = Text::Tradition->new(
1532     'name'  => 'inline',
1533     'input' => 'CollateX',
1534     'file'  => $cxfile,
1535     );
1536 my $c = $t->collation;
1537
1538 # Make an svg
1539 my $table = $c->alignment_table;
1540 ok( $c->has_cached_table, "Alignment table was cached" );
1541 is( $c->alignment_table, $table, "Cached table returned upon second call" );
1542 $c->calculate_ranks;
1543 is( $c->alignment_table, $table, "Cached table retained with no rank change" );
1544 $c->add_relationship( 'n24', 'n23', { 'type' => 'spelling' } );
1545 isnt( $c->alignment_table, $table, "Alignment table changed after relationship add" );
1546
1547 =end testing
1548
1549 =cut
1550
1551 sub calculate_ranks {
1552     my $self = shift;
1553     # Save the existing ranks, in case we need to invalidate the cached SVG.
1554     my %existing_ranks;
1555     map { $existing_ranks{$_} = $_->rank } $self->readings;
1556
1557     # Do the rankings based on the relationship equivalence graph, starting
1558     # with the start node.
1559     my ( $node_ranks, $rank_nodes ) = $self->relations->equivalence_ranks();
1560
1561     # Transfer our rankings from the topological graph to the real one.
1562     foreach my $r ( $self->readings ) {
1563         if( defined $node_ranks->{$self->equivalence( $r->id )} ) {
1564             $r->rank( $node_ranks->{$self->equivalence( $r->id )} );
1565         } else {
1566                 # Die. Find the last rank we calculated.
1567                 my @all_defined = sort { ( $node_ranks->{$self->equivalence( $a->id )}||-1 )
1568                                  <=> ( $node_ranks->{$self->equivalence( $b->id )}||-1 ) }
1569                         $self->readings;
1570                 my $last = pop @all_defined;
1571             throw( "Ranks not calculated after $last - do you have a cycle in the graph?" );
1572         }
1573     }
1574     # Do we need to invalidate the cached data?
1575     if( $self->has_cached_table ) {
1576         foreach my $r ( $self->readings ) {
1577                 next if defined( $existing_ranks{$r} )
1578                         && $existing_ranks{$r} == $r->rank;
1579                 # Something has changed, so clear the cache
1580                 $self->_clear_cache;
1581                         # ...and recalculate the common readings.
1582                         $self->calculate_common_readings();
1583                 last;
1584         }
1585     }
1586         # The graph calculation information is now up to date.
1587         $self->_graphcalc_done(1);
1588 }
1589
1590 sub _clear_cache {
1591         my $self = shift;
1592         $self->wipe_table if $self->has_cached_table;
1593 }
1594
1595
1596 =head2 flatten_ranks
1597
1598 A convenience method for parsing collation data.  Searches the graph for readings
1599 with the same text at the same rank, and merges any that are found.
1600
1601 =cut
1602
1603 sub flatten_ranks {
1604     my $self = shift;
1605     my %unique_rank_rdg;
1606     my $changed;
1607     foreach my $rdg ( $self->readings ) {
1608         next unless $rdg->has_rank;
1609         my $key = $rdg->rank . "||" . $rdg->text;
1610         if( exists $unique_rank_rdg{$key} ) {
1611                 # Make sure they don't have different grammatical forms
1612                         my $ur = $unique_rank_rdg{$key};
1613                 if( $rdg->is_identical( $ur ) ) {
1614                                 # Combine!
1615                                 #say STDERR "Combining readings at same rank: $key";
1616                                 $changed = 1;
1617                                 $self->merge_readings( $unique_rank_rdg{$key}, $rdg );
1618                                 # TODO see if this now makes a common point.
1619                         }
1620         } else {
1621             $unique_rank_rdg{$key} = $rdg;
1622         }
1623     }
1624     # If we merged readings, the ranks are still fine but the alignment
1625     # table is wrong. Wipe it.
1626     $self->wipe_table() if $changed;
1627 }
1628
1629
1630 =head2 calculate_common_readings
1631
1632 Goes through the graph identifying the readings that appear in every witness
1633 (apart from those with lacunae at that spot.) Marks them as common and returns
1634 the list.
1635
1636 =begin testing
1637
1638 use Text::Tradition;
1639
1640 my $cxfile = 't/data/Collatex-16.xml';
1641 my $t = Text::Tradition->new(
1642     'name'  => 'inline',
1643     'input' => 'CollateX',
1644     'file'  => $cxfile,
1645     );
1646 my $c = $t->collation;
1647
1648 my @common = $c->calculate_common_readings();
1649 is( scalar @common, 8, "Found correct number of common readings" );
1650 my @marked = sort $c->common_readings();
1651 is( scalar @common, 8, "All common readings got marked as such" );
1652 my @expected = qw/ n1 n11 n16 n19 n20 n5 n6 n7 /;
1653 is_deeply( \@marked, \@expected, "Found correct list of common readings" );
1654
1655 =end testing
1656
1657 =cut
1658
1659 sub calculate_common_readings {
1660         my $self = shift;
1661         my @common;
1662         map { $_->is_common( 0 ) } $self->readings;
1663         # Implicitly calls calculate_ranks
1664         my $table = $self->alignment_table;
1665         foreach my $idx ( 0 .. $table->{'length'} - 1 ) {
1666                 my @row = map { $_->{'tokens'}->[$idx]
1667                                                         ? $_->{'tokens'}->[$idx]->{'t'} : '' }
1668                                         @{$table->{'alignment'}};
1669                 my %hash;
1670                 foreach my $r ( @row ) {
1671                         if( $r ) {
1672                                 $hash{$r->id} = $r unless $r->is_meta;
1673                         } else {
1674                                 $hash{'UNDEF'} = $r;
1675                         }
1676                 }
1677                 if( keys %hash == 1 && !exists $hash{'UNDEF'} ) {
1678                         my( $r ) = values %hash;
1679                         $r->is_common( 1 );
1680                         push( @common, $r );
1681                 }
1682         }
1683         return @common;
1684 }
1685
1686 =head2 text_from_paths
1687
1688 Calculate the text array for all witnesses from the path, for later consistency
1689 checking.  Only to be used if there is no non-graph-based way to know the
1690 original texts.
1691
1692 =cut
1693
1694 sub text_from_paths {
1695         my $self = shift;
1696     foreach my $wit ( $self->tradition->witnesses ) {
1697         my @readings = $self->reading_sequence( $self->start, $self->end, $wit->sigil );
1698         my @text;
1699         foreach my $r ( @readings ) {
1700                 next if $r->is_meta;
1701                 push( @text, $r->text );
1702         }
1703         $wit->text( \@text );
1704         if( $wit->is_layered ) {
1705                         my @ucrdgs = $self->reading_sequence( $self->start, $self->end,
1706                                                                                                   $wit->sigil.$self->ac_label );
1707                         my @uctext;
1708                         foreach my $r ( @ucrdgs ) {
1709                                 next if $r->is_meta;
1710                                 push( @uctext, $r->text );
1711                         }
1712                         $wit->layertext( \@uctext );
1713         }
1714     }
1715 }
1716
1717 =head1 UTILITY FUNCTIONS
1718
1719 =head2 common_predecessor( $reading_a, $reading_b )
1720
1721 Find the last reading that occurs in sequence before both the given readings.
1722 At the very least this should be $self->start.
1723
1724 =head2 common_successor( $reading_a, $reading_b )
1725
1726 Find the first reading that occurs in sequence after both the given readings.
1727 At the very least this should be $self->end.
1728
1729 =begin testing
1730
1731 use Text::Tradition;
1732
1733 my $cxfile = 't/data/Collatex-16.xml';
1734 my $t = Text::Tradition->new(
1735     'name'  => 'inline',
1736     'input' => 'CollateX',
1737     'file'  => $cxfile,
1738     );
1739 my $c = $t->collation;
1740
1741 is( $c->common_predecessor( 'n24', 'n23' )->id,
1742     'n20', "Found correct common predecessor" );
1743 is( $c->common_successor( 'n24', 'n23' )->id,
1744     '__END__', "Found correct common successor" );
1745
1746 is( $c->common_predecessor( 'n19', 'n17' )->id,
1747     'n16', "Found correct common predecessor for readings on same path" );
1748 is( $c->common_successor( 'n21', 'n10' )->id,
1749     '__END__', "Found correct common successor for readings on same path" );
1750
1751 =end testing
1752
1753 =cut
1754
1755 ## Return the closest reading that is a predecessor of both the given readings.
1756 sub common_predecessor {
1757         my $self = shift;
1758         my( $r1, $r2 ) = $self->_objectify_args( @_ );
1759         return $self->_common_in_path( $r1, $r2, 'predecessors' );
1760 }
1761
1762 sub common_successor {
1763         my $self = shift;
1764         my( $r1, $r2 ) = $self->_objectify_args( @_ );
1765         return $self->_common_in_path( $r1, $r2, 'successors' );
1766 }
1767
1768
1769 # TODO think about how to do this without ranks...
1770 sub _common_in_path {
1771         my( $self, $r1, $r2, $dir ) = @_;
1772         my $iter = $self->end->rank;
1773         my @candidates;
1774         my @last_r1 = ( $r1 );
1775         my @last_r2 = ( $r2 );
1776         # my %all_seen = ( $r1 => 'r1', $r2 => 'r2' );
1777         my %all_seen;
1778         # say STDERR "Finding common $dir for $r1, $r2";
1779         while( !@candidates ) {
1780                 last unless $iter--;  # Avoid looping infinitely
1781                 # Iterate separately down the graph from r1 and r2
1782                 my( @new_lc1, @new_lc2 );
1783                 foreach my $lc ( @last_r1 ) {
1784                         foreach my $p ( $lc->$dir ) {
1785                                 if( $all_seen{$p->id} && $all_seen{$p->id} ne 'r1' ) {
1786                                         # say STDERR "Path candidate $p from $lc";
1787                                         push( @candidates, $p );
1788                                 } elsif( !$all_seen{$p->id} ) {
1789                                         $all_seen{$p->id} = 'r1';
1790                                         push( @new_lc1, $p );
1791                                 }
1792                         }
1793                 }
1794                 foreach my $lc ( @last_r2 ) {
1795                         foreach my $p ( $lc->$dir ) {
1796                                 if( $all_seen{$p->id} && $all_seen{$p->id} ne 'r2' ) {
1797                                         # say STDERR "Path candidate $p from $lc";
1798                                         push( @candidates, $p );
1799                                 } elsif( !$all_seen{$p->id} ) {
1800                                         $all_seen{$p->id} = 'r2';
1801                                         push( @new_lc2, $p );
1802                                 }
1803                         }
1804                 }
1805                 @last_r1 = @new_lc1;
1806                 @last_r2 = @new_lc2;
1807         }
1808         my @answer = sort { $a->rank <=> $b->rank } @candidates;
1809         return $dir eq 'predecessors' ? pop( @answer ) : shift ( @answer );
1810 }
1811
1812 sub throw {
1813         Text::Tradition::Error->throw(
1814                 'ident' => 'Collation error',
1815                 'message' => $_[0],
1816                 );
1817 }
1818
1819 no Moose;
1820 __PACKAGE__->meta->make_immutable;
1821
1822 =head1 BUGS/TODO
1823
1824 =over
1825
1826 =item * Rework XML serialization in a more modular way
1827
1828 =back
1829
1830 =head1 LICENSE
1831
1832 This package is free software and is provided "as is" without express
1833 or implied warranty.  You can redistribute it and/or modify it under
1834 the same terms as Perl itself.
1835
1836 =head1 AUTHOR
1837
1838 Tara L Andrews E<lt>aurum@cpan.orgE<gt>