Porting/makemeta

   1 #!./perl -w
   2 # this script must be run by the current perl to get perl's version right
   3 #
   4 # Create a META.yml file in the current directory. Must be run from the
   5 # root directory of a perl source tree.
   6
   7 use strict;
   8 use warnings;
   9 use lib "Porting";
  10
  11 use File::Basename qw( dirname );
  12
  13 my $file = "META.yml";
  14 die "$0: will not override $file, delete it first.\n" if -e $file;
  15
  16 use Maintainers qw(%Modules get_module_files get_module_pat);
  17
  18 my @CPAN  = grep { $Modules{$_}{CPAN} } keys %Modules;
  19 my @files = ('lib/unicore/mktables', 'TestInit.pm',
  20              'Porting/Maintainers.pm', 'Porting/perldelta_template.pod',
  21              map { get_module_files($_) } @CPAN);
  22 my @dirs  = ('cpan', 'win32', grep { -d $_ && $_  !~ /^cpan/ } map { get_module_pat($_) } @CPAN);
  23
  24 my %dirs;
  25 @dirs{@dirs} = ();
  26
  27 my $files = join '', map { "    - $_\n" }
  28   grep {
  29     my $d = $_;
  30     while(($d = dirname($d)) ne "."){
  31       last if exists $dirs{$d};
  32     }
  33
  34     # if $d is "." it means we tried every parent dir of the file and none
  35     # of them were in the private list
  36
  37     $d eq ".";
  38   }
  39   sort { lc $a cmp lc $b } @files;
  40
  41 my $dirs  = join '', map { "    - $_\n" } sort { lc $a cmp lc $b } @dirs;
  42
  43 open my $fh, ">$file" or die "Can't open $file: $!";
  44
  45 print $fh <<"EOI";
  46 name: perl
  47 version: $]
  48 abstract: Practical Extraction and Report Language
  49 author: perl5-porters\@perl.org
  50 license: perl
  51 resources:
  52   homepage: http://www.perl.org/
  53   bugtracker: http://rt.perl.org/perlbug/
  54   license: http://dev.perl.org/licenses/
  55   repository: http://perl5.git.perl.org/
  56 distribution_type: core
  57 generated_by: $0
  58 no_index:
  59   directory:
  60 $dirs
  61   file:
  62 $files
  63 EOI
  64
  65 close $fh;
  66