Porting/findrfuncs

   1 #!/usr/bin/perl -w
   2
   3 #
   4 # findrfuncs: find reentrant variants of functions used in an executable.
   5 # Requires a functional "nm -u".  Searches headers in /usr/include
   6 # to find available *_r functions and looks for non-reentrant
   7 # variants used in the supplied executable.
   8 #
   9 # Gurusamy Sarathy
  10 # gsar@ActiveState.com
  11 #
  12 # Hacked to automatically find the executable and shared objects.
  13 # --jhi
  14
  15 use strict;
  16 use File::Find;
  17
  18 my @EXES;
  19 my $NMU = 'nm -u';
  20 my @INCDIRS = qw(/usr/include);
  21 my $SO = 'so';
  22 my $EXE = '';
  23
  24 if (open(CONFIG, "config.sh")) {
  25     local $/;
  26     my $CONFIG = <CONFIG>;
  27     $SO  = $1 if $CONFIG =~ /^so='(\w+)'/m;
  28     $EXE = $1 if $CONFIG =~ /^_exe='\.(\w+)'/m;
  29     close(CONFIG);
  30 }
  31
  32 push @EXES, "perl$EXE";
  33
  34 find(sub {push @EXES, $File::Find::name if /.$SO$/}, '.' );
  35
  36 push @EXES, @ARGV;
  37
  38 if ($^O eq 'dec_osf') {
  39     $NMU = 'nm -Bu';
  40 } elsif ($^O eq 'irix') {
  41     $NMU = 'nm -pu';
  42 }
  43
  44 my %rfuncs;
  45 my @syms;
  46 find(sub {
  47         return unless -f $File::Find::name;
  48         open my $F, "<$File::Find::name"
  49             or die "Can't open $File::Find::name: $!";
  50         my $line;
  51         while (defined ($line = <$F>)) {
  52             if ($line =~ /\b(\w+_r)\b/) {
  53                 #warn "$1 => $File::Find::name\n";
  54                 $rfuncs{$1}->{$File::Find::name}++;
  55             }
  56         }
  57         close $F;
  58      }, @INCDIRS);
  59
  60 # delete bogus symbols grepped out of comments and such
  61 delete $rfuncs{setlocale_r} if $^O eq 'linux';
  62
  63 my %syms;
  64
  65 for my $exe (@EXES) {
  66     # warn "#--- $exe\n";
  67     for my $sym (`$NMU $exe`) {
  68         chomp $sym;
  69         $sym =~ s/^\s+//;
  70         $sym =~ s/^([0-9A-Fa-f]+\s+)?[Uu]\s+//;
  71         next if /\s/;
  72         $sym =~ s/\@.*\z//;     # remove @@GLIBC_2.0 etc
  73         # warn "#### $sym\n";
  74         if (exists $rfuncs{"${sym}_r"} && ! $syms{"$sym:$exe"}++) {
  75             push @syms, $sym;
  76         }
  77     }
  78
  79     if (@syms) {
  80         print "\nFollowing symbols in $exe have reentrant versions:\n";
  81         for my $sym (@syms) {
  82             my @f = sort keys %{$rfuncs{$sym . '_r'}};
  83             print "$sym => $sym" . "_r (@f)\n";
  84         }
  85     }
  86     @syms = ();
  87 }
  88