Porting/cmpVERSION.pl

   1 #!/usr/bin/perl -w
   2
   3 #
   4 # cmpVERSION - compare two Perl source trees for modules
   5 # that have identical version numbers but different contents.
   6 #
   7 # Original by slaven@rezic.de, modified by jhi.
   8 #
   9
  10 use strict;
  11
  12 use ExtUtils::MakeMaker;
  13 use File::Compare;
  14 use File::Find;
  15 use File::Spec::Functions qw(rel2abs abs2rel catfile catdir curdir);
  16
  17 for (@ARGV[0, 1]) {
  18     die "$0: '$_' does not look like Perl directory\n"
  19         unless -f catfile($_, "perl.h") && -d catdir($_, "Porting");
  20 }
  21
  22 my $dir2 = rel2abs($ARGV[1]);
  23 chdir $ARGV[0] or die "$0: chdir '$ARGV[0]' failed: $!\n";
  24
  25 # Files to skip from the check for one reason or another,
  26 # usually because they pull in their version from some other file.
  27 my %skip;
  28 @skip{
  29     './lib/Carp/Heavy.pm',
  30     './lib/Exporter/Heavy.pm',
  31     './win32/FindExt.pm'
  32 } = ();
  33 my $skip_dirs = qr|^\./t/lib|;
  34
  35 my @wanted;
  36 find(
  37      sub { /\.pm$/ &&
  38                $File::Find::dir !~ $skip_dirs &&
  39                ! exists $skip{$File::Find::name}
  40                &&
  41                do { my $file2 =
  42                         catfile(catdir($dir2, $File::Find::dir), $_);
  43                     (my $xs_file1 = $_)     =~ s/\.pm$/.xs/;
  44                     (my $xs_file2 = $file2) =~ s/\.pm$/.xs/;
  45                     if (-e $xs_file1 && -e $xs_file2) {
  46                         return if compare($_, $file2) == 0 &&
  47                                   compare($xs_file1, $xs_file2) == 0;
  48                     } else {
  49                         return if compare($_, $file2) == 0;
  50                     }
  51                     my $version1 = eval {MM->parse_version($_)};
  52                     my $version2 = eval {MM->parse_version($file2)};
  53                     push @wanted, $File::Find::name
  54                         if defined $version1 &&
  55                            defined $version2 &&
  56                            $version1 eq $version2
  57                 } }, curdir);
  58 print map { $_, "\n" } sort @wanted;
  59