Porting/checkcfgvar.pl

   1 #!/usr/bin/perl -w
   2
   3 #
   4 # Check that the various config.sh-clones have (at least) all the
   5 # same symbols as the top-level config_h.SH so that the (potentially)
   6 # needed symbols are not lagging after how Configure thinks the world
   7 # is laid out.
   8 #
   9 # VMS is probably not handled properly here, due to their own
  10 # rather elaborate DCL scripting.
  11 #
  12
  13 use strict;
  14
  15 my $MASTER_CFG = "config_h.SH";
  16 my %MASTER_CFG;
  17
  18 my @CFG = (
  19            # This list contains both 5.8.x and 5.9.x files,
  20            # we check from MANIFEST whether they are expected to be present.
  21            # We can't base our check on $], because that's the version of the
  22            # perl that we are running, not the version of the source tree.
  23            "Cross/config.sh-arm-linux",
  24            "epoc/config.sh",
  25            "NetWare/config.wc",
  26            "symbian/config.sh",
  27            "uconfig.sh",
  28            "plan9/config_sh.sample",
  29            "vos/config.alpha.def",
  30            "vos/config.ga.def",
  31            "win32/config.bc",
  32            "win32/config.gc",
  33            "win32/config.vc",
  34            "win32/config.vc64",
  35            "win32/config.ce",
  36            "configure.com",
  37           );
  38
  39 sub read_file {
  40     my ($fn, $sub) = @_;
  41     if (open(my $fh, $fn)) {
  42         local $_;
  43         while (<$fh>) {
  44             &$sub;
  45         }
  46     } else {
  47         die "$0: Failed to open '$fn' for reading: $!\n";
  48     }
  49 }
  50
  51 sub config_h_SH_reader {
  52     my $cfg = shift;
  53     return sub {
  54         while (/[^\\]\$([a-z]\w+)/g) {
  55             my $v = $1;
  56             next if $v =~ /^(CONFIG_H|CONFIG_SH)$/;
  57             $cfg->{$v}++;
  58         }
  59     }
  60 }
  61
  62 read_file($MASTER_CFG,
  63           config_h_SH_reader(\%MASTER_CFG));
  64
  65 my %MANIFEST;
  66
  67 read_file("MANIFEST",
  68           sub {
  69               $MANIFEST{$1}++ if /^(.+?)\t/;
  70           });
  71
  72 my @MASTER_CFG = sort keys %MASTER_CFG;
  73
  74 sub check_cfg {
  75     my ($fn, $cfg) = @_;
  76     for my $v (@MASTER_CFG) {
  77         print "$fn: missing '$v'\n" unless exists $cfg->{$v};
  78     }
  79 }
  80
  81 for my $cfg (@CFG) {
  82     unless (exists $MANIFEST{$cfg}) {
  83         print "[skipping not-expected '$cfg']\n";
  84         next;
  85     }
  86     my %cfg;
  87     read_file($cfg,
  88               sub {
  89                   return if /^\#/ || /^\s*$/;
  90                   if ($cfg eq 'configure.com') {
  91                       s/(\s*!.*|\s*)$//; # remove trailing comments or whitespace
  92                       return if ! /^\$\s+WC "(\w+)='(.*)'"$/;
  93                   }
  94                   # foo='bar'
  95                   # foo=bar
  96                   # $foo='bar' # VOS 5.8.x specialty
  97                   # $foo=bar   # VOS 5.8.x specialty
  98                   if (/^\$?(\w+)='(.*)'$/) {
  99                       $cfg{$1}++;
 100                   }
 101                   elsif (/^\$?(\w+)=(.*)$/) {
 102                       $cfg{$1}++;
 103                   }
 104                   elsif (/^\$\s+WC "(\w+)='(.*)'"$/) {
 105                       $cfg{$1}++;
 106                   } else {
 107                       warn "$cfg:$.:$_";
 108                   }
 109               });
 110     if ($cfg eq 'configure.com') {
 111         $cfg{startperl}++; # Cheat.
 112     }
 113     check_cfg($cfg, \%cfg);
 114 }