Makefile.PL

   1 use strict;
   2 use warnings FATAL => 'all';
   3 use ExtUtils::MakeMaker;
   4 (do 'maint/Makefile.PL.include' or die $@) unless -f 'META.yml';
   5
   6 my %WriteMakefileArgs = (
   7   NAME => 'JSON::MaybeXS',
   8   VERSION_FROM => 'lib/JSON/MaybeXS.pm',
   9
  10   META_MERGE => {
  11     'meta-spec' => { version => 2 },
  12     dynamic_config => 1,
  13     resources => {
  14       repository => {
  15         url => 'https://github.com/karenetheridge/JSON-MaybeXS.git',
  16         web => 'https://github.com/karenetheridge/JSON-MaybeXS',
  17         type => 'git',
  18       },
  19       bugtracker => {
  20         mailto => 'bug-JSON-MaybeXS@rt.cpan.org',
  21         web => 'https://rt.cpan.org/Public/Dist/Display.html?Name=JSON-MaybeXS',
  22       },
  23     },
  24   },
  25
  26   META_ADD => {
  27     prereqs => {
  28       configure => {
  29         requires => {
  30           'ExtUtils::MakeMaker' => '0',
  31           'ExtUtils::CBuilder' => '0.27',
  32           'File::Spec' => '0',
  33           'File::Temp' => '0',
  34         },
  35       },
  36       runtime => {
  37         requires => {
  38           'JSON::PP' => '2.27202',
  39           # we may also add a runtime prereq for Cpanel::JSON::XS, on the
  40           # installer's machine
  41           perl => '5.006',
  42         },
  43         recommends => { 'Cpanel::JSON::XS' => '2.3310' },
  44       },
  45       test => {
  46         requires => {
  47           'Test::Without::Module' => '0.17',
  48           'Test::More' => '0.88',
  49         },
  50       },
  51     },
  52   },
  53
  54   realclean => { FILES => [ 'Distar/', 'MANIFEST*' ] },
  55 );
  56
  57 my $eumm_version  = eval $ExtUtils::MakeMaker::VERSION;
  58
  59 for (qw(configure build test runtime)) {
  60   my $key = $_ eq 'runtime' ? 'PREREQ_PM' : uc $_.'_REQUIRES';
  61   next unless exists $WriteMakefileArgs{META_ADD}{prereqs}{$_}
  62            or exists $WriteMakefileArgs{$key};
  63   my $r = $WriteMakefileArgs{$key} = {
  64     %{$WriteMakefileArgs{META_ADD}{prereqs}{$_}{requires} || {}},
  65     %{delete $WriteMakefileArgs{$key} || {}},
  66   };
  67   defined $r->{$_} or delete $r->{$_} for keys %$r;
  68 }
  69
  70 # we require Cpanel::JSON::XS, except if JSON::XS is already installed.
  71 # (we also always recommend Cpanel::JSON::XS, just to make sure.)
  72 $WriteMakefileArgs{PREREQ_PM}{'Cpanel::JSON::XS'} = '2.3310'
  73     if can_xs() && !eval { require JSON::XS; 1; };
  74
  75 $WriteMakefileArgs{MIN_PERL_VERSION} = delete $WriteMakefileArgs{PREREQ_PM}{perl} || 0;
  76
  77 $WriteMakefileArgs{BUILD_REQUIRES} = {
  78     %{$WriteMakefileArgs{BUILD_REQUIRES} || {}},
  79     %{delete $WriteMakefileArgs{TEST_REQUIRES}}
  80 } if $eumm_version < 6.63_03;
  81
  82 $WriteMakefileArgs{PREREQ_PM} = {
  83     %{$WriteMakefileArgs{PREREQ_PM}},
  84     %{delete $WriteMakefileArgs{BUILD_REQUIRES}}
  85 } if $eumm_version < 6.55_01;
  86
  87 delete $WriteMakefileArgs{CONFIGURE_REQUIRES}
  88   if $eumm_version < 6.51_03;
  89
  90 delete $WriteMakefileArgs{MIN_PERL_VERSION}
  91   if $eumm_version < 6.48;
  92
  93 delete @WriteMakefileArgs{qw(META_ADD META_MERGE)}
  94   if $eumm_version < 6.46;
  95
  96 delete $WriteMakefileArgs{LICENSE}
  97   if $eumm_version < 6.31;
  98
  99 WriteMakefile(%WriteMakefileArgs);
 100
 101 # can we locate a (the) C compiler
 102 sub can_cc {
 103   my @chunks = split(/ /, $Config::Config{cc}) or return;
 104
 105   # $Config{cc} may contain args; try to find out the program part
 106   while (@chunks) {
 107     return can_run("@chunks") || (pop(@chunks), next);
 108   }
 109
 110   return;
 111 }
 112
 113 # check if we can run some command
 114 sub can_run {
 115   my ($cmd) = @_;
 116
 117   return $cmd if -x $cmd;
 118   if (my $found_cmd = MM->maybe_command($cmd)) {
 119     return $found_cmd;
 120   }
 121
 122   require File::Spec;
 123   for my $dir ((split /$Config::Config{path_sep}/, $ENV{PATH}), '.') {
 124     next if $dir eq '';
 125     my $abs = File::Spec->catfile($dir, $cmd);
 126     return $abs if (-x $abs or $abs = MM->maybe_command($abs));
 127   }
 128
 129   return;
 130 }
 131
 132 # Can our C compiler environment build XS files
 133 sub can_xs {
 134   # Do we have the configure_requires checker?
 135   local $@;
 136   eval "require ExtUtils::CBuilder; ExtUtils::CBuilder->VERSION(0.27)";
 137   if ( $@ ) {
 138     # They don't obey configure_requires, so it is
 139     # someone old and delicate. Try to avoid hurting
 140     # them by falling back to an older simpler test.
 141     return can_cc();
 142   }
 143
 144   # Do we have a working C compiler
 145   my $builder = ExtUtils::CBuilder->new(
 146     quiet => 1,
 147   );
 148   unless ( $builder->have_compiler ) {
 149     # No working C compiler
 150     return 0;
 151   }
 152
 153   # Write a C file representative of what XS becomes
 154   require File::Temp;
 155   my ( $FH, $tmpfile ) = File::Temp::tempfile(
 156     "compilexs-XXXXX",
 157     SUFFIX => '.c',
 158   );
 159   binmode $FH;
 160   print $FH <<'END_C';
 161 #include "EXTERN.h"
 162 #include "perl.h"
 163 #include "XSUB.h"
 164
 165 int main(int argc, char **argv) {
 166     return 0;
 167 }
 168
 169 int boot_sanexs() {
 170     return 1;
 171 }
 172
 173 END_C
 174   close $FH;
 175
 176   # Can the C compiler access the same headers XS does
 177   my @libs   = ();
 178   my $object = undef;
 179   eval {
 180     local $^W = 0;
 181     $object = $builder->compile(
 182       source => $tmpfile,
 183     );
 184     @libs = $builder->link(
 185       objects     => $object,
 186       module_name => 'sanexs',
 187     );
 188   };
 189   my $result = $@ ? 0 : 1;
 190
 191   # Clean up all the build files
 192   foreach ( $tmpfile, $object, @libs ) {
 193     next unless defined $_;
 194     1 while unlink;
 195   }
 196
 197   return $result;
 198 }