Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN {
   7   # needs to happen early for old EUMM
   8   makemaker_args( NORECURS => 1 );
   9
  10   local @INC = ('lib', @INC);
  11   require DBIx::Class::Optional::Dependencies;
  12 }
  13
  14 ##
  15 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  16 ##
  17 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  18 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  19 # for that)
  20 BEGIN {
  21   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  22 }
  23
  24 name         'DBIx-Class';
  25 version_from 'lib/DBIx/Class.pm';
  26 perl_version '5.008001';
  27
  28 ###
  29 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  30 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  31 ###
  32 my $runtime_requires = {
  33
  34   # DBI itself should be capable of installation and execution in pure-perl
  35   # mode. However it has never been tested yet, so consider XS for the time
  36   # being
  37 ###
  38 ### IMPORTANT - do not raise this dependency
  39 ### even though many bugfixes are present in newer versions, the general DBIC
  40 ### rule is to bend over backwards for available DBI versions (given upgrading
  41 ### them is often *not* easy or even possible)
  42 ###
  43   'DBI'                      => '1.57',
  44
  45   # on older versions first() leaks
  46   # for the time being make it a hard dep - when we get
  47   # rid of Sub::Name will revisit this (possibility is
  48   # to use Devel::HideXS to force the pure-perl version
  49   # or something like that)
  50   'List::Util'               => '1.16',
  51
  52   # XS (or XS-dependent) libs
  53   'Sub::Name'                => '0.04',
  54
  55   # pure-perl (FatPack-able) libs
  56   'Class::Accessor::Grouped' => '0.10012',
  57   'Class::C3::Componentised' => '1.0009',
  58   'Class::Inspector'         => '1.24',
  59   'Config::Any'              => '0.20',
  60   'Context::Preserve'        => '0.01',
  61   'Data::Dumper::Concise'    => '2.020',
  62   'Data::Page'               => '2.00',
  63   'Devel::GlobalDestruction' => '0.09',
  64   'Hash::Merge'              => '0.12',
  65   'Moo'                      => '2.000',
  66   'MRO::Compat'              => '0.12',
  67   'Module::Find'             => '0.07',
  68   'namespace::clean'         => '0.24',
  69   'Path::Class'              => '0.18',
  70   'Scope::Guard'             => '0.03',
  71   'SQL::Abstract'            => '1.81',
  72   'Try::Tiny'                => '0.07',
  73
  74   # Technically this is not a core dependency - it is only required
  75   # by the MySQL codepath. However this particular version is bundled
  76   # since 5.10.0 and is a pure-perl module anyway - let it slide
  77   'Text::Balanced'           => '2.00',
  78 };
  79
  80 my $build_requires = {
  81 };
  82
  83 my $test_requires = {
  84   'File::Temp'               => '0.22',
  85   'Test::Deep'               => '0.101',
  86   'Test::Exception'          => '0.31',
  87   'Test::Warn'               => '0.21',
  88   'Test::More'               => '0.94',
  89
  90   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
  91   # remove and do a manual glob-collection if n::c is no longer a dep
  92   'Package::Stash'           => '0.28',
  93
  94   # needed for testing only, not for operation
  95   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  96   %{ DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_sqlite') },
  97 };
  98
  99 # if the user has this env var set and no SQLT installed, tests will fail
 100 # Note - this is added as test_requires *directly*, so it gets properly
 101 # excluded on META.yml cleansing (even though no dist can be created from this)
 102 # we force this req regarless of author_deps, worst case scenario it will
 103 # be specified twice
 104 #
 105 # also note that we *do* set dynamic_config => 0, as this is the only thing
 106 # that we determine dynamically, and in all fairness if someone sets the
 107 # envvar *and* is not running a full Makefile/make/maketest cycle - they get
 108 # to keep the pieces
 109 if ($ENV{DBICTEST_SQLT_DEPLOY}) {
 110   my $deploy_req = DBIx::Class::Optional::Dependencies->req_list_for('deploy');
 111   for (keys %$deploy_req) {
 112     test_requires ($_ => $deploy_req->{$_})
 113   }
 114 }
 115
 116 tests_recursive (
 117   't',
 118   ( (
 119     $Module::Install::AUTHOR
 120       or
 121     $ENV{DBICTEST_RUN_ALL_TESTS}
 122       or
 123     ( $ENV{TRAVIS}||'' ) eq 'true'
 124       or
 125     ( $ENV{AUTOMATED_TESTING} and ! $ENV{PERL5_CPANM_IS_RUNNING} and ! $ENV{RELEASE_TESTING} )
 126   ) ? 'xt' : () ),
 127 );
 128
 129 install_script (qw|
 130     script/dbicadmin
 131 |);
 132
 133 # this is so we can order requires alphabetically
 134 # copies are needed for potential author requires injection
 135 my $reqs = {
 136   build_requires => { %$build_requires },
 137   requires => { %$runtime_requires },
 138   test_requires => { %$test_requires },
 139 };
 140
 141 # only do author-includes if not part of a `make` run
 142 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 143   invoke_author_mode()
 144 }
 145 else {
 146   # make sure this Makefile can not be used to make a dist
 147   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 148   postamble <<EOP;
 149 create_distdir: nonauthor_stop_distdir_creation
 150 nonauthor_stop_distdir_creation:
 151 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 152 \t\$(NOECHO) \$(FALSE)
 153 EOP
 154 }
 155
 156 # compose final req list, for alphabetical ordering
 157 my %final_req;
 158 for my $rtype (keys %$reqs) {
 159   for my $mod (keys %{$reqs->{$rtype}} ) {
 160
 161     # sanity check req duplications
 162     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 163       if $final_req{$mod};
 164
 165     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 166   }
 167 }
 168
 169 # actual require
 170 for my $mod (sort keys %final_req) {
 171   my ($rtype, $ver) = @{$final_req{$mod}};
 172   no strict 'refs';
 173   $rtype->($mod, $ver);
 174 }
 175
 176 # author-mode or not - this is where we show a list of missing deps
 177 # IFF we are running interactively
 178 auto_install();
 179
 180 {
 181   # M::I understands unicode in meta but does not write with the right
 182   # layers - fhtagn!!!
 183   local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /Wide character in print/ };
 184   WriteAll();
 185 }
 186
 187 exit 0;
 188
 189
 190 ###
 191 ### Nothing user-serviceable beyond this point
 192 ### (none of this executes on regular install)
 193 ###
 194
 195
 196 # needs to be here to keep 5.8 string eval happy
 197 # (the include of Makefile.PL.inc loop)
 198 my $mm_proto;
 199
 200 sub invoke_author_mode {
 201   # get options here, make $args available to all snippets
 202   require Getopt::Long;
 203   my $getopt = Getopt::Long::Parser->new(
 204     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 205   );
 206   my $args = {
 207     skip_author_deps => undef,
 208   };
 209   $getopt->getoptions($args, qw/
 210     skip_author_deps|skip-author-deps
 211   /);
 212   if (@ARGV) {
 213     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 214   }
 215
 216   # We need the MM facilities to generate the pieces for the final MM run.
 217   # Just instantiate a throaway object here
 218   #
 219   # Also EUMM and MI disagree on what is the format of Meta->name, just
 220   # punt here until a new M::I is shipped (if at all)
 221   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 222   $name =~ s/\-/::/g;
 223   $mm_proto = ExtUtils::MakeMaker->new({
 224     NORECURS => 1,
 225     NAME => $name,
 226   });
 227
 228   # Crutch for DISTBUILDING_IN_HELL
 229   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 230   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 231   # not take into account the CRLF layer present on win32
 232   my $crlf_fixup = sub {
 233     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 234     my $targets = join ', ', map { "q($_)" } @_;
 235     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 236   };
 237
 238   # we are in the process of (re)writing the makefile - some things we
 239   # call below very well may fail
 240   local $ENV{DBICTEST_NO_MAKEFILE_VERIFICATION} = 1;
 241
 242   require File::Spec;
 243   # string-eval, not do(), because we need to provide the
 244   # $mm_proto, $reqs and $*_requires lexicals to the included file
 245   # (some includes *do* modify $reqs above)
 246   for my $inc (sort glob ( File::Spec->catfile('maint', 'Makefile.PL.inc', '*') ) ) {
 247     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 248     eval "use warnings; use strict; $src" or die sprintf
 249       "Failed execution of %s: %s\n",
 250       $inc,
 251       ($@ || $! || 'Unknown error'),
 252     ;
 253   }
 254 }