Makefile.PL

   1 use inc::Module::Install 1.00;
   2 use strict;
   3 use warnings;
   4
   5 use 5.008001;
   6
   7 use FindBin;
   8 use lib "$FindBin::Bin/lib";
   9 use DBIx::Class::Optional::Dependencies;
  10
  11 # adjust ENV for $AUTHOR system() calls
  12 use Config;
  13 $ENV{PERL5LIB} = join ($Config{path_sep}, @INC);
  14
  15 use Getopt::Long ();
  16
  17 my $getopt = Getopt::Long::Parser->new(
  18   config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
  19 );
  20 my $args = {
  21   skip_author_deps => undef,
  22 };
  23 $getopt->getoptions($args, 'skip_author_deps');
  24 if (@ARGV) {
  25   warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
  26 }
  27
  28 # get cpanX --installdeps . to behave in a checkout (most users do not need
  29 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  30 # for that)
  31 ##
  32 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  33 ##
  34 $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  35
  36 ###
  37 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  38 ### All of them should go to DBIx::Class::Optional::Dependencies
  39 ###
  40
  41 name     'DBIx-Class';
  42 perl_version '5.008001';
  43 all_from 'lib/DBIx/Class.pm';
  44
  45 my $build_requires = {
  46   # needed for testing only, not for operation
  47   'DBD::SQLite'              => '1.29',
  48 };
  49
  50 my $test_requires = {
  51   'File::Temp'               => '0.22',
  52   'Test::Builder'            => '0.33',
  53   'Test::Exception'          => '0.31',
  54   'Test::More'               => '0.92',
  55   'Test::Warn'               => '0.21',
  56
  57   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
  58   # remove and do a manual glob-collection if n::c is no longer a dep
  59   'Package::Stash'           => '0.28',
  60 };
  61
  62 my $runtime_requires = {
  63   'Class::Accessor::Grouped' => '0.10002',
  64   'Class::C3::Componentised' => '1.0009',
  65   'Class::Inspector'         => '1.24',
  66   'Config::Any'              => '0.20',
  67   'Context::Preserve'        => '0.01',
  68   'Data::Dumper::Concise'    => '2.020',
  69   'Data::Page'               => '2.00',
  70   'Hash::Merge'              => '0.12',
  71   'MRO::Compat'              => '0.09',
  72   'Module::Find'             => '0.06',
  73   'Path::Class'              => '0.18',
  74   'Scope::Guard'             => '0.03',
  75   'SQL::Abstract'            => '1.72',
  76   'Test::Deep'               => '0.108',
  77   'Try::Tiny'                => '0.04',
  78
  79   # XS (or XS-dependent) libs
  80   'DBI'                      => '1.57',
  81   'namespace::clean'         => '0.20',
  82   'Sub::Name'                => '0.04',
  83   'Variable::Magic'          => '0.44',
  84
  85   # dual-life corelibs needing a specific bugfixed version
  86   'File::Path'               => '2.07',
  87 };
  88
  89 # this is so we can order requires alphabetically
  90 # copies are needed for author requires injection
  91 my $reqs = {
  92   build_requires => { %$build_requires },
  93   requires => { %$runtime_requires },
  94   test_requires => { %$test_requires },
  95 };
  96
  97 my %reqs_for_group = %{DBIx::Class::Optional::Dependencies->req_group_list};
  98
  99 # exclude the rdbms_* groups which are for DBIC users
 100 my $opt_testdeps = {
 101   map { %{$reqs_for_group{$_}} } grep { !/^rdbms_/ } keys %reqs_for_group
 102 };
 103
 104 # require extra modules for testing if we're in a checkout
 105 my $optdep_msg;
 106 if ($Module::Install::AUTHOR) {
 107   if ($args->{skip_author_deps}) {
 108     $optdep_msg = <<'EOW';
 109
 110 ******************************************************************************
 111 ******************************************************************************
 112 ***                                                                        ***
 113 *** IGNORING AUTHOR MODE: no optional test dependencies will be forced.    ***
 114 ***                                                                        ***
 115 *** If you are using this checkout with the intention of submitting a DBIC ***
 116 *** patch, you are *STRONGLY ENCOURAGED* to install all dependencies, so   ***
 117 *** that every possible unit-test will run.                                ***
 118 ***                                                                        ***
 119 ******************************************************************************
 120 ******************************************************************************
 121
 122 EOW
 123   }
 124   else {
 125     $optdep_msg = <<'EOW';
 126
 127 ******************************************************************************
 128 ******************************************************************************
 129 ***                                                                        ***
 130 *** AUTHOR MODE: all optional test dependencies converted to hard requires ***
 131 ***       ( to disable re-run Makefile.PL with --skip_author_deps )        ***
 132 ***                                                                        ***
 133 ******************************************************************************
 134 ******************************************************************************
 135
 136 EOW
 137
 138     $reqs->{test_requires} = {
 139       %{$reqs->{test_requires}},
 140       %$opt_testdeps
 141     };
 142   }
 143 }
 144
 145 # compose final req list, for alphabetical ordering
 146 my %final_req;
 147 for my $rtype (keys %$reqs) {
 148   for my $mod (keys %{$reqs->{$rtype}} ) {
 149
 150     # sanity check req duplications
 151     if ($final_req{$mod}) {
 152       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 153     }
 154
 155     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 156   }
 157 }
 158
 159 # actual require
 160 for my $mod (sort keys %final_req) {
 161   my ($rtype, $ver) = @{$final_req{$mod}};
 162   no strict 'refs';
 163   $rtype->($mod, $ver);
 164 }
 165
 166 # output twice since the deplist is > 70 lines
 167 warn $optdep_msg if $Module::Install::AUTHOR;
 168 auto_install();
 169 warn $optdep_msg if $Module::Install::AUTHOR;
 170
 171
 172 # re-create various autogenerated documentation bits
 173 if ($Module::Install::AUTHOR) {
 174
 175   print "Regenerating README\n";
 176   system('pod2text lib/DBIx/Class.pm > README');
 177
 178   if (-f 'MANIFEST') {
 179     print "Removing MANIFEST\n";
 180     unlink 'MANIFEST';
 181   }
 182
 183   print "Regenerating Optional/Dependencies.pod\n";
 184   require DBIx::Class::Optional::Dependencies;
 185   DBIx::Class::Optional::Dependencies->_gen_pod (Meta->version);
 186
 187   # FIXME Disabled due to unsolved issues, ask theorbtwo
 188   #  require Module::Install::Pod::Inherit;
 189   #  PodInherit();
 190 }
 191
 192
 193 tests_recursive (qw|
 194     t
 195 |);
 196
 197 # temporary(?) until I get around to fix M::I wrt xt/
 198 # needs Module::Install::AuthorTests
 199 eval {
 200   # this should not be necessary since the autoloader is supposed
 201   # to work, but there were reports of it failing
 202   require Module::Install::AuthorTests;
 203   recursive_author_tests (qw/xt/);
 204   1;
 205 } || do {
 206   if ($Module::Install::AUTHOR && ! $args->{skip_author_deps}) {
 207     my $err = $@;
 208
 209     # better error message in case of missing dep
 210     eval { require Module::Install::AuthorTests }
 211       || die "\nYou need Module::Install::AuthorTests installed to run this Makefile.PL in author mode (or supply --skip_author_deps):\n\n$@\n";
 212
 213     die $err;
 214   }
 215 };
 216
 217
 218 install_script (qw|
 219     script/dbicadmin
 220 |);
 221
 222
 223 ### Mangle makefile - read the comments for more info
 224 #
 225 postamble <<"EOP";
 226
 227 # This will add an extra dep-spec for the distdir target,
 228 # which `make` will fold together in a first-come first-serve
 229 # fashion. What we do here is essentially adding extra
 230 # commands to execute once the distdir is assembled (via
 231 # create_distdir), but before control is returned to a higher
 232 # calling rule.
 233 distdir : dbicadmin_pod_inject
 234
 235 # The pod self-injection code is in fact a hidden option in
 236 # dbicadmin itself
 237 dbicadmin_pod_inject :
 238 \tcd \$(DISTVNAME) && \$(ABSPERL) -Ilib script/dbicadmin --selfinject-pod
 239
 240 # Regenerate manifest before running create_distdir.
 241 create_distdir : manifest
 242
 243 EOP
 244
 245 homepage 'http://www.dbix-class.org/';
 246 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
 247 resources 'license'     => 'http://dev.perl.org/licenses/';
 248 resources 'repository'  => 'git://git.shadowcat.co.uk/dbsrgits/DBIx-Class.git';
 249 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
 250 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
 251
 252 # Deprecated/internal modules need no exposure
 253 no_index directory => $_ for (qw|
 254   lib/DBIx/Class/Admin
 255   lib/DBIx/Class/PK/Auto
 256   lib/DBIx/Class/CDBICompat
 257 |);
 258 no_index package => $_ for (qw/
 259   DBIx::Class::Storage::DBIHacks
 260   DBIx::Class::Carp
 261 /);
 262
 263 WriteAll();
 264
 265 # Re-write META.yml to _exclude_ all forced build-requires (we do not want to ship
 266 # this) We are also not using M::I::AuthorRequires as this will be an extra dep,
 267 # and deps in Makefile.PL still suck
 268 # Also always test the result so we stop shipping borked dependency lists to CPAN
 269
 270 # FIXME test_requires is not yet part of META
 271 my %original_build_requires = ( %$build_requires, %$test_requires );
 272 my @all_build_requires = @{delete Meta->{values}{build_requires}};
 273 my %removed_build_requires;
 274
 275 for (@all_build_requires) {
 276   if ($original_build_requires{$_->[0]}) {
 277     push @{Meta->{values}{build_requires}}, $_;
 278   }
 279   else {
 280     $removed_build_requires{$_->[0]} = $_->[1]
 281       unless $_->[0] eq 'ExtUtils::MakeMaker';
 282   }
 283 }
 284
 285 # Rewrite only in author mode, the original META should not contain anything anyway
 286 # if we executed as non-author
 287 if ($Module::Install::AUTHOR && keys %removed_build_requires) {
 288   print "Regenerating META with author requires excluded\n";
 289   Meta->write;
 290 }
 291
 292 # test that we really took things away (just in case, happened twice somehow)
 293 if (! -f 'META.yml') {
 294   warn "No META.yml generated?! aborting...\n";
 295   exit 1;
 296 }
 297 my $meta = do { local @ARGV = 'META.yml'; local $/; <> };
 298
 299 # this is safe as there is a fatal check earlier to make sure $opt_testdeps does
 300 # not contain any real dependencies
 301 my @illegal_leftovers = grep
 302   { $meta =~ /^ \s+ \Q$_\E \: \s+ /mx }
 303   ( sort keys %$opt_testdeps )
 304 ;
 305
 306 if (@illegal_leftovers) {
 307   die join ("\n",
 308     "\n\nFATAL FAIL! It looks like some author dependencies made it to the META.yml:\n",
 309     map { "\t$_" } @illegal_leftovers
 310   ) . "\n\n";
 311 }