Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6
   7 ##
   8 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
   9 ##
  10 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  11 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  12 # for that)
  13 BEGIN {
  14   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  15 }
  16
  17 name     'DBIx-Class';
  18 perl_version '5.008001';
  19 all_from 'lib/DBIx/Class.pm';
  20 Meta->{values}{x_authority} = 'cpan:RIBASUSHI';
  21
  22 tests_recursive (qw|
  23     t
  24 |);
  25
  26 install_script (qw|
  27     script/dbicadmin
  28 |);
  29
  30 homepage 'http://www.dbix-class.org/';
  31 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
  32 resources 'license'     => 'http://dev.perl.org/licenses/';
  33 resources 'repository'  => 'https://github.com/dbsrgits/DBIx-Class';
  34 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
  35 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
  36
  37 ###
  38 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  39 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  40 ###
  41 my $runtime_requires = {
  42   # FIXME - temporary, needs throwing out for something more efficient
  43   'Data::Compare'            => '1.22',
  44
  45   # Moo does not yet depend on this higher version
  46   'strictures'               => '1.003001',
  47
  48   # DBI itself should be capable of installation and execution in pure-perl
  49   # mode. However it has never been tested yet, so consider XS for the time
  50   # being
  51   'DBI'                      => '1.57',
  52
  53   # XS (or XS-dependent) libs
  54   'Sub::Name'                => '0.04',
  55
  56   # pure-perl (FatPack-able) libs
  57   'Class::Accessor::Grouped' => '0.10007',
  58   'Class::C3::Componentised' => '1.0009',
  59   'Class::Inspector'         => '1.24',
  60   'Class::Method::Modifiers' => '1.06',
  61   'Config::Any'              => '0.20',
  62   'Context::Preserve'        => '0.01',
  63   'Data::Dumper::Concise'    => '2.020',
  64   'Data::Page'               => '2.00',
  65   'Devel::GlobalDestruction' => '0',
  66   'Hash::Merge'              => '0.12',
  67   'Moo'                      => '0.009100',
  68   'MRO::Compat'              => '0.09',
  69   'Module::Find'             => '0.06',
  70   'namespace::clean'         => '0.20',
  71   'Path::Class'              => '0.18',
  72   'Scope::Guard'             => '0.03',
  73   'SQL::Abstract'            => '1.73',
  74   'Try::Tiny'                => '0.04',
  75
  76   # dual-life corelibs needing a specific bugfixed version
  77   'File::Path'               => '2.07',
  78 };
  79
  80 my $build_requires = {
  81   # needed for testing only, not for operation
  82   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  83   'DBD::SQLite'              => '1.29',
  84 };
  85
  86 my $test_requires = {
  87   'File::Temp'               => '0.22',
  88   'Test::Exception'          => '0.31',
  89   'Test::Warn'               => '0.21',
  90   'Test::More'               => '0.94',
  91   # not sure if this is necessary at all, ask schwern some day
  92   'Test::Builder'            => '0.94',
  93
  94   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
  95   # remove and do a manual glob-collection if n::c is no longer a dep
  96   'Package::Stash'           => '0.28',
  97 };
  98
  99 # make strictures.pm happy (DO NOT LIKE, TOO MUCH XS!)
 100 # (i.e. what if the .git/.svn is *not* because of DBIC?)
 101 #
 102 # Note - this is added as test_requires *directly*, so it gets properly
 103 # excluded on META.yml cleansing
 104 if (-e '.git' or -e '.svn') {
 105   test_requires 'indirect'              => '0.25';
 106   test_requires 'multidimensional'      => '0.008';
 107   test_requires 'bareword::filehandles' => '0.003';
 108 }
 109
 110 # if the user has this env var set and no SQLT installed, tests will fail
 111 # same rationale for direct test_requires as the strictures stuff above
 112 # (even though no dist will be created from this)
 113 # we force this req regarless of author_deps, worst case scenario it will
 114 # be specified twice
 115 if ($ENV{DBICTEST_SQLT_DEPLOY}) {
 116   local @INC = ('lib', @INC);
 117   require DBIx::Class::Optional::Dependencies;
 118   my $dep_req = DBIx::Class::Optional::Dependencies->req_list_for('deploy');
 119   for (keys %$dep_req) {
 120     test_requires ($_ => $dep_req->{$_})
 121   }
 122 }
 123
 124 # this is so we can order requires alphabetically
 125 # copies are needed for potential author requires injection
 126 my $reqs = {
 127   build_requires => { %$build_requires },
 128   requires => { %$runtime_requires },
 129   test_requires => { %$test_requires },
 130 };
 131
 132 # only do author-includes if not part of a `make` run
 133 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 134   # get options here, make $args available to all snippets
 135   require Getopt::Long;
 136   my $getopt = Getopt::Long::Parser->new(
 137     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 138   );
 139   my $args = {
 140     skip_author_deps => undef,
 141   };
 142   $getopt->getoptions($args, qw/
 143     skip_author_deps|skip-author-deps
 144   /);
 145   if (@ARGV) {
 146     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 147   }
 148
 149   require File::Spec;
 150   # string-eval, not do(), because we need to provide the
 151   # $reqs and $*_requires lexicals to the included file
 152   # (some includes *do* modify $reqs above)
 153   for my $inc (sort glob ( File::Spec->catfile('maint', 'Makefile.PL.inc', '*') ) ) {
 154     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 155     eval "use warnings; use strict; $src" or die sprintf
 156       "Failed execution of %s: %s\n",
 157       $inc,
 158       ($@ || $! || 'Unknown error'),
 159     ;
 160   }
 161 }
 162 else {
 163   # make sure this Makefile can not be used to make a dist
 164   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 165   postamble <<EOP;
 166 .PHONY: nonauthor_stop_distdir_creation
 167 create_distdir: nonauthor_stop_distdir_creation
 168 nonauthor_stop_distdir_creation:
 169 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 170 \t\$(NOECHO) \$(FALSE)
 171 EOP
 172 }
 173
 174 # compose final req list, for alphabetical ordering
 175 my %final_req;
 176 for my $rtype (keys %$reqs) {
 177   for my $mod (keys %{$reqs->{$rtype}} ) {
 178
 179     # sanity check req duplications
 180     if ($final_req{$mod}) {
 181       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 182     }
 183
 184     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 185   }
 186 }
 187
 188 # actual require
 189 for my $mod (sort keys %final_req) {
 190   my ($rtype, $ver) = @{$final_req{$mod}};
 191   no strict 'refs';
 192   $rtype->($mod, $ver);
 193 }
 194
 195 # author-mode or not - this is where we show a list of missing deps
 196 # IFF we are running interactively
 197 auto_install();
 198
 199 WriteAll();