Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN { makemaker_args( NORECURS => 1 ) } # needs to happen early for old EUMM
   7
   8 ##
   9 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  10 ##
  11 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  12 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  13 # for that)
  14 BEGIN {
  15   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  16 }
  17
  18 homepage 'http://www.dbix-class.org/';
  19 resources 'x_IRC'       => 'irc://irc.perl.org/#dbix-class';
  20 resources 'x_WebIRC'    => 'https://chat.mibbit.com/#dbix-class@irc.perl.org';
  21 resources 'license'     => 'http://dev.perl.org/licenses/';
  22 resources 'repository'  => 'https://github.com/dbsrgits/DBIx-Class';
  23 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
  24 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
  25
  26 name     'DBIx-Class';
  27 perl_version '5.008001';
  28 all_from 'lib/DBIx/Class.pm';
  29 Meta->{values}{x_authority} = 'cpan:RIBASUSHI';
  30
  31 # nothing determined at runtime, except for possibly SQLT dep, see
  32 # comment further down
  33 dynamic_config 0;
  34
  35 tests_recursive (qw|
  36     t
  37 |);
  38
  39 install_script (qw|
  40     script/dbicadmin
  41 |);
  42
  43 ###
  44 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  45 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  46 ###
  47 my $runtime_requires = {
  48   # FIXME - temporary, needs throwing out for something more efficient
  49   'Data::Compare'            => '1.22',
  50
  51   # DBI itself should be capable of installation and execution in pure-perl
  52   # mode. However it has never been tested yet, so consider XS for the time
  53   # being
  54 ###
  55 ### IMPORTANT - do not raise this dependency
  56 ### even though many bugfixes are present in newer versions, the general DBIC
  57 ### rule is to bend over backwards for available DBI versions (given upgrading
  58 ### them is often *not* easy or even possible)
  59 ###
  60   'DBI'                      => '1.57',
  61
  62   # on older versions first() leaks
  63   # for the time being make it a hard dep - when we get
  64   # rid of Sub::Name will revisit this (possibility is
  65   # to use Devel::HideXS to force the pure-perl version
  66   # or something like that)
  67   'List::Util'               => '1.16',
  68
  69   # XS (or XS-dependent) libs
  70   'Sub::Name'                => '0.04',
  71
  72   # pure-perl (FatPack-able) libs
  73   'Class::Accessor::Grouped' => '0.10010',
  74   'Class::C3::Componentised' => '1.0009',
  75   'Class::Inspector'         => '1.24',
  76   'Config::Any'              => '0.20',
  77   'Context::Preserve'        => '0.01',
  78   'Data::Dumper::Concise'    => '2.020',
  79   'Data::Page'               => '2.00',
  80   'Devel::GlobalDestruction' => '0.09',
  81   'Hash::Merge'              => '0.12',
  82   'Moo'                      => '1.002',
  83   'MRO::Compat'              => '0.12',
  84   'Module::Find'             => '0.07',
  85   'namespace::clean'         => '0.24',
  86   'Path::Class'              => '0.18',
  87   'Scope::Guard'             => '0.03',
  88   'SQL::Abstract'            => '1.78',
  89   'Try::Tiny'                => '0.07',
  90
  91   # Technically this is not a core dependency - it is only required
  92   # by the MySQL codepath. However this particular version is bundled
  93   # since 5.10.0 and is a pure-perl module anyway - let it slide
  94   'Text::Balanced'           => '2.00',
  95 };
  96
  97 my $build_requires = {
  98 };
  99
 100 my $test_requires = {
 101   'File::Temp'               => '0.22',
 102   'Test::Deep'               => '0.101',
 103   'Test::Exception'          => '0.31',
 104   'Test::Warn'               => '0.21',
 105   'Test::More'               => '0.94',
 106
 107   # needed for testing only, not for operation
 108   # we will move away from this dep eventually, perhaps to DBD::CSV or something
 109 ###
 110 ### IMPORTANT - do not raise this dependency
 111 ### even though many bugfixes are present in newer versions, the general DBIC
 112 ### rule is to bend over backwards for available DBDs (given upgrading them is
 113 ### often *not* easy or even possible)
 114 ###
 115   'DBD::SQLite'              => '1.29',
 116
 117   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
 118   # remove and do a manual glob-collection if n::c is no longer a dep
 119   'Package::Stash'           => '0.28',
 120 };
 121
 122 # if the user has this env var set and no SQLT installed, tests will fail
 123 # Note - this is added as test_requires *directly*, so it gets properly
 124 # excluded on META.yml cleansing (even though no dist can be created from this)
 125 # we force this req regarless of author_deps, worst case scenario it will
 126 # be specified twice
 127 #
 128 # also note that we *do* set dynamic_config => 0, as this is the only thing
 129 # that we determine dynamically, and in all fairness if someone sets the
 130 # envvar *and* is not running a full Makefile/make/maketest cycle - they get
 131 # to keep the pieces
 132 if ($ENV{DBICTEST_SQLT_DEPLOY}) {
 133   local @INC = ('lib', @INC);
 134   require DBIx::Class::Optional::Dependencies;
 135   my $dep_req = DBIx::Class::Optional::Dependencies->req_list_for('deploy');
 136   for (keys %$dep_req) {
 137     test_requires ($_ => $dep_req->{$_})
 138   }
 139 }
 140
 141 # this is so we can order requires alphabetically
 142 # copies are needed for potential author requires injection
 143 my $reqs = {
 144   build_requires => { %$build_requires },
 145   requires => { %$runtime_requires },
 146   test_requires => { %$test_requires },
 147 };
 148
 149 # only do author-includes if not part of a `make` run
 150 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 151   invoke_author_mode()
 152 }
 153 else {
 154   # make sure this Makefile can not be used to make a dist
 155   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 156   postamble <<EOP;
 157 create_distdir: nonauthor_stop_distdir_creation
 158 nonauthor_stop_distdir_creation:
 159 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 160 \t\$(NOECHO) \$(FALSE)
 161 EOP
 162 }
 163
 164 # compose final req list, for alphabetical ordering
 165 my %final_req;
 166 for my $rtype (keys %$reqs) {
 167   for my $mod (keys %{$reqs->{$rtype}} ) {
 168
 169     # sanity check req duplications
 170     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 171       if $final_req{$mod};
 172
 173     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 174   }
 175 }
 176
 177 # actual require
 178 for my $mod (sort keys %final_req) {
 179   my ($rtype, $ver) = @{$final_req{$mod}};
 180   no strict 'refs';
 181   $rtype->($mod, $ver);
 182 }
 183
 184 # author-mode or not - this is where we show a list of missing deps
 185 # IFF we are running interactively
 186 auto_install();
 187
 188 WriteAll();
 189
 190 exit 0;
 191
 192 # needs to be here to keep 5.8 string eval happy
 193 # (the include of Makefile.PL.inc loop)
 194 my $mm_proto;
 195
 196 sub invoke_author_mode {
 197   # get options here, make $args available to all snippets
 198   require Getopt::Long;
 199   my $getopt = Getopt::Long::Parser->new(
 200     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 201   );
 202   my $args = {
 203     skip_author_deps => undef,
 204   };
 205   $getopt->getoptions($args, qw/
 206     skip_author_deps|skip-author-deps
 207   /);
 208   if (@ARGV) {
 209     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 210   }
 211
 212   # We need the MM facilities to generate the pieces for the final MM run.
 213   # Just instantiate a throaway object here
 214   #
 215   # Also EUMM and MI disagree on what is the format of Meta->name, just
 216   # punt here until a new M::I is shipped (if at all)
 217   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 218   $name =~ s/\-/::/g;
 219   $mm_proto = ExtUtils::MakeMaker->new({
 220     NORECURS => 1,
 221     NAME => $name,
 222   });
 223
 224   # Crutch for DISTBUILDING_IN_HELL
 225   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 226   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 227   # not take into account the CRLF layer present on win32
 228   my $crlf_fixup = sub {
 229     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 230     my $targets = join ', ', map { "q($_)" } @_;
 231     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 232   };
 233
 234   # we are in the process of (re)writing the makefile - some things we
 235   # call below very well may fail
 236   local $ENV{DBICTEST_NO_MAKEFILE_VERIFICATION} = 1;
 237
 238   require File::Spec;
 239   # string-eval, not do(), because we need to provide the
 240   # $mm_proto, $reqs and $*_requires lexicals to the included file
 241   # (some includes *do* modify $reqs above)
 242   for my $inc (sort glob ( File::Spec->catfile('maint', 'Makefile.PL.inc', '*') ) ) {
 243     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 244     eval "use warnings; use strict; $src" or die sprintf
 245       "Failed execution of %s: %s\n",
 246       $inc,
 247       ($@ || $! || 'Unknown error'),
 248     ;
 249   }
 250 }