Makefile.PL

   1 use inc::Module::Install 1.00;
   2 use strict;
   3 use warnings;
   4
   5 use 5.008001;
   6
   7 use FindBin;
   8 use lib "$FindBin::Bin/lib";
   9 use DBIx::Class::Optional::Dependencies;
  10
  11 # adjust ENV for $AUTHOR system() calls
  12 use Config;
  13 $ENV{PERL5LIB} = join ($Config{path_sep}, @INC);
  14
  15 use Getopt::Long ();
  16
  17 my $getopt = Getopt::Long::Parser->new(
  18   config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
  19 );
  20 my $args = {
  21   skip_author_deps => undef,
  22 };
  23 $getopt->getoptions($args, 'skip_author_deps');
  24 if (@ARGV) {
  25   warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
  26 }
  27
  28 # get cpanX --installdeps . to behave in a checkout (most users do not need
  29 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  30 # for that)
  31 ##
  32 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  33 ##
  34 $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  35
  36 ###
  37 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  38 ### All of them should go to DBIx::Class::Optional::Dependencies
  39 ###
  40
  41 name     'DBIx-Class';
  42 perl_version '5.008001';
  43 all_from 'lib/DBIx/Class.pm';
  44
  45 my $build_requires = {
  46   # needed for testing only, not for operation
  47   'DBD::SQLite'              => '1.29',
  48 };
  49
  50 my $test_requires = {
  51   'File::Temp'               => '0.22',
  52   'Test::Builder'            => '0.33',
  53   'Test::Exception'          => '0.31',
  54   'Test::More'               => '0.92',
  55   'Test::Warn'               => '0.21',
  56 };
  57
  58 my $runtime_requires = {
  59   'Carp::Clan'               => '6.0',
  60   'Class::Accessor::Grouped' => '0.10000',
  61   'Class::C3::Componentised' => '1.0005',
  62   'Class::Inspector'         => '1.24',
  63   'Config::Any'              => '0.20',
  64   'Context::Preserve'        => '0.01',
  65   'Data::Dumper::Concise'    => '1.000',
  66   'Data::Page'               => '2.00',
  67   'MRO::Compat'              => '0.09',
  68   'Module::Find'             => '0.06',
  69   'Path::Class'              => '0.18',
  70   'Scope::Guard'             => '0.03',
  71   'SQL::Abstract'            => '1.72',
  72   'Try::Tiny'                => '0.04',
  73
  74   # XS (or XS-dependent) libs
  75   'DBI'                      => '1.609',
  76   'namespace::clean'         => '0.14',
  77   'Sub::Name'                => '0.04',
  78   'Variable::Magic'          => '0.44',
  79
  80   # corelibs needing a specific bugfixed version
  81   'File::Path'               => '2.07',
  82
  83   # Oracle-only optionals
  84   'Math::BigInt'             => '1.89',
  85   'Math::Base36'             => '0.07',
  86 };
  87
  88 # this is so we can order requires alphabetically
  89 # copies are needed for author requires injection
  90 my $reqs = {
  91   build_requires => { %$build_requires },
  92   requires => { %$runtime_requires },
  93   test_requires => { %$test_requires },
  94 };
  95
  96 my $opt_testdeps = {
  97   map { %$_ } (values %{DBIx::Class::Optional::Dependencies->req_group_list})
  98 };
  99
 100 # require extra modules for testing if we're in a checkout
 101 my $optdep_msg;
 102 if ($Module::Install::AUTHOR) {
 103   if ($args->{skip_author_deps}) {
 104     $optdep_msg = <<'EOW';
 105
 106 ******************************************************************************
 107 ******************************************************************************
 108 ***                                                                        ***
 109 *** IGNORING AUTHOR MODE: no optional test dependencies will be forced.    ***
 110 ***                                                                        ***
 111 *** If you are using this checkout with the intention of submitting a DBIC ***
 112 *** patch, you are *STRONGLY ENCOURAGED* to install all dependencies, so   ***
 113 *** that every possible unit-test will run.                                ***
 114 ***                                                                        ***
 115 ******************************************************************************
 116 ******************************************************************************
 117
 118 EOW
 119   }
 120   else {
 121     $optdep_msg = <<'EOW';
 122
 123 ******************************************************************************
 124 ******************************************************************************
 125 ***                                                                        ***
 126 *** AUTHOR MODE: all optional test dependencies converted to hard requires ***
 127 ***       ( to disable re-run Makefile.PL with --skip_author_deps )        ***
 128 ***                                                                        ***
 129 ******************************************************************************
 130 ******************************************************************************
 131
 132 EOW
 133
 134     $reqs->{test_requires} = {
 135       %{$reqs->{test_requires}},
 136       %$opt_testdeps
 137     };
 138   }
 139 }
 140
 141 # compose final req list, for alphabetical ordering
 142 my %final_req;
 143 for my $rtype (keys %$reqs) {
 144   for my $mod (keys %{$reqs->{$rtype}} ) {
 145
 146     # sanity check req duplications
 147     if ($final_req{$mod}) {
 148       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 149     }
 150
 151     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 152   }
 153 }
 154
 155 # actual require
 156 for my $mod (sort keys %final_req) {
 157   my ($rtype, $ver) = @{$final_req{$mod}};
 158   no strict 'refs';
 159   $rtype->($mod, $ver);
 160 }
 161
 162 # output twice since the deplist is > 70 lines
 163 warn $optdep_msg if $Module::Install::AUTHOR;
 164 auto_install();
 165 warn $optdep_msg if $Module::Install::AUTHOR;
 166
 167 # re-create various autogenerated documentation bits
 168 if ($Module::Install::AUTHOR) {
 169
 170   print "Regenerating README\n";
 171   system('pod2text lib/DBIx/Class.pm > README');
 172
 173   if (-f 'MANIFEST') {
 174     print "Removing MANIFEST\n";
 175     unlink 'MANIFEST';
 176   }
 177
 178   print "Regenerating Optional/Dependencies.pod\n";
 179   require DBIx::Class::Optional::Dependencies;
 180   DBIx::Class::Optional::Dependencies->_gen_pod (Meta->version);
 181
 182   # FIXME Disabled due to unsolved issues, ask theorbtwo
 183   #  require Module::Install::Pod::Inherit;
 184   #  PodInherit();
 185 }
 186
 187
 188 tests_recursive (qw|
 189     t
 190 |);
 191
 192 # temporary(?) until I get around to fix M::I wrt xt/
 193 # needs Module::Install::AuthorTests
 194 eval {
 195   recursive_author_tests (qw/xt/);
 196   1;
 197 } || do {
 198   if ($Module::Install::AUTHOR && ! $args->{skip_author_deps}) {
 199     my $err = $@;
 200     eval { require Module::Install::AuthorTests }
 201       || die "\nYou need Module::Install::AuthorTests installed to run this Makefile.PL in author mode (or supply --skip_author_deps):\n\n$@\n";
 202     die $@;
 203   }
 204 };
 205
 206
 207 install_script (qw|
 208     script/dbicadmin
 209 |);
 210
 211
 212 ### Mangle makefile - read the comments for more info
 213 #
 214 postamble <<"EOP";
 215
 216 # This will add an extra dep-spec for the distdir target,
 217 # which `make` will fold together in a first-come first-serve
 218 # fashion. What we do here is essentially adding extra
 219 # commands to execute once the distdir is assembled (via
 220 # create_distdir), but before control is returned to a higher
 221 # calling rule.
 222 distdir : dbicadmin_pod_inject
 223
 224 # The pod self-injection code is in fact a hidden option in
 225 # dbicadmin itself
 226 dbicadmin_pod_inject :
 227 \tcd \$(DISTVNAME) && \$(ABSPERL) -Ilib script/dbicadmin --selfinject-pod
 228
 229 # Regenerate manifest before running create_distdir.
 230 create_distdir : manifest
 231
 232 EOP
 233
 234 homepage 'http://www.dbix-class.org/';
 235 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
 236 resources 'license'     => 'http://dev.perl.org/licenses/';
 237 resources 'repository'  => 'git://git.shadowcat.co.uk/dbsrgits/DBIx-Class.git';
 238 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
 239 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
 240
 241 # Deprecated/internal modules need no exposure
 242 no_index directory => $_ for (qw|
 243   lib/DBIx/Class/Admin
 244   lib/DBIx/Class/PK/Auto
 245   lib/DBIx/Class/CDBICompat
 246 |);
 247 no_index package => $_ for (qw/
 248   DBIx::Class::Storage::DBIHacks
 249 /);
 250
 251 WriteAll();
 252
 253 # Re-write META.yml to _exclude_ all forced build-requires (we do not want to ship
 254 # this) We are also not using M::I::AuthorRequires as this will be an extra dep,
 255 # and deps in Makefile.PL still suck
 256 # Also always test the result so we stop shipping borked dependency lists to CPAN
 257
 258 # FIXME test_requires is not yet part of META
 259 my %original_build_requires = ( %$build_requires, %$test_requires );
 260 my @all_build_requires = @{delete Meta->{values}{build_requires}};
 261 my %removed_build_requires;
 262
 263 for (@all_build_requires) {
 264   if ($original_build_requires{$_->[0]}) {
 265     push @{Meta->{values}{build_requires}}, $_;
 266   }
 267   else {
 268     $removed_build_requires{$_->[0]} = $_->[1]
 269       unless $_->[0] eq 'ExtUtils::MakeMaker';
 270   }
 271 }
 272
 273 # Rewrite only in author mode, the original META should not contain anything anyway
 274 # if we executed as non-author
 275 if ($Module::Install::AUTHOR && keys %removed_build_requires) {
 276   print "Regenerating META with author requires excluded\n";
 277   Meta->write;
 278 }
 279
 280 # test that we really took things away (just in case, happened twice somehow)
 281 exit 0 unless -f 'META.yml';  # in case bizarro comes around
 282 my $meta = do { local @ARGV = 'META.yml'; local $/; <> };
 283
 284 # this is safe as there is a fatal check earlier to make sure $opt_testdeps does
 285 # not contain any real dependencies
 286 my @illegal_leftovers = grep
 287   { $meta =~ /^ \s+ \Q$_\E \: \s+ /mx }
 288   ( sort keys %$opt_testdeps )
 289 ;
 290
 291 if (@illegal_leftovers) {
 292   die join ("\n",
 293     "\n\nFATAL FAIL! It looks like some author dependencies made it to the META.yml:\n",
 294     map { "\t$_" } @illegal_leftovers
 295   ) . "\n\n";
 296 }