[p5sagit/p5-mst-13.2.git] / t / test.pl

#
# t/test.pl - most of Test::More functionality without the fuss
#

$Level = 1;
my $test = 1;
my $planned;
my $noplan;

$TODO = 0;
$NO_ENDING = 0;

sub plan {
    my $n;
    if (@_ == 1) {
	$n = shift;
	if ($n eq 'no_plan') {
	  undef $n;
	  $noplan = 1;
	}
    } else {
	my %plan = @_;
	$n = $plan{tests}; 
    }
    print STDOUT "1..$n\n" unless $noplan;
    $planned = $n;
}

END {
    my $ran = $test - 1;
    if (!$NO_ENDING) {
	if (defined $planned && $planned != $ran) {
	    print STDERR
		"# Looks like you planned $planned tests but ran $ran.\n";
	} elsif ($noplan) {
	    print "1..$ran\n";
	}
    }
}

# Use this instead of "print STDERR" when outputing failure diagnostic 
# messages
sub _diag {
    return unless @_;
    my @mess = map { /^#/ ? "$_\n" : "# $_\n" } 
               map { split /\n/ } @_;
    my $fh = $TODO ? *STDOUT : *STDERR;
    print $fh @mess;

}

sub skip_all {
    if (@_) {
	print STDOUT "1..0 # Skipped: @_\n";
    } else {
	print STDOUT "1..0\n";
    }
    exit(0);
}

sub _ok {
    my ($pass, $where, $name, @mess) = @_;
    # Do not try to microoptimize by factoring out the "not ".
    # VMS will avenge.
    my $out;
    if ($name) {
        # escape out '#' or it will interfere with '# skip' and such
        $name =~ s/#/\\#/g;
	$out = $pass ? "ok $test - $name" : "not ok $test - $name";
    } else {
	$out = $pass ? "ok $test" : "not ok $test";
    }

    $out .= " # TODO $TODO" if $TODO;
    print STDOUT "$out\n";

    unless ($pass) {
	_diag "# Failed $where\n";
    }

    # Ensure that the message is properly escaped.
    _diag @mess;

    $test++;

    return $pass;
}

sub _where {
    my @caller = caller($Level);
    return "at $caller[1] line $caller[2]";
}

# DON'T use this for matches. Use like() instead.
sub ok ($@) {
    my ($pass, $name, @mess) = @_;
    _ok($pass, _where(), $name, @mess);
}

sub _q {
    my $x = shift;
    return 'undef' unless defined $x;
    my $q = $x;
    $q =~ s/\\/\\\\/g;
    $q =~ s/'/\\'/g;
    return "'$q'";
}

sub _qq {
    my $x = shift;
    return defined $x ? '"' . display ($x) . '"' : 'undef';
};

# keys are the codes \n etc map to, values are 2 char strings such as \n
my %backslash_escape;
foreach my $x (split //, 'nrtfa\\\'"') {
    $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
}
# A way to display scalars containing control characters and Unicode.
# Trying to avoid setting $_, or relying on local $_ to work.
sub display {
    my @result;
    foreach my $x (@_) {
        if (defined $x and not ref $x) {
            my $y = '';
            foreach my $c (unpack("U*", $x)) {
                if ($c > 255) {
                    $y .= sprintf "\\x{%x}", $c;
                } elsif ($backslash_escape{$c}) {
                    $y .= $backslash_escape{$c};
                } else {
                    my $z = chr $c; # Maybe we can get away with a literal...
                    $z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
                    $y .= $z;
                }
            }
            $x = $y;
        }
        return $x unless wantarray;
        push @result, $x;
    }
    return @result;
}

sub is ($$@) {
    my ($got, $expected, $name, @mess) = @_;

    my $pass;
    if( !defined $got || !defined $expected ) {
        # undef only matches undef
        $pass = !defined $got && !defined $expected;
    }
    else {
        $pass = $got eq $expected;
    }

    unless ($pass) {
	unshift(@mess, "#      got "._q($got)."\n",
		       "# expected "._q($expected)."\n");
    }
    _ok($pass, _where(), $name, @mess);
}

sub isnt ($$@) {
    my ($got, $isnt, $name, @mess) = @_;

    my $pass;
    if( !defined $got || !defined $isnt ) {
        # undef only matches undef
        $pass = defined $got || defined $isnt;
    }
    else {
        $pass = $got ne $isnt;
    }

    unless( $pass ) {
        unshift(@mess, "# it should not be "._q($got)."\n",
                       "# but it is.\n");
    }
    _ok($pass, _where(), $name, @mess);
}

sub cmp_ok ($$$@) {
    my($got, $type, $expected, $name, @mess) = @_;

    my $pass;
    {
        local $^W = 0;
        local($@,$!);   # don't interfere with $@
                        # eval() sometimes resets $!
        $pass = eval "\$got $type \$expected";
    }
    unless ($pass) {
        # It seems Irix long doubles can have 2147483648 and 2147483648
        # that stringify to the same thing but are acutally numerically
        # different. Display the numbers if $type isn't a string operator,
        # and the numbers are stringwise the same.
        # (all string operators have alphabetic names, so tr/a-z// is true)
        # This will also show numbers for some uneeded cases, but will
        # definately be helpful for things such as == and <= that fail
        if ($got eq $expected and $type !~ tr/a-z//) {
            unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
        }
        unshift(@mess, "#      got "._q($got)."\n",
                       "# expected $type "._q($expected)."\n");
    }
    _ok($pass, _where(), $name, @mess);
}

# Check that $got is within $range of $expected
# if $range is 0, then check it's exact
# else if $expected is 0, then $range is an absolute value
# otherwise $range is a fractional error.
# Here $range must be numeric, >= 0
# Non numeric ranges might be a useful future extension. (eg %)
sub within ($$$@) {
    my ($got, $expected, $range, $name, @mess) = @_;
    my $pass;
    if (!defined $got or !defined $expected or !defined $range) {
        # This is a fail, but doesn't need extra diagnostics
    } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
        # This is a fail
        unshift @mess, "# got, expected and range must be numeric\n";
    } elsif ($range < 0) {
        # This is also a fail
        unshift @mess, "# range must not be negative\n";
    } elsif ($range == 0) {
        # Within 0 is ==
        $pass = $got == $expected;
    } elsif ($expected == 0) {
        # If expected is 0, treat range as absolute
        $pass = ($got <= $range) && ($got >= - $range);
    } else {
        my $diff = $got - $expected;
        $pass = abs ($diff / $expected) < $range;
    }
    unless ($pass) {
        if ($got eq $expected) {
            unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
        }
	unshift@mess, "#      got "._q($got)."\n",
		      "# expected "._q($expected)." (within "._q($range).")\n";
    }
    _ok($pass, _where(), $name, @mess);
}

# Note: this isn't quite as fancy as Test::More::like().

sub like   ($$@) { like_yn (0,@_) }; # 0 for -
sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-

sub like_yn ($$$@) {
    my ($flip, $got, $expected, $name, @mess) = @_;
    my $pass;
    $pass = $got =~ /$expected/ if !$flip;
    $pass = $got !~ /$expected/ if $flip;
    unless ($pass) {
	unshift(@mess, "#      got '$got'\n",
		"# expected /$expected/\n");
    }
    local $Level = 2;
    _ok($pass, _where(), $name, @mess);
}

sub pass {
    _ok(1, '', @_);
}

sub fail {
    _ok(0, _where(), @_);
}

sub curr_test {
    $test = shift if @_;
    return $test;
}

sub next_test {
  $test++;
}

# Note: can't pass multipart messages since we try to
# be compatible with Test::More::skip().
sub skip {
    my $why = shift;
    my $n    = @_ ? shift : 1;
    for (1..$n) {
        print STDOUT "ok $test # skip: $why\n";
        $test++;
    }
    local $^W = 0;
    last SKIP;
}

sub todo_skip {
    my $why = shift;
    my $n   = @_ ? shift : 1;

    for (1..$n) {
        print STDOUT "not ok $test # TODO & SKIP: $why\n";
        $test++;
    }
    local $^W = 0;
    last TODO;
}

sub eq_array {
    my ($ra, $rb) = @_;
    return 0 unless $#$ra == $#$rb;
    for my $i (0..$#$ra) {
	next     if !defined $ra->[$i] && !defined $rb->[$i]; 
	return 0 if !defined $ra->[$i];
	return 0 if !defined $rb->[$i];
	return 0 unless $ra->[$i] eq $rb->[$i];
    }
    return 1;
}

sub eq_hash {
  my ($orig, $suspect) = @_;
  my $fail;
  while (my ($key, $value) = each %$suspect) {
    # Force a hash recompute if this perl's internals can cache the hash key.
    $key = "" . $key;
    if (exists $orig->{$key}) {
      if ($orig->{$key} ne $value) {
        print STDOUT "# key ", _qq($key), " was ", _qq($orig->{$key}),
                     " now ", _qq($value), "\n";
        $fail = 1;
      }
    } else {
      print STDOUT "# key ", _qq($key), " is ", _qq($value), 
                   ", not in original.\n";
      $fail = 1;
    }
  }
  foreach (keys %$orig) {
    # Force a hash recompute if this perl's internals can cache the hash key.
    $_ = "" . $_;
    next if (exists $suspect->{$_});
    print STDOUT "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
    $fail = 1;
  }
  !$fail;
}

sub require_ok ($) {
    my ($require) = @_;
    eval <<REQUIRE_OK;
require $require;
REQUIRE_OK
    _ok(!$@, _where(), "require $require");
}

sub use_ok ($) {
    my ($use) = @_;
    eval <<USE_OK;
use $use;
USE_OK
    _ok(!$@, _where(), "use $use");
}

# runperl - Runs a separate perl interpreter.
# Arguments :
#   switches => [ command-line switches ]
#   nolib    => 1 # don't use -I../lib (included by default)
#   prog     => one-liner (avoid quotes)
#   progs    => [ multi-liner (avoid quotes) ]
#   progfile => perl script
#   stdin    => string to feed the stdin
#   stderr   => redirect stderr to stdout
#   args     => [ command-line arguments to the perl program ]
#   verbose  => print the command line

my $is_mswin    = $^O eq 'MSWin32';
my $is_netware  = $^O eq 'NetWare';
my $is_macos    = $^O eq 'MacOS';
my $is_vms      = $^O eq 'VMS';

sub _quote_args {
    my ($runperl, $args) = @_;

    foreach (@$args) {
	# In VMS protect with doublequotes because otherwise
	# DCL will lowercase -- unless already doublequoted.
       $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
	$$runperl .= ' ' . $_;
    }
}

sub _create_runperl { # Create the string to qx in runperl().
    my %args = @_;
    my $runperl = $^X =~ m/\s/ ? qq{"$^X"} : $^X;
    #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
    if ($ENV{PERL_RUNPERL_DEBUG}) {
	$runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
    }
    unless ($args{nolib}) {
	if ($is_macos) {
	    $runperl .= ' -I::lib';
	    # Use UNIX style error messages instead of MPW style.
	    $runperl .= ' -MMac::err=unix' if $args{stderr};
	}
	else {
	    $runperl .= ' "-I../lib"'; # doublequotes because of VMS
	}
    }
    if ($args{switches}) {
	local $Level = 2;
	die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
	    unless ref $args{switches} eq "ARRAY";
	_quote_args(\$runperl, $args{switches});
    }
    if (defined $args{prog}) {
	die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
	    if defined $args{progs};
        $args{progs} = [$args{prog}]
    }
    if (defined $args{progs}) {
	die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
	    unless ref $args{progs} eq "ARRAY";
        foreach my $prog (@{$args{progs}}) {
            if ($is_mswin || $is_netware || $is_vms) {
                $runperl .= qq ( -e "$prog" );
            }
            else {
                $runperl .= qq ( -e '$prog' );
            }
        }
    } elsif (defined $args{progfile}) {
	$runperl .= qq( "$args{progfile}");
    } else {
	# You probaby didn't want to be sucking in from the upstream stdin
	die "test.pl:runperl(): none of prog, progs, progfile, args, "
	    . " switches or stdin specified"
	    unless defined $args{args} or defined $args{switches}
		or defined $args{stdin};
    }
    if (defined $args{stdin}) {
	# so we don't try to put literal newlines and crs onto the
	# command line.
	$args{stdin} =~ s/\n/\\n/g;
	$args{stdin} =~ s/\r/\\r/g;

	if ($is_mswin || $is_netware || $is_vms) {
	    $runperl = qq{$^X -e "print qq(} .
		$args{stdin} . q{)" | } . $runperl;
	}
	elsif ($is_macos) {
	    # MacOS can only do two processes under MPW at once;
	    # the test itself is one; we can't do two more, so
	    # write to temp file
	    my $stdin = qq{$^X -e 'print qq(} . $args{stdin} . qq{)' > teststdin; };
	    if ($args{verbose}) {
		my $stdindisplay = $stdin;
		$stdindisplay =~ s/\n/\n\#/g;
		print STDERR "# $stdindisplay\n";
	    }
	    `$stdin`;
	    $runperl .= q{ < teststdin };
	}
	else {
	    $runperl = qq{$^X -e 'print qq(} .
		$args{stdin} . q{)' | } . $runperl;
	}
    }
    if (defined $args{args}) {
	_quote_args(\$runperl, $args{args});
    }
    $runperl .= ' 2>&1'          if  $args{stderr} && !$is_macos;
    $runperl .= " \xB3 Dev:Null" if !$args{stderr} &&  $is_macos;
    if ($args{verbose}) {
	my $runperldisplay = $runperl;
	$runperldisplay =~ s/\n/\n\#/g;
	print STDERR "# $runperldisplay\n";
    }
    return $runperl;
}

sub runperl {
    die "test.pl:runperl() does not take a hashref"
	if ref $_[0] and ref $_[0] eq 'HASH';
    my $runperl = &_create_runperl;
    my $result = `$runperl`;
    $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
    return $result;
}

*run_perl = \&runperl; # Nice alias.

sub DIE {
    print STDERR "# @_\n";
    exit 1;
}

# A somewhat safer version of the sometimes wrong $^X.
my $Perl;
sub which_perl {
    unless (defined $Perl) {
	$Perl = $^X;
	
	# VMS should have 'perl' aliased properly
	return $Perl if $^O eq 'VMS';

	my $exe;
	eval "require Config; Config->import";
	if ($@) {
	    warn "test.pl had problems loading Config: $@";
	    $exe = '';
	} else {
	    $exe = $Config{_exe};
	}
       $exe = '' unless defined $exe;
	
	# This doesn't absolutize the path: beware of future chdirs().
	# We could do File::Spec->abs2rel() but that does getcwd()s,
	# which is a bit heavyweight to do here.
	
	if ($Perl =~ /^perl\Q$exe\E$/i) {
	    my $perl = "perl$exe";
	    eval "require File::Spec";
	    if ($@) {
		warn "test.pl had problems loading File::Spec: $@";
		$Perl = "./$perl";
	    } else {
		$Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
	    }
	}

	# Build up the name of the executable file from the name of
	# the command.

	if ($Perl !~ /\Q$exe\E$/i) {
	    $Perl .= $exe;
	}

	warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
	
	# For subcommands to use.
	$ENV{PERLEXE} = $Perl;
    }
    return $Perl;
}

sub unlink_all {
    foreach my $file (@_) {
        1 while unlink $file;
        print STDERR "# Couldn't unlink '$file': $!\n" if -f $file;
    }
}


my $tmpfile = "misctmp000";
1 while -f ++$tmpfile;
END { unlink_all $tmpfile }

#
# _fresh_perl
#
# The $resolve must be a subref that tests the first argument
# for success, or returns the definition of success (e.g. the
# expected scalar) if given no arguments.
#

sub _fresh_perl {
    my($prog, $resolve, $runperl_args, $name) = @_;

    $runperl_args ||= {};
    $runperl_args->{progfile} = $tmpfile;
    $runperl_args->{stderr} = 1;

    open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";

    # VMS adjustments
    if( $^O eq 'VMS' ) {
        $prog =~ s#/dev/null#NL:#;

        # VMS file locking 
        $prog =~ s{if \(-e _ and -f _ and -r _\)}
                  {if (-e _ and -f _)}
    }

    print TEST $prog;
    close TEST or die "Cannot close $tmpfile: $!";

    my $results = runperl(%$runperl_args);
    my $status = $?;

    # Clean up the results into something a bit more predictable.
    $results =~ s/\n+$//;
    $results =~ s/at\s+misctmp\d+\s+line/at - line/g;
    $results =~ s/of\s+misctmp\d+\s+aborted/of - aborted/g;

    # bison says 'parse error' instead of 'syntax error',
    # various yaccs may or may not capitalize 'syntax'.
    $results =~ s/^(syntax|parse) error/syntax error/mig;

    if ($^O eq 'VMS') {
        # some tests will trigger VMS messages that won't be expected
        $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;

        # pipes double these sometimes
        $results =~ s/\n\n/\n/g;
    }

    my $pass = $resolve->($results);
    unless ($pass) {
        _diag "# PROG: \n$prog\n";
        _diag "# EXPECTED:\n", $resolve->(), "\n";
        _diag "# GOT:\n$results\n";
        _diag "# STATUS: $status\n";
    }

    # Use the first line of the program as a name if none was given
    unless( $name ) {
        ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
        $name .= '...' if length $first_line > length $name;
    }

    _ok($pass, _where(), "fresh_perl - $name");
}

#
# fresh_perl_is
#
# Combination of run_perl() and is().
#

sub fresh_perl_is {
    my($prog, $expected, $runperl_args, $name) = @_;
    local $Level = 2;
    _fresh_perl($prog,
		sub { @_ ? $_[0] eq $expected : $expected },
		$runperl_args, $name);
}

#
# fresh_perl_like
#
# Combination of run_perl() and like().
#

sub fresh_perl_like {
    my($prog, $expected, $runperl_args, $name) = @_;
    local $Level = 2;
    _fresh_perl($prog,
		sub { @_ ?
			  $_[0] =~ (ref $expected ? $expected : /$expected/) :
		          $expected },
		$runperl_args, $name);
}

sub can_ok ($@) {
    my($proto, @methods) = @_;
    my $class = ref $proto || $proto;

    unless( @methods ) {
        return _ok( 0, _where(), "$class->can(...)" );
    }

    my @nok = ();
    foreach my $method (@methods) {
        local($!, $@);  # don't interfere with caller's $@
                        # eval sometimes resets $!
        eval { $proto->can($method) } || push @nok, $method;
    }

    my $name;
    $name = @methods == 1 ? "$class->can('$methods[0]')" 
                          : "$class->can(...)";
    
    _ok( !@nok, _where(), $name );
}

sub isa_ok ($$;$) {
    my($object, $class, $obj_name) = @_;

    my $diag;
    $obj_name = 'The object' unless defined $obj_name;
    my $name = "$obj_name isa $class";
    if( !defined $object ) {
        $diag = "$obj_name isn't defined";
    }
    elsif( !ref $object ) {
        $diag = "$obj_name isn't a reference";
    }
    else {
        # We can't use UNIVERSAL::isa because we want to honor isa() overrides
        local($@, $!);  # eval sometimes resets $!
        my $rslt = eval { $object->isa($class) };
        if( $@ ) {
            if( $@ =~ /^Can't call method "isa" on unblessed reference/ ) {
                if( !UNIVERSAL::isa($object, $class) ) {
                    my $ref = ref $object;
                    $diag = "$obj_name isn't a '$class' it's a '$ref'";
                }
            } else {
                die <<WHOA;
WHOA! I tried to call ->isa on your object and got some weird error.
This should never happen.  Please contact the author immediately.
Here's the error.
$@
WHOA
            }
        }
        elsif( !$rslt ) {
            my $ref = ref $object;
            $diag = "$obj_name isn't a '$class' it's a '$ref'";
        }
    }

    _ok( !$diag, _where(), $name );
}

1;
Commit	Line	Data
69026470	1	#
	2	# t/test.pl - most of Test::More functionality without the fuss
	3	#
	4
dcc7f481	5	$Level = 1;
69026470	6	my $test = 1;
69026470	7	my $planned;
6137113d	8	my $noplan;
69026470	9
7d932aad	10	$TODO = 0;
b6345914	11	$NO_ENDING = 0;
7d932aad	12
69026470	13	sub plan {
	14	my $n;
	15	if (@_ == 1) {
	16	$n = shift;
6137113d	17	if ($n eq 'no_plan') {
	18	undef $n;
	19	$noplan = 1;
	20	}
69026470	21	} else {
	22	my %plan = @_;
	23	$n = $plan{tests};
	24	}
6137113d	25	print STDOUT "1..$n\n" unless $noplan;
69026470	26	$planned = $n;
	27	}
	28
	29	END {
	30	my $ran = $test - 1;
6137113d	31	if (!$NO_ENDING) {
	32	if (defined $planned && $planned != $ran) {
	33	print STDERR
	34	"# Looks like you planned $planned tests but ran $ran.\n";
	35	} elsif ($noplan) {
	36	print "1..$ran\n";
	37	}
69026470	38	}
	39	}
	40
de522f7a	41	# Use this instead of "print STDERR" when outputing failure diagnostic
	42	# messages
	43	sub _diag {
cf8feb78	44	return unless @_;
	45	my @mess = map { /^#/ ? "$_\n" : "# $_\n" }
	46	map { split /\n/ } @_;
de522f7a	47	my $fh = $TODO ? STDOUT : STDERR;
cf8feb78	48	print $fh @mess;
cf8feb78	49
de522f7a	50	}
de522f7a	51
69026470	52	sub skip_all {
69026470	53	if (@_) {
195d559b	54	print STDOUT "1..0 # Skipped: @_\n";
69026470	55	} else {
ad20d923	56	print STDOUT "1..0\n";
69026470	57	}
	58	exit(0);
	59	}
	60
	61	sub _ok {
7d932aad	62	my ($pass, $where, $name, @mess) = @_;
69026470	63	# Do not try to microoptimize by factoring out the "not ".
69026470	64	# VMS will avenge.
7d932aad	65	my $out;
7d932aad	66	if ($name) {
b734d6c9	67	# escape out '#' or it will interfere with '# skip' and such
b734d6c9	68	$name =~ s/#/\\#/g;
7d932aad	69	$out = $pass ? "ok $test - $name" : "not ok $test - $name";
69026470	70	} else {
7d932aad	71	$out = $pass ? "ok $test" : "not ok $test";
69026470	72	}
7d932aad	73
7d932aad	74	$out .= " # TODO $TODO" if $TODO;
ad20d923	75	print STDOUT "$out\n";
7d932aad	76
69026470	77	unless ($pass) {
de522f7a	78	_diag "# Failed $where\n";
69026470	79	}
7d932aad	80
7d932aad	81	# Ensure that the message is properly escaped.
cf8feb78	82	_diag @mess;
7d932aad	83
69026470	84	$test++;
1577bb16	85
1577bb16	86	return $pass;
69026470	87	}
	88
	89	sub _where {
dcc7f481	90	my @caller = caller($Level);
69026470	91	return "at $caller[1] line $caller[2]";
	92	}
	93
1d662fb6	94	# DON'T use this for matches. Use like() instead.
c3029c66	95	sub ok ($@) {
7d932aad	96	my ($pass, $name, @mess) = @_;
7d932aad	97	_ok($pass, _where(), $name, @mess);
69026470	98	}
69026470	99
b3c72391	100	sub _q {
	101	my $x = shift;
	102	return 'undef' unless defined $x;
	103	my $q = $x;
d279d8f8	104	$q =~ s/\\/\\\\/g;
d279d8f8	105	$q =~ s/'/\\'/g;
b3c72391	106	return "'$q'";
	107	}
	108
677fb045	109	sub _qq {
	110	my $x = shift;
	111	return defined $x ? '"' . display ($x) . '"' : 'undef';
	112	};
	113
	114	# keys are the codes \n etc map to, values are 2 char strings such as \n
	115	my %backslash_escape;
	116	foreach my $x (split //, 'nrtfa\\\'"') {
	117	$backslash_escape{ord eval "\"\\$x\""} = "\\$x";
	118	}
	119	# A way to display scalars containing control characters and Unicode.
	120	# Trying to avoid setting $_, or relying on local $_ to work.
	121	sub display {
	122	my @result;
	123	foreach my $x (@_) {
	124	if (defined $x and not ref $x) {
	125	my $y = '';
	126	foreach my $c (unpack("U*", $x)) {
	127	if ($c > 255) {
	128	$y .= sprintf "\\x{%x}", $c;
	129	} elsif ($backslash_escape{$c}) {
	130	$y .= $backslash_escape{$c};
	131	} else {
	132	my $z = chr $c; # Maybe we can get away with a literal...
	133	$z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
	134	$y .= $z;
	135	}
	136	}
	137	$x = $y;
	138	}
	139	return $x unless wantarray;
	140	push @result, $x;
	141	}
	142	return @result;
	143	}
	144
c3029c66	145	sub is ($$@) {
7d932aad	146	my ($got, $expected, $name, @mess) = @_;
c831d34f	147
	148	my $pass;
	149	if( !defined $got \|\| !defined $expected ) {
	150	# undef only matches undef
	151	$pass = !defined $got && !defined $expected;
	152	}
	153	else {
	154	$pass = $got eq $expected;
	155	}
	156
69026470	157	unless ($pass) {
b3c72391	158	unshift(@mess, "# got "._q($got)."\n",
b3c72391	159	"# expected "._q($expected)."\n");
69026470	160	}
7d932aad	161	_ok($pass, _where(), $name, @mess);
69026470	162	}
69026470	163
c3029c66	164	sub isnt ($$@) {
3e90d5a3	165	my ($got, $isnt, $name, @mess) = @_;
c831d34f	166
	167	my $pass;
	168	if( !defined $got \|\| !defined $isnt ) {
	169	# undef only matches undef
	170	$pass = defined $got \|\| defined $isnt;
	171	}
	172	else {
	173	$pass = $got ne $isnt;
	174	}
	175
3e90d5a3	176	unless( $pass ) {
b3c72391	177	unshift(@mess, "# it should not be "._q($got)."\n",
3e90d5a3	178	"# but it is.\n");
	179	}
	180	_ok($pass, _where(), $name, @mess);
	181	}
	182
c3029c66	183	sub cmp_ok ($$$@) {
58d76dfd	184	my($got, $type, $expected, $name, @mess) = @_;
	185
	186	my $pass;
	187	{
	188	local $^W = 0;
	189	local($@,$!); # don't interfere with $@
	190	# eval() sometimes resets $!
	191	$pass = eval "\$got $type \$expected";
	192	}
	193	unless ($pass) {
	194	# It seems Irix long doubles can have 2147483648 and 2147483648
	195	# that stringify to the same thing but are acutally numerically
	196	# different. Display the numbers if $type isn't a string operator,
	197	# and the numbers are stringwise the same.
	198	# (all string operators have alphabetic names, so tr/a-z// is true)
	199	# This will also show numbers for some uneeded cases, but will
	200	# definately be helpful for things such as == and <= that fail
	201	if ($got eq $expected and $type !~ tr/a-z//) {
	202	unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
	203	}
	204	unshift(@mess, "# got "._q($got)."\n",
	205	"# expected $type "._q($expected)."\n");
	206	}
	207	_ok($pass, _where(), $name, @mess);
	208	}
	209
	210	# Check that $got is within $range of $expected
	211	# if $range is 0, then check it's exact
	212	# else if $expected is 0, then $range is an absolute value
	213	# otherwise $range is a fractional error.
	214	# Here $range must be numeric, >= 0
	215	# Non numeric ranges might be a useful future extension. (eg %)
c3029c66	216	sub within ($$$@) {
58d76dfd	217	my ($got, $expected, $range, $name, @mess) = @_;
	218	my $pass;
	219	if (!defined $got or !defined $expected or !defined $range) {
	220	# This is a fail, but doesn't need extra diagnostics
	221	} elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
	222	# This is a fail
	223	unshift @mess, "# got, expected and range must be numeric\n";
	224	} elsif ($range < 0) {
	225	# This is also a fail
	226	unshift @mess, "# range must not be negative\n";
	227	} elsif ($range == 0) {
	228	# Within 0 is ==
	229	$pass = $got == $expected;
	230	} elsif ($expected == 0) {
	231	# If expected is 0, treat range as absolute
	232	$pass = ($got <= $range) && ($got >= - $range);
	233	} else {
	234	my $diff = $got - $expected;
	235	$pass = abs ($diff / $expected) < $range;
	236	}
	237	unless ($pass) {
	238	if ($got eq $expected) {
	239	unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
	240	}
	241	unshift@mess, "# got "._q($got)."\n",
	242	"# expected "._q($expected)." (within "._q($range).")\n";
	243	}
	244	_ok($pass, _where(), $name, @mess);
	245	}
	246
69026470	247	# Note: this isn't quite as fancy as Test::More::like().
724aa791	248
	249	sub like ($$@) { like_yn (0,@_) }; # 0 for -
	250	sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
	251
	252	sub like_yn ($$$@) {
	253	my ($flip, $got, $expected, $name, @mess) = @_;
69026470	254	my $pass;
724aa791	255	$pass = $got =~ /$expected/ if !$flip;
	256	$pass = $got !~ /$expected/ if $flip;
	257	unless ($pass) {
	258	unshift(@mess, "# got '$got'\n",
	259	"# expected /$expected/\n");
69026470	260	}
8fb276b8	261	local $Level = 2;
7d932aad	262	_ok($pass, _where(), $name, @mess);
69026470	263	}
	264
	265	sub pass {
	266	_ok(1, '', @_);
	267	}
	268
	269	sub fail {
	270	_ok(0, _where(), @_);
	271	}
	272
ad20d923	273	sub curr_test {
cf8feb78	274	$test = shift if @_;
ad20d923	275	return $test;
	276	}
	277
3e90d5a3	278	sub next_test {
cf8feb78	279	$test++;
3e90d5a3	280	}
3e90d5a3	281
69026470	282	# Note: can't pass multipart messages since we try to
	283	# be compatible with Test::More::skip().
	284	sub skip {
7d932aad	285	my $why = shift;
982b7cb7	286	my $n = @_ ? shift : 1;
69026470	287	for (1..$n) {
ad20d923	288	print STDOUT "ok $test # skip: $why\n";
e6c299c8	289	$test++;
69026470	290	}
	291	local $^W = 0;
	292	last SKIP;
	293	}
	294
09f04786	295	sub todo_skip {
	296	my $why = shift;
	297	my $n = @_ ? shift : 1;
	298
	299	for (1..$n) {
a27e4e7f	300	print STDOUT "not ok $test # TODO & SKIP: $why\n";
09f04786	301	$test++;
	302	}
	303	local $^W = 0;
	304	last TODO;
	305	}
	306
69026470	307	sub eq_array {
	308	my ($ra, $rb) = @_;
	309	return 0 unless $#$ra == $#$rb;
	310	for my $i (0..$#$ra) {
135d199b	311	next if !defined $ra->[$i] && !defined $rb->[$i];
	312	return 0 if !defined $ra->[$i];
	313	return 0 if !defined $rb->[$i];
69026470	314	return 0 unless $ra->[$i] eq $rb->[$i];
	315	}
	316	return 1;
	317	}
	318
677fb045	319	sub eq_hash {
	320	my ($orig, $suspect) = @_;
	321	my $fail;
	322	while (my ($key, $value) = each %$suspect) {
	323	# Force a hash recompute if this perl's internals can cache the hash key.
	324	$key = "" . $key;
	325	if (exists $orig->{$key}) {
	326	if ($orig->{$key} ne $value) {
de522f7a	327	print STDOUT "# key ", _qq($key), " was ", _qq($orig->{$key}),
de522f7a	328	" now ", _qq($value), "\n";
677fb045	329	$fail = 1;
	330	}
	331	} else {
de522f7a	332	print STDOUT "# key ", _qq($key), " is ", _qq($value),
75385f53	333	", not in original.\n";
677fb045	334	$fail = 1;
	335	}
	336	}
	337	foreach (keys %$orig) {
	338	# Force a hash recompute if this perl's internals can cache the hash key.
	339	$_ = "" . $_;
	340	next if (exists $suspect->{$_});
de522f7a	341	print STDOUT "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
677fb045	342	$fail = 1;
	343	}
	344	!$fail;
	345	}
	346
c3029c66	347	sub require_ok ($) {
69026470	348	my ($require) = @_;
	349	eval <<REQUIRE_OK;
	350	require $require;
	351	REQUIRE_OK
1577bb16	352	_ok(!$@, _where(), "require $require");
69026470	353	}
69026470	354
c3029c66	355	sub use_ok ($) {
69026470	356	my ($use) = @_;
	357	eval <<USE_OK;
	358	use $use;
	359	USE_OK
1577bb16	360	_ok(!$@, _where(), "use $use");
69026470	361	}
69026470	362
137352a2	363	# runperl - Runs a separate perl interpreter.
	364	# Arguments :
	365	# switches => [ command-line switches ]
	366	# nolib => 1 # don't use -I../lib (included by default)
	367	# prog => one-liner (avoid quotes)
d83945bc	368	# progs => [ multi-liner (avoid quotes) ]
137352a2	369	# progfile => perl script
	370	# stdin => string to feed the stdin
	371	# stderr => redirect stderr to stdout
	372	# args => [ command-line arguments to the perl program ]
cb9c5e20	373	# verbose => print the command line
137352a2	374
	375	my $is_mswin = $^O eq 'MSWin32';
	376	my $is_netware = $^O eq 'NetWare';
	377	my $is_macos = $^O eq 'MacOS';
	378	my $is_vms = $^O eq 'VMS';
	379
cb9c5e20	380	sub _quote_args {
	381	my ($runperl, $args) = @_;
	382
	383	foreach (@$args) {
	384	# In VMS protect with doublequotes because otherwise
	385	# DCL will lowercase -- unless already doublequoted.
ea9ac5ad	386	$_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
cb9c5e20	387	$$runperl .= ' ' . $_;
	388	}
	389	}
	390
4cd2bd1f	391	sub _create_runperl { # Create the string to qx in runperl().
137352a2	392	my %args = @_;
44cb023c	393	my $runperl = $^X =~ m/\s/ ? qq{"$^X"} : $^X;
6cf707aa	394	#- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
	395	if ($ENV{PERL_RUNPERL_DEBUG}) {
	396	$runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
	397	}
f93a5f07	398	unless ($args{nolib}) {
f93a5f07	399	if ($is_macos) {
cb9c5e20	400	$runperl .= ' -I::lib';
f93a5f07	401	# Use UNIX style error messages instead of MPW style.
cb9c5e20	402	$runperl .= ' -MMac::err=unix' if $args{stderr};
137352a2	403	}
137352a2	404	else {
cb9c5e20	405	$runperl .= ' "-I../lib"'; # doublequotes because of VMS
137352a2	406	}
137352a2	407	}
d83945bc	408	if ($args{switches}) {
343d4a7b	409	local $Level = 2;
	410	die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
	411	unless ref $args{switches} eq "ARRAY";
d83945bc	412	_quote_args(\$runperl, $args{switches});
d83945bc	413	}
137352a2	414	if (defined $args{prog}) {
21820af6	415	die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
21820af6	416	if defined $args{progs};
d83945bc	417	$args{progs} = [$args{prog}]
	418	}
	419	if (defined $args{progs}) {
21820af6	420	die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
21820af6	421	unless ref $args{progs} eq "ARRAY";
d83945bc	422	foreach my $prog (@{$args{progs}}) {
	423	if ($is_mswin \|\| $is_netware \|\| $is_vms) {
	424	$runperl .= qq ( -e "$prog" );
	425	}
	426	else {
	427	$runperl .= qq ( -e '$prog' );
	428	}
	429	}
137352a2	430	} elsif (defined $args{progfile}) {
137352a2	431	$runperl .= qq( "$args{progfile}");
9a731dbd	432	} else {
	433	# You probaby didn't want to be sucking in from the upstream stdin
	434	die "test.pl:runperl(): none of prog, progs, progfile, args, "
	435	. " switches or stdin specified"
	436	unless defined $args{args} or defined $args{switches}
	437	or defined $args{stdin};
137352a2	438	}
137352a2	439	if (defined $args{stdin}) {
dc459aad	440	# so we don't try to put literal newlines and crs onto the
	441	# command line.
	442	$args{stdin} =~ s/\n/\\n/g;
	443	$args{stdin} =~ s/\r/\\r/g;
5ae09a77	444
137352a2	445	if ($is_mswin \|\| $is_netware \|\| $is_vms) {
f93a5f07	446	$runperl = qq{$^X -e "print qq(} .
137352a2	447	$args{stdin} . q{)" \| } . $runperl;
137352a2	448	}
dc459aad	449	elsif ($is_macos) {
	450	# MacOS can only do two processes under MPW at once;
	451	# the test itself is one; we can't do two more, so
	452	# write to temp file
	453	my $stdin = qq{$^X -e 'print qq(} . $args{stdin} . qq{)' > teststdin; };
	454	if ($args{verbose}) {
	455	my $stdindisplay = $stdin;
	456	$stdindisplay =~ s/\n/\n\#/g;
	457	print STDERR "# $stdindisplay\n";
	458	}
	459	`$stdin`;
	460	$runperl .= q{ < teststdin };
	461	}
137352a2	462	else {
f93a5f07	463	$runperl = qq{$^X -e 'print qq(} .
137352a2	464	$args{stdin} . q{)' \| } . $runperl;
	465	}
	466	}
	467	if (defined $args{args}) {
cb9c5e20	468	_quote_args(\$runperl, $args{args});
	469	}
	470	$runperl .= ' 2>&1' if $args{stderr} && !$is_macos;
	471	$runperl .= " \xB3 Dev:Null" if !$args{stderr} && $is_macos;
	472	if ($args{verbose}) {
	473	my $runperldisplay = $runperl;
	474	$runperldisplay =~ s/\n/\n\#/g;
75385f53	475	print STDERR "# $runperldisplay\n";
137352a2	476	}
4cd2bd1f	477	return $runperl;
	478	}
	479
	480	sub runperl {
9a731dbd	481	die "test.pl:runperl() does not take a hashref"
9a731dbd	482	if ref $_[0] and ref $_[0] eq 'HASH';
4cd2bd1f	483	my $runperl = &_create_runperl;
137352a2	484	my $result = `$runperl`;
	485	$result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
	486	return $result;
	487	}
	488
d2c6a9c9	489	*run_perl = \&runperl; # Nice alias.
8799135f	490
c4fbe247	491	sub DIE {
75385f53	492	print STDERR "# @_\n";
c4fbe247	493	exit 1;
8799135f	494	}
8799135f	495
b5fe401b	496	# A somewhat safer version of the sometimes wrong $^X.
17a740d5	497	my $Perl;
	498	sub which_perl {
	499	unless (defined $Perl) {
	500	$Perl = $^X;
	501
73421c4a	502	# VMS should have 'perl' aliased properly
	503	return $Perl if $^O eq 'VMS';
	504
17a740d5	505	my $exe;
17a740d5	506	eval "require Config; Config->import";
85363d30	507	if ($@) {
17a740d5	508	warn "test.pl had problems loading Config: $@";
17a740d5	509	$exe = '';
85363d30	510	} else {
17a740d5	511	$exe = $Config{_exe};
85363d30	512	}
da405c16	513	$exe = '' unless defined $exe;
17a740d5	514
	515	# This doesn't absolutize the path: beware of future chdirs().
	516	# We could do File::Spec->abs2rel() but that does getcwd()s,
	517	# which is a bit heavyweight to do here.
	518
	519	if ($Perl =~ /^perl\Q$exe\E$/i) {
8db06b02	520	my $perl = "perl$exe";
17a740d5	521	eval "require File::Spec";
	522	if ($@) {
	523	warn "test.pl had problems loading File::Spec: $@";
8db06b02	524	$Perl = "./$perl";
17a740d5	525	} else {
8db06b02	526	$Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
17a740d5	527	}
17a740d5	528	}
196918b0	529
	530	# Build up the name of the executable file from the name of
	531	# the command.
	532
	533	if ($Perl !~ /\Q$exe\E$/i) {
	534	$Perl .= $exe;
	535	}
c880be78	536
8db06b02	537	warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
17a740d5	538
	539	# For subcommands to use.
	540	$ENV{PERLEXE} = $Perl;
85363d30	541	}
17a740d5	542	return $Perl;
b5fe401b	543	}
b5fe401b	544
435e7af6	545	sub unlink_all {
	546	foreach my $file (@_) {
	547	1 while unlink $file;
75385f53	548	print STDERR "# Couldn't unlink '$file': $!\n" if -f $file;
435e7af6	549	}
435e7af6	550	}
eeabcb2d	551
	552
	553	my $tmpfile = "misctmp000";
	554	1 while -f ++$tmpfile;
	555	END { unlink_all $tmpfile }
	556
f5cda331	557	#
	558	# _fresh_perl
	559	#
	560	# The $resolve must be a subref that tests the first argument
	561	# for success, or returns the definition of success (e.g. the
	562	# expected scalar) if given no arguments.
	563	#
	564
	565	sub _fresh_perl {
	566	my($prog, $resolve, $runperl_args, $name) = @_;
eeabcb2d	567
	568	$runperl_args \|\|= {};
	569	$runperl_args->{progfile} = $tmpfile;
	570	$runperl_args->{stderr} = 1;
	571
	572	open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
	573
	574	# VMS adjustments
	575	if( $^O eq 'VMS' ) {
	576	$prog =~ s#/dev/null#NL:#;
	577
	578	# VMS file locking
	579	$prog =~ s{if \(-e _ and -f _ and -r _\)}
	580	{if (-e _ and -f _)}
	581	}
	582
0d65d7d5	583	print TEST $prog;
eeabcb2d	584	close TEST or die "Cannot close $tmpfile: $!";
	585
	586	my $results = runperl(%$runperl_args);
	587	my $status = $?;
	588
	589	# Clean up the results into something a bit more predictable.
	590	$results =~ s/\n+$//;
	591	$results =~ s/at\s+misctmp\d+\s+line/at - line/g;
	592	$results =~ s/of\s+misctmp\d+\s+aborted/of - aborted/g;
	593
	594	# bison says 'parse error' instead of 'syntax error',
	595	# various yaccs may or may not capitalize 'syntax'.
	596	$results =~ s/^(syntax\|parse) error/syntax error/mig;
	597
	598	if ($^O eq 'VMS') {
	599	# some tests will trigger VMS messages that won't be expected
	600	$results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
	601
	602	# pipes double these sometimes
	603	$results =~ s/\n\n/\n/g;
	604	}
	605
f5cda331	606	my $pass = $resolve->($results);
eeabcb2d	607	unless ($pass) {
cf8feb78	608	_diag "# PROG: \n$prog\n";
	609	_diag "# EXPECTED:\n", $resolve->(), "\n";
	610	_diag "# GOT:\n$results\n";
	611	_diag "# STATUS: $status\n";
eeabcb2d	612	}
eeabcb2d	613
e2c38acd	614	# Use the first line of the program as a name if none was given
	615	unless( $name ) {
	616	($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
	617	$name .= '...' if length $first_line > length $name;
	618	}
eeabcb2d	619
f5cda331	620	_ok($pass, _where(), "fresh_perl - $name");
	621	}
	622
	623	#
141f445b	624	# fresh_perl_is
f5cda331	625	#
	626	# Combination of run_perl() and is().
	627	#
	628
	629	sub fresh_perl_is {
	630	my($prog, $expected, $runperl_args, $name) = @_;
dcc7f481	631	local $Level = 2;
f5cda331	632	_fresh_perl($prog,
	633	sub { @_ ? $_[0] eq $expected : $expected },
	634	$runperl_args, $name);
	635	}
	636
	637	#
141f445b	638	# fresh_perl_like
f5cda331	639	#
	640	# Combination of run_perl() and like().
	641	#
	642
	643	sub fresh_perl_like {
	644	my($prog, $expected, $runperl_args, $name) = @_;
dcc7f481	645	local $Level = 2;
f5cda331	646	_fresh_perl($prog,
	647	sub { @_ ?
	648	$_[0] =~ (ref $expected ? $expected : /$expected/) :
	649	$expected },
	650	$runperl_args, $name);
eeabcb2d	651	}
eeabcb2d	652
35a60386	653	sub can_ok ($@) {
	654	my($proto, @methods) = @_;
	655	my $class = ref $proto \|\| $proto;
	656
	657	unless( @methods ) {
	658	return _ok( 0, _where(), "$class->can(...)" );
	659	}
	660
	661	my @nok = ();
	662	foreach my $method (@methods) {
	663	local($!, $@); # don't interfere with caller's $@
	664	# eval sometimes resets $!
	665	eval { $proto->can($method) } \|\| push @nok, $method;
	666	}
	667
	668	my $name;
	669	$name = @methods == 1 ? "$class->can('$methods[0]')"
	670	: "$class->can(...)";
	671
	672	_ok( !@nok, _where(), $name );
	673	}
	674
	675	sub isa_ok ($$;$) {
	676	my($object, $class, $obj_name) = @_;
	677
	678	my $diag;
	679	$obj_name = 'The object' unless defined $obj_name;
	680	my $name = "$obj_name isa $class";
	681	if( !defined $object ) {
	682	$diag = "$obj_name isn't defined";
	683	}
	684	elsif( !ref $object ) {
	685	$diag = "$obj_name isn't a reference";
	686	}
	687	else {
	688	# We can't use UNIVERSAL::isa because we want to honor isa() overrides
	689	local($@, $!); # eval sometimes resets $!
	690	my $rslt = eval { $object->isa($class) };
	691	if( $@ ) {
	692	if( $@ =~ /^Can't call method "isa" on unblessed reference/ ) {
	693	if( !UNIVERSAL::isa($object, $class) ) {
	694	my $ref = ref $object;
	695	$diag = "$obj_name isn't a '$class' it's a '$ref'";
	696	}
	697	} else {
	698	die <<WHOA;
	699	WHOA! I tried to call ->isa on your object and got some weird error.
	700	This should never happen. Please contact the author immediately.
	701	Here's the error.
	702	$@
	703	WHOA
	704	}
	705	}
	706	elsif( !$rslt ) {
	707	my $ref = ref $object;
	708	$diag = "$obj_name isn't a '$class' it's a '$ref'";
	709	}
	710	}
	711
	712	_ok( !$diag, _where(), $name );
	713	}
	714
69026470	715	1;