[p5sagit/p5-mst-13.2.git] / t / test.pl

#
# t/test.pl - most of Test::More functionality without the fuss
#

$Level = 1;
my $test = 1;
my $planned;

$TODO = 0;
$NO_ENDING = 0;

sub plan {
    my $n;
    if (@_ == 1) {
	$n = shift;
    } else {
	my %plan = @_;
	$n = $plan{tests}; 
    }
    print STDOUT "1..$n\n";
    $planned = $n;
}

END {
    my $ran = $test - 1;
    if (!$NO_ENDING && defined $planned && $planned != $ran) {
        print STDERR "# Looks like you planned $planned tests but ran $ran.\n";
    }
}

# Use this instead of "print STDERR" when outputing failure diagnostic 
# messages
sub _diag {
    return unless @_;
    my @mess = map { /^#/ ? "$_\n" : "# $_\n" } 
               map { split /\n/ } @_;
    my $fh = $TODO ? *STDOUT : *STDERR;
    print $fh @mess;

}

sub skip_all {
    if (@_) {
	print STDOUT "1..0 # Skipped: @_\n";
    } else {
	print STDOUT "1..0\n";
    }
    exit(0);
}

sub _ok {
    my ($pass, $where, $name, @mess) = @_;
    # Do not try to microoptimize by factoring out the "not ".
    # VMS will avenge.
    my $out;
    if ($name) {
        # escape out '#' or it will interfere with '# skip' and such
        $name =~ s/#/\\#/g;
	$out = $pass ? "ok $test - $name" : "not ok $test - $name";
    } else {
	$out = $pass ? "ok $test" : "not ok $test";
    }

    $out .= " # TODO $TODO" if $TODO;
    print STDOUT "$out\n";

    unless ($pass) {
	_diag "# Failed $where\n";
    }

    # Ensure that the message is properly escaped.
    _diag @mess;

    $test++;

    return $pass;
}

sub _where {
    my @caller = caller($Level);
    return "at $caller[1] line $caller[2]";
}

# DON'T use this for matches. Use like() instead.
sub ok ($@) {
    my ($pass, $name, @mess) = @_;
    _ok($pass, _where(), $name, @mess);
}

sub _q {
    my $x = shift;
    return 'undef' unless defined $x;
    my $q = $x;
    $q =~ s/\\/\\\\/;
    $q =~ s/'/\\'/;
    return "'$q'";
}

sub _qq {
    my $x = shift;
    return defined $x ? '"' . display ($x) . '"' : 'undef';
};

# keys are the codes \n etc map to, values are 2 char strings such as \n
my %backslash_escape;
foreach my $x (split //, 'nrtfa\\\'"') {
    $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
}
# A way to display scalars containing control characters and Unicode.
# Trying to avoid setting $_, or relying on local $_ to work.
sub display {
    my @result;
    foreach my $x (@_) {
        if (defined $x and not ref $x) {
            my $y = '';
            foreach my $c (unpack("U*", $x)) {
                if ($c > 255) {
                    $y .= sprintf "\\x{%x}", $c;
                } elsif ($backslash_escape{$c}) {
                    $y .= $backslash_escape{$c};
                } else {
                    my $z = chr $c; # Maybe we can get away with a literal...
                    $z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
                    $y .= $z;
                }
            }
            $x = $y;
        }
        return $x unless wantarray;
        push @result, $x;
    }
    return @result;
}

sub is ($$@) {
    my ($got, $expected, $name, @mess) = @_;

    my $pass;
    if( !defined $got || !defined $expected ) {
        # undef only matches undef
        $pass = !defined $got && !defined $expected;
    }
    else {
        $pass = $got eq $expected;
    }

    unless ($pass) {
	unshift(@mess, "#      got "._q($got)."\n",
		       "# expected "._q($expected)."\n");
    }
    _ok($pass, _where(), $name, @mess);
}

sub isnt ($$@) {
    my ($got, $isnt, $name, @mess) = @_;

    my $pass;
    if( !defined $got || !defined $isnt ) {
        # undef only matches undef
        $pass = defined $got || defined $isnt;
    }
    else {
        $pass = $got ne $isnt;
    }

    unless( $pass ) {
        unshift(@mess, "# it should not be "._q($got)."\n",
                       "# but it is.\n");
    }
    _ok($pass, _where(), $name, @mess);
}

sub cmp_ok ($$$@) {
    my($got, $type, $expected, $name, @mess) = @_;

    my $pass;
    {
        local $^W = 0;
        local($@,$!);   # don't interfere with $@
                        # eval() sometimes resets $!
        $pass = eval "\$got $type \$expected";
    }
    unless ($pass) {
        # It seems Irix long doubles can have 2147483648 and 2147483648
        # that stringify to the same thing but are acutally numerically
        # different. Display the numbers if $type isn't a string operator,
        # and the numbers are stringwise the same.
        # (all string operators have alphabetic names, so tr/a-z// is true)
        # This will also show numbers for some uneeded cases, but will
        # definately be helpful for things such as == and <= that fail
        if ($got eq $expected and $type !~ tr/a-z//) {
            unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
        }
        unshift(@mess, "#      got "._q($got)."\n",
                       "# expected $type "._q($expected)."\n");
    }
    _ok($pass, _where(), $name, @mess);
}

# Check that $got is within $range of $expected
# if $range is 0, then check it's exact
# else if $expected is 0, then $range is an absolute value
# otherwise $range is a fractional error.
# Here $range must be numeric, >= 0
# Non numeric ranges might be a useful future extension. (eg %)
sub within ($$$@) {
    my ($got, $expected, $range, $name, @mess) = @_;
    my $pass;
    if (!defined $got or !defined $expected or !defined $range) {
        # This is a fail, but doesn't need extra diagnostics
    } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
        # This is a fail
        unshift @mess, "# got, expected and range must be numeric\n";
    } elsif ($range < 0) {
        # This is also a fail
        unshift @mess, "# range must not be negative\n";
    } elsif ($range == 0) {
        # Within 0 is ==
        $pass = $got == $expected;
    } elsif ($expected == 0) {
        # If expected is 0, treat range as absolute
        $pass = ($got <= $range) && ($got >= - $range);
    } else {
        my $diff = $got - $expected;
        $pass = abs ($diff / $expected) < $range;
    }
    unless ($pass) {
        if ($got eq $expected) {
            unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
        }
	unshift@mess, "#      got "._q($got)."\n",
		      "# expected "._q($expected)." (within "._q($range).")\n";
    }
    _ok($pass, _where(), $name, @mess);
}

# Note: this isn't quite as fancy as Test::More::like().

sub like   ($$@) { like_yn (0,@_) }; # 0 for -
sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-

sub like_yn ($$$@) {
    my ($flip, $got, $expected, $name, @mess) = @_;
    my $pass;
    $pass = $got =~ /$expected/ if !$flip;
    $pass = $got !~ /$expected/ if $flip;
    unless ($pass) {
	unshift(@mess, "#      got '$got'\n",
		"# expected /$expected/\n");
    }
    _ok($pass, _where(), $name, @mess);
}

sub pass {
    _ok(1, '', @_);
}

sub fail {
    _ok(0, _where(), @_);
}

sub curr_test {
    $test = shift if @_;
    return $test;
}

sub next_test {
  $test++;
}

# Note: can't pass multipart messages since we try to
# be compatible with Test::More::skip().
sub skip {
    my $why = shift;
    my $n    = @_ ? shift : 1;
    for (1..$n) {
        print STDOUT "ok $test # skip: $why\n";
        $test++;
    }
    local $^W = 0;
    last SKIP;
}

sub eq_array {
    my ($ra, $rb) = @_;
    return 0 unless $#$ra == $#$rb;
    for my $i (0..$#$ra) {
	return 0 unless $ra->[$i] eq $rb->[$i];
    }
    return 1;
}

sub eq_hash {
  my ($orig, $suspect) = @_;
  my $fail;
  while (my ($key, $value) = each %$suspect) {
    # Force a hash recompute if this perl's internals can cache the hash key.
    $key = "" . $key;
    if (exists $orig->{$key}) {
      if ($orig->{$key} ne $value) {
        print STDOUT "# key ", _qq($key), " was ", _qq($orig->{$key}),
                     " now ", _qq($value), "\n";
        $fail = 1;
      }
    } else {
      print STDOUT "# key ", _qq($key), " is ", _qq($value), 
                   ", not in original.\n";
      $fail = 1;
    }
  }
  foreach (keys %$orig) {
    # Force a hash recompute if this perl's internals can cache the hash key.
    $_ = "" . $_;
    next if (exists $suspect->{$_});
    print STDOUT "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
    $fail = 1;
  }
  !$fail;
}

sub require_ok ($) {
    my ($require) = @_;
    eval <<REQUIRE_OK;
require $require;
REQUIRE_OK
    _ok(!$@, _where(), "require $require");
}

sub use_ok ($) {
    my ($use) = @_;
    eval <<USE_OK;
use $use;
USE_OK
    _ok(!$@, _where(), "use $use");
}

# runperl - Runs a separate perl interpreter.
# Arguments :
#   switches => [ command-line switches ]
#   nolib    => 1 # don't use -I../lib (included by default)
#   prog     => one-liner (avoid quotes)
#   progs    => [ multi-liner (avoid quotes) ]
#   progfile => perl script
#   stdin    => string to feed the stdin
#   stderr   => redirect stderr to stdout
#   args     => [ command-line arguments to the perl program ]
#   verbose  => print the command line

my $is_mswin    = $^O eq 'MSWin32';
my $is_netware  = $^O eq 'NetWare';
my $is_macos    = $^O eq 'MacOS';
my $is_vms      = $^O eq 'VMS';

sub _quote_args {
    my ($runperl, $args) = @_;

    foreach (@$args) {
	# In VMS protect with doublequotes because otherwise
	# DCL will lowercase -- unless already doublequoted.
       $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
	$$runperl .= ' ' . $_;
    }
}

sub _create_runperl { # Create the string to qx in runperl().
    my %args = @_;
    my $runperl = $^X =~ m/\s/ ? qq{"$^X"} : $^X;
    unless ($args{nolib}) {
	if ($is_macos) {
	    $runperl .= ' -I::lib';
	    # Use UNIX style error messages instead of MPW style.
	    $runperl .= ' -MMac::err=unix' if $args{stderr};
	}
	else {
	    $runperl .= ' "-I../lib"'; # doublequotes because of VMS
	}
    }
    if ($args{switches}) {
	local $Level = 2;
	die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
	    unless ref $args{switches} eq "ARRAY";
	_quote_args(\$runperl, $args{switches});
    }
    if (defined $args{prog}) {
	die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
	    if defined $args{progs};
        $args{progs} = [$args{prog}]
    }
    if (defined $args{progs}) {
	die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
	    unless ref $args{progs} eq "ARRAY";
        foreach my $prog (@{$args{progs}}) {
            if ($is_mswin || $is_netware || $is_vms) {
                $runperl .= qq ( -e "$prog" );
            }
            else {
                $runperl .= qq ( -e '$prog' );
            }
        }
    } elsif (defined $args{progfile}) {
	$runperl .= qq( "$args{progfile}");
    }
    if (defined $args{stdin}) {
	# so we don't try to put literal newlines and crs onto the
	# command line.
	$args{stdin} =~ s/\n/\\n/g;
	$args{stdin} =~ s/\r/\\r/g;

	if ($is_mswin || $is_netware || $is_vms) {
	    $runperl = qq{$^X -e "print qq(} .
		$args{stdin} . q{)" | } . $runperl;
	}
	elsif ($is_macos) {
	    # MacOS can only do two processes under MPW at once;
	    # the test itself is one; we can't do two more, so
	    # write to temp file
	    my $stdin = qq{$^X -e 'print qq(} . $args{stdin} . qq{)' > teststdin; };
	    if ($args{verbose}) {
		my $stdindisplay = $stdin;
		$stdindisplay =~ s/\n/\n\#/g;
		print STDERR "# $stdindisplay\n";
	    }
	    `$stdin`;
	    $runperl .= q{ < teststdin };
	}
	else {
	    $runperl = qq{$^X -e 'print qq(} .
		$args{stdin} . q{)' | } . $runperl;
	}
    }
    if (defined $args{args}) {
	_quote_args(\$runperl, $args{args});
    }
    $runperl .= ' 2>&1'          if  $args{stderr} && !$is_macos;
    $runperl .= " \xB3 Dev:Null" if !$args{stderr} &&  $is_macos;
    if ($args{verbose}) {
	my $runperldisplay = $runperl;
	$runperldisplay =~ s/\n/\n\#/g;
	print STDERR "# $runperldisplay\n";
    }
    return $runperl;
}

sub runperl {
    my $runperl = &_create_runperl;
    my $result = `$runperl`;
    $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
    return $result;
}

*run_perl = \&runperl; # Nice alias.

sub DIE {
    print STDERR "# @_\n";
    exit 1;
}

# A somewhat safer version of the sometimes wrong $^X.
my $Perl;
sub which_perl {
    unless (defined $Perl) {
	$Perl = $^X;
	
	# VMS should have 'perl' aliased properly
	return $Perl if $^O eq 'VMS';

	my $exe;
	eval "require Config; Config->import";
	if ($@) {
	    warn "test.pl had problems loading Config: $@";
	    $exe = '';
	} else {
	    $exe = $Config{_exe};
	}
       $exe = '' unless defined $exe;
	
	# This doesn't absolutize the path: beware of future chdirs().
	# We could do File::Spec->abs2rel() but that does getcwd()s,
	# which is a bit heavyweight to do here.
	
	if ($Perl =~ /^perl\Q$exe\E$/i) {
	    my $perl = "perl$exe";
	    eval "require File::Spec";
	    if ($@) {
		warn "test.pl had problems loading File::Spec: $@";
		$Perl = "./$perl";
	    } else {
		$Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
	    }
	}

	# Build up the name of the executable file from the name of
	# the command.

	if ($Perl !~ /\Q$exe\E$/i) {
	    $Perl .= $exe;
	}

	warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
	
	# For subcommands to use.
	$ENV{PERLEXE} = $Perl;
    }
    return $Perl;
}

sub unlink_all {
    foreach my $file (@_) {
        1 while unlink $file;
        print STDERR "# Couldn't unlink '$file': $!\n" if -f $file;
    }
}


my $tmpfile = "misctmp000";
1 while -f ++$tmpfile;
END { unlink_all $tmpfile }

#
# _fresh_perl
#
# The $resolve must be a subref that tests the first argument
# for success, or returns the definition of success (e.g. the
# expected scalar) if given no arguments.
#

sub _fresh_perl {
    my($prog, $resolve, $runperl_args, $name) = @_;

    $runperl_args ||= {};
    $runperl_args->{progfile} = $tmpfile;
    $runperl_args->{stderr} = 1;

    open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";

    # VMS adjustments
    if( $^O eq 'VMS' ) {
        $prog =~ s#/dev/null#NL:#;

        # VMS file locking 
        $prog =~ s{if \(-e _ and -f _ and -r _\)}
                  {if (-e _ and -f _)}
    }

    print TEST $prog, "\n";
    close TEST or die "Cannot close $tmpfile: $!";

    my $results = runperl(%$runperl_args);
    my $status = $?;

    # Clean up the results into something a bit more predictable.
    $results =~ s/\n+$//;
    $results =~ s/at\s+misctmp\d+\s+line/at - line/g;
    $results =~ s/of\s+misctmp\d+\s+aborted/of - aborted/g;

    # bison says 'parse error' instead of 'syntax error',
    # various yaccs may or may not capitalize 'syntax'.
    $results =~ s/^(syntax|parse) error/syntax error/mig;

    if ($^O eq 'VMS') {
        # some tests will trigger VMS messages that won't be expected
        $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;

        # pipes double these sometimes
        $results =~ s/\n\n/\n/g;
    }

    my $pass = $resolve->($results);
    unless ($pass) {
        _diag "# PROG: \n$prog\n";
        _diag "# EXPECTED:\n", $resolve->(), "\n";
        _diag "# GOT:\n$results\n";
        _diag "# STATUS: $status\n";
    }

    # Use the first line of the program as a name if none was given
    unless( $name ) {
        ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
        $name .= '...' if length $first_line > length $name;
    }

    _ok($pass, _where(), "fresh_perl - $name");
}

#
# fresh_perl_is
#
# Combination of run_perl() and is().
#

sub fresh_perl_is {
    my($prog, $expected, $runperl_args, $name) = @_;
    local $Level = 2;
    _fresh_perl($prog,
		sub { @_ ? $_[0] eq $expected : $expected },
		$runperl_args, $name);
}

#
# fresh_perl_like
#
# Combination of run_perl() and like().
#

sub fresh_perl_like {
    my($prog, $expected, $runperl_args, $name) = @_;
    local $Level = 2;
    _fresh_perl($prog,
		sub { @_ ?
			  $_[0] =~ (ref $expected ? $expected : /$expected/) :
		          $expected },
		$runperl_args, $name);
}

1;
Commit	Line	Data
69026470	1	#
	2	# t/test.pl - most of Test::More functionality without the fuss
	3	#
	4
dcc7f481	5	$Level = 1;
69026470	6	my $test = 1;
	7	my $planned;
	8
7d932aad	9	$TODO = 0;
b6345914	10	$NO_ENDING = 0;
7d932aad	11
69026470	12	sub plan {
	13	my $n;
	14	if (@_ == 1) {
	15	$n = shift;
	16	} else {
	17	my %plan = @_;
	18	$n = $plan{tests};
	19	}
ad20d923	20	print STDOUT "1..$n\n";
69026470	21	$planned = $n;
	22	}
	23
	24	END {
	25	my $ran = $test - 1;
b6345914	26	if (!$NO_ENDING && defined $planned && $planned != $ran) {
75385f53	27	print STDERR "# Looks like you planned $planned tests but ran $ran.\n";
69026470	28	}
	29	}
	30
de522f7a	31	# Use this instead of "print STDERR" when outputing failure diagnostic
	32	# messages
	33	sub _diag {
cf8feb78	34	return unless @_;
	35	my @mess = map { /^#/ ? "$_\n" : "# $_\n" }
	36	map { split /\n/ } @_;
de522f7a	37	my $fh = $TODO ? STDOUT : STDERR;
cf8feb78	38	print $fh @mess;
cf8feb78	39
de522f7a	40	}
de522f7a	41
69026470	42	sub skip_all {
69026470	43	if (@_) {
195d559b	44	print STDOUT "1..0 # Skipped: @_\n";
69026470	45	} else {
ad20d923	46	print STDOUT "1..0\n";
69026470	47	}
	48	exit(0);
	49	}
	50
	51	sub _ok {
7d932aad	52	my ($pass, $where, $name, @mess) = @_;
69026470	53	# Do not try to microoptimize by factoring out the "not ".
69026470	54	# VMS will avenge.
7d932aad	55	my $out;
7d932aad	56	if ($name) {
b734d6c9	57	# escape out '#' or it will interfere with '# skip' and such
b734d6c9	58	$name =~ s/#/\\#/g;
7d932aad	59	$out = $pass ? "ok $test - $name" : "not ok $test - $name";
69026470	60	} else {
7d932aad	61	$out = $pass ? "ok $test" : "not ok $test";
69026470	62	}
7d932aad	63
7d932aad	64	$out .= " # TODO $TODO" if $TODO;
ad20d923	65	print STDOUT "$out\n";
7d932aad	66
69026470	67	unless ($pass) {
de522f7a	68	_diag "# Failed $where\n";
69026470	69	}
7d932aad	70
7d932aad	71	# Ensure that the message is properly escaped.
cf8feb78	72	_diag @mess;
7d932aad	73
69026470	74	$test++;
1577bb16	75
1577bb16	76	return $pass;
69026470	77	}
	78
	79	sub _where {
dcc7f481	80	my @caller = caller($Level);
69026470	81	return "at $caller[1] line $caller[2]";
	82	}
	83
1d662fb6	84	# DON'T use this for matches. Use like() instead.
c3029c66	85	sub ok ($@) {
7d932aad	86	my ($pass, $name, @mess) = @_;
7d932aad	87	_ok($pass, _where(), $name, @mess);
69026470	88	}
69026470	89
b3c72391	90	sub _q {
	91	my $x = shift;
	92	return 'undef' unless defined $x;
	93	my $q = $x;
677fb045	94	$q =~ s/\\/\\\\/;
b3c72391	95	$q =~ s/'/\\'/;
	96	return "'$q'";
	97	}
	98
677fb045	99	sub _qq {
	100	my $x = shift;
	101	return defined $x ? '"' . display ($x) . '"' : 'undef';
	102	};
	103
	104	# keys are the codes \n etc map to, values are 2 char strings such as \n
	105	my %backslash_escape;
	106	foreach my $x (split //, 'nrtfa\\\'"') {
	107	$backslash_escape{ord eval "\"\\$x\""} = "\\$x";
	108	}
	109	# A way to display scalars containing control characters and Unicode.
	110	# Trying to avoid setting $_, or relying on local $_ to work.
	111	sub display {
	112	my @result;
	113	foreach my $x (@_) {
	114	if (defined $x and not ref $x) {
	115	my $y = '';
	116	foreach my $c (unpack("U*", $x)) {
	117	if ($c > 255) {
	118	$y .= sprintf "\\x{%x}", $c;
	119	} elsif ($backslash_escape{$c}) {
	120	$y .= $backslash_escape{$c};
	121	} else {
	122	my $z = chr $c; # Maybe we can get away with a literal...
	123	$z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
	124	$y .= $z;
	125	}
	126	}
	127	$x = $y;
	128	}
	129	return $x unless wantarray;
	130	push @result, $x;
	131	}
	132	return @result;
	133	}
	134
c3029c66	135	sub is ($$@) {
7d932aad	136	my ($got, $expected, $name, @mess) = @_;
c831d34f	137
	138	my $pass;
	139	if( !defined $got \|\| !defined $expected ) {
	140	# undef only matches undef
	141	$pass = !defined $got && !defined $expected;
	142	}
	143	else {
	144	$pass = $got eq $expected;
	145	}
	146
69026470	147	unless ($pass) {
b3c72391	148	unshift(@mess, "# got "._q($got)."\n",
b3c72391	149	"# expected "._q($expected)."\n");
69026470	150	}
7d932aad	151	_ok($pass, _where(), $name, @mess);
69026470	152	}
69026470	153
c3029c66	154	sub isnt ($$@) {
3e90d5a3	155	my ($got, $isnt, $name, @mess) = @_;
c831d34f	156
	157	my $pass;
	158	if( !defined $got \|\| !defined $isnt ) {
	159	# undef only matches undef
	160	$pass = defined $got \|\| defined $isnt;
	161	}
	162	else {
	163	$pass = $got ne $isnt;
	164	}
	165
3e90d5a3	166	unless( $pass ) {
b3c72391	167	unshift(@mess, "# it should not be "._q($got)."\n",
3e90d5a3	168	"# but it is.\n");
	169	}
	170	_ok($pass, _where(), $name, @mess);
	171	}
	172
c3029c66	173	sub cmp_ok ($$$@) {
58d76dfd	174	my($got, $type, $expected, $name, @mess) = @_;
	175
	176	my $pass;
	177	{
	178	local $^W = 0;
	179	local($@,$!); # don't interfere with $@
	180	# eval() sometimes resets $!
	181	$pass = eval "\$got $type \$expected";
	182	}
	183	unless ($pass) {
	184	# It seems Irix long doubles can have 2147483648 and 2147483648
	185	# that stringify to the same thing but are acutally numerically
	186	# different. Display the numbers if $type isn't a string operator,
	187	# and the numbers are stringwise the same.
	188	# (all string operators have alphabetic names, so tr/a-z// is true)
	189	# This will also show numbers for some uneeded cases, but will
	190	# definately be helpful for things such as == and <= that fail
	191	if ($got eq $expected and $type !~ tr/a-z//) {
	192	unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
	193	}
	194	unshift(@mess, "# got "._q($got)."\n",
	195	"# expected $type "._q($expected)."\n");
	196	}
	197	_ok($pass, _where(), $name, @mess);
	198	}
	199
	200	# Check that $got is within $range of $expected
	201	# if $range is 0, then check it's exact
	202	# else if $expected is 0, then $range is an absolute value
	203	# otherwise $range is a fractional error.
	204	# Here $range must be numeric, >= 0
	205	# Non numeric ranges might be a useful future extension. (eg %)
c3029c66	206	sub within ($$$@) {
58d76dfd	207	my ($got, $expected, $range, $name, @mess) = @_;
	208	my $pass;
	209	if (!defined $got or !defined $expected or !defined $range) {
	210	# This is a fail, but doesn't need extra diagnostics
	211	} elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
	212	# This is a fail
	213	unshift @mess, "# got, expected and range must be numeric\n";
	214	} elsif ($range < 0) {
	215	# This is also a fail
	216	unshift @mess, "# range must not be negative\n";
	217	} elsif ($range == 0) {
	218	# Within 0 is ==
	219	$pass = $got == $expected;
	220	} elsif ($expected == 0) {
	221	# If expected is 0, treat range as absolute
	222	$pass = ($got <= $range) && ($got >= - $range);
	223	} else {
	224	my $diff = $got - $expected;
	225	$pass = abs ($diff / $expected) < $range;
	226	}
	227	unless ($pass) {
	228	if ($got eq $expected) {
	229	unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
	230	}
	231	unshift@mess, "# got "._q($got)."\n",
	232	"# expected "._q($expected)." (within "._q($range).")\n";
	233	}
	234	_ok($pass, _where(), $name, @mess);
	235	}
	236
69026470	237	# Note: this isn't quite as fancy as Test::More::like().
724aa791	238
	239	sub like ($$@) { like_yn (0,@_) }; # 0 for -
	240	sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
	241
	242	sub like_yn ($$$@) {
	243	my ($flip, $got, $expected, $name, @mess) = @_;
69026470	244	my $pass;
724aa791	245	$pass = $got =~ /$expected/ if !$flip;
	246	$pass = $got !~ /$expected/ if $flip;
	247	unless ($pass) {
	248	unshift(@mess, "# got '$got'\n",
	249	"# expected /$expected/\n");
69026470	250	}
7d932aad	251	_ok($pass, _where(), $name, @mess);
69026470	252	}
	253
	254	sub pass {
	255	_ok(1, '', @_);
	256	}
	257
	258	sub fail {
	259	_ok(0, _where(), @_);
	260	}
	261
ad20d923	262	sub curr_test {
cf8feb78	263	$test = shift if @_;
ad20d923	264	return $test;
	265	}
	266
3e90d5a3	267	sub next_test {
cf8feb78	268	$test++;
3e90d5a3	269	}
3e90d5a3	270
69026470	271	# Note: can't pass multipart messages since we try to
	272	# be compatible with Test::More::skip().
	273	sub skip {
7d932aad	274	my $why = shift;
982b7cb7	275	my $n = @_ ? shift : 1;
69026470	276	for (1..$n) {
ad20d923	277	print STDOUT "ok $test # skip: $why\n";
e6c299c8	278	$test++;
69026470	279	}
	280	local $^W = 0;
	281	last SKIP;
	282	}
	283
	284	sub eq_array {
	285	my ($ra, $rb) = @_;
	286	return 0 unless $#$ra == $#$rb;
	287	for my $i (0..$#$ra) {
	288	return 0 unless $ra->[$i] eq $rb->[$i];
	289	}
	290	return 1;
	291	}
	292
677fb045	293	sub eq_hash {
	294	my ($orig, $suspect) = @_;
	295	my $fail;
	296	while (my ($key, $value) = each %$suspect) {
	297	# Force a hash recompute if this perl's internals can cache the hash key.
	298	$key = "" . $key;
	299	if (exists $orig->{$key}) {
	300	if ($orig->{$key} ne $value) {
de522f7a	301	print STDOUT "# key ", _qq($key), " was ", _qq($orig->{$key}),
de522f7a	302	" now ", _qq($value), "\n";
677fb045	303	$fail = 1;
	304	}
	305	} else {
de522f7a	306	print STDOUT "# key ", _qq($key), " is ", _qq($value),
75385f53	307	", not in original.\n";
677fb045	308	$fail = 1;
	309	}
	310	}
	311	foreach (keys %$orig) {
	312	# Force a hash recompute if this perl's internals can cache the hash key.
	313	$_ = "" . $_;
	314	next if (exists $suspect->{$_});
de522f7a	315	print STDOUT "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
677fb045	316	$fail = 1;
	317	}
	318	!$fail;
	319	}
	320
c3029c66	321	sub require_ok ($) {
69026470	322	my ($require) = @_;
	323	eval <<REQUIRE_OK;
	324	require $require;
	325	REQUIRE_OK
1577bb16	326	_ok(!$@, _where(), "require $require");
69026470	327	}
69026470	328
c3029c66	329	sub use_ok ($) {
69026470	330	my ($use) = @_;
	331	eval <<USE_OK;
	332	use $use;
	333	USE_OK
1577bb16	334	_ok(!$@, _where(), "use $use");
69026470	335	}
69026470	336
137352a2	337	# runperl - Runs a separate perl interpreter.
	338	# Arguments :
	339	# switches => [ command-line switches ]
	340	# nolib => 1 # don't use -I../lib (included by default)
	341	# prog => one-liner (avoid quotes)
d83945bc	342	# progs => [ multi-liner (avoid quotes) ]
137352a2	343	# progfile => perl script
	344	# stdin => string to feed the stdin
	345	# stderr => redirect stderr to stdout
	346	# args => [ command-line arguments to the perl program ]
cb9c5e20	347	# verbose => print the command line
137352a2	348
	349	my $is_mswin = $^O eq 'MSWin32';
	350	my $is_netware = $^O eq 'NetWare';
	351	my $is_macos = $^O eq 'MacOS';
	352	my $is_vms = $^O eq 'VMS';
	353
cb9c5e20	354	sub _quote_args {
	355	my ($runperl, $args) = @_;
	356
	357	foreach (@$args) {
	358	# In VMS protect with doublequotes because otherwise
	359	# DCL will lowercase -- unless already doublequoted.
ea9ac5ad	360	$_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
cb9c5e20	361	$$runperl .= ' ' . $_;
	362	}
	363	}
	364
4cd2bd1f	365	sub _create_runperl { # Create the string to qx in runperl().
137352a2	366	my %args = @_;
44cb023c	367	my $runperl = $^X =~ m/\s/ ? qq{"$^X"} : $^X;
f93a5f07	368	unless ($args{nolib}) {
f93a5f07	369	if ($is_macos) {
cb9c5e20	370	$runperl .= ' -I::lib';
f93a5f07	371	# Use UNIX style error messages instead of MPW style.
cb9c5e20	372	$runperl .= ' -MMac::err=unix' if $args{stderr};
137352a2	373	}
137352a2	374	else {
cb9c5e20	375	$runperl .= ' "-I../lib"'; # doublequotes because of VMS
137352a2	376	}
137352a2	377	}
d83945bc	378	if ($args{switches}) {
343d4a7b	379	local $Level = 2;
	380	die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
	381	unless ref $args{switches} eq "ARRAY";
d83945bc	382	_quote_args(\$runperl, $args{switches});
d83945bc	383	}
137352a2	384	if (defined $args{prog}) {
21820af6	385	die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
21820af6	386	if defined $args{progs};
d83945bc	387	$args{progs} = [$args{prog}]
	388	}
	389	if (defined $args{progs}) {
21820af6	390	die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
21820af6	391	unless ref $args{progs} eq "ARRAY";
d83945bc	392	foreach my $prog (@{$args{progs}}) {
	393	if ($is_mswin \|\| $is_netware \|\| $is_vms) {
	394	$runperl .= qq ( -e "$prog" );
	395	}
	396	else {
	397	$runperl .= qq ( -e '$prog' );
	398	}
	399	}
137352a2	400	} elsif (defined $args{progfile}) {
	401	$runperl .= qq( "$args{progfile}");
	402	}
	403	if (defined $args{stdin}) {
dc459aad	404	# so we don't try to put literal newlines and crs onto the
	405	# command line.
	406	$args{stdin} =~ s/\n/\\n/g;
	407	$args{stdin} =~ s/\r/\\r/g;
5ae09a77	408
137352a2	409	if ($is_mswin \|\| $is_netware \|\| $is_vms) {
f93a5f07	410	$runperl = qq{$^X -e "print qq(} .
137352a2	411	$args{stdin} . q{)" \| } . $runperl;
137352a2	412	}
dc459aad	413	elsif ($is_macos) {
	414	# MacOS can only do two processes under MPW at once;
	415	# the test itself is one; we can't do two more, so
	416	# write to temp file
	417	my $stdin = qq{$^X -e 'print qq(} . $args{stdin} . qq{)' > teststdin; };
	418	if ($args{verbose}) {
	419	my $stdindisplay = $stdin;
	420	$stdindisplay =~ s/\n/\n\#/g;
	421	print STDERR "# $stdindisplay\n";
	422	}
	423	`$stdin`;
	424	$runperl .= q{ < teststdin };
	425	}
137352a2	426	else {
f93a5f07	427	$runperl = qq{$^X -e 'print qq(} .
137352a2	428	$args{stdin} . q{)' \| } . $runperl;
	429	}
	430	}
	431	if (defined $args{args}) {
cb9c5e20	432	_quote_args(\$runperl, $args{args});
	433	}
	434	$runperl .= ' 2>&1' if $args{stderr} && !$is_macos;
	435	$runperl .= " \xB3 Dev:Null" if !$args{stderr} && $is_macos;
	436	if ($args{verbose}) {
	437	my $runperldisplay = $runperl;
	438	$runperldisplay =~ s/\n/\n\#/g;
75385f53	439	print STDERR "# $runperldisplay\n";
137352a2	440	}
4cd2bd1f	441	return $runperl;
	442	}
	443
	444	sub runperl {
	445	my $runperl = &_create_runperl;
137352a2	446	my $result = `$runperl`;
	447	$result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
	448	return $result;
	449	}
	450
d2c6a9c9	451	*run_perl = \&runperl; # Nice alias.
8799135f	452
c4fbe247	453	sub DIE {
75385f53	454	print STDERR "# @_\n";
c4fbe247	455	exit 1;
8799135f	456	}
8799135f	457
b5fe401b	458	# A somewhat safer version of the sometimes wrong $^X.
17a740d5	459	my $Perl;
	460	sub which_perl {
	461	unless (defined $Perl) {
	462	$Perl = $^X;
	463
73421c4a	464	# VMS should have 'perl' aliased properly
	465	return $Perl if $^O eq 'VMS';
	466
17a740d5	467	my $exe;
17a740d5	468	eval "require Config; Config->import";
85363d30	469	if ($@) {
17a740d5	470	warn "test.pl had problems loading Config: $@";
17a740d5	471	$exe = '';
85363d30	472	} else {
17a740d5	473	$exe = $Config{_exe};
85363d30	474	}
da405c16	475	$exe = '' unless defined $exe;
17a740d5	476
	477	# This doesn't absolutize the path: beware of future chdirs().
	478	# We could do File::Spec->abs2rel() but that does getcwd()s,
	479	# which is a bit heavyweight to do here.
	480
	481	if ($Perl =~ /^perl\Q$exe\E$/i) {
8db06b02	482	my $perl = "perl$exe";
17a740d5	483	eval "require File::Spec";
	484	if ($@) {
	485	warn "test.pl had problems loading File::Spec: $@";
8db06b02	486	$Perl = "./$perl";
17a740d5	487	} else {
8db06b02	488	$Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
17a740d5	489	}
17a740d5	490	}
196918b0	491
	492	# Build up the name of the executable file from the name of
	493	# the command.
	494
	495	if ($Perl !~ /\Q$exe\E$/i) {
	496	$Perl .= $exe;
	497	}
c880be78	498
8db06b02	499	warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
17a740d5	500
	501	# For subcommands to use.
	502	$ENV{PERLEXE} = $Perl;
85363d30	503	}
17a740d5	504	return $Perl;
b5fe401b	505	}
b5fe401b	506
435e7af6	507	sub unlink_all {
	508	foreach my $file (@_) {
	509	1 while unlink $file;
75385f53	510	print STDERR "# Couldn't unlink '$file': $!\n" if -f $file;
435e7af6	511	}
435e7af6	512	}
eeabcb2d	513
	514
	515	my $tmpfile = "misctmp000";
	516	1 while -f ++$tmpfile;
	517	END { unlink_all $tmpfile }
	518
f5cda331	519	#
	520	# _fresh_perl
	521	#
	522	# The $resolve must be a subref that tests the first argument
	523	# for success, or returns the definition of success (e.g. the
	524	# expected scalar) if given no arguments.
	525	#
	526
	527	sub _fresh_perl {
	528	my($prog, $resolve, $runperl_args, $name) = @_;
eeabcb2d	529
	530	$runperl_args \|\|= {};
	531	$runperl_args->{progfile} = $tmpfile;
	532	$runperl_args->{stderr} = 1;
	533
	534	open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
	535
	536	# VMS adjustments
	537	if( $^O eq 'VMS' ) {
	538	$prog =~ s#/dev/null#NL:#;
	539
	540	# VMS file locking
	541	$prog =~ s{if \(-e _ and -f _ and -r _\)}
	542	{if (-e _ and -f _)}
	543	}
	544
	545	print TEST $prog, "\n";
	546	close TEST or die "Cannot close $tmpfile: $!";
	547
	548	my $results = runperl(%$runperl_args);
	549	my $status = $?;
	550
	551	# Clean up the results into something a bit more predictable.
	552	$results =~ s/\n+$//;
	553	$results =~ s/at\s+misctmp\d+\s+line/at - line/g;
	554	$results =~ s/of\s+misctmp\d+\s+aborted/of - aborted/g;
	555
	556	# bison says 'parse error' instead of 'syntax error',
	557	# various yaccs may or may not capitalize 'syntax'.
	558	$results =~ s/^(syntax\|parse) error/syntax error/mig;
	559
	560	if ($^O eq 'VMS') {
	561	# some tests will trigger VMS messages that won't be expected
	562	$results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
	563
	564	# pipes double these sometimes
	565	$results =~ s/\n\n/\n/g;
	566	}
	567
f5cda331	568	my $pass = $resolve->($results);
eeabcb2d	569	unless ($pass) {
cf8feb78	570	_diag "# PROG: \n$prog\n";
	571	_diag "# EXPECTED:\n", $resolve->(), "\n";
	572	_diag "# GOT:\n$results\n";
	573	_diag "# STATUS: $status\n";
eeabcb2d	574	}
eeabcb2d	575
e2c38acd	576	# Use the first line of the program as a name if none was given
	577	unless( $name ) {
	578	($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
	579	$name .= '...' if length $first_line > length $name;
	580	}
eeabcb2d	581
f5cda331	582	_ok($pass, _where(), "fresh_perl - $name");
	583	}
	584
	585	#
141f445b	586	# fresh_perl_is
f5cda331	587	#
	588	# Combination of run_perl() and is().
	589	#
	590
	591	sub fresh_perl_is {
	592	my($prog, $expected, $runperl_args, $name) = @_;
dcc7f481	593	local $Level = 2;
f5cda331	594	_fresh_perl($prog,
	595	sub { @_ ? $_[0] eq $expected : $expected },
	596	$runperl_args, $name);
	597	}
	598
	599	#
141f445b	600	# fresh_perl_like
f5cda331	601	#
	602	# Combination of run_perl() and like().
	603	#
	604
	605	sub fresh_perl_like {
	606	my($prog, $expected, $runperl_args, $name) = @_;
dcc7f481	607	local $Level = 2;
f5cda331	608	_fresh_perl($prog,
	609	sub { @_ ?
	610	$_[0] =~ (ref $expected ? $expected : /$expected/) :
	611	$expected },
	612	$runperl_args, $name);
eeabcb2d	613	}
eeabcb2d	614
69026470	615	1;