[p5sagit/p5-mst-13.2.git] / t / test.pl

#
# t/test.pl - most of Test::More functionality without the fuss
#

my $test = 1;
my $planned;

$TODO = 0;
$NO_ENDING = 0;

sub plan {
    my $n;
    if (@_ == 1) {
	$n = shift;
    } else {
	my %plan = @_;
	$n = $plan{tests}; 
    }
    print STDOUT "1..$n\n";
    $planned = $n;
}

END {
    my $ran = $test - 1;
    if (!$NO_ENDING && defined $planned && $planned != $ran) {
        print STDERR "# Looks like you planned $planned tests but ran $ran.\n";
    }
}

# Use this instead of "print STDERR" when outputing failure diagnostic 
# messages
sub _diag {
    my $fh = $TODO ? *STDOUT : *STDERR;
    print $fh @_;
}

sub skip_all {
    if (@_) {
	print STDOUT "1..0 - @_\n";
    } else {
	print STDOUT "1..0\n";
    }
    exit(0);
}

sub _ok {
    my ($pass, $where, $name, @mess) = @_;
    # Do not try to microoptimize by factoring out the "not ".
    # VMS will avenge.
    my $out;
    if ($name) {
        # escape out '#' or it will interfere with '# skip' and such
        $name =~ s/#/\\#/g;
	$out = $pass ? "ok $test - $name" : "not ok $test - $name";
    } else {
	$out = $pass ? "ok $test" : "not ok $test";
    }

    $out .= " # TODO $TODO" if $TODO;
    print STDOUT "$out\n";

    unless ($pass) {
	_diag "# Failed $where\n";
    }

    # Ensure that the message is properly escaped.
    _diag map { /^#/ ? "$_\n" : "# $_\n" } 
          map { split /\n/ } @mess if @mess;

    $test++;

    return $pass;
}

sub _where {
    my @caller = caller(1);
    return "at $caller[1] line $caller[2]";
}

# DON'T use this for matches. Use like() instead.
sub ok {
    my ($pass, $name, @mess) = @_;
    _ok($pass, _where(), $name, @mess);
}

sub _q {
    my $x = shift;
    return 'undef' unless defined $x;
    my $q = $x;
    $q =~ s/\\/\\\\/;
    $q =~ s/'/\\'/;
    return "'$q'";
}

sub _qq {
    my $x = shift;
    return defined $x ? '"' . display ($x) . '"' : 'undef';
};

# keys are the codes \n etc map to, values are 2 char strings such as \n
my %backslash_escape;
foreach my $x (split //, 'nrtfa\\\'"') {
    $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
}
# A way to display scalars containing control characters and Unicode.
# Trying to avoid setting $_, or relying on local $_ to work.
sub display {
    my @result;
    foreach my $x (@_) {
        if (defined $x and not ref $x) {
            my $y = '';
            foreach my $c (unpack("U*", $x)) {
                if ($c > 255) {
                    $y .= sprintf "\\x{%x}", $c;
                } elsif ($backslash_escape{$c}) {
                    $y .= $backslash_escape{$c};
                } else {
                    my $z = chr $c; # Maybe we can get away with a literal...
                    $z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
                    $y .= $z;
                }
            }
            $x = $y;
        }
        return $x unless wantarray;
        push @result, $x;
    }
    return @result;
}

sub is {
    my ($got, $expected, $name, @mess) = @_;
    my $pass = $got eq $expected;
    unless ($pass) {
	unshift(@mess, "#      got "._q($got)."\n",
		       "# expected "._q($expected)."\n");
    }
    _ok($pass, _where(), $name, @mess);
}

sub isnt {
    my ($got, $isnt, $name, @mess) = @_;
    my $pass = $got ne $isnt;
    unless( $pass ) {
        unshift(@mess, "# it should not be "._q($got)."\n",
                       "# but it is.\n");
    }
    _ok($pass, _where(), $name, @mess);
}

sub cmp_ok {
    my($got, $type, $expected, $name, @mess) = @_;

    my $pass;
    {
        local $^W = 0;
        local($@,$!);   # don't interfere with $@
                        # eval() sometimes resets $!
        $pass = eval "\$got $type \$expected";
    }
    unless ($pass) {
        # It seems Irix long doubles can have 2147483648 and 2147483648
        # that stringify to the same thing but are acutally numerically
        # different. Display the numbers if $type isn't a string operator,
        # and the numbers are stringwise the same.
        # (all string operators have alphabetic names, so tr/a-z// is true)
        # This will also show numbers for some uneeded cases, but will
        # definately be helpful for things such as == and <= that fail
        if ($got eq $expected and $type !~ tr/a-z//) {
            unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
        }
        unshift(@mess, "#      got "._q($got)."\n",
                       "# expected $type "._q($expected)."\n");
    }
    _ok($pass, _where(), $name, @mess);
}

# Check that $got is within $range of $expected
# if $range is 0, then check it's exact
# else if $expected is 0, then $range is an absolute value
# otherwise $range is a fractional error.
# Here $range must be numeric, >= 0
# Non numeric ranges might be a useful future extension. (eg %)
sub within {
    my ($got, $expected, $range, $name, @mess) = @_;
    my $pass;
    if (!defined $got or !defined $expected or !defined $range) {
        # This is a fail, but doesn't need extra diagnostics
    } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
        # This is a fail
        unshift @mess, "# got, expected and range must be numeric\n";
    } elsif ($range < 0) {
        # This is also a fail
        unshift @mess, "# range must not be negative\n";
    } elsif ($range == 0) {
        # Within 0 is ==
        $pass = $got == $expected;
    } elsif ($expected == 0) {
        # If expected is 0, treat range as absolute
        $pass = ($got <= $range) && ($got >= - $range);
    } else {
        my $diff = $got - $expected;
        $pass = abs ($diff / $expected) < $range;
    }
    unless ($pass) {
        if ($got eq $expected) {
            unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
        }
	unshift@mess, "#      got "._q($got)."\n",
		      "# expected "._q($expected)." (within "._q($range).")\n";
    }
    _ok($pass, _where(), $name, @mess);
}

# Note: this isn't quite as fancy as Test::More::like().
sub like {
    my ($got, $expected, $name, @mess) = @_;
    my $pass;
    if (ref $expected eq 'Regexp') {
	$pass = $got =~ $expected;
	unless ($pass) {
	    unshift(@mess, "#      got '$got'\n",
		           "# expected /$expected/\n");
	}
    } else {
	$pass = $got =~ /$expected/;
	unless ($pass) {
	    unshift(@mess, "#      got '$got'\n",
		           "# expected /$expected/\n");
	}
    }
    _ok($pass, _where(), $name, @mess);
}

sub pass {
    _ok(1, '', @_);
}

sub fail {
    _ok(0, _where(), @_);
}

sub curr_test {
    return $test;
}

sub next_test {
    $test++
}

# Note: can't pass multipart messages since we try to
# be compatible with Test::More::skip().
sub skip {
    my $why = shift;
    my $n    = @_ ? shift : 1;
    for (1..$n) {
        print STDOUT "ok $test # skip: $why\n";
        $test++;
    }
    local $^W = 0;
    last SKIP;
}

sub eq_array {
    my ($ra, $rb) = @_;
    return 0 unless $#$ra == $#$rb;
    for my $i (0..$#$ra) {
	return 0 unless $ra->[$i] eq $rb->[$i];
    }
    return 1;
}

sub eq_hash {
  my ($orig, $suspect) = @_;
  my $fail;
  while (my ($key, $value) = each %$suspect) {
    # Force a hash recompute if this perl's internals can cache the hash key.
    $key = "" . $key;
    if (exists $orig->{$key}) {
      if ($orig->{$key} ne $value) {
        print STDOUT "# key ", _qq($key), " was ", _qq($orig->{$key}),
                     " now ", _qq($value), "\n";
        $fail = 1;
      }
    } else {
      print STDOUT "# key ", _qq($key), " is ", _qq($value), 
                   ", not in original.\n";
      $fail = 1;
    }
  }
  foreach (keys %$orig) {
    # Force a hash recompute if this perl's internals can cache the hash key.
    $_ = "" . $_;
    next if (exists $suspect->{$_});
    print STDOUT "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
    $fail = 1;
  }
  !$fail;
}

sub require_ok {
    my ($require) = @_;
    eval <<REQUIRE_OK;
require $require;
REQUIRE_OK
    _ok(!$@, _where(), "require $require");
}

sub use_ok {
    my ($use) = @_;
    eval <<USE_OK;
use $use;
USE_OK
    _ok(!$@, _where(), "use $use");
}

# runperl - Runs a separate perl interpreter.
# Arguments :
#   switches => [ command-line switches ]
#   nolib    => 1 # don't use -I../lib (included by default)
#   prog     => one-liner (avoid quotes)
#   progfile => perl script
#   stdin    => string to feed the stdin
#   stderr   => redirect stderr to stdout
#   args     => [ command-line arguments to the perl program ]
#   verbose  => print the command line

my $is_mswin    = $^O eq 'MSWin32';
my $is_netware  = $^O eq 'NetWare';
my $is_macos    = $^O eq 'MacOS';
my $is_vms      = $^O eq 'VMS';

sub _quote_args {
    my ($runperl, $args) = @_;

    foreach (@$args) {
	# In VMS protect with doublequotes because otherwise
	# DCL will lowercase -- unless already doublequoted.
       $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
	$$runperl .= ' ' . $_;
    }
}

sub runperl {
    my %args = @_;
    my $runperl = $^X;
    if ($args{switches}) {
	_quote_args(\$runperl, $args{switches});
    }
    unless ($args{nolib}) {
	if ($is_macos) {
	    $runperl .= ' -I::lib';
	    # Use UNIX style error messages instead of MPW style.
	    $runperl .= ' -MMac::err=unix' if $args{stderr};
	}
	else {
	    $runperl .= ' "-I../lib"'; # doublequotes because of VMS
	}
    }
    if (defined $args{prog}) {
	if ($is_mswin || $is_netware || $is_vms) {
	    $runperl .= qq( -e ") . $args{prog} . qq(");
	}
	else {
	    $runperl .= qq( -e ') . $args{prog} . qq(');
	}
    } elsif (defined $args{progfile}) {
	$runperl .= qq( "$args{progfile}");
    }
    if (defined $args{stdin}) {
        # so we don't try to put literal newlines and crs onto the
        # command line.
        $args{stdin} =~ s/\n/\\n/g;
        $args{stdin} =~ s/\r/\\r/g;

	if ($is_mswin || $is_netware || $is_vms) {
	    $runperl = qq{$^X -e "print qq(} .
		$args{stdin} . q{)" | } . $runperl;
	}
	else {
	    $runperl = qq{$^X -e 'print qq(} .
		$args{stdin} . q{)' | } . $runperl;
	}
    }
    if (defined $args{args}) {
	_quote_args(\$runperl, $args{args});
    }
    $runperl .= ' 2>&1'          if  $args{stderr} && !$is_macos;
    $runperl .= " \xB3 Dev:Null" if !$args{stderr} &&  $is_macos;
    if ($args{verbose}) {
	my $runperldisplay = $runperl;
	$runperldisplay =~ s/\n/\n\#/g;
	print STDERR "# $runperldisplay\n";
    }
    my $result = `$runperl`;
    $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
    return $result;
}


sub DIE {
    print STDERR "# @_\n";
    exit 1;
}

# A somewhat safer version of the sometimes wrong $^X.
my $Perl;
sub which_perl {
    unless (defined $Perl) {
	$Perl = $^X;
	
	my $exe;
	eval "require Config; Config->import";
	if ($@) {
	    warn "test.pl had problems loading Config: $@";
	    $exe = '';
	} else {
	    $exe = $Config{_exe};
	}
       $exe = '' unless defined $exe;
	
	# This doesn't absolutize the path: beware of future chdirs().
	# We could do File::Spec->abs2rel() but that does getcwd()s,
	# which is a bit heavyweight to do here.
	
	if ($Perl =~ /^perl\Q$exe\E$/i) {
	    my $perl = "perl$exe";
	    eval "require File::Spec";
	    if ($@) {
		warn "test.pl had problems loading File::Spec: $@";
		$Perl = "./$perl";
	    } else {
		$Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
	    }
	}

	# Build up the name of the executable file from the name of
	# the command.

	if ($Perl !~ /\Q$exe\E$/i) {
	    $Perl .= $exe;
	}

	warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
	
	# For subcommands to use.
	$ENV{PERLEXE} = $Perl;
    }
    return $Perl;
}

sub unlink_all {
    foreach my $file (@_) {
        1 while unlink $file;
        print STDERR "# Couldn't unlink '$file': $!\n" if -f $file;
    }
}


my $tmpfile = "misctmp000";
1 while -f ++$tmpfile;
END { unlink_all $tmpfile }

#
# _fresh_perl
#
# The $resolve must be a subref that tests the first argument
# for success, or returns the definition of success (e.g. the
# expected scalar) if given no arguments.
#

sub _fresh_perl {
    my($prog, $resolve, $runperl_args, $name) = @_;

    $runperl_args ||= {};
    $runperl_args->{progfile} = $tmpfile;
    $runperl_args->{stderr} = 1;

    open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";

    # VMS adjustments
    if( $^O eq 'VMS' ) {
        $prog =~ s#/dev/null#NL:#;

        # VMS file locking 
        $prog =~ s{if \(-e _ and -f _ and -r _\)}
                  {if (-e _ and -f _)}
    }

    print TEST $prog, "\n";
    close TEST or die "Cannot close $tmpfile: $!";

    my $results = runperl(%$runperl_args);
    my $status = $?;

    # Clean up the results into something a bit more predictable.
    $results =~ s/\n+$//;
    $results =~ s/at\s+misctmp\d+\s+line/at - line/g;
    $results =~ s/of\s+misctmp\d+\s+aborted/of - aborted/g;

    # bison says 'parse error' instead of 'syntax error',
    # various yaccs may or may not capitalize 'syntax'.
    $results =~ s/^(syntax|parse) error/syntax error/mig;

    if ($^O eq 'VMS') {
        # some tests will trigger VMS messages that won't be expected
        $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;

        # pipes double these sometimes
        $results =~ s/\n\n/\n/g;
    }

    my $pass = $resolve->($results);
    unless ($pass) {
        print STDERR "# PROG: $switch\n$prog\n";
        print STDERR "# EXPECTED:\n", $resolve->(), "\n";
        print STDERR "# GOT:\n$results\n";
        print STDERR "# STATUS: $status\n";
    }

    # Use the first line of the program as a name if none was given
    unless( $name ) {
        ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
        $name .= '...' if length $first_line > length $name;
    }

    _ok($pass, _where(), "fresh_perl - $name");
}

#
# run_perl_is
#
# Combination of run_perl() and is().
#

sub fresh_perl_is {
    my($prog, $expected, $runperl_args, $name) = @_;
    _fresh_perl($prog,
		sub { @_ ? $_[0] eq $expected : $expected },
		$runperl_args, $name);
}

#
# run_perl_like
#
# Combination of run_perl() and like().
#

sub fresh_perl_like {
    my($prog, $expected, $runperl_args, $name) = @_;
    _fresh_perl($prog,
		sub { @_ ?
			  $_[0] =~ (ref $expected ? $expected : /$expected/) :
		          $expected },
		$runperl_args, $name);
}

1;
Commit	Line	Data
69026470	1	#
	2	# t/test.pl - most of Test::More functionality without the fuss
	3	#
	4
	5	my $test = 1;
	6	my $planned;
	7
7d932aad	8	$TODO = 0;
b6345914	9	$NO_ENDING = 0;
7d932aad	10
69026470	11	sub plan {
	12	my $n;
	13	if (@_ == 1) {
	14	$n = shift;
	15	} else {
	16	my %plan = @_;
	17	$n = $plan{tests};
	18	}
ad20d923	19	print STDOUT "1..$n\n";
69026470	20	$planned = $n;
	21	}
	22
	23	END {
	24	my $ran = $test - 1;
b6345914	25	if (!$NO_ENDING && defined $planned && $planned != $ran) {
75385f53	26	print STDERR "# Looks like you planned $planned tests but ran $ran.\n";
69026470	27	}
	28	}
	29
de522f7a	30	# Use this instead of "print STDERR" when outputing failure diagnostic
	31	# messages
	32	sub _diag {
	33	my $fh = $TODO ? STDOUT : STDERR;
	34	print $fh @_;
	35	}
	36
69026470	37	sub skip_all {
69026470	38	if (@_) {
ad20d923	39	print STDOUT "1..0 - @_\n";
69026470	40	} else {
ad20d923	41	print STDOUT "1..0\n";
69026470	42	}
	43	exit(0);
	44	}
	45
	46	sub _ok {
7d932aad	47	my ($pass, $where, $name, @mess) = @_;
69026470	48	# Do not try to microoptimize by factoring out the "not ".
69026470	49	# VMS will avenge.
7d932aad	50	my $out;
7d932aad	51	if ($name) {
b734d6c9	52	# escape out '#' or it will interfere with '# skip' and such
b734d6c9	53	$name =~ s/#/\\#/g;
7d932aad	54	$out = $pass ? "ok $test - $name" : "not ok $test - $name";
69026470	55	} else {
7d932aad	56	$out = $pass ? "ok $test" : "not ok $test";
69026470	57	}
7d932aad	58
7d932aad	59	$out .= " # TODO $TODO" if $TODO;
ad20d923	60	print STDOUT "$out\n";
7d932aad	61
69026470	62	unless ($pass) {
de522f7a	63	_diag "# Failed $where\n";
69026470	64	}
7d932aad	65
7d932aad	66	# Ensure that the message is properly escaped.
de522f7a	67	_diag map { /^#/ ? "$_\n" : "# $_\n" }
de522f7a	68	map { split /\n/ } @mess if @mess;
7d932aad	69
69026470	70	$test++;
1577bb16	71
1577bb16	72	return $pass;
69026470	73	}
	74
	75	sub _where {
	76	my @caller = caller(1);
	77	return "at $caller[1] line $caller[2]";
	78	}
	79
1d662fb6	80	# DON'T use this for matches. Use like() instead.
69026470	81	sub ok {
7d932aad	82	my ($pass, $name, @mess) = @_;
7d932aad	83	_ok($pass, _where(), $name, @mess);
69026470	84	}
69026470	85
b3c72391	86	sub _q {
	87	my $x = shift;
	88	return 'undef' unless defined $x;
	89	my $q = $x;
677fb045	90	$q =~ s/\\/\\\\/;
b3c72391	91	$q =~ s/'/\\'/;
	92	return "'$q'";
	93	}
	94
677fb045	95	sub _qq {
	96	my $x = shift;
	97	return defined $x ? '"' . display ($x) . '"' : 'undef';
	98	};
	99
	100	# keys are the codes \n etc map to, values are 2 char strings such as \n
	101	my %backslash_escape;
	102	foreach my $x (split //, 'nrtfa\\\'"') {
	103	$backslash_escape{ord eval "\"\\$x\""} = "\\$x";
	104	}
	105	# A way to display scalars containing control characters and Unicode.
	106	# Trying to avoid setting $_, or relying on local $_ to work.
	107	sub display {
	108	my @result;
	109	foreach my $x (@_) {
	110	if (defined $x and not ref $x) {
	111	my $y = '';
	112	foreach my $c (unpack("U*", $x)) {
	113	if ($c > 255) {
	114	$y .= sprintf "\\x{%x}", $c;
	115	} elsif ($backslash_escape{$c}) {
	116	$y .= $backslash_escape{$c};
	117	} else {
	118	my $z = chr $c; # Maybe we can get away with a literal...
	119	$z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
	120	$y .= $z;
	121	}
	122	}
	123	$x = $y;
	124	}
	125	return $x unless wantarray;
	126	push @result, $x;
	127	}
	128	return @result;
	129	}
	130
69026470	131	sub is {
7d932aad	132	my ($got, $expected, $name, @mess) = @_;
69026470	133	my $pass = $got eq $expected;
69026470	134	unless ($pass) {
b3c72391	135	unshift(@mess, "# got "._q($got)."\n",
b3c72391	136	"# expected "._q($expected)."\n");
69026470	137	}
7d932aad	138	_ok($pass, _where(), $name, @mess);
69026470	139	}
69026470	140
3e90d5a3	141	sub isnt {
	142	my ($got, $isnt, $name, @mess) = @_;
	143	my $pass = $got ne $isnt;
	144	unless( $pass ) {
b3c72391	145	unshift(@mess, "# it should not be "._q($got)."\n",
3e90d5a3	146	"# but it is.\n");
	147	}
	148	_ok($pass, _where(), $name, @mess);
	149	}
	150
58d76dfd	151	sub cmp_ok {
	152	my($got, $type, $expected, $name, @mess) = @_;
	153
	154	my $pass;
	155	{
	156	local $^W = 0;
	157	local($@,$!); # don't interfere with $@
	158	# eval() sometimes resets $!
	159	$pass = eval "\$got $type \$expected";
	160	}
	161	unless ($pass) {
	162	# It seems Irix long doubles can have 2147483648 and 2147483648
	163	# that stringify to the same thing but are acutally numerically
	164	# different. Display the numbers if $type isn't a string operator,
	165	# and the numbers are stringwise the same.
	166	# (all string operators have alphabetic names, so tr/a-z// is true)
	167	# This will also show numbers for some uneeded cases, but will
	168	# definately be helpful for things such as == and <= that fail
	169	if ($got eq $expected and $type !~ tr/a-z//) {
	170	unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
	171	}
	172	unshift(@mess, "# got "._q($got)."\n",
	173	"# expected $type "._q($expected)."\n");
	174	}
	175	_ok($pass, _where(), $name, @mess);
	176	}
	177
	178	# Check that $got is within $range of $expected
	179	# if $range is 0, then check it's exact
	180	# else if $expected is 0, then $range is an absolute value
	181	# otherwise $range is a fractional error.
	182	# Here $range must be numeric, >= 0
	183	# Non numeric ranges might be a useful future extension. (eg %)
	184	sub within {
	185	my ($got, $expected, $range, $name, @mess) = @_;
	186	my $pass;
	187	if (!defined $got or !defined $expected or !defined $range) {
	188	# This is a fail, but doesn't need extra diagnostics
	189	} elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
	190	# This is a fail
	191	unshift @mess, "# got, expected and range must be numeric\n";
	192	} elsif ($range < 0) {
	193	# This is also a fail
	194	unshift @mess, "# range must not be negative\n";
	195	} elsif ($range == 0) {
	196	# Within 0 is ==
	197	$pass = $got == $expected;
	198	} elsif ($expected == 0) {
	199	# If expected is 0, treat range as absolute
	200	$pass = ($got <= $range) && ($got >= - $range);
	201	} else {
	202	my $diff = $got - $expected;
	203	$pass = abs ($diff / $expected) < $range;
	204	}
	205	unless ($pass) {
	206	if ($got eq $expected) {
	207	unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
	208	}
	209	unshift@mess, "# got "._q($got)."\n",
	210	"# expected "._q($expected)." (within "._q($range).")\n";
	211	}
	212	_ok($pass, _where(), $name, @mess);
	213	}
	214
69026470	215	# Note: this isn't quite as fancy as Test::More::like().
69026470	216	sub like {
7d932aad	217	my ($got, $expected, $name, @mess) = @_;
69026470	218	my $pass;
	219	if (ref $expected eq 'Regexp') {
	220	$pass = $got =~ $expected;
	221	unless ($pass) {
435e7af6	222	unshift(@mess, "# got '$got'\n",
435e7af6	223	"# expected /$expected/\n");
69026470	224	}
	225	} else {
	226	$pass = $got =~ /$expected/;
	227	unless ($pass) {
7d932aad	228	unshift(@mess, "# got '$got'\n",
7d932aad	229	"# expected /$expected/\n");
69026470	230	}
69026470	231	}
7d932aad	232	_ok($pass, _where(), $name, @mess);
69026470	233	}
	234
	235	sub pass {
	236	_ok(1, '', @_);
	237	}
	238
	239	sub fail {
	240	_ok(0, _where(), @_);
	241	}
	242
ad20d923	243	sub curr_test {
	244	return $test;
	245	}
	246
3e90d5a3	247	sub next_test {
	248	$test++
	249	}
	250
69026470	251	# Note: can't pass multipart messages since we try to
	252	# be compatible with Test::More::skip().
	253	sub skip {
7d932aad	254	my $why = shift;
982b7cb7	255	my $n = @_ ? shift : 1;
69026470	256	for (1..$n) {
ad20d923	257	print STDOUT "ok $test # skip: $why\n";
e6c299c8	258	$test++;
69026470	259	}
	260	local $^W = 0;
	261	last SKIP;
	262	}
	263
	264	sub eq_array {
	265	my ($ra, $rb) = @_;
	266	return 0 unless $#$ra == $#$rb;
	267	for my $i (0..$#$ra) {
	268	return 0 unless $ra->[$i] eq $rb->[$i];
	269	}
	270	return 1;
	271	}
	272
677fb045	273	sub eq_hash {
	274	my ($orig, $suspect) = @_;
	275	my $fail;
	276	while (my ($key, $value) = each %$suspect) {
	277	# Force a hash recompute if this perl's internals can cache the hash key.
	278	$key = "" . $key;
	279	if (exists $orig->{$key}) {
	280	if ($orig->{$key} ne $value) {
de522f7a	281	print STDOUT "# key ", _qq($key), " was ", _qq($orig->{$key}),
de522f7a	282	" now ", _qq($value), "\n";
677fb045	283	$fail = 1;
	284	}
	285	} else {
de522f7a	286	print STDOUT "# key ", _qq($key), " is ", _qq($value),
75385f53	287	", not in original.\n";
677fb045	288	$fail = 1;
	289	}
	290	}
	291	foreach (keys %$orig) {
	292	# Force a hash recompute if this perl's internals can cache the hash key.
	293	$_ = "" . $_;
	294	next if (exists $suspect->{$_});
de522f7a	295	print STDOUT "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
677fb045	296	$fail = 1;
	297	}
	298	!$fail;
	299	}
	300
69026470	301	sub require_ok {
	302	my ($require) = @_;
	303	eval <<REQUIRE_OK;
	304	require $require;
	305	REQUIRE_OK
1577bb16	306	_ok(!$@, _where(), "require $require");
69026470	307	}
	308
	309	sub use_ok {
	310	my ($use) = @_;
	311	eval <<USE_OK;
	312	use $use;
	313	USE_OK
1577bb16	314	_ok(!$@, _where(), "use $use");
69026470	315	}
69026470	316
137352a2	317	# runperl - Runs a separate perl interpreter.
	318	# Arguments :
	319	# switches => [ command-line switches ]
	320	# nolib => 1 # don't use -I../lib (included by default)
	321	# prog => one-liner (avoid quotes)
	322	# progfile => perl script
	323	# stdin => string to feed the stdin
	324	# stderr => redirect stderr to stdout
	325	# args => [ command-line arguments to the perl program ]
cb9c5e20	326	# verbose => print the command line
137352a2	327
	328	my $is_mswin = $^O eq 'MSWin32';
	329	my $is_netware = $^O eq 'NetWare';
	330	my $is_macos = $^O eq 'MacOS';
	331	my $is_vms = $^O eq 'VMS';
	332
cb9c5e20	333	sub _quote_args {
	334	my ($runperl, $args) = @_;
	335
	336	foreach (@$args) {
	337	# In VMS protect with doublequotes because otherwise
	338	# DCL will lowercase -- unless already doublequoted.
ea9ac5ad	339	$_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
cb9c5e20	340	$$runperl .= ' ' . $_;
	341	}
	342	}
	343
137352a2	344	sub runperl {
	345	my %args = @_;
	346	my $runperl = $^X;
f93a5f07	347	if ($args{switches}) {
8da5ed17	348	_quote_args(\$runperl, $args{switches});
137352a2	349	}
f93a5f07	350	unless ($args{nolib}) {
f93a5f07	351	if ($is_macos) {
cb9c5e20	352	$runperl .= ' -I::lib';
f93a5f07	353	# Use UNIX style error messages instead of MPW style.
cb9c5e20	354	$runperl .= ' -MMac::err=unix' if $args{stderr};
137352a2	355	}
137352a2	356	else {
cb9c5e20	357	$runperl .= ' "-I../lib"'; # doublequotes because of VMS
137352a2	358	}
	359	}
	360	if (defined $args{prog}) {
	361	if ($is_mswin \|\| $is_netware \|\| $is_vms) {
	362	$runperl .= qq( -e ") . $args{prog} . qq(");
	363	}
	364	else {
	365	$runperl .= qq( -e ') . $args{prog} . qq(');
	366	}
	367	} elsif (defined $args{progfile}) {
	368	$runperl .= qq( "$args{progfile}");
	369	}
	370	if (defined $args{stdin}) {
5ae09a77	371	# so we don't try to put literal newlines and crs onto the
	372	# command line.
	373	$args{stdin} =~ s/\n/\\n/g;
	374	$args{stdin} =~ s/\r/\\r/g;
	375
137352a2	376	if ($is_mswin \|\| $is_netware \|\| $is_vms) {
f93a5f07	377	$runperl = qq{$^X -e "print qq(} .
137352a2	378	$args{stdin} . q{)" \| } . $runperl;
	379	}
	380	else {
f93a5f07	381	$runperl = qq{$^X -e 'print qq(} .
137352a2	382	$args{stdin} . q{)' \| } . $runperl;
	383	}
	384	}
	385	if (defined $args{args}) {
cb9c5e20	386	_quote_args(\$runperl, $args{args});
	387	}
	388	$runperl .= ' 2>&1' if $args{stderr} && !$is_macos;
	389	$runperl .= " \xB3 Dev:Null" if !$args{stderr} && $is_macos;
	390	if ($args{verbose}) {
	391	my $runperldisplay = $runperl;
	392	$runperldisplay =~ s/\n/\n\#/g;
75385f53	393	print STDERR "# $runperldisplay\n";
137352a2	394	}
137352a2	395	my $result = `$runperl`;
	396	$result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
	397	return $result;
	398	}
	399
8799135f	400
c4fbe247	401	sub DIE {
75385f53	402	print STDERR "# @_\n";
c4fbe247	403	exit 1;
8799135f	404	}
8799135f	405
b5fe401b	406	# A somewhat safer version of the sometimes wrong $^X.
17a740d5	407	my $Perl;
	408	sub which_perl {
	409	unless (defined $Perl) {
	410	$Perl = $^X;
	411
	412	my $exe;
	413	eval "require Config; Config->import";
85363d30	414	if ($@) {
17a740d5	415	warn "test.pl had problems loading Config: $@";
17a740d5	416	$exe = '';
85363d30	417	} else {
17a740d5	418	$exe = $Config{_exe};
85363d30	419	}
da405c16	420	$exe = '' unless defined $exe;
17a740d5	421
	422	# This doesn't absolutize the path: beware of future chdirs().
	423	# We could do File::Spec->abs2rel() but that does getcwd()s,
	424	# which is a bit heavyweight to do here.
	425
	426	if ($Perl =~ /^perl\Q$exe\E$/i) {
8db06b02	427	my $perl = "perl$exe";
17a740d5	428	eval "require File::Spec";
	429	if ($@) {
	430	warn "test.pl had problems loading File::Spec: $@";
8db06b02	431	$Perl = "./$perl";
17a740d5	432	} else {
8db06b02	433	$Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
17a740d5	434	}
17a740d5	435	}
196918b0	436
	437	# Build up the name of the executable file from the name of
	438	# the command.
	439
	440	if ($Perl !~ /\Q$exe\E$/i) {
	441	$Perl .= $exe;
	442	}
c880be78	443
8db06b02	444	warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
17a740d5	445
	446	# For subcommands to use.
	447	$ENV{PERLEXE} = $Perl;
85363d30	448	}
17a740d5	449	return $Perl;
b5fe401b	450	}
b5fe401b	451
435e7af6	452	sub unlink_all {
	453	foreach my $file (@_) {
	454	1 while unlink $file;
75385f53	455	print STDERR "# Couldn't unlink '$file': $!\n" if -f $file;
435e7af6	456	}
435e7af6	457	}
eeabcb2d	458
	459
	460	my $tmpfile = "misctmp000";
	461	1 while -f ++$tmpfile;
	462	END { unlink_all $tmpfile }
	463
f5cda331	464	#
	465	# _fresh_perl
	466	#
	467	# The $resolve must be a subref that tests the first argument
	468	# for success, or returns the definition of success (e.g. the
	469	# expected scalar) if given no arguments.
	470	#
	471
	472	sub _fresh_perl {
	473	my($prog, $resolve, $runperl_args, $name) = @_;
eeabcb2d	474
	475	$runperl_args \|\|= {};
	476	$runperl_args->{progfile} = $tmpfile;
	477	$runperl_args->{stderr} = 1;
	478
	479	open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
	480
	481	# VMS adjustments
	482	if( $^O eq 'VMS' ) {
	483	$prog =~ s#/dev/null#NL:#;
	484
	485	# VMS file locking
	486	$prog =~ s{if \(-e _ and -f _ and -r _\)}
	487	{if (-e _ and -f _)}
	488	}
	489
	490	print TEST $prog, "\n";
	491	close TEST or die "Cannot close $tmpfile: $!";
	492
	493	my $results = runperl(%$runperl_args);
	494	my $status = $?;
	495
	496	# Clean up the results into something a bit more predictable.
	497	$results =~ s/\n+$//;
	498	$results =~ s/at\s+misctmp\d+\s+line/at - line/g;
	499	$results =~ s/of\s+misctmp\d+\s+aborted/of - aborted/g;
	500
	501	# bison says 'parse error' instead of 'syntax error',
	502	# various yaccs may or may not capitalize 'syntax'.
	503	$results =~ s/^(syntax\|parse) error/syntax error/mig;
	504
	505	if ($^O eq 'VMS') {
	506	# some tests will trigger VMS messages that won't be expected
	507	$results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
	508
	509	# pipes double these sometimes
	510	$results =~ s/\n\n/\n/g;
	511	}
	512
f5cda331	513	my $pass = $resolve->($results);
eeabcb2d	514	unless ($pass) {
eeabcb2d	515	print STDERR "# PROG: $switch\n$prog\n";
f5cda331	516	print STDERR "# EXPECTED:\n", $resolve->(), "\n";
eeabcb2d	517	print STDERR "# GOT:\n$results\n";
	518	print STDERR "# STATUS: $status\n";
	519	}
	520
e2c38acd	521	# Use the first line of the program as a name if none was given
	522	unless( $name ) {
	523	($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
	524	$name .= '...' if length $first_line > length $name;
	525	}
eeabcb2d	526
f5cda331	527	_ok($pass, _where(), "fresh_perl - $name");
	528	}
	529
	530	#
	531	# run_perl_is
	532	#
	533	# Combination of run_perl() and is().
	534	#
	535
	536	sub fresh_perl_is {
	537	my($prog, $expected, $runperl_args, $name) = @_;
	538	_fresh_perl($prog,
	539	sub { @_ ? $_[0] eq $expected : $expected },
	540	$runperl_args, $name);
	541	}
	542
	543	#
	544	# run_perl_like
	545	#
	546	# Combination of run_perl() and like().
	547	#
	548
	549	sub fresh_perl_like {
	550	my($prog, $expected, $runperl_args, $name) = @_;
	551	_fresh_perl($prog,
	552	sub { @_ ?
	553	$_[0] =~ (ref $expected ? $expected : /$expected/) :
	554	$expected },
	555	$runperl_args, $name);
eeabcb2d	556	}
eeabcb2d	557
69026470	558	1;