sanify alias/SELECT list rendering

[dbsrgits/Data-Query.git] / t / sql.t

use strictures 1;
use Test::More qw(no_plan);

use Devel::Dwarn;
use Data::Query::Renderer::SQL::Naive;
use Data::Query::ExprHelpers qw(perl_scalar_value);

BEGIN { require 't/expr.include' }

my $rend = Data::Query::Renderer::SQL::Naive->new({ quote_chars => [ "'" ] });

sub binding { map perl_scalar_value($_), @_ }

sub expr_sql_is (&;@) {
  my $sub = shift;
  @_
    ? is_deeply($rend->render(_run_expr($sub)->{expr}), @_)
    : ::Dwarn($rend->render(_run_expr($sub)->{expr}));
}

expr_sql_is { $_->foo }
  [ 'foo' ],
  "Simple identifier -> SQL";

expr_sql_is { $_->group }
  [ q{'group'} ],
  "Simple identifier needing quoting -> SQL";

expr_sql_is { $_->foo->group }
  [ q{foo.'group'} ],
  "Complex identifier -> SQL";

expr_sql_is { $_->foo == 1 }
  [ "foo = ?", binding(1) ],
  "Simple expression -> SQL";

expr_sql_is { ($_->foo == 1) & ($_->bar eq "foo") }
  [ "( foo = ? AND bar = ? )", binding(1, "foo") ],
  "Compound expression -> SQL";


expr_sql_is { ($_->foo == 1) & ($_->bar eq "foo") & ($_->baz > 3) }
  [ "( foo = ? AND bar = ? AND baz > ? )", binding(1, "foo", 3) ],
  "Flatten expression ok";

expr_sql_is { !$_->foo }
  [ "NOT foo" ],
  "Unary expression ok";

expr_sql_is { SELECT { $_->foo } }
  [ "SELECT foo" ],
  "Simple identifier";

expr_sql_is { SELECT { $_->foo, 1 } }
  # the extra space here is a little icky but Naive's _flatten_structure
  # will need rewriting to fix it - commit bits available if you do it first
  [ "SELECT foo, ?", binding(1) ],
  "Identifier and literal";

expr_sql_is { SELECT { $_->foo => AS("foom"), 1 } }
  [ "SELECT foo AS foom, ?", binding(1) ],
  "AS with parens";

expr_sql_is { SELECT { $_->foo => AS "foom", 1 } }
  [ "SELECT foo AS foom, ?", binding(1) ],
  "AS without parens";