fix dynamic generation skip bug

[scpubgit/System-Introspector-Report.git] / t / publish_mediawiki_parser.t

use strictures 1;
use Test::More;

use aliased 'System::Introspector::Report::Publish::MediaWiki::Parser';

my $parser = Parser->new;
my $stream = $parser->parse(<<'EOR');

= Heading =

<!-- SI:TITLE begin foo -->
== Foo ==
<!-- SI:TITLE end foo -->

User description

<!-- SI:TABLE begin foo -->
<table class="si-report">
  <tr>
    <th class="si-colhead-bar">Bar</th>
    <th class="si-colhead-baz">Baz</th>
    <th>
        Qux
    </th>
  </tr>
  <tr>
    <td class="si-column-bar">231</td>
    <td class="si-column-baz">421</td>
    <td>171</td>
  </tr>
  <tr>
    <td class="si-column-bar">232</td>
    <td class="si-column-baz">422</td>
    <td>172</td>
    <td>173</td>
  </tr>
  <tr>
    <td class="si-column-bar">foo<br/>bar</td>
    <td class="si-column-baz">bar<br/>baz</td>
    <td>199</td>
  </tr>
</table>
<!-- SI:TABLE end foo -->

End Text

EOR

is shift(@$stream), '', 'empty line';
is shift(@$stream), '= Heading =', 'heading';
is shift(@$stream), '', 'empty line';

do {
  my $report = shift @$stream;
  is ref($report), 'HASH', 'report structure';

  is_deeply $report->{id}, ['foo'], 'report id';
  is $report->{title}, 'Foo', 'report title';

  is $report->{columns}[0]{key}, 'bar', 'first column key';
  is $report->{columns}[0]{label}, 'Bar', 'first column label';
  ok not($report->{columns}[0]{user}), 'first column not user supplied';

  is $report->{columns}[1]{key}, 'baz', 'second column key';
  is $report->{columns}[1]{label}, 'Baz', 'second column label';
  ok not($report->{columns}[1]{user}), 'second column not user supplied';

  is $report->{columns}[2]{key}, '__usercol_0', 'first user supplied column key';
  like $report->{columns}[2]{label}, qr{^\s+Qux\s+$}, 'first user supplied column label';
  ok $report->{columns}[2]{user}, 'third column is user supplied';

  is $report->{columns}[3]{key}, '__usercol_orph_0', 'second user supplied column key';
  is $report->{columns}[3]{label}, undef, 'second user supplied column label is empty';
  ok $report->{columns}[3]{user}, 'fourth column is user supplied';

  is_deeply $report->{rows}[0], {
    bar => 231, baz => 421, __usercol_0 => 171,
  }, 'first row';
  is_deeply $report->{rows}[1], {
    bar => 232, baz => 422, __usercol_0 => 172, __usercol_orph_0 => 173,
  }, 'second row';
  is_deeply $report->{rows}[2], {
    bar => "foo\nbar", baz => "bar\nbaz", __usercol_0 => 199,
  }, 'third row';
};

is shift(@$stream), '', 'empty line';
is shift(@$stream), 'End Text', 'end text';
is shift(@$stream), '', 'empty line'
  while @$stream;

done_testing;