dynamic page-name publishing for mediawiki

[scpubgit/System-Introspector-Report.git] / t / publish_mediawiki.t

use strictures 1;
use Test::More;
use IO::All;
use FindBin;

use aliased 'System::Introspector::Report::Publish::MediaWiki';

my %result;

do {
  package TestConnection;
  use Moo;
  use IO::All;
  use aliased 'System::Introspector::Report::Publish::MediaWiki::Page';

  sub get {
    my ($self, $name) = @_;
    return Page->new(
      name      => $name,
      timestamp => 23,
      content   => scalar(io("$FindBin::Bin/data/$name.txt")->slurp),
    );
  }

  sub put {
    my ($self, $page) = @_;
    $result{$page->name} = $page->content;
  }
};

my $conn = TestConnection->new;
my $wiki = MediaWiki->new(
  connection => $conn,
  page => {
    foo => {
      report => ['foo:*'],
    },
  },
);

ok $wiki->publish([
  { id => [qw( foo a )],
    title => "Foo A",
    rowid => ['bar'],
    columns => [
      { key => 'bar', label => 'Bar' },
      { key => 'baz', label => 'Baz' },
    ],
    rows => [
      { bar => 231, baz => 421 },
      { bar => 232, baz => 884 },
      { bar => 332, baz => 784 },
    ],
  },
  { id => [qw( foo b )],
    title => "Foo B",
    rowid => ['bar'],
    columns => [
      { key => 'bar', label => 'Bar' },
      { key => 'baz', label => 'Baz' },
    ],
    rows => [
      { bar => 231, baz => 421 },
      { bar => 332, baz => 784 },
    ],
  },
  { id => [qw( foo c )],
    title => "Foo C",
    rowid => ['bar'],
    columns => [
      { key => 'bar', label => 'New Bar' },
      { key => 'baz', label => 'New Baz' },
    ],
    rows => [
      { bar => 232, baz => 884 },
      { bar => 332, baz => 784 },
    ],
  },
]), 'publish ok';

my $_despace = sub {
  my $string = shift;
  $string =~ s{[\s\n]+}{}g;
  return $string;
};

## uncomment to regenerate result file
# do { no warnings; $result{foo} > io("$FindBin::Bin/data/result/foo.txt") };

is $result{foo}->$_despace,
   scalar(io("$FindBin::Bin/data/result/foo.txt")->slurp)->$_despace,
   'resulting page looks correct';

done_testing;