add compose routine and refactor FetchFirst to functional style

[dbsrgits/Data-Query.git] / t / perl.t

use strictures 1;
use Test::More qw(no_plan);

use Devel::Dwarn;
use Data::Query::Renderer::Perl;
use Data::Query::ExprHelpers qw(perl_scalar_value);

BEGIN { require 't/expr.include' }

my $rend = Data::Query::Renderer::Perl->new;

sub binding { map perl_scalar_value($_), @_ }

sub expr_perl_is (&;@) {
  my $sub = shift;
    @_
      ? is_deeply($rend->render(_run_expr($sub)->{expr}), @_)
      : ::Dwarn($rend->render(_run_expr($sub)->{expr}));
}

expr_perl_is { $_->foo }
  [ '$_->foo' ],
  'Simple identifier -> Perl';

expr_perl_is { $_->foo->group }
  [ '$_->foo->group' ],
  'Complex identifier -> Perl';

expr_perl_is { $_->foo == 1 }
  [ "( \$_->foo == +shift )", binding(1) ],
  "Simple expression -> Perl";

expr_perl_is { ($_->foo == 1) & ($_->bar eq "foo") }
  [
    "( ( \$_->foo == +shift ) and ( \$_->bar eq +shift ) )",
    binding(1, "foo")
  ],
  "Compound expression -> Perl";

# Skipping flattening test for now

expr_perl_is { !$_->foo }
  [ '!( $_->foo )' ],
  "Unary expression ok";