[DOC PATCH] Re: [ID 20020324.002] \G bug on zero-length matches

[p5sagit/p5-mst-13.2.git] / t / lib / 1_compile.t

#!./perl

# Modules should have their own tests.  For historical reasons, some
# do not.  This does basic compile tests on modules that have no tests
# of their own.

BEGIN {
    chdir 't';
    @INC = '../lib';
}

use strict;
use warnings;

# Okay, this is the list.

my @Core_Modules = grep /\S/, <DATA>;
chomp @Core_Modules;

# Two Net:: modules need the Convert::EBCDIC if in EBDCIC.
if (ord("A") != 193 || eval { require Convert::EBCDIC }) {
    push @Core_Modules, qw(Net::Cmd Net::POP3);
}

@Core_Modules = sort @Core_Modules;

print "1..".(1+@Core_Modules)."\n";

my $message
  = "ok 1 - All modules should have tests # TODO Make Schwern Poorer\n";
if (@Core_Modules) {
  print "not $message";
} else {
  print $message;
}

my $test_num = 2;

foreach my $module (@Core_Modules) {
    print "$module compile failed\nnot " unless compile_module($module);
    print "ok $test_num\n";
    $test_num++;
}

# We do this as a separate process else we'll blow the hell
# out of our namespace.
sub compile_module {
    my ($module) = $_[0];

    my $out = scalar `$^X "-I../lib" lib/compmod.pl $module`;
    print "# $out";
    return $out =~ /^ok/;
}

# These modules have no tests of their own.
# Keep up to date with
# http://www.pobox.com/~schwern/cgi-bin/perl-qa-wiki.cgi?UntestedModules
# and vice-versa.  The list should only shrink.
__DATA__
B::CC
B::Disassembler
B::Stackobj
ByteLoader
CPAN
CPAN::FirstTime
DynaLoader
ExtUtils::MM_NW5
ExtUtils::Install
ExtUtils::Liblist
ExtUtils::Mksymlists
Net::Domain
O
Pod::Plainer
Test::Harness::Iterator