Merge 'trunk' into 'sybase'

[dbsrgits/DBIx-Class-Historic.git] / t / inflate / datetime_sybase.t

use strict;
use warnings;  

use Test::More;
use Test::Exception;
use lib qw(t/lib);
use DBICTest;

my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};

if (not ($dsn && $user)) {
  plan skip_all =>
    'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test' .
    "\nWarning: This test drops and creates a table called 'track'";
} else {
  eval "use DateTime; use DateTime::Format::Sybase;";
  if ($@) {
    plan skip_all => 'needs DateTime and DateTime::Format::Sybase for testing';
  }
  else {
    plan tests => (4 * 2 * 2) + 2; # (tests * dt_types * storage_types) + storage_tests
  }
}

my @storage_types = (
  'DBI::Sybase',
  'DBI::Sybase::NoBindVars',
);
my $schema;

for my $storage_type (@storage_types) {
  $schema = DBICTest::Schema->clone;

  unless ($storage_type eq 'DBI::Sybase') { # autodetect
    $schema->storage_type("::$storage_type");
  }
  $schema->connection($dsn, $user, $pass, {
    AutoCommit => 1,
    on_connect_call => [ 'datetime_setup' ],
  });

  $schema->storage->ensure_connected;

  isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );

  my @dt_types = (
    ['DATETIME', '2004-08-21T14:36:48.080Z'],
    ['SMALLDATETIME', '2004-08-21T14:36:00.000Z'], # minute precision
  );
  
  for my $dt_type (@dt_types) {
    my ($type, $sample_dt) = @$dt_type;

    eval { $schema->storage->dbh->do("DROP TABLE track") };
    $schema->storage->dbh->do(<<"SQL");
CREATE TABLE track (
   trackid INT IDENTITY PRIMARY KEY,
   cd INT,
   position INT,
   last_updated_on $type,
)
SQL
    ok(my $dt = DateTime::Format::Sybase->parse_datetime($sample_dt));

    my $row;
    ok( $row = $schema->resultset('Track')->create({
          last_updated_on => $dt,
          cd => 1,
        }));
    ok( $row = $schema->resultset('Track')
      ->search({ trackid => $row->trackid }, { select => ['last_updated_on'] })
      ->first
    );
    is( $row->updated_date, $dt, 'DateTime roundtrip' );
  }
}

# clean up our mess
END {
  if (my $dbh = eval { $schema->storage->_dbh }) {
    $dbh->do('DROP TABLE track');
  }
}