[TEST PATCH] %^H can now propagate into eval

[p5sagit/p5-mst-13.2.git] / t / comp / hints.t

#!./perl

# Tests the scoping of $^H and %^H

BEGIN {
    chdir 't' if -d 't';
    @INC = qw(. ../lib);
}


BEGIN { print "1..17\n"; }
BEGIN {
    print "not " if exists $^H{foo};
    print "ok 1 - \$^H{foo} doesn't exist initially\n";
    print "not " if $^H & 0x00020000;
    print "ok 2 - \$^H doesn't contain HINT_LOCALIZE_HH initially\n";
}
{
    # simulate a pragma -- don't forget HINT_LOCALIZE_HH | HINT_HH_FOR_EVAL
    BEGIN { $^H |= 0x04020000; $^H{foo} = "a"; }
    BEGIN {
	print "not " if $^H{foo} ne "a";
	print "ok 3 - \$^H{foo} is now 'a'\n";
	print "not " unless $^H & 0x00020000;
	print "ok 4 - \$^H contains HINT_LOCALIZE_HH while compiling\n";
	print "not " unless $^H & 0x04000000;
	print "ok 5 - \$^H contains HINT_HH_FOR_EVAL while compiling\n";
    }
    {
	BEGIN { $^H |= 0x00020000; $^H{foo} = "b"; }
	BEGIN {
	    print "not " if $^H{foo} ne "b";
	    print "ok 6 - \$^H{foo} is now 'b'\n";
	}
    }
    BEGIN {
	print "not " if $^H{foo} ne "a";
	print "ok 7 - \$H^{foo} restored to 'a'\n";
    }
    # The pragma settings disappear after compilation
    # (test at CHECK-time and at run-time)
    CHECK {
	print "not " if exists $^H{foo};
	print "ok 10 - \$^H{foo} doesn't exist when compilation complete\n";
	print "not " if $^H & 0x00020000;
	print "ok 11 - \$^H doesn't contain HINT_LOCALIZE_HH when compilation complete\n";
    }
    print "not " if exists $^H{foo};
    print "ok 12 - \$^H{foo} doesn't exist at runtime\n";
    print "not " if $^H & 0x00020000;
    print "ok 13 - \$^H doesn't contain HINT_LOCALIZE_HH at run-time\n";
    print "not " if $^H & 0x04000000;
    print "ok 14 - \$^H doesn't contain HINT_HH_FOR_EVAL at run-time\n";
    # op_entereval should keep the pragmas it was compiled with
    eval q*
	print "not " if $^H{foo} ne "a";
	print "ok 15 - \$^H{foo} is 'a' at eval-\"\" time\n";
	print "not " unless $^H & 0x00020000;
	print "ok 16 - \$^H contains HINT_LOCALIZE_HH at eval\"\"-time\n";
    *;
}
BEGIN {
    print "not " if exists $^H{foo};
    print "ok 8 - \$^H{foo} doesn't exist while finishing compilation\n";
    print "not " if $^H & 0x00020000;
    print "ok 9 - \$^H doesn't contain HINT_LOCALIZE_HH while finishing compilation\n";
}

require 'test.pl';

# bug #27040: hints hash was being double-freed
my $result = runperl(
    prog => '$^H |= 0x20000; eval q{BEGIN { $^H |= 0x20000 }}',
    stderr => 1
);
print "not " if length $result;
print "ok 17 - double-freeing hints hash\n";
print "# got: $result\n" if length $result;