allow usage of a pool of mediawiki updaters instead of just single-process

[scpubgit/System-Introspector-Report.git] / t / builder_perls.t

use strictures 1;
use Test::More;
use FindBin;
use aliased 'System::Introspector::Report::Source';

my $source  = Source->new(root => "$FindBin::Bin/data/json/");
my @reports = $source->generate(['Perls', {}]);

is scalar(@reports), 1, 'single report generated';
my $rep = $reports[0];

is $rep->{id}, 'perls', 'report id';
like $rep->{title}, qr{perl}i, 'report title contains perl';
is_deeply $rep->{meta}, {}, 'no metadata in this report';
is_deeply $rep->{rowid}, [qw( remote location )], 'correct rowid';
my %cols = map { ($_->{key}, 1) } @{$rep->{columns}};
ok $cols{$_}, "$_ column exists"
  for qw( remote hostname location version );
my @rows = (
  { hostname => 'a.example.com',
    remote   => 'hostA',
    location => '/foo/bar/perl',
    version  => '5.10.0',
  },
  { hostname => 'a.example.com',
    remote   => 'hostA',
    location => '/foo/baz/perl',
    version  => '5.14.1',
  },
  { hostname => 'b.example.com',
    remote   => 'hostB',
    location => '/foo/bar/perl',
    version  => '5.10.0',
  },
  { hostname => 'b.example.com',
    remote   => 'hostB',
    location => '/foo/qux/perl',
    version  => '5.14.1',
  },
);
for my $idx (0 .. $#rows) {
  is $rep->{rows}[$idx]{$_}, $rows[$idx]{$_}, "row $idx $_ value"
    for sort keys %{$rows[$idx]};
}

done_testing;