add a simple summary to mediawiki edits

[scpubgit/System-Introspector-Report.git] / t / builder_packages-apt-byhost.t

use strictures 1;
use Test::More;
use FindBin;
use aliased 'System::Introspector::Report::Source';

my $source  = Source->new(root => "$FindBin::Bin/data/json/");
my @reports = $source->generate(['Packages::Apt::ByHost', {}]);

is scalar(@reports), 2, 'two reports received';

my $_test_columns = sub {
  my ($rep, @columns) = @_;
  my %cols = map { ($_->{key}, 1) } @{$rep->{columns}};
  ok $cols{$_}, "$_ column exists"
    for @columns;
};

my $_test_rows = sub {
  my ($rep, @rows) = @_;
  is scalar(@{$rep->{rows}}), scalar(@rows), 'matching number of rows';
  for my $idx (0 .. $#rows) {
    is $rep->{rows}[$idx]{$_}, $rows[$idx]{$_}, "row $idx $_ value"
      for sort keys %{$rows[$idx]};
  }
};

subtest "first report" => sub {
  my $rep = $reports[0];
  is_deeply $rep->{id}, ['packages-apt-by-remote', 'hostA'], 'report id';
  like $rep->{title}, qr{hostA}, 'report title contains remote';
  is_deeply $rep->{meta}, { remote => 'hostA' }, 'meta data';
  is_deeply $rep->{rowid}, ['package'], 'correct rowid';
  $rep->$_test_columns(qw( package version upgrade ));
  $rep->$_test_rows(
    { package => 'bar', version => 17, upgrade => '18' },
    { package => 'baz', version => undef, upgrade => undef, },
    { package => 'foo', version => 23, upgrade => undef },
    { package => 'qux', version => 77, upgrade => '80' },
  );
};

subtest "second report" => sub {
  my $rep = $reports[1];
  is_deeply $rep->{id}, ['packages-apt-by-remote', 'hostB'], 'report id';
  like $rep->{title}, qr{hostB}, 'report title contains remote';
  is_deeply $rep->{meta}, { remote => 'hostB' }, 'meta data';
  is_deeply $rep->{rowid}, ['package'], 'correct rowid';
  $rep->$_test_columns(qw( package version upgrade ));
  $rep->$_test_rows(
    { package => 'bar', version => 18, upgrade => undef },
    { package => 'baz', version => 99, upgrade => undef, },
    { package => 'foo', version => 23, upgrade => 'unparsable' },
    { package => 'qux', version => undef, upgrade => undef },
  );
};

done_testing;