perl 5.003_01: [patch re-organisation and patch series introduction]

[p5sagit/p5-mst-13.2.git] / t / TEST

#!./perl

# $RCSfile: TEST,v $$Revision: 4.1 $$Date: 92/08/07 18:27:00 $

# This is written in a peculiar style, since we're trying to avoid
# most of the constructs we'll be testing for.

$| = 1;

if ($ARGV[0] eq '-v') {
    $verbose = 1;
    shift;
}

chdir 't' if -f 't/TEST';

die "You need to run \"make test\" first to set things up.\n" 
  unless -e 'perl' or -e 'perl.exe';

$ENV{EMXSHELL} = 'sh';        # For OS/2

if ($ARGV[0] eq '') {
    @ARGV = split(/[ \n]/,
      `echo base/*.t comp/*.t cmd/*.t io/*.t; echo op/*.t lib/*.t`);
}

open(CONFIG,"../config.sh");
while (<CONFIG>) {
    if (/sharpbang='(.*)'/) {
	$sharpbang = ($1 eq '#!');
	last;
    }
}
$sharpbang = 0 if $ENV{OS2_SHELL};		# OS/2
$bad = 0;
$good = 0;
$total = @ARGV;
while ($test = shift) {
    if ($test =~ /^$/) {
	next;
    }
    $te = $test;
    chop($te);
    print "$te" . '.' x (15 - length($te));
    if ($sharpbang) {
	open(results,"./$test |") || (print "can't run.\n");
    } else {
	open(script,"$test") || die "Can't run $test.\n";
	$_ = <script>;
	close(script);
	if (/#!..perl(.*)/) {
	    $switch = $1;
	} else {
	    $switch = '';
	}
	open(results,"./perl$switch $test |") || (print "can't run.\n");
    }
    $ok = 0;
    $next = 0;
    while (<results>) {
	if ($verbose) {
	    print $_;
	}
	unless (/^#/) {
	    if (/^1\.\.([0-9]+)/) {
		$max = $1;
		$totmax += $max;
		$files += 1;
		$next = 1;
		$ok = 1;
	    } else {
		$next = $1, $ok = 0, last if /^not ok ([0-9]*)/;
		if (/^ok (.*)/ && $1 == $next) {
		    $next = $next + 1;
		} else {
		    $ok = 0;
		}
	    }
	}
    }
    $next = $next - 1;
    if ($ok && $next == $max) {
	if ($max) {
	    print "ok\n";
	    $good = $good + 1;
	} else {
	    print "skipping test on this platform\n";
	    $files -= 1;
	}
    } else {
	$next += 1;
	print "FAILED on test $next\n";
	$bad = $bad + 1;
	$_ = $test;
	if (/^base/) {
	    die "Failed a basic test--cannot continue.\n";
	}
    }
}

if ($bad == 0) {
    if ($ok) {
	print "All tests successful.\n";
    } else {
	die "FAILED--no tests were run for some reason.\n";
    }
} else {
    $pct = sprintf("%.2f", $good / $total * 100);
    if ($bad == 1) {
	warn "Failed 1 test, $pct% okay.\n";
    } else {
	die "Failed $bad/$total tests, $pct% okay.\n";
    }
}
($user,$sys,$cuser,$csys) = times;
print sprintf("u=%g  s=%g  cu=%g  cs=%g  files=%d  tests=%d\n",
    $user,$sys,$cuser,$csys,$files,$totmax);