added role self_check and self_check_any to User store

[catagits/Catalyst-Authentication-Store-DBIx-Class.git] / t / 13-auth-roles-column-self_check.t

#!perl

use strict;
use warnings;
use DBI;
use File::Path;
use FindBin;
use Test::More;
use lib "$FindBin::Bin/lib";

BEGIN {
    eval { require DBD::SQLite }
        or plan skip_all =>
        "DBD::SQLite is required for this test";

    eval { require Catalyst::Plugin::Authorization::Roles }
        or plan skip_all =>
        "Catalyst::Plugin::Authorization::Roles is required for this test";

    plan tests => 29;

    use TestApp;
    TestApp->config( {
        name => 'TestApp',
        authentication => {
            default_realm => "users",
            realms => {
                users => {
                    credential => {
                        'class' => "Password",
                        'password_field' => 'password',
                        'password_type' => 'clear'
                    },
                    store => {
                        'class' => 'DBIx::Class',
                        'user_model' => 'TestApp::User',
                        'role_column' => 'role_text',
                        'check_roles'   => 't_check_roles',
                        'check_roles_any' => 't_check_roles_any'
                    },
                },
            },
        },
    } );

    TestApp->setup(
        qw/Authentication
           Authorization::Roles
           /
    );
}

use Catalyst::Test 'TestApp';

# test user's admin access
{
    ok( my $res = request('http://localhost/user_login?username=joeuser&password=hackme&detach=is_admin'), 'request ok' );
    is( $res->content, 'ok', 'user is an admin' );
}

# test unauthorized user's admin access
{
    ok( my $res = request('http://localhost/user_login?username=jayk&password=letmein&detach=is_admin'), 'request ok' );
    is( $res->content, 'failed', 'user is not an admin' );
}

# test multiple auth roles
{
    ok( my $res = request('http://localhost/user_login?username=nuffin&password=much&detach=is_admin_user'), 'request ok' );
    is( $res->content, 'ok', 'user is an admin and a user' );
}

# test multiple unauth roles
{
    ok( my $res = request('http://localhost/user_login?username=joeuser&password=hackme&detach=is_admin_user'), 'request ok' );
    is( $res->content, 'failed', 'user is not an admin and a user' );
}

# test assert_any_user_role
{
    ok( my ( $res, $c )= ctx_request('http://localhost/user_login?username=joeuser&password=hackme&detach=is_any_admin_user'), 'request ok' );
    is( $res->content, 'ok', 'user is user' );
    is ( my @roles = $c->user->roles, 1, 'only 1 role' );
    is ( $roles[0], 'admin', 'role is admin' );
}

# test assert_any_user_role
{
    ok( my ( $res, $c )= ctx_request('http://localhost/user_login?username=nuffin&password=much&detach=is_any_admin_user'), 'request ok' );
    is( $res->content, 'ok', 'user is user and an admin' );
    is ( my @roles = $c->user->roles, 2, '2 roles' );
    is ( $roles[0], 'user', 'role is user' );
    is ( $roles[1], 'admin', 'role is admin' );
}

# test superuser role override
{
    ok( my ( $res, $c )= ctx_request('http://localhost/user_login?username=graeme&password=supersecret&detach=is_admin_user'), 'request ok' );
    is( $res->content, 'ok', 'superuser role is all roles' );
    is ( my @roles = $c->user->roles, 1, 'only 1 role' );
    is ( $roles[0], 'superadmin', 'role is user' );
}

# test superuser role override none existant roles
{
    ok( my ( $res, $c )= ctx_request('http://localhost/user_login?username=graeme&password=supersecret&detach=is_nonexistant_roles'), 'request ok' );
    is( $res->content, 'ok', 'superuser role is all roles' );
    is ( my @roles = $c->user->roles, 1, 'only 1 role' );
    is ( $roles[0], 'superadmin', 'role is user' );
}

# test superuser role override any none existant roles
{
    ok( my ( $res, $c )= ctx_request('http://localhost/user_login?username=graeme&password=supersecret&detach=is_any_nonexistant_role'), 'request ok' );
    is( $res->content, 'ok', 'superuser role is all roles' );
    is ( my @roles = $c->user->roles, 1, 'only 1 role' );
    is ( $roles[0], 'superadmin', 'role is user' );
}