Added unflocks to all tests so that the tests run on OSX

[dbsrgits/DBM-Deep.git] / t / 08_deephash.t

##
# DBM::Deep Test
##
use strict;
use Test::More tests => 5;
use File::Temp qw( tempfile tempdir );
use Fcntl qw( :flock );

use_ok( 'DBM::Deep' );

my $dir = tempdir( CLEANUP => 1 );
my ($fh, $filename) = tempfile( 'tmpXXXX', UNLINK => 1, DIR => $dir );
flock $fh, LOCK_UN;

my $max_levels = 1000;

{
    my $db = DBM::Deep->new(
        file => $filename,
        type => DBM::Deep->TYPE_HASH,
    );

    ##
    # basic deep hash
    ##
    $db->{company} = {};
    $db->{company}->{name} = "My Co.";
    $db->{company}->{employees} = {};
    $db->{company}->{employees}->{"Henry Higgins"} = {};
    $db->{company}->{employees}->{"Henry Higgins"}->{salary} = 90000;

    is( $db->{company}->{name}, "My Co.", "Set and retrieved a second-level value" );
    is( $db->{company}->{employees}->{"Henry Higgins"}->{salary}, 90000, "Set and retrieved a fourth-level value" );

    ##
    # super deep hash
    ##
    $db->{base_level} = {};
    my $temp_db = $db->{base_level};

    for my $k ( 0 .. $max_levels ) {
        $temp_db->{"level$k"} = {};
        $temp_db = $temp_db->{"level$k"};
    }
    $temp_db->{deepkey} = "deepvalue";
}

{
    my $db = DBM::Deep->new(
        file => $filename,
        type => DBM::Deep->TYPE_HASH,
    );

    my $cur_level = -1;
    my $temp_db = $db->{base_level};
    for my $k ( 0 .. $max_levels ) {
        $cur_level = $k;
        $temp_db = $temp_db->{"level$k"};
        eval { $temp_db->isa( 'DBM::Deep' ) } or last;
    }
    is( $cur_level, $max_levels, "We read all the way down to level $cur_level" );
    is( $temp_db->{deepkey}, "deepvalue", "And we retrieved the value at the bottom of the ocean" );
}