method modifiers,.. I think the API needs work

[gitmo/Class-MOP.git] / t / 017_add_method_modifier.t

#!/usr/bin/perl

use strict;
use warnings;

use Test::More no_plan => 53;
use Test::Exception;

BEGIN {
    use_ok('Class::MOP');
}

{
    package BankAccount;
    
    use strict;
    use warnings;
    use metaclass;
        
    use Carp 'confess';
    
    BankAccount->meta->add_attribute('$:balance' => (
        accessor => 'balance',
		init_arg => 'balance',
        default  => 0
    ));
    
    sub new { (shift)->meta->new_object(@_) }
    
    sub deposit {
        my ($self, $amount) = @_;
		#warn "deposited $amount in $self";
        $self->balance($self->balance + $amount);
    }
    
    sub withdraw {
       my ($self, $amount) = @_;
       my $current_balance = $self->balance();
       ($current_balance >= $amount)
            || confess "Account overdrawn";
		#warn "withdrew $amount from $self";
        $self->balance($current_balance - $amount);
    }

	package CheckingAccount;
	
	use strict;
	use warnings;
	
	use base 'BankAccount';
	
    CheckingAccount->meta->add_attribute('$:overdraft_account' => (
        accessor => 'overdraft_account',
		init_arg => 'overdraft',
    ));	

	CheckingAccount->meta->add_method_modifier('withdraw' => 'before' => sub {
		my ($self, $amount) = @_;
		#warn "hello from before";
		my $overdraft_amount = $amount - $self->balance();
		if ($overdraft_amount > 0) {
			#warn "overdrawn $overdraft_amount";
			$self->overdraft_account->withdraw($overdraft_amount);
			$self->deposit($overdraft_amount);
		}
		#warn "balance after overdraft : " . $self->balance;		
	});

	::ok(CheckingAccount->meta->has_method('withdraw'), '... checking account now has a withdraw method');
}


my $savings_account = BankAccount->new(balance => 250);
isa_ok($savings_account, 'BankAccount');

is($savings_account->balance, 250, '... got the right savings balance');
lives_ok {
	$savings_account->withdraw(50);
} '... withdrew from savings successfully';
is($savings_account->balance, 200, '... got the right savings balance after withdrawl');

$savings_account->deposit(150);
is($savings_account->balance, 350, '... got the right savings balance after deposit');

my $checking_account = CheckingAccount->new(
							balance   => 100,
							overdraft => $savings_account
						);
isa_ok($checking_account, 'CheckingAccount');
isa_ok($checking_account, 'BankAccount');

is($checking_account->overdraft_account, $savings_account, '... got the right overdraft account');

is($checking_account->balance, 100, '... got the right checkings balance');

lives_ok {
	$checking_account->withdraw(200);
} '... withdrew from checking successfully';

is($checking_account->balance, 0, '... got the right checkings balance after withdrawl');
is($savings_account->balance, 250, '... got the right savings balance after overdraft withdrawl');