Commit | Line | Data |
a0d0e21e |
1 | =head1 NAME |
2 | |
3 | perlref - Perl references and nested data structures |
4 | |
5 | =head1 DESCRIPTION |
6 | |
cb1a09d0 |
7 | Before release 5 of Perl it was difficult to represent complex data |
8 | structures, because all references had to be symbolic, and even that was |
9 | difficult to do when you wanted to refer to a variable rather than a |
5f05dabc |
10 | symbol table entry. Perl not only makes it easier to use symbolic |
cb1a09d0 |
11 | references to variables, but lets you have "hard" references to any piece |
5f05dabc |
12 | of data. Any scalar may hold a hard reference. Because arrays and hashes |
cb1a09d0 |
13 | contain scalars, you can now easily build arrays of arrays, arrays of |
14 | hashes, hashes of arrays, arrays of hashes of functions, and so on. |
a0d0e21e |
15 | |
16 | Hard references are smart--they keep track of reference counts for you, |
2d24ed35 |
17 | automatically freeing the thing referred to when its reference count goes |
18 | to zero. (Note: The reference counts for values in self-referential or |
19 | cyclic data structures may not go to zero without a little help; see |
6309d9d9 |
20 | L<perlobj/"Two-Phased Garbage Collection"> for a detailed explanation. |
2d24ed35 |
21 | If that thing happens to be an object, the object is destructed. See |
22 | L<perlobj> for more about objects. (In a sense, everything in Perl is an |
23 | object, but we usually reserve the word for references to objects that |
24 | have been officially "blessed" into a class package.) |
25 | |
26 | Symbolic references are names of variables or other objects, just as a |
54310121 |
27 | symbolic link in a Unix filesystem contains merely the name of a file. |
2d24ed35 |
28 | The C<*glob> notation is a kind of symbolic reference. (Symbolic |
29 | references are sometimes called "soft references", but please don't call |
30 | them that; references are confusing enough without useless synonyms.) |
31 | |
54310121 |
32 | In contrast, hard references are more like hard links in a Unix file |
2d24ed35 |
33 | system: They are used to access an underlying object without concern for |
34 | what its (other) name is. When the word "reference" is used without an |
35 | adjective, like in the following paragraph, it usually is talking about a |
36 | hard reference. |
37 | |
38 | References are easy to use in Perl. There is just one overriding |
39 | principle: Perl does no implicit referencing or dereferencing. When a |
40 | scalar is holding a reference, it always behaves as a simple scalar. It |
41 | doesn't magically start being an array or hash or subroutine; you have to |
42 | tell it explicitly to do so, by dereferencing it. |
a0d0e21e |
43 | |
54310121 |
44 | References can be constructed in several ways. |
a0d0e21e |
45 | |
46 | =over 4 |
47 | |
48 | =item 1. |
49 | |
50 | By using the backslash operator on a variable, subroutine, or value. |
54310121 |
51 | (This works much like the & (address-of) operator in C.) Note |
5f05dabc |
52 | that this typically creates I<ANOTHER> reference to a variable, because |
a0d0e21e |
53 | there's already a reference to the variable in the symbol table. But |
54 | the symbol table reference might go away, and you'll still have the |
55 | reference that the backslash returned. Here are some examples: |
56 | |
57 | $scalarref = \$foo; |
58 | $arrayref = \@ARGV; |
59 | $hashref = \%ENV; |
60 | $coderef = \&handler; |
55497cff |
61 | $globref = \*foo; |
cb1a09d0 |
62 | |
5f05dabc |
63 | It isn't possible to create a true reference to an IO handle (filehandle or |
36477c24 |
64 | dirhandle) using the backslash operator. See the explanation of the |
5f05dabc |
65 | *foo{THING} syntax below. (However, you're apt to find Perl code |
54310121 |
66 | out there using globrefs as though they were IO handles, which is |
5f05dabc |
67 | grandfathered into continued functioning.) |
a0d0e21e |
68 | |
69 | =item 2. |
70 | |
71 | A reference to an anonymous array can be constructed using square |
72 | brackets: |
73 | |
74 | $arrayref = [1, 2, ['a', 'b', 'c']]; |
75 | |
76 | Here we've constructed a reference to an anonymous array of three elements |
54310121 |
77 | whose final element is itself a reference to another anonymous array of three |
a0d0e21e |
78 | elements. (The multidimensional syntax described later can be used to |
184e9718 |
79 | access this. For example, after the above, C<$arrayref-E<gt>[2][1]> would have |
a0d0e21e |
80 | the value "b".) |
81 | |
cb1a09d0 |
82 | Note that taking a reference to an enumerated list is not the same |
83 | as using square brackets--instead it's the same as creating |
84 | a list of references! |
85 | |
54310121 |
86 | @list = (\$a, \@b, \%c); |
58e0a6ae |
87 | @list = \($a, @b, %c); # same thing! |
88 | |
54310121 |
89 | As a special case, C<\(@foo)> returns a list of references to the contents |
58e0a6ae |
90 | of C<@foo>, not a reference to C<@foo> itself. Likewise for C<%foo>. |
cb1a09d0 |
91 | |
a0d0e21e |
92 | =item 3. |
93 | |
94 | A reference to an anonymous hash can be constructed using curly |
95 | brackets: |
96 | |
97 | $hashref = { |
98 | 'Adam' => 'Eve', |
99 | 'Clyde' => 'Bonnie', |
100 | }; |
101 | |
102 | Anonymous hash and array constructors can be intermixed freely to |
103 | produce as complicated a structure as you want. The multidimensional |
104 | syntax described below works for these too. The values above are |
105 | literals, but variables and expressions would work just as well, because |
106 | assignment operators in Perl (even within local() or my()) are executable |
107 | statements, not compile-time declarations. |
108 | |
109 | Because curly brackets (braces) are used for several other things |
110 | including BLOCKs, you may occasionally have to disambiguate braces at the |
111 | beginning of a statement by putting a C<+> or a C<return> in front so |
112 | that Perl realizes the opening brace isn't starting a BLOCK. The economy and |
113 | mnemonic value of using curlies is deemed worth this occasional extra |
114 | hassle. |
115 | |
116 | For example, if you wanted a function to make a new hash and return a |
117 | reference to it, you have these options: |
118 | |
119 | sub hashem { { @_ } } # silently wrong |
120 | sub hashem { +{ @_ } } # ok |
121 | sub hashem { return { @_ } } # ok |
122 | |
123 | =item 4. |
124 | |
125 | A reference to an anonymous subroutine can be constructed by using |
126 | C<sub> without a subname: |
127 | |
128 | $coderef = sub { print "Boink!\n" }; |
129 | |
130 | Note the presence of the semicolon. Except for the fact that the code |
131 | inside isn't executed immediately, a C<sub {}> is not so much a |
132 | declaration as it is an operator, like C<do{}> or C<eval{}>. (However, no |
133 | matter how many times you execute that line (unless you're in an |
134 | C<eval("...")>), C<$coderef> will still have a reference to the I<SAME> |
135 | anonymous subroutine.) |
136 | |
748a9306 |
137 | Anonymous subroutines act as closures with respect to my() variables, |
138 | that is, variables visible lexically within the current scope. Closure |
139 | is a notion out of the Lisp world that says if you define an anonymous |
140 | function in a particular lexical context, it pretends to run in that |
141 | context even when it's called outside of the context. |
142 | |
143 | In human terms, it's a funny way of passing arguments to a subroutine when |
144 | you define it as well as when you call it. It's useful for setting up |
145 | little bits of code to run later, such as callbacks. You can even |
54310121 |
146 | do object-oriented stuff with it, though Perl already provides a different |
147 | mechanism to do that--see L<perlobj>. |
748a9306 |
148 | |
149 | You can also think of closure as a way to write a subroutine template without |
150 | using eval. (In fact, in version 5.000, eval was the I<only> way to get |
151 | closures. You may wish to use "require 5.001" if you use closures.) |
152 | |
153 | Here's a small example of how closures works: |
154 | |
155 | sub newprint { |
156 | my $x = shift; |
157 | return sub { my $y = shift; print "$x, $y!\n"; }; |
a0d0e21e |
158 | } |
748a9306 |
159 | $h = newprint("Howdy"); |
160 | $g = newprint("Greetings"); |
161 | |
162 | # Time passes... |
163 | |
164 | &$h("world"); |
165 | &$g("earthlings"); |
a0d0e21e |
166 | |
748a9306 |
167 | This prints |
168 | |
169 | Howdy, world! |
170 | Greetings, earthlings! |
171 | |
172 | Note particularly that $x continues to refer to the value passed into |
cb1a09d0 |
173 | newprint() I<despite> the fact that the "my $x" has seemingly gone out of |
748a9306 |
174 | scope by the time the anonymous subroutine runs. That's what closure |
175 | is all about. |
176 | |
5f05dabc |
177 | This applies to only lexical variables, by the way. Dynamic variables |
748a9306 |
178 | continue to work as they have always worked. Closure is not something |
179 | that most Perl programmers need trouble themselves about to begin with. |
a0d0e21e |
180 | |
181 | =item 5. |
182 | |
183 | References are often returned by special subroutines called constructors. |
748a9306 |
184 | Perl objects are just references to a special kind of object that happens to know |
a0d0e21e |
185 | which package it's associated with. Constructors are just special |
186 | subroutines that know how to create that association. They do so by |
187 | starting with an ordinary reference, and it remains an ordinary reference |
188 | even while it's also being an object. Constructors are customarily |
189 | named new(), but don't have to be: |
190 | |
191 | $objref = new Doggie (Tail => 'short', Ears => 'long'); |
192 | |
193 | =item 6. |
194 | |
195 | References of the appropriate type can spring into existence if you |
5f05dabc |
196 | dereference them in a context that assumes they exist. Because we haven't |
a0d0e21e |
197 | talked about dereferencing yet, we can't show you any examples yet. |
198 | |
cb1a09d0 |
199 | =item 7. |
200 | |
55497cff |
201 | A reference can be created by using a special syntax, lovingly known as |
202 | the *foo{THING} syntax. *foo{THING} returns a reference to the THING |
203 | slot in *foo (which is the symbol table entry which holds everything |
204 | known as foo). |
cb1a09d0 |
205 | |
55497cff |
206 | $scalarref = *foo{SCALAR}; |
207 | $arrayref = *ARGV{ARRAY}; |
208 | $hashref = *ENV{HASH}; |
209 | $coderef = *handler{CODE}; |
36477c24 |
210 | $ioref = *STDIN{IO}; |
55497cff |
211 | $globref = *foo{GLOB}; |
212 | |
36477c24 |
213 | All of these are self-explanatory except for *foo{IO}. It returns the |
214 | IO handle, used for file handles (L<perlfunc/open>), sockets |
215 | (L<perlfunc/socket> and L<perlfunc/socketpair>), and directory handles |
216 | (L<perlfunc/opendir>). For compatibility with previous versions of |
217 | Perl, *foo{FILEHANDLE} is a synonym for *foo{IO}. |
55497cff |
218 | |
5f05dabc |
219 | *foo{THING} returns undef if that particular THING hasn't been used yet, |
220 | except in the case of scalars. *foo{SCALAR} returns a reference to an |
221 | anonymous scalar if $foo hasn't been used yet. This might change in a |
222 | future release. |
223 | |
224 | The use of *foo{IO} is the best way to pass bareword filehandles into or |
225 | out of subroutines, or to store them in larger data structures. |
36477c24 |
226 | |
227 | splutter(*STDOUT{IO}); |
cb1a09d0 |
228 | sub splutter { |
229 | my $fh = shift; |
230 | print $fh "her um well a hmmm\n"; |
231 | } |
232 | |
36477c24 |
233 | $rec = get_rec(*STDIN{IO}); |
cb1a09d0 |
234 | sub get_rec { |
235 | my $fh = shift; |
236 | return scalar <$fh>; |
237 | } |
238 | |
5f05dabc |
239 | Beware, though, that you can't do this with a routine which is going to |
240 | open the filehandle for you, because *HANDLE{IO} will be undef if HANDLE |
241 | hasn't been used yet. Use \*HANDLE for that sort of thing instead. |
242 | |
243 | Using \*HANDLE (or *HANDLE) is another way to use and store non-bareword |
a6006777 |
244 | filehandles (before perl version 5.002 it was the only way). The two |
245 | methods are largely interchangeable, you can do |
5f05dabc |
246 | |
247 | splutter(\*STDOUT); |
248 | $rec = get_rec(\*STDIN); |
249 | |
250 | with the above subroutine definitions. |
55497cff |
251 | |
a0d0e21e |
252 | =back |
253 | |
254 | That's it for creating references. By now you're probably dying to |
255 | know how to use references to get back to your long-lost data. There |
256 | are several basic methods. |
257 | |
258 | =over 4 |
259 | |
260 | =item 1. |
261 | |
6309d9d9 |
262 | Anywhere you'd put an identifier (or chain of identifiers) as part |
263 | of a variable or subroutine name, you can replace the identifier with |
264 | a simple scalar variable containing a reference of the correct type: |
a0d0e21e |
265 | |
266 | $bar = $$scalarref; |
267 | push(@$arrayref, $filename); |
268 | $$arrayref[0] = "January"; |
269 | $$hashref{"KEY"} = "VALUE"; |
270 | &$coderef(1,2,3); |
cb1a09d0 |
271 | print $globref "output\n"; |
a0d0e21e |
272 | |
273 | It's important to understand that we are specifically I<NOT> dereferencing |
274 | C<$arrayref[0]> or C<$hashref{"KEY"}> there. The dereference of the |
275 | scalar variable happens I<BEFORE> it does any key lookups. Anything more |
276 | complicated than a simple scalar variable must use methods 2 or 3 below. |
277 | However, a "simple scalar" includes an identifier that itself uses method |
278 | 1 recursively. Therefore, the following prints "howdy". |
279 | |
280 | $refrefref = \\\"howdy"; |
281 | print $$$$refrefref; |
282 | |
283 | =item 2. |
284 | |
6309d9d9 |
285 | Anywhere you'd put an identifier (or chain of identifiers) as part of a |
286 | variable or subroutine name, you can replace the identifier with a |
287 | BLOCK returning a reference of the correct type. In other words, the |
288 | previous examples could be written like this: |
a0d0e21e |
289 | |
290 | $bar = ${$scalarref}; |
291 | push(@{$arrayref}, $filename); |
292 | ${$arrayref}[0] = "January"; |
293 | ${$hashref}{"KEY"} = "VALUE"; |
294 | &{$coderef}(1,2,3); |
36477c24 |
295 | $globref->print("output\n"); # iff IO::Handle is loaded |
a0d0e21e |
296 | |
297 | Admittedly, it's a little silly to use the curlies in this case, but |
298 | the BLOCK can contain any arbitrary expression, in particular, |
299 | subscripted expressions: |
300 | |
54310121 |
301 | &{ $dispatch{$index} }(1,2,3); # call correct routine |
a0d0e21e |
302 | |
303 | Because of being able to omit the curlies for the simple case of C<$$x>, |
304 | people often make the mistake of viewing the dereferencing symbols as |
305 | proper operators, and wonder about their precedence. If they were, |
5f05dabc |
306 | though, you could use parentheses instead of braces. That's not the case. |
a0d0e21e |
307 | Consider the difference below; case 0 is a short-hand version of case 1, |
308 | I<NOT> case 2: |
309 | |
310 | $$hashref{"KEY"} = "VALUE"; # CASE 0 |
311 | ${$hashref}{"KEY"} = "VALUE"; # CASE 1 |
312 | ${$hashref{"KEY"}} = "VALUE"; # CASE 2 |
313 | ${$hashref->{"KEY"}} = "VALUE"; # CASE 3 |
314 | |
315 | Case 2 is also deceptive in that you're accessing a variable |
316 | called %hashref, not dereferencing through $hashref to the hash |
317 | it's presumably referencing. That would be case 3. |
318 | |
319 | =item 3. |
320 | |
321 | The case of individual array elements arises often enough that it gets |
322 | cumbersome to use method 2. As a form of syntactic sugar, the two |
323 | lines like that above can be written: |
324 | |
325 | $arrayref->[0] = "January"; |
748a9306 |
326 | $hashref->{"KEY"} = "VALUE"; |
a0d0e21e |
327 | |
328 | The left side of the array can be any expression returning a reference, |
329 | including a previous dereference. Note that C<$array[$x]> is I<NOT> the |
330 | same thing as C<$array-E<gt>[$x]> here: |
331 | |
332 | $array[$x]->{"foo"}->[0] = "January"; |
333 | |
334 | This is one of the cases we mentioned earlier in which references could |
335 | spring into existence when in an lvalue context. Before this |
336 | statement, C<$array[$x]> may have been undefined. If so, it's |
337 | automatically defined with a hash reference so that we can look up |
338 | C<{"foo"}> in it. Likewise C<$array[$x]-E<gt>{"foo"}> will automatically get |
339 | defined with an array reference so that we can look up C<[0]> in it. |
340 | |
341 | One more thing here. The arrow is optional I<BETWEEN> brackets |
342 | subscripts, so you can shrink the above down to |
343 | |
344 | $array[$x]{"foo"}[0] = "January"; |
345 | |
346 | Which, in the degenerate case of using only ordinary arrays, gives you |
347 | multidimensional arrays just like C's: |
348 | |
349 | $score[$x][$y][$z] += 42; |
350 | |
351 | Well, okay, not entirely like C's arrays, actually. C doesn't know how |
352 | to grow its arrays on demand. Perl does. |
353 | |
354 | =item 4. |
355 | |
356 | If a reference happens to be a reference to an object, then there are |
357 | probably methods to access the things referred to, and you should probably |
358 | stick to those methods unless you're in the class package that defines the |
359 | object's methods. In other words, be nice, and don't violate the object's |
360 | encapsulation without a very good reason. Perl does not enforce |
361 | encapsulation. We are not totalitarians here. We do expect some basic |
362 | civility though. |
363 | |
364 | =back |
365 | |
366 | The ref() operator may be used to determine what type of thing the |
367 | reference is pointing to. See L<perlfunc>. |
368 | |
369 | The bless() operator may be used to associate a reference with a package |
370 | functioning as an object class. See L<perlobj>. |
371 | |
5f05dabc |
372 | A typeglob may be dereferenced the same way a reference can, because |
a0d0e21e |
373 | the dereference syntax always indicates the kind of reference desired. |
374 | So C<${*foo}> and C<${\$foo}> both indicate the same scalar variable. |
375 | |
376 | Here's a trick for interpolating a subroutine call into a string: |
377 | |
cb1a09d0 |
378 | print "My sub returned @{[mysub(1,2,3)]} that time.\n"; |
379 | |
380 | The way it works is that when the C<@{...}> is seen in the double-quoted |
381 | string, it's evaluated as a block. The block creates a reference to an |
382 | anonymous array containing the results of the call to C<mysub(1,2,3)>. So |
383 | the whole block returns a reference to an array, which is then |
384 | dereferenced by C<@{...}> and stuck into the double-quoted string. This |
385 | chicanery is also useful for arbitrary expressions: |
a0d0e21e |
386 | |
184e9718 |
387 | print "That yields @{[$n + 5]} widgets\n"; |
a0d0e21e |
388 | |
389 | =head2 Symbolic references |
390 | |
391 | We said that references spring into existence as necessary if they are |
392 | undefined, but we didn't say what happens if a value used as a |
393 | reference is already defined, but I<ISN'T> a hard reference. If you |
394 | use it as a reference in this case, it'll be treated as a symbolic |
395 | reference. That is, the value of the scalar is taken to be the I<NAME> |
396 | of a variable, rather than a direct link to a (possibly) anonymous |
397 | value. |
398 | |
399 | People frequently expect it to work like this. So it does. |
400 | |
401 | $name = "foo"; |
402 | $$name = 1; # Sets $foo |
403 | ${$name} = 2; # Sets $foo |
404 | ${$name x 2} = 3; # Sets $foofoo |
405 | $name->[0] = 4; # Sets $foo[0] |
406 | @$name = (); # Clears @foo |
407 | &$name(); # Calls &foo() (as in Perl 4) |
408 | $pack = "THAT"; |
409 | ${"${pack}::$name"} = 5; # Sets $THAT::foo without eval |
410 | |
411 | This is very powerful, and slightly dangerous, in that it's possible |
412 | to intend (with the utmost sincerity) to use a hard reference, and |
413 | accidentally use a symbolic reference instead. To protect against |
414 | that, you can say |
415 | |
416 | use strict 'refs'; |
417 | |
418 | and then only hard references will be allowed for the rest of the enclosing |
54310121 |
419 | block. An inner block may countermand that with |
a0d0e21e |
420 | |
421 | no strict 'refs'; |
422 | |
423 | Only package variables are visible to symbolic references. Lexical |
424 | variables (declared with my()) aren't in a symbol table, and thus are |
425 | invisible to this mechanism. For example: |
426 | |
427 | local($value) = 10; |
428 | $ref = \$value; |
429 | { |
430 | my $value = 20; |
431 | print $$ref; |
54310121 |
432 | } |
a0d0e21e |
433 | |
434 | This will still print 10, not 20. Remember that local() affects package |
435 | variables, which are all "global" to the package. |
436 | |
748a9306 |
437 | =head2 Not-so-symbolic references |
438 | |
a6006777 |
439 | A new feature contributing to readability in perl version 5.001 is that the |
440 | brackets around a symbolic reference behave more like quotes, just as they |
748a9306 |
441 | always have within a string. That is, |
442 | |
443 | $push = "pop on "; |
444 | print "${push}over"; |
445 | |
446 | has always meant to print "pop on over", despite the fact that push is |
447 | a reserved word. This has been generalized to work the same outside |
448 | of quotes, so that |
449 | |
450 | print ${push} . "over"; |
451 | |
452 | and even |
453 | |
454 | print ${ push } . "over"; |
455 | |
456 | will have the same effect. (This would have been a syntax error in |
a6006777 |
457 | Perl 5.000, though Perl 4 allowed it in the spaceless form.) Note that this |
748a9306 |
458 | construct is I<not> considered to be a symbolic reference when you're |
459 | using strict refs: |
460 | |
461 | use strict 'refs'; |
462 | ${ bareword }; # Okay, means $bareword. |
463 | ${ "bareword" }; # Error, symbolic reference. |
464 | |
465 | Similarly, because of all the subscripting that is done using single |
466 | words, we've applied the same rule to any bareword that is used for |
467 | subscripting a hash. So now, instead of writing |
468 | |
469 | $array{ "aaa" }{ "bbb" }{ "ccc" } |
470 | |
5f05dabc |
471 | you can write just |
748a9306 |
472 | |
473 | $array{ aaa }{ bbb }{ ccc } |
474 | |
475 | and not worry about whether the subscripts are reserved words. In the |
476 | rare event that you do wish to do something like |
477 | |
478 | $array{ shift } |
479 | |
480 | you can force interpretation as a reserved word by adding anything that |
481 | makes it more than a bareword: |
482 | |
483 | $array{ shift() } |
484 | $array{ +shift } |
485 | $array{ shift @_ } |
486 | |
487 | The B<-w> switch will warn you if it interprets a reserved word as a string. |
5f05dabc |
488 | But it will no longer warn you about using lowercase words, because the |
748a9306 |
489 | string is effectively quoted. |
490 | |
cb1a09d0 |
491 | =head1 WARNING |
748a9306 |
492 | |
493 | You may not (usefully) use a reference as the key to a hash. It will be |
494 | converted into a string: |
495 | |
496 | $x{ \$a } = $a; |
497 | |
54310121 |
498 | If you try to dereference the key, it won't do a hard dereference, and |
184e9718 |
499 | you won't accomplish what you're attempting. You might want to do something |
cb1a09d0 |
500 | more like |
748a9306 |
501 | |
cb1a09d0 |
502 | $r = \@a; |
503 | $x{ $r } = $r; |
504 | |
505 | And then at least you can use the values(), which will be |
506 | real refs, instead of the keys(), which won't. |
507 | |
508 | =head1 SEE ALSO |
a0d0e21e |
509 | |
510 | Besides the obvious documents, source code can be instructive. |
511 | Some rather pathological examples of the use of references can be found |
512 | in the F<t/op/ref.t> regression test in the Perl source directory. |
cb1a09d0 |
513 | |
514 | See also L<perldsc> and L<perllol> for how to use references to create |
515 | complex data structures, and L<perlobj> for how to use them to create |
516 | objects. |