Commit | Line | Data |
a0d0e21e |
1 | =head1 NAME |
2 | |
3 | perlobj - Perl objects |
4 | |
5 | =head1 DESCRIPTION |
6 | |
14218588 |
7 | First you need to understand what references are in Perl. |
5f05dabc |
8 | See L<perlref> for that. Second, if you still find the following |
9 | reference work too complicated, a tutorial on object-oriented programming |
19799a22 |
10 | in Perl can be found in L<perltoot> and L<perltootc>. |
a0d0e21e |
11 | |
54310121 |
12 | If you're still with us, then |
5f05dabc |
13 | here are three very simple definitions that you should find reassuring. |
a0d0e21e |
14 | |
15 | =over 4 |
16 | |
17 | =item 1. |
18 | |
19 | An object is simply a reference that happens to know which class it |
20 | belongs to. |
21 | |
22 | =item 2. |
23 | |
24 | A class is simply a package that happens to provide methods to deal |
25 | with object references. |
26 | |
27 | =item 3. |
28 | |
29 | A method is simply a subroutine that expects an object reference (or |
55497cff |
30 | a package name, for class methods) as the first argument. |
a0d0e21e |
31 | |
32 | =back |
33 | |
34 | We'll cover these points now in more depth. |
35 | |
36 | =head2 An Object is Simply a Reference |
37 | |
38 | Unlike say C++, Perl doesn't provide any special syntax for |
39 | constructors. A constructor is merely a subroutine that returns a |
cb1a09d0 |
40 | reference to something "blessed" into a class, generally the |
a0d0e21e |
41 | class that the subroutine is defined in. Here is a typical |
42 | constructor: |
43 | |
44 | package Critter; |
45 | sub new { bless {} } |
46 | |
5a964f20 |
47 | That word C<new> isn't special. You could have written |
48 | a construct this way, too: |
49 | |
50 | package Critter; |
51 | sub spawn { bless {} } |
52 | |
14218588 |
53 | This might even be preferable, because the C++ programmers won't |
5a964f20 |
54 | be tricked into thinking that C<new> works in Perl as it does in C++. |
55 | It doesn't. We recommend that you name your constructors whatever |
56 | makes sense in the context of the problem you're solving. For example, |
57 | constructors in the Tk extension to Perl are named after the widgets |
58 | they create. |
59 | |
60 | One thing that's different about Perl constructors compared with those in |
61 | C++ is that in Perl, they have to allocate their own memory. (The other |
62 | things is that they don't automatically call overridden base-class |
63 | constructors.) The C<{}> allocates an anonymous hash containing no |
64 | key/value pairs, and returns it The bless() takes that reference and |
65 | tells the object it references that it's now a Critter, and returns |
66 | the reference. This is for convenience, because the referenced object |
67 | itself knows that it has been blessed, and the reference to it could |
68 | have been returned directly, like this: |
a0d0e21e |
69 | |
70 | sub new { |
71 | my $self = {}; |
72 | bless $self; |
73 | return $self; |
74 | } |
75 | |
14218588 |
76 | You often see such a thing in more complicated constructors |
a0d0e21e |
77 | that wish to call methods in the class as part of the construction: |
78 | |
79 | sub new { |
5a964f20 |
80 | my $self = {}; |
a0d0e21e |
81 | bless $self; |
82 | $self->initialize(); |
cb1a09d0 |
83 | return $self; |
84 | } |
85 | |
1fef88e7 |
86 | If you care about inheritance (and you should; see |
b687b08b |
87 | L<perlmodlib/"Modules: Creation, Use, and Abuse">), |
1fef88e7 |
88 | then you want to use the two-arg form of bless |
cb1a09d0 |
89 | so that your constructors may be inherited: |
90 | |
91 | sub new { |
92 | my $class = shift; |
93 | my $self = {}; |
5a964f20 |
94 | bless $self, $class; |
cb1a09d0 |
95 | $self->initialize(); |
96 | return $self; |
97 | } |
98 | |
c47ff5f1 |
99 | Or if you expect people to call not just C<< CLASS->new() >> but also |
100 | C<< $obj->new() >>, then use something like this. The initialize() |
54310121 |
101 | method used will be of whatever $class we blessed the |
cb1a09d0 |
102 | object into: |
103 | |
104 | sub new { |
105 | my $this = shift; |
106 | my $class = ref($this) || $this; |
107 | my $self = {}; |
5a964f20 |
108 | bless $self, $class; |
cb1a09d0 |
109 | $self->initialize(); |
110 | return $self; |
a0d0e21e |
111 | } |
112 | |
113 | Within the class package, the methods will typically deal with the |
114 | reference as an ordinary reference. Outside the class package, |
115 | the reference is generally treated as an opaque value that may |
5f05dabc |
116 | be accessed only through the class's methods. |
a0d0e21e |
117 | |
14218588 |
118 | Although a constructor can in theory re-bless a referenced object |
19799a22 |
119 | currently belonging to another class, this is almost certainly going |
120 | to get you into trouble. The new class is responsible for all |
121 | cleanup later. The previous blessing is forgotten, as an object |
122 | may belong to only one class at a time. (Although of course it's |
123 | free to inherit methods from many classes.) If you find yourself |
124 | having to do this, the parent class is probably misbehaving, though. |
a0d0e21e |
125 | |
126 | A clarification: Perl objects are blessed. References are not. Objects |
127 | know which package they belong to. References do not. The bless() |
5f05dabc |
128 | function uses the reference to find the object. Consider |
a0d0e21e |
129 | the following example: |
130 | |
131 | $a = {}; |
132 | $b = $a; |
133 | bless $a, BLAH; |
134 | print "\$b is a ", ref($b), "\n"; |
135 | |
54310121 |
136 | This reports $b as being a BLAH, so obviously bless() |
a0d0e21e |
137 | operated on the object and not on the reference. |
138 | |
139 | =head2 A Class is Simply a Package |
140 | |
141 | Unlike say C++, Perl doesn't provide any special syntax for class |
5f05dabc |
142 | definitions. You use a package as a class by putting method |
a0d0e21e |
143 | definitions into the class. |
144 | |
5a964f20 |
145 | There is a special array within each package called @ISA, which says |
a0d0e21e |
146 | where else to look for a method if you can't find it in the current |
147 | package. This is how Perl implements inheritance. Each element of the |
148 | @ISA array is just the name of another package that happens to be a |
149 | class package. The classes are searched (depth first) for missing |
150 | methods in the order that they occur in @ISA. The classes accessible |
54310121 |
151 | through @ISA are known as base classes of the current class. |
a0d0e21e |
152 | |
5a964f20 |
153 | All classes implicitly inherit from class C<UNIVERSAL> as their |
154 | last base class. Several commonly used methods are automatically |
155 | supplied in the UNIVERSAL class; see L<"Default UNIVERSAL methods"> for |
156 | more details. |
157 | |
14218588 |
158 | If a missing method is found in a base class, it is cached |
a0d0e21e |
159 | in the current class for efficiency. Changing @ISA or defining new |
160 | subroutines invalidates the cache and causes Perl to do the lookup again. |
161 | |
5a964f20 |
162 | If neither the current class, its named base classes, nor the UNIVERSAL |
163 | class contains the requested method, these three places are searched |
164 | all over again, this time looking for a method named AUTOLOAD(). If an |
165 | AUTOLOAD is found, this method is called on behalf of the missing method, |
166 | setting the package global $AUTOLOAD to be the fully qualified name of |
167 | the method that was intended to be called. |
168 | |
169 | If none of that works, Perl finally gives up and complains. |
170 | |
ed850460 |
171 | If you want to stop the AUTOLOAD inheritance say simply |
172 | |
173 | sub AUTOLOAD; |
174 | |
175 | and the call will die using the name of the sub being called. |
176 | |
5a964f20 |
177 | Perl classes do method inheritance only. Data inheritance is left up |
178 | to the class itself. By and large, this is not a problem in Perl, |
179 | because most classes model the attributes of their object using an |
180 | anonymous hash, which serves as its own little namespace to be carved up |
181 | by the various classes that might want to do something with the object. |
182 | The only problem with this is that you can't sure that you aren't using |
183 | a piece of the hash that isn't already used. A reasonable workaround |
184 | is to prepend your fieldname in the hash with the package name. |
185 | |
186 | sub bump { |
187 | my $self = shift; |
188 | $self->{ __PACKAGE__ . ".count"}++; |
189 | } |
a0d0e21e |
190 | |
191 | =head2 A Method is Simply a Subroutine |
192 | |
193 | Unlike say C++, Perl doesn't provide any special syntax for method |
194 | definition. (It does provide a little syntax for method invocation |
195 | though. More on that later.) A method expects its first argument |
19799a22 |
196 | to be the object (reference) or package (string) it is being invoked |
197 | on. There are two ways of calling methods, which we'll call class |
198 | methods and instance methods. |
a0d0e21e |
199 | |
55497cff |
200 | A class method expects a class name as the first argument. It |
19799a22 |
201 | provides functionality for the class as a whole, not for any |
202 | individual object belonging to the class. Constructors are often |
203 | class methods, but see L<perltoot> and L<perltootc> for alternatives. |
204 | Many class methods simply ignore their first argument, because they |
205 | already know what package they're in and don't care what package |
5f05dabc |
206 | they were invoked via. (These aren't necessarily the same, because |
55497cff |
207 | class methods follow the inheritance tree just like ordinary instance |
208 | methods.) Another typical use for class methods is to look up an |
a0d0e21e |
209 | object by name: |
210 | |
211 | sub find { |
212 | my ($class, $name) = @_; |
213 | $objtable{$name}; |
214 | } |
215 | |
55497cff |
216 | An instance method expects an object reference as its first argument. |
a0d0e21e |
217 | Typically it shifts the first argument into a "self" or "this" variable, |
218 | and then uses that as an ordinary reference. |
219 | |
220 | sub display { |
221 | my $self = shift; |
222 | my @keys = @_ ? @_ : sort keys %$self; |
223 | foreach $key (@keys) { |
224 | print "\t$key => $self->{$key}\n"; |
225 | } |
226 | } |
227 | |
228 | =head2 Method Invocation |
229 | |
230 | There are two ways to invoke a method, one of which you're already |
231 | familiar with, and the other of which will look familiar. Perl 4 |
232 | already had an "indirect object" syntax that you use when you say |
233 | |
234 | print STDERR "help!!!\n"; |
235 | |
55497cff |
236 | This same syntax can be used to call either class or instance methods. |
237 | We'll use the two methods defined above, the class method to lookup |
238 | an object reference and the instance method to print out its attributes. |
a0d0e21e |
239 | |
240 | $fred = find Critter "Fred"; |
241 | display $fred 'Height', 'Weight'; |
242 | |
243 | These could be combined into one statement by using a BLOCK in the |
244 | indirect object slot: |
245 | |
246 | display {find Critter "Fred"} 'Height', 'Weight'; |
247 | |
c47ff5f1 |
248 | For C++ fans, there's also a syntax using -> notation that does exactly |
a0d0e21e |
249 | the same thing. The parentheses are required if there are any arguments. |
250 | |
251 | $fred = Critter->find("Fred"); |
252 | $fred->display('Height', 'Weight'); |
253 | |
254 | or in one statement, |
255 | |
256 | Critter->find("Fred")->display('Height', 'Weight'); |
257 | |
258 | There are times when one syntax is more readable, and times when the |
259 | other syntax is more readable. The indirect object syntax is less |
260 | cluttered, but it has the same ambiguity as ordinary list operators. |
567ce7b1 |
261 | Indirect object method calls are usually parsed using the same rule as list |
a0d0e21e |
262 | operators: "If it looks like a function, it is a function". (Presuming |
263 | for the moment that you think two words in a row can look like a |
264 | function name. C++ programmers seem to think so with some regularity, |
5f05dabc |
265 | especially when the first word is "new".) Thus, the parentheses of |
a0d0e21e |
266 | |
267 | new Critter ('Barney', 1.5, 70) |
268 | |
269 | are assumed to surround ALL the arguments of the method call, regardless |
270 | of what comes after. Saying |
271 | |
272 | new Critter ('Bam' x 2), 1.4, 45 |
273 | |
274 | would be equivalent to |
275 | |
276 | Critter->new('Bam' x 2), 1.4, 45 |
277 | |
567ce7b1 |
278 | which is unlikely to do what you want. Confusingly, however, this |
279 | rule applies only when the indirect object is a bareword package name, |
280 | not when it's a scalar, a BLOCK, or a C<Package::> qualified package name. |
281 | In those cases, the arguments are parsed in the same way as an |
282 | indirect object list operator like print, so |
283 | |
284 | new Critter:: ('Bam' x 2), 1.4, 45 |
285 | |
286 | is the same as |
287 | |
288 | Critter::->new(('Bam' x 2), 1.4, 45) |
289 | |
290 | For more reasons why the indirect object syntax is ambiguous, see |
291 | L<"WARNING"> below. |
a0d0e21e |
292 | |
293 | There are times when you wish to specify which class's method to use. |
14218588 |
294 | Here you can call your method as an ordinary subroutine |
a0d0e21e |
295 | call, being sure to pass the requisite first argument explicitly: |
296 | |
297 | $fred = MyCritter::find("Critter", "Fred"); |
298 | MyCritter::display($fred, 'Height', 'Weight'); |
299 | |
14218588 |
300 | Unlike method calls, function calls don't consider inheritance. If you wish |
5f05dabc |
301 | merely to specify that Perl should I<START> looking for a method in a |
a0d0e21e |
302 | particular package, use an ordinary method call, but qualify the method |
303 | name with the package like this: |
304 | |
305 | $fred = Critter->MyCritter::find("Fred"); |
306 | $fred->MyCritter::display('Height', 'Weight'); |
307 | |
cb1a09d0 |
308 | If you're trying to control where the method search begins I<and> you're |
5f05dabc |
309 | executing in the class itself, then you may use the SUPER pseudo class, |
cb1a09d0 |
310 | which says to start looking in your base class's @ISA list without having |
5f05dabc |
311 | to name it explicitly: |
cb1a09d0 |
312 | |
313 | $self->SUPER::display('Height', 'Weight'); |
314 | |
5f05dabc |
315 | Please note that the C<SUPER::> construct is meaningful I<only> within the |
cb1a09d0 |
316 | class. |
317 | |
748a9306 |
318 | Sometimes you want to call a method when you don't know the method name |
319 | ahead of time. You can use the arrow form, replacing the method name |
19799a22 |
320 | with a simple scalar variable containing the method name or a |
321 | reference to the function. |
748a9306 |
322 | |
323 | $method = $fast ? "findfirst" : "findbest"; |
19799a22 |
324 | $fred->$method(@args); # call by name |
325 | |
326 | if ($coderef = $fred->can($parent . "::findbest")) { |
327 | $self->$coderef(@args); # call by coderef |
328 | } |
329 | |
330 | =head2 WARNING |
331 | |
332 | While indirect object syntax may well be appealing to English speakers and |
333 | to C++ programmers, be not seduced! It suffers from two grave problems. |
334 | |
335 | The first problem is that an indirect object is limited to a name, |
336 | a scalar variable, or a block, because it would have to do too much |
337 | lookahead otherwise, just like any other postfix dereference in the |
338 | language. (These are the same quirky rules as are used for the filehandle |
339 | slot in functions like C<print> and C<printf>.) This can lead to horribly |
340 | confusing precedence problems, as in these next two lines: |
341 | |
342 | move $obj->{FIELD}; # probably wrong! |
343 | move $ary[$i]; # probably wrong! |
344 | |
345 | Those actually parse as the very surprising: |
346 | |
347 | $obj->move->{FIELD}; # Well, lookee here |
4f298f32 |
348 | $ary->move([$i]); # Didn't expect this one, eh? |
19799a22 |
349 | |
350 | Rather than what you might have expected: |
351 | |
352 | $obj->{FIELD}->move(); # You should be so lucky. |
353 | $ary[$i]->move; # Yeah, sure. |
354 | |
c47ff5f1 |
355 | The left side of ``->'' is not so limited, because it's an infix operator, |
19799a22 |
356 | not a postfix operator. |
357 | |
358 | As if that weren't bad enough, think about this: Perl must guess I<at |
359 | compile time> whether C<name> and C<move> above are functions or methods. |
360 | Usually Perl gets it right, but when it doesn't it, you get a function |
361 | call compiled as a method, or vice versa. This can introduce subtle |
362 | bugs that are hard to unravel. For example, calling a method C<new> |
363 | in indirect notation--as C++ programmers are so wont to do--can |
364 | be miscompiled into a subroutine call if there's already a C<new> |
365 | function in scope. You'd end up calling the current package's C<new> |
366 | as a subroutine, rather than the desired class's method. The compiler |
367 | tries to cheat by remembering bareword C<require>s, but the grief if it |
368 | messes up just isn't worth the years of debugging it would likely take |
14218588 |
369 | you to track such subtle bugs down. |
19799a22 |
370 | |
c47ff5f1 |
371 | The infix arrow notation using ``C<< -> >>'' doesn't suffer from either |
19799a22 |
372 | of these disturbing ambiguities, so we recommend you use it exclusively. |
748a9306 |
373 | |
a2bdc9a5 |
374 | =head2 Default UNIVERSAL methods |
375 | |
376 | The C<UNIVERSAL> package automatically contains the following methods that |
377 | are inherited by all other classes: |
378 | |
379 | =over 4 |
380 | |
71be2cbc |
381 | =item isa(CLASS) |
a2bdc9a5 |
382 | |
68dc0745 |
383 | C<isa> returns I<true> if its object is blessed into a subclass of C<CLASS> |
a2bdc9a5 |
384 | |
385 | C<isa> is also exportable and can be called as a sub with two arguments. This |
386 | allows the ability to check what a reference points to. Example |
387 | |
388 | use UNIVERSAL qw(isa); |
389 | |
390 | if(isa($ref, 'ARRAY')) { |
5a964f20 |
391 | #... |
a2bdc9a5 |
392 | } |
393 | |
71be2cbc |
394 | =item can(METHOD) |
a2bdc9a5 |
395 | |
396 | C<can> checks to see if its object has a method called C<METHOD>, |
397 | if it does then a reference to the sub is returned, if it does not then |
398 | I<undef> is returned. |
399 | |
71be2cbc |
400 | =item VERSION( [NEED] ) |
760ac839 |
401 | |
71be2cbc |
402 | C<VERSION> returns the version number of the class (package). If the |
403 | NEED argument is given then it will check that the current version (as |
404 | defined by the $VERSION variable in the given package) not less than |
405 | NEED; it will die if this is not the case. This method is normally |
406 | called as a class method. This method is called automatically by the |
407 | C<VERSION> form of C<use>. |
a2bdc9a5 |
408 | |
a2bdc9a5 |
409 | use A 1.2 qw(some imported subs); |
71be2cbc |
410 | # implies: |
411 | A->VERSION(1.2); |
a2bdc9a5 |
412 | |
a2bdc9a5 |
413 | =back |
414 | |
415 | B<NOTE:> C<can> directly uses Perl's internal code for method lookup, and |
416 | C<isa> uses a very similar method and cache-ing strategy. This may cause |
417 | strange effects if the Perl code dynamically changes @ISA in any package. |
418 | |
419 | You may add other methods to the UNIVERSAL class via Perl or XS code. |
14218588 |
420 | You do not need to C<use UNIVERSAL> to make these methods |
71be2cbc |
421 | available to your program. This is necessary only if you wish to |
422 | have C<isa> available as a plain subroutine in the current package. |
a2bdc9a5 |
423 | |
54310121 |
424 | =head2 Destructors |
a0d0e21e |
425 | |
426 | When the last reference to an object goes away, the object is |
427 | automatically destroyed. (This may even be after you exit, if you've |
428 | stored references in global variables.) If you want to capture control |
429 | just before the object is freed, you may define a DESTROY method in |
430 | your class. It will automatically be called at the appropriate moment, |
4e8e7886 |
431 | and you can do any extra cleanup you need to do. Perl passes a reference |
432 | to the object under destruction as the first (and only) argument. Beware |
433 | that the reference is a read-only value, and cannot be modified by |
434 | manipulating C<$_[0]> within the destructor. The object itself (i.e. |
435 | the thingy the reference points to, namely C<${$_[0]}>, C<@{$_[0]}>, |
436 | C<%{$_[0]}> etc.) is not similarly constrained. |
437 | |
438 | If you arrange to re-bless the reference before the destructor returns, |
439 | perl will again call the DESTROY method for the re-blessed object after |
440 | the current one returns. This can be used for clean delegation of |
441 | object destruction, or for ensuring that destructors in the base classes |
442 | of your choosing get called. Explicitly calling DESTROY is also possible, |
443 | but is usually never needed. |
444 | |
14218588 |
445 | Do not confuse the previous discussion with how objects I<CONTAINED> in the current |
4e8e7886 |
446 | one are destroyed. Such objects will be freed and destroyed automatically |
447 | when the current object is freed, provided no other references to them exist |
448 | elsewhere. |
a0d0e21e |
449 | |
450 | =head2 Summary |
451 | |
5f05dabc |
452 | That's about all there is to it. Now you need just to go off and buy a |
a0d0e21e |
453 | book about object-oriented design methodology, and bang your forehead |
454 | with it for the next six months or so. |
455 | |
cb1a09d0 |
456 | =head2 Two-Phased Garbage Collection |
457 | |
14218588 |
458 | For most purposes, Perl uses a fast and simple, reference-based |
459 | garbage collection system. That means there's an extra |
cb1a09d0 |
460 | dereference going on at some level, so if you haven't built |
461 | your Perl executable using your C compiler's C<-O> flag, performance |
462 | will suffer. If you I<have> built Perl with C<cc -O>, then this |
463 | probably won't matter. |
464 | |
465 | A more serious concern is that unreachable memory with a non-zero |
466 | reference count will not normally get freed. Therefore, this is a bad |
54310121 |
467 | idea: |
cb1a09d0 |
468 | |
469 | { |
470 | my $a; |
471 | $a = \$a; |
54310121 |
472 | } |
cb1a09d0 |
473 | |
474 | Even thought $a I<should> go away, it can't. When building recursive data |
475 | structures, you'll have to break the self-reference yourself explicitly |
476 | if you don't care to leak. For example, here's a self-referential |
477 | node such as one might use in a sophisticated tree structure: |
478 | |
479 | sub new_node { |
480 | my $self = shift; |
481 | my $class = ref($self) || $self; |
482 | my $node = {}; |
483 | $node->{LEFT} = $node->{RIGHT} = $node; |
484 | $node->{DATA} = [ @_ ]; |
485 | return bless $node => $class; |
54310121 |
486 | } |
cb1a09d0 |
487 | |
488 | If you create nodes like that, they (currently) won't go away unless you |
489 | break their self reference yourself. (In other words, this is not to be |
490 | construed as a feature, and you shouldn't depend on it.) |
491 | |
492 | Almost. |
493 | |
494 | When an interpreter thread finally shuts down (usually when your program |
495 | exits), then a rather costly but complete mark-and-sweep style of garbage |
496 | collection is performed, and everything allocated by that thread gets |
497 | destroyed. This is essential to support Perl as an embedded or a |
54310121 |
498 | multithreadable language. For example, this program demonstrates Perl's |
cb1a09d0 |
499 | two-phased garbage collection: |
500 | |
54310121 |
501 | #!/usr/bin/perl |
cb1a09d0 |
502 | package Subtle; |
503 | |
504 | sub new { |
505 | my $test; |
506 | $test = \$test; |
507 | warn "CREATING " . \$test; |
508 | return bless \$test; |
54310121 |
509 | } |
cb1a09d0 |
510 | |
511 | sub DESTROY { |
512 | my $self = shift; |
513 | warn "DESTROYING $self"; |
54310121 |
514 | } |
cb1a09d0 |
515 | |
516 | package main; |
517 | |
518 | warn "starting program"; |
519 | { |
520 | my $a = Subtle->new; |
521 | my $b = Subtle->new; |
522 | $$a = 0; # break selfref |
523 | warn "leaving block"; |
54310121 |
524 | } |
cb1a09d0 |
525 | |
526 | warn "just exited block"; |
527 | warn "time to die..."; |
528 | exit; |
529 | |
530 | When run as F</tmp/test>, the following output is produced: |
531 | |
532 | starting program at /tmp/test line 18. |
533 | CREATING SCALAR(0x8e5b8) at /tmp/test line 7. |
534 | CREATING SCALAR(0x8e57c) at /tmp/test line 7. |
535 | leaving block at /tmp/test line 23. |
536 | DESTROYING Subtle=SCALAR(0x8e5b8) at /tmp/test line 13. |
537 | just exited block at /tmp/test line 26. |
538 | time to die... at /tmp/test line 27. |
539 | DESTROYING Subtle=SCALAR(0x8e57c) during global destruction. |
540 | |
541 | Notice that "global destruction" bit there? That's the thread |
54310121 |
542 | garbage collector reaching the unreachable. |
cb1a09d0 |
543 | |
14218588 |
544 | Objects are always destructed, even when regular refs aren't. Objects |
545 | are destructed in a separate pass before ordinary refs just to |
cb1a09d0 |
546 | prevent object destructors from using refs that have been themselves |
5f05dabc |
547 | destructed. Plain refs are only garbage-collected if the destruct level |
cb1a09d0 |
548 | is greater than 0. You can test the higher levels of global destruction |
549 | by setting the PERL_DESTRUCT_LEVEL environment variable, presuming |
550 | C<-DDEBUGGING> was enabled during perl build time. |
551 | |
552 | A more complete garbage collection strategy will be implemented |
553 | at a future date. |
554 | |
5a964f20 |
555 | In the meantime, the best solution is to create a non-recursive container |
556 | class that holds a pointer to the self-referential data structure. |
557 | Define a DESTROY method for the containing object's class that manually |
558 | breaks the circularities in the self-referential structure. |
559 | |
a0d0e21e |
560 | =head1 SEE ALSO |
561 | |
19799a22 |
562 | A kinder, gentler tutorial on object-oriented programming in Perl |
563 | can be found in L<perltoot> and L<perltootc>. You should also check |
564 | out L<perlbot> for other object tricks, traps, and tips, as well |
565 | as L<perlmodlib> for some style guides on constructing both modules |
cb1a09d0 |
566 | and classes. |