Commit | Line | Data |
68dc0745 |
1 | =head1 NAME |
2 | |
3 | perlfaq6 - Regexps ($Revision: 1.14 $) |
4 | |
5 | =head1 DESCRIPTION |
6 | |
7 | This section is surprisingly small because the rest of the FAQ is |
8 | littered with answers involving regular expressions. For example, |
9 | decoding a URL and checking whether something is a number are handled |
10 | with regular expressions, but those answers are found elsewhere in |
11 | this document (in the section on Data and the Networking one on |
12 | networking, to be precise). |
13 | |
14 | =head2 How can I hope to use regular expressions without creating illegible and unmaintainable code? |
15 | |
16 | Three techniques can make regular expressions maintainable and |
17 | understandable. |
18 | |
19 | =over 4 |
20 | |
21 | =item Comments Outside the Regexp |
22 | |
23 | Describe what you're doing and how you're doing it, using normal Perl |
24 | comments. |
25 | |
26 | # turn the line into the first word, a colon, and the |
27 | # number of characters on the rest of the line |
28 | s/^(\w+)(.*)/ lc($1) . ":" . length($2) /ge; |
29 | |
30 | =item Comments Inside the Regexp |
31 | |
32 | The C</x> modifier causes whitespace to be ignored in a regexp pattern |
33 | (except in a character class), and also allows you to use normal |
34 | comments there, too. As you can imagine, whitespace and comments help |
35 | a lot. |
36 | |
37 | C</x> lets you turn this: |
38 | |
39 | s{<(?:[^>'"]*|".*?"|'.*?')+>}{}gs; |
40 | |
41 | into this: |
42 | |
43 | s{ < # opening angle bracket |
44 | (?: # Non-backreffing grouping paren |
45 | [^>'"] * # 0 or more things that are neither > nor ' nor " |
46 | | # or else |
47 | ".*?" # a section between double quotes (stingy match) |
48 | | # or else |
49 | '.*?' # a section between single quotes (stingy match) |
50 | ) + # all occurring one or more times |
51 | > # closing angle bracket |
52 | }{}gsx; # replace with nothing, i.e. delete |
53 | |
54 | It's still not quite so clear as prose, but it is very useful for |
55 | describing the meaning of each part of the pattern. |
56 | |
57 | =item Different Delimiters |
58 | |
59 | While we normally think of patterns as being delimited with C</> |
60 | characters, they can be delimited by almost any character. L<perlre> |
61 | describes this. For example, the C<s///> above uses braces as |
62 | delimiters. Selecting another delimiter can avoid quoting the |
63 | delimiter within the pattern: |
64 | |
65 | s/\/usr\/local/\/usr\/share/g; # bad delimiter choice |
66 | s#/usr/local#/usr/share#g; # better |
67 | |
68 | =back |
69 | |
70 | =head2 I'm having trouble matching over more than one line. What's wrong? |
71 | |
72 | Either you don't have newlines in your string, or you aren't using the |
73 | correct modifier(s) on your pattern. |
74 | |
75 | There are many ways to get multiline data into a string. If you want |
76 | it to happen automatically while reading input, you'll want to set $/ |
77 | (probably to '' for paragraphs or C<undef> for the whole file) to |
78 | allow you to read more than one line at a time. |
79 | |
80 | Read L<perlre> to help you decide which of C</s> and C</m> (or both) |
81 | you might want to use: C</s> allows dot to include newline, and C</m> |
82 | allows caret and dollar to match next to a newline, not just at the |
83 | end of the string. You do need to make sure that you've actually |
84 | got a multiline string in there. |
85 | |
86 | For example, this program detects duplicate words, even when they span |
87 | line breaks (but not paragraph ones). For this example, we don't need |
88 | C</s> because we aren't using dot in a regular expression that we want |
89 | to cross line boundaries. Neither do we need C</m> because we aren't |
90 | wanting caret or dollar to match at any point inside the record next |
91 | to newlines. But it's imperative that $/ be set to something other |
92 | than the default, or else we won't actually ever have a multiline |
93 | record read in. |
94 | |
95 | $/ = ''; # read in more whole paragraph, not just one line |
96 | while ( <> ) { |
97 | while ( /\b(\w\S+)(\s+\1)+\b/gi ) { |
98 | print "Duplicate $1 at paragraph $.\n"; |
99 | } |
100 | } |
101 | |
102 | Here's code that finds sentences that begin with "From " (which would |
103 | be mangled by many mailers): |
104 | |
105 | $/ = ''; # read in more whole paragraph, not just one line |
106 | while ( <> ) { |
107 | while ( /^From /gm ) { # /m makes ^ match next to \n |
108 | print "leading from in paragraph $.\n"; |
109 | } |
110 | } |
111 | |
112 | Here's code that finds everything between START and END in a paragraph: |
113 | |
114 | undef $/; # read in whole file, not just one line or paragraph |
115 | while ( <> ) { |
116 | while ( /START(.*?)END/sm ) { # /s makes . cross line boundaries |
117 | print "$1\n"; |
118 | } |
119 | } |
120 | |
121 | =head2 How can I pull out lines between two patterns that are themselves on different lines? |
122 | |
123 | You can use Perl's somewhat exotic C<..> operator (documented in |
124 | L<perlop>): |
125 | |
126 | perl -ne 'print if /START/ .. /END/' file1 file2 ... |
127 | |
128 | If you wanted text and not lines, you would use |
129 | |
130 | perl -0777 -pe 'print "$1\n" while /START(.*?)END/gs' file1 file2 ... |
131 | |
132 | But if you want nested occurrences of C<START> through C<END>, you'll |
133 | run up against the problem described in the question in this section |
134 | on matching balanced text. |
135 | |
136 | =head2 I put a regular expression into $/ but it didn't work. What's wrong? |
137 | |
138 | $/ must be a string, not a regular expression. Awk has to be better |
139 | for something. :-) |
140 | |
141 | Actually, you could do this if you don't mind reading the whole file into |
142 | |
143 | undef $/; |
144 | @records = split /your_pattern/, <FH>; |
145 | |
146 | =head2 How do I substitute case insensitively on the LHS, but preserving case on the RHS? |
147 | |
148 | It depends on what you mean by "preserving case". The following |
149 | script makes the substitution have the same case, letter by letter, as |
150 | the original. If the substitution has more characters than the string |
151 | being substituted, the case of the last character is used for the rest |
152 | of the substitution. |
153 | |
154 | # Original by Nathan Torkington, massaged by Jeffrey Friedl |
155 | # |
156 | sub preserve_case($$) |
157 | { |
158 | my ($old, $new) = @_; |
159 | my ($state) = 0; # 0 = no change; 1 = lc; 2 = uc |
160 | my ($i, $oldlen, $newlen, $c) = (0, length($old), length($new)); |
161 | my ($len) = $oldlen < $newlen ? $oldlen : $newlen; |
162 | |
163 | for ($i = 0; $i < $len; $i++) { |
164 | if ($c = substr($old, $i, 1), $c =~ /[\W\d_]/) { |
165 | $state = 0; |
166 | } elsif (lc $c eq $c) { |
167 | substr($new, $i, 1) = lc(substr($new, $i, 1)); |
168 | $state = 1; |
169 | } else { |
170 | substr($new, $i, 1) = uc(substr($new, $i, 1)); |
171 | $state = 2; |
172 | } |
173 | } |
174 | # finish up with any remaining new (for when new is longer than old) |
175 | if ($newlen > $oldlen) { |
176 | if ($state == 1) { |
177 | substr($new, $oldlen) = lc(substr($new, $oldlen)); |
178 | } elsif ($state == 2) { |
179 | substr($new, $oldlen) = uc(substr($new, $oldlen)); |
180 | } |
181 | } |
182 | return $new; |
183 | } |
184 | |
185 | $a = "this is a TEsT case"; |
186 | $a =~ s/(test)/preserve_case($1, "success")/gie; |
187 | print "$a\n"; |
188 | |
189 | This prints: |
190 | |
191 | this is a SUcCESS case |
192 | |
193 | =head2 How can I make C<\w> match accented characters? |
194 | |
195 | See L<perllocale>. |
196 | |
197 | =head2 How can I match a locale-smart version of C</[a-zA-Z]/>? |
198 | |
199 | One alphabetic character would be C</[^\W\d_]/>, no matter what locale |
200 | you're in. Non-alphabetics would be C</[\W\d_]/> (assuming you don't |
201 | consider an underscore a letter). |
202 | |
203 | =head2 How can I quote a variable to use in a regexp? |
204 | |
205 | The Perl parser will expand $variable and @variable references in |
206 | regular expressions unless the delimiter is a single quote. Remember, |
207 | too, that the right-hand side of a C<s///> substitution is considered |
208 | a double-quoted string (see L<perlop> for more details). Remember |
209 | also that any regexp special characters will be acted on unless you |
210 | precede the substitution with \Q. Here's an example: |
211 | |
212 | $string = "to die?"; |
213 | $lhs = "die?"; |
214 | $rhs = "sleep no more"; |
215 | |
216 | $string =~ s/\Q$lhs/$rhs/; |
217 | # $string is now "to sleep no more" |
218 | |
219 | Without the \Q, the regexp would also spuriously match "di". |
220 | |
221 | =head2 What is C</o> really for? |
222 | |
223 | Using a variable in a regular expression match forces a re-evaluation |
224 | (and perhaps recompilation) each time through. The C</o> modifier |
225 | locks in the regexp the first time it's used. This always happens in a |
226 | constant regular expression, and in fact, the pattern was compiled |
227 | into the internal format at the same time your entire program was. |
228 | |
229 | Use of C</o> is irrelevant unless variable interpolation is used in |
230 | the pattern, and if so, the regexp engine will neither know nor care |
231 | whether the variables change after the pattern is evaluated the I<very |
232 | first> time. |
233 | |
234 | C</o> is often used to gain an extra measure of efficiency by not |
235 | performing subsequent evaluations when you know it won't matter |
236 | (because you know the variables won't change), or more rarely, when |
237 | you don't want the regexp to notice if they do. |
238 | |
239 | For example, here's a "paragrep" program: |
240 | |
241 | $/ = ''; # paragraph mode |
242 | $pat = shift; |
243 | while (<>) { |
244 | print if /$pat/o; |
245 | } |
246 | |
247 | =head2 How do I use a regular expression to strip C style comments from a file? |
248 | |
249 | While this actually can be done, it's much harder than you'd think. |
250 | For example, this one-liner |
251 | |
252 | perl -0777 -pe 's{/\*.*?\*/}{}gs' foo.c |
253 | |
254 | will work in many but not all cases. You see, it's too simple-minded for |
255 | certain kinds of C programs, in particular, those with what appear to be |
256 | comments in quoted strings. For that, you'd need something like this, |
257 | created by Jeffrey Friedl: |
258 | |
259 | $/ = undef; |
260 | $_ = <>; |
261 | s#/\*[^*]*\*+([^/*][^*]*\*+)*/|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|\n+|.[^/"'\\]*)#$2#g; |
262 | print; |
263 | |
264 | This could, of course, be more legibly written with the C</x> modifier, adding |
265 | whitespace and comments. |
266 | |
267 | =head2 Can I use Perl regular expressions to match balanced text? |
268 | |
269 | Although Perl regular expressions are more powerful than "mathematical" |
270 | regular expressions, because they feature conveniences like backreferences |
271 | (C<\1> and its ilk), they still aren't powerful enough. You still need |
272 | to use non-regexp techniques to parse balanced text, such as the text |
273 | enclosed between matching parentheses or braces, for example. |
274 | |
275 | An elaborate subroutine (for 7-bit ASCII only) to pull out balanced |
276 | and possibly nested single chars, like C<`> and C<'>, C<{> and C<}>, |
277 | or C<(> and C<)> can be found in |
278 | http://www.perl.com/CPAN/authors/id/TOMC/scripts/pull_quotes.gz . |
279 | |
280 | The C::Scan module from CPAN contains such subs for internal usage, |
281 | but they are undocumented. |
282 | |
283 | =head2 What does it mean that regexps are greedy? How can I get around it? |
284 | |
285 | Most people mean that greedy regexps match as much as they can. |
286 | Technically speaking, it's actually the quantifiers (C<?>, C<*>, C<+>, |
287 | C<{}>) that are greedy rather than the whole pattern; Perl prefers local |
288 | greed and immediate gratification to overall greed. To get non-greedy |
289 | versions of the same quantifiers, use (C<??>, C<*?>, C<+?>, C<{}?>). |
290 | |
291 | An example: |
292 | |
293 | $s1 = $s2 = "I am very very cold"; |
294 | $s1 =~ s/ve.*y //; # I am cold |
295 | $s2 =~ s/ve.*?y //; # I am very cold |
296 | |
297 | Notice how the second substitution stopped matching as soon as it |
298 | encountered "y ". The C<*?> quantifier effectively tells the regular |
299 | expression engine to find a match as quickly as possible and pass |
300 | control on to whatever is next in line, like you would if you were |
301 | playing hot potato. |
302 | |
303 | =head2 How do I process each word on each line? |
304 | |
305 | Use the split function: |
306 | |
307 | while (<>) { |
308 | foreach $word ( split ) { |
309 | # do something with $word here |
310 | } |
311 | } |
312 | |
313 | Note that this isn't really a word in the English sense; it's just |
314 | chunks of consecutive non-whitespace characters. |
315 | |
316 | To work with only alphanumeric sequences, you might consider |
317 | |
318 | while (<>) { |
319 | foreach $word (m/(\w+)/g) { |
320 | # do something with $word here |
321 | } |
322 | } |
323 | |
324 | =head2 How can I print out a word-frequency or line-frequency summary? |
325 | |
326 | To do this, you have to parse out each word in the input stream. We'll |
327 | pretend that by word you mean chunk of alphabetics, hyphens, or |
328 | apostrophes, rather than the non-whitespace chunk idea of a word given |
329 | in the previous question: |
330 | |
331 | while (<>) { |
332 | while ( /(\b[^\W_\d][\w'-]+\b)/g ) { # misses "`sheep'" |
333 | $seen{$1}++; |
334 | } |
335 | } |
336 | while ( ($word, $count) = each %seen ) { |
337 | print "$count $word\n"; |
338 | } |
339 | |
340 | If you wanted to do the same thing for lines, you wouldn't need a |
341 | regular expression: |
342 | |
343 | while (<>) { |
344 | $seen{$_}++; |
345 | } |
346 | while ( ($line, $count) = each %seen ) { |
347 | print "$count $line"; |
348 | } |
349 | |
350 | If you want these output in a sorted order, see the section on Hashes. |
351 | |
352 | =head2 How can I do approximate matching? |
353 | |
354 | See the module String::Approx available from CPAN. |
355 | |
356 | =head2 How do I efficiently match many regular expressions at once? |
357 | |
358 | The following is super-inefficient: |
359 | |
360 | while (<FH>) { |
361 | foreach $pat (@patterns) { |
362 | if ( /$pat/ ) { |
363 | # do something |
364 | } |
365 | } |
366 | } |
367 | |
368 | Instead, you either need to use one of the experimental Regexp extension |
369 | modules from CPAN (which might well be overkill for your purposes), |
370 | or else put together something like this, inspired from a routine |
371 | in Jeffrey Friedl's book: |
372 | |
373 | sub _bm_build { |
374 | my $condition = shift; |
375 | my @regexp = @_; # this MUST not be local(); need my() |
376 | my $expr = join $condition => map { "m/\$regexp[$_]/o" } (0..$#regexp); |
377 | my $match_func = eval "sub { $expr }"; |
378 | die if $@; # propagate $@; this shouldn't happen! |
379 | return $match_func; |
380 | } |
381 | |
382 | sub bm_and { _bm_build('&&', @_) } |
383 | sub bm_or { _bm_build('||', @_) } |
384 | |
385 | $f1 = bm_and qw{ |
386 | xterm |
387 | (?i)window |
388 | }; |
389 | |
390 | $f2 = bm_or qw{ |
391 | \b[Ff]ree\b |
392 | \bBSD\B |
393 | (?i)sys(tem)?\s*[V5]\b |
394 | }; |
395 | |
396 | # feed me /etc/termcap, prolly |
397 | while ( <> ) { |
398 | print "1: $_" if &$f1; |
399 | print "2: $_" if &$f2; |
400 | } |
401 | |
402 | =head2 Why don't word-boundary searches with C<\b> work for me? |
403 | |
404 | Two common misconceptions are that C<\b> is a synonym for C<\s+>, and |
405 | that it's the edge between whitespace characters and non-whitespace |
406 | characters. Neither is correct. C<\b> is the place between a C<\w> |
407 | character and a C<\W> character (that is, C<\b> is the edge of a |
408 | "word"). It's a zero-width assertion, just like C<^>, C<$>, and all |
409 | the other anchors, so it doesn't consume any characters. L<perlre> |
410 | describes the behaviour of all the regexp metacharacters. |
411 | |
412 | Here are examples of the incorrect application of C<\b>, with fixes: |
413 | |
414 | "two words" =~ /(\w+)\b(\w+)/; # WRONG |
415 | "two words" =~ /(\w+)\s+(\w+)/; # right |
416 | |
417 | " =matchless= text" =~ /\b=(\w+)=\b/; # WRONG |
418 | " =matchless= text" =~ /=(\w+)=/; # right |
419 | |
420 | Although they may not do what you thought they did, C<\b> and C<\B> |
421 | can still be quite useful. For an example of the correct use of |
422 | C<\b>, see the example of matching duplicate words over multiple |
423 | lines. |
424 | |
425 | An example of using C<\B> is the pattern C<\Bis\B>. This will find |
426 | occurrences of "is" on the insides of words only, as in "thistle", but |
427 | not "this" or "island". |
428 | |
429 | =head2 Why does using $&, $`, or $' slow my program down? |
430 | |
431 | Because once Perl sees that you need one of these variables anywhere |
432 | in the program, it has to provide them on each and every pattern |
433 | match. The same mechanism that handles these provides for the use of |
434 | $1, $2, etc., so you pay the same price for each regexp that contains |
435 | capturing parentheses. But if you never use $&, etc., in your script, |
436 | then regexps I<without> capturing parentheses won't be penalized. So |
437 | avoid $&, $', and $` if you can, but if you can't (and some algorithms |
438 | really appreciate them), once you've used them once, use them at will, |
439 | because you've already paid the price. |
440 | |
441 | =head2 What good is C<\G> in a regular expression? |
442 | |
443 | The notation C<\G> is used in a match or substitution in conjunction the |
444 | C</g> modifier (and ignored if there's no C</g>) to anchor the regular |
445 | expression to the point just past where the last match occurred, i.e. the |
446 | pos() point. |
447 | |
448 | For example, suppose you had a line of text quoted in standard mail |
449 | and Usenet notation, (that is, with leading C<E<gt>> characters), and |
450 | you want change each leading C<E<gt>> into a corresponding C<:>. You |
451 | could do so in this way: |
452 | |
453 | s/^(>+)/':' x length($1)/gem; |
454 | |
455 | Or, using C<\G>, the much simpler (and faster): |
456 | |
457 | s/\G>/:/g; |
458 | |
459 | A more sophisticated use might involve a tokenizer. The following |
460 | lex-like example is courtesy of Jeffrey Friedl. It did not work in |
461 | 5.003 due to bugs in that release, but does work in 5.004 or better: |
462 | |
463 | while (<>) { |
464 | chomp; |
465 | PARSER: { |
466 | m/ \G( \d+\b )/gx && do { print "number: $1\n"; redo; }; |
467 | m/ \G( \w+ )/gx && do { print "word: $1\n"; redo; }; |
468 | m/ \G( \s+ )/gx && do { print "space: $1\n"; redo; }; |
469 | m/ \G( [^\w\d]+ )/gx && do { print "other: $1\n"; redo; }; |
470 | } |
471 | } |
472 | |
473 | Of course, that could have been written as |
474 | |
475 | while (<>) { |
476 | chomp; |
477 | PARSER: { |
478 | if ( /\G( \d+\b )/gx { |
479 | print "number: $1\n"; |
480 | redo PARSER; |
481 | } |
482 | if ( /\G( \w+ )/gx { |
483 | print "word: $1\n"; |
484 | redo PARSER; |
485 | } |
486 | if ( /\G( \s+ )/gx { |
487 | print "space: $1\n"; |
488 | redo PARSER; |
489 | } |
490 | if ( /\G( [^\w\d]+ )/gx { |
491 | print "other: $1\n"; |
492 | redo PARSER; |
493 | } |
494 | } |
495 | } |
496 | |
497 | But then you lose the vertical alignment of the regular expressions. |
498 | |
499 | =head2 Are Perl regexps DFAs or NFAs? Are they POSIX compliant? |
500 | |
501 | While it's true that Perl's regular expressions resemble the DFAs |
502 | (deterministic finite automata) of the egrep(1) program, they are in |
503 | fact implemented as NFAs (non-deterministic finite automata) to allow |
504 | backtracking and backreferencing. And they aren't POSIX-style either, |
505 | because those guarantee worst-case behavior for all cases. (It seems |
506 | that some people prefer guarantees of consistency, even when what's |
507 | guaranteed is slowness.) See the book "Mastering Regular Expressions" |
508 | (from O'Reilly) by Jeffrey Friedl for all the details you could ever |
509 | hope to know on these matters (a full citation appears in |
510 | L<perlfaq2>). |
511 | |
512 | =head2 What's wrong with using grep or map in a void context? |
513 | |
514 | Strictly speaking, nothing. Stylistically speaking, it's not a good |
515 | way to write maintainable code. That's because you're using these |
516 | constructs not for their return values but rather for their |
517 | side-effects, and side-effects can be mystifying. There's no void |
518 | grep() that's not better written as a C<for> (well, C<foreach>, |
519 | technically) loop. |
520 | |
521 | =head2 How can I match strings with multi-byte characters? |
522 | |
523 | This is hard, and there's no good way. Perl does not directly support |
524 | wide characters. It pretends that a byte and a character are |
525 | synonymous. The following set of approaches was offered by Jeffrey |
526 | Friedl, whose article in issue #5 of The Perl Journal talks about this |
527 | very matter. |
528 | |
529 | Let's suppose you have some weird Martian encoding where pairs of ASCII |
530 | uppercase letters encode single Martian letters (i.e. the two bytes |
531 | "CV" make a single Martian letter, as do the two bytes "SG", "VS", |
532 | "XX", etc.). Other bytes represent single characters, just like ASCII. |
533 | |
534 | So, the string of Martian "I am CVSGXX!" uses 12 bytes to encode the nine |
535 | characters 'I', ' ', 'a', 'm', ' ', 'CV', 'SG', 'XX', '!'. |
536 | |
537 | Now, say you want to search for the single character C</GX/>. Perl |
538 | doesn't know about Martian, so it'll find the two bytes "GX" in the |
539 | "I am CVSGXX!" string, even though that character isn't there: it just |
540 | looks like it is because "SG" is next to "XX", but there's no real "GX". |
541 | This is a big problem. |
542 | |
543 | Here are a few ways, all painful, to deal with it: |
544 | |
545 | $martian =~ s/([A-Z][A-Z])/ $1 /g; # Make sure adjacent ``maritan'' bytes |
546 | # are no longer adjacent. |
547 | print "found GX!\n" if $martian =~ /GX/; |
548 | |
549 | Or like this: |
550 | |
551 | @chars = $martian =~ m/([A-Z][A-Z]|[^A-Z])/g; |
552 | # above is conceptually similar to: @chars = $text =~ m/(.)/g; |
553 | # |
554 | foreach $char (@chars) { |
555 | print "found GX!\n", last if $char eq 'GX'; |
556 | } |
557 | |
558 | Or like this: |
559 | |
560 | while ($martian =~ m/\G([A-Z][A-Z]|.)/gs) { # \G probably unneeded |
561 | print "found GX!\n", last if $1 eq 'GX'; |
562 | } |
563 | |
564 | Or like this: |
565 | |
566 | die "sorry, Perl doesn't (yet) have Martian support )-:\n"; |
567 | |
568 | In addition, a sample program which converts half-width to full-width |
569 | katakana (in Shift-JIS or EUC encoding) is available from CPAN as |
570 | |
571 | =for Tom make it so |
572 | |
573 | There are many double- (and multi-) byte encodings commonly used these |
574 | days. Some versions of these have 1-, 2-, 3-, and 4-byte characters, |
575 | all mixed. |
576 | |
577 | =head1 AUTHOR AND COPYRIGHT |
578 | |
579 | Copyright (c) 1997 Tom Christiansen and Nathan Torkington. |
580 | All rights reserved. See L<perlfaq> for distribution information. |