[p5sagit/p5-mst-13.2.git] / perly.y

/*    perly.y
 *
 *    Copyright (c) 1991-1994, Larry Wall
 *
 *    You may distribute under the terms of either the GNU General Public
 *    License or the Artistic License, as specified in the README file.
 *
 */

/*
 * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
 * All that is gold does not glitter, not all those that wander are lost.'
 */

%{
#include "EXTERN.h"
#include "perl.h"

static void
dep()
{
    deprecate("\"do\" to call subroutines");
}

%}

%start prog

%union {
    I32	ival;
    char *pval;
    OP *opval;
    GV *gvval;
}

%token <ival> '{' ')'

%token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
%token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
%token <pval> LABEL
%token <ival> FORMAT SUB ANONSUB PACKAGE USE
%token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
%token <ival> LOOPEX DOTDOT
%token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP
%token <ival> RELOP EQOP MULOP ADDOP
%token <ival> DOLSHARP DO HASHBRACK NOAMP
%token LOCAL MY

%type <ival> prog decl local format startsub startanonsub startformsub
%type <ival> remember mremember '&'
%type <opval> block mblock lineseq line loop cond else
%type <opval> expr term scalar ary hsh arylen star amper sideff
%type <opval> argexpr nexpr texpr iexpr mexpr mnexpr mtexpr miexpr
%type <opval> listexpr listexprcom indirob listop method
%type <opval> formname subname proto subbody cont my_scalar
%type <pval> label

%left <ival> OROP
%left ANDOP
%right NOTOP
%nonassoc LSTOP LSTOPSUB
%left ','
%right <ival> ASSIGNOP
%right '?' ':'
%nonassoc DOTDOT
%left OROR
%left ANDAND
%left <ival> BITOROP
%left <ival> BITANDOP
%nonassoc EQOP
%nonassoc RELOP
%nonassoc UNIOP UNIOPSUB
%left <ival> SHIFTOP
%left ADDOP
%left MULOP
%left <ival> MATCHOP
%right '!' '~' UMINUS REFGEN
%right <ival> POWOP
%nonassoc PREINC PREDEC POSTINC POSTDEC
%left ARROW
%left '('

%% /* RULES */

prog	:	/* NULL */
		{
#if defined(YYDEBUG) && defined(DEBUGGING)
		    yydebug = (debug & 1);
#endif
		    expect = XSTATE;
		}
	/*CONTINUED*/	lineseq
			{ newPROG($2); }
	;

block	:	'{' remember lineseq '}'
			{ if (copline > (line_t)$1)
			      copline = $1;
			  $$ = block_end($2, $3); }
	;

remember:	/* NULL */	/* start a full lexical scope */
			{ $$ = block_start(TRUE); }
	;

mblock	:	'{' mremember lineseq '}'
			{ if (copline > (line_t)$1)
			      copline = $1;
			  $$ = block_end($2, $3); }
	;

mremember:	/* NULL */	/* start a partial lexical scope */
			{ $$ = block_start(FALSE); }
	;

lineseq	:	/* NULL */
			{ $$ = Nullop; }
	|	lineseq decl
			{ $$ = $1; }
	|	lineseq line
			{   $$ = append_list(OP_LINESEQ,
				(LISTOP*)$1, (LISTOP*)$2);
			    pad_reset_pending = TRUE;
			    if ($1 && $2) hints |= HINT_BLOCK_SCOPE; }
	;

line	:	label cond
			{ $$ = newSTATEOP(0, $1, $2); }
	|	loop	/* loops add their own labels */
	|	label ';'
			{ if ($1 != Nullch) {
			      $$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
			    }
			    else {
			      $$ = Nullop;
			      copline = NOLINE;
			    }
			    expect = XSTATE; }
	|	label sideff ';'
			{ $$ = newSTATEOP(0, $1, $2);
			  expect = XSTATE; }
	;

sideff	:	error
			{ $$ = Nullop; }
	|	expr
			{ $$ = $1; }
	|	expr IF expr
			{ $$ = newLOGOP(OP_AND, 0, $3, $1); }
	|	expr UNLESS expr
			{ $$ = newLOGOP(OP_OR, 0, $3, $1); }
	|	expr WHILE expr
			{ $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
	|	expr UNTIL iexpr
			{ $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);}
	;

else	:	/* NULL */
			{ $$ = Nullop; }
	|	ELSE mblock
			{ $$ = scope($2); }
	|	ELSIF '(' mexpr ')' mblock else
			{ copline = $1;
			    $$ = newSTATEOP(0, Nullch,
				   newCONDOP(0, $3, scope($5), $6));
			    hints |= HINT_BLOCK_SCOPE; }
	;

cond	:	IF '(' remember mexpr ')' mblock else
			{ copline = $1;
			    $$ = block_end($3,
				   newCONDOP(0, $4, scope($6), $7)); }
	|	UNLESS '(' remember miexpr ')' mblock else
			{ copline = $1;
			    $$ = block_end($3,
				   newCONDOP(0, $4, scope($6), $7)); }
	;

cont	:	/* NULL */
			{ $$ = Nullop; }
	|	CONTINUE block
			{ $$ = scope($2); }
	;

loop	:	label WHILE '(' remember mtexpr ')' mblock cont
			{ copline = $2;
			    $$ = block_end($4,
				   newSTATEOP(0, $1,
				     newWHILEOP(0, 1, (LOOP*)Nullop,
						$5, $7, $8))); }
	|	label UNTIL '(' remember miexpr ')' mblock cont
			{ copline = $2;
			    $$ = block_end($4,
				   newSTATEOP(0, $1,
				     newWHILEOP(0, 1, (LOOP*)Nullop,
						$5, $7, $8))); }
	|	label FOR MY remember my_scalar '(' mexpr ')' mblock cont
			{ $$ = block_end($4,
				 newFOROP(0, $1, $2, $5, $7, $9, $10)); }
	|	label FOR scalar '(' remember mexpr ')' mblock cont
			{ $$ = block_end($5,
				 newFOROP(0, $1, $2, mod($3, OP_ENTERLOOP),
					  $6, $8, $9)); }
	|	label FOR '(' remember mexpr ')' mblock cont
			{ $$ = block_end($4,
				 newFOROP(0, $1, $2, Nullop, $5, $7, $8)); }
	|	label FOR '(' remember mnexpr ';' mtexpr ';' mnexpr ')' mblock
			/* basically fake up an initialize-while lineseq */
			{ copline = $2;
			    $$ = block_end($4,
				   append_elem(OP_LINESEQ, scalar($5),
				     newSTATEOP(0, $1,
				       newWHILEOP(0, 1, (LOOP*)Nullop,
						  scalar($7),
						  $11, scalar($9))))); }
	|	label block cont  /* a block is a loop that happens once */
			{ $$ = newSTATEOP(0,
				$1, newWHILEOP(0, 1, (LOOP*)Nullop,
					Nullop, $2, $3)); }
	;

nexpr	:	/* NULL */
			{ $$ = Nullop; }
	|	sideff
	;

texpr	:	/* NULL means true */
			{ (void)scan_num("1"); $$ = yylval.opval; }
	|	expr
	;

iexpr	:	expr
			{ $$ = invert(scalar($1)); }
	;

mexpr	:	expr
			{ $$ = $1; intro_my(); }
	;

mnexpr	:	nexpr
			{ $$ = $1; intro_my(); }
	;

mtexpr	:	texpr
			{ $$ = $1; intro_my(); }
	;

miexpr	:	iexpr
			{ $$ = $1; intro_my(); }
	;

label	:	/* empty */
			{ $$ = Nullch; }
	|	LABEL
	;

decl	:	format
			{ $$ = 0; }
	|	subrout
			{ $$ = 0; }
	|	package
			{ $$ = 0; }
	|	use
			{ $$ = 0; }
	;

format	:	FORMAT startformsub formname block
			{ newFORM($2, $3, $4); }
	;

formname:	WORD		{ $$ = $1; }
	|	/* NULL */	{ $$ = Nullop; }
	;

subrout	:	SUB startsub subname proto subbody
			{ newSUB($2, $3, $4, $5); }
	;

startsub:	/* NULL */	/* start a subroutine scope */
			{ $$ = start_subparse(); }
	;

startanonsub:	/* NULL */	/* start an anonymous subroutine scope */
			{ $$ = start_subparse();
			  CvANON_on(compcv); }
	;

startformsub:	/* NULL */	/* start a format subroutine scope */
			{ $$ = start_subparse();
			  CvFORMAT_on(compcv); }
	;

subname	:	WORD	{ char *name = SvPVx(((SVOP*)$1)->op_sv, na);
			  if (strEQ(name, "BEGIN") || strEQ(name, "END"))
			      CvUNIQUE_on(compcv);
			  $$ = $1; }
	;

proto	:	/* NULL */
			{ $$ = Nullop; }
	|	THING
	;

subbody	:	block	{ $$ = $1; }
	|	';'	{ $$ = Nullop; expect = XSTATE; }
	;

package :	PACKAGE WORD ';'
			{ package($2); }
	|	PACKAGE ';'
			{ package(Nullop); }
	;

use	:	USE startsub
			{ CvUNIQUE_on(compcv); /* It's a BEGIN {} */ }
		    WORD WORD listexpr ';'
			{ utilize($1, $2, $4, $5, $6); }
	;

expr	:	expr ANDOP expr
			{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
	|	expr OROP expr
			{ $$ = newLOGOP($2, 0, $1, $3); }
	|	argexpr
	;

argexpr	:	argexpr ','
			{ $$ = $1; }
	|	argexpr ',' term
			{ $$ = append_elem(OP_LIST, $1, $3); }
	|	term
	;

listop	:	LSTOP indirob argexpr
			{ $$ = convert($1, OPf_STACKED,
				prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
	|	FUNC '(' indirob expr ')'
			{ $$ = convert($1, OPf_STACKED,
				prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
	|	term ARROW method '(' listexprcom ')'
			{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
				append_elem(OP_LIST,
				    prepend_elem(OP_LIST, scalar($1), $5),
				    newUNOP(OP_METHOD, 0, $3))); }
	|	METHOD indirob listexpr
			{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
				append_elem(OP_LIST,
				    prepend_elem(OP_LIST, $2, $3),
				    newUNOP(OP_METHOD, 0, $1))); }
	|	FUNCMETH indirob '(' listexprcom ')'
			{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
				append_elem(OP_LIST,
				    prepend_elem(OP_LIST, $2, $4),
				    newUNOP(OP_METHOD, 0, $1))); }
	|	LSTOP listexpr
			{ $$ = convert($1, 0, $2); }
	|	FUNC '(' listexprcom ')'
			{ $$ = convert($1, 0, $3); }
	|	LSTOPSUB startanonsub block
			{ $3 = newANONSUB($2, 0, $3); }
		    listexpr		%prec LSTOP
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
				 append_elem(OP_LIST,
				   prepend_elem(OP_LIST, $3, $5), $1)); }
	;

method	:	METHOD
	|	scalar
	;

term	:	term ASSIGNOP term
			{ $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
	|	term POWOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term MULOP term
			{   if ($2 != OP_REPEAT)
				scalar($1);
			    $$ = newBINOP($2, 0, $1, scalar($3)); }
	|	term ADDOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term SHIFTOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term RELOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term EQOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term BITANDOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term BITOROP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term DOTDOT term
			{ $$ = newRANGE($2, scalar($1), scalar($3));}
	|	term ANDAND term
			{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
	|	term OROR term
			{ $$ = newLOGOP(OP_OR, 0, $1, $3); }
	|	term '?' term ':' term
			{ $$ = newCONDOP(0, $1, $3, $5); }
	|	term MATCHOP term
			{ $$ = bind_match($2, $1, $3); }

	|	'-' term %prec UMINUS
			{ $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
	|	'+' term %prec UMINUS
			{ $$ = $2; }
	|	'!' term
			{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
	|	'~' term
			{ $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
	|	REFGEN term
			{ $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
	|	term POSTINC
			{ $$ = newUNOP(OP_POSTINC, 0,
					mod(scalar($1), OP_POSTINC)); }
	|	term POSTDEC
			{ $$ = newUNOP(OP_POSTDEC, 0,
					mod(scalar($1), OP_POSTDEC)); }
	|	PREINC term
			{ $$ = newUNOP(OP_PREINC, 0,
					mod(scalar($2), OP_PREINC)); }
	|	PREDEC term
			{ $$ = newUNOP(OP_PREDEC, 0,
					mod(scalar($2), OP_PREDEC)); }
	|	local term	%prec UNIOP
			{ $$ = localize($2,$1); }
	|	'(' expr ')'
			{ $$ = sawparens($2); }
	|	'(' ')'
			{ $$ = sawparens(newNULLLIST()); }
	|	'[' expr ']'				%prec '('
			{ $$ = newANONLIST($2); }
	|	'[' ']'					%prec '('
			{ $$ = newANONLIST(Nullop); }
	|	HASHBRACK expr ';' '}'			%prec '('
			{ $$ = newANONHASH($2); }
	|	HASHBRACK ';' '}'				%prec '('
			{ $$ = newANONHASH(Nullop); }
	|	ANONSUB startanonsub proto block		%prec '('
			{ $$ = newANONSUB($2, $3, $4); }
	|	scalar	%prec '('
			{ $$ = $1; }
	|	star '{' expr ';' '}'
			{ $$ = newBINOP(OP_GELEM, 0, newGVREF(0,$1), $3); }
	|	star	%prec '('
			{ $$ = $1; }
	|	scalar '[' expr ']'	%prec '('
			{ $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
	|	term ARROW '[' expr ']'	%prec '('
			{ $$ = newBINOP(OP_AELEM, 0,
					ref(newAVREF($1),OP_RV2AV),
					scalar($4));}
	|	term '[' expr ']'	%prec '('
			{ assertref($1); $$ = newBINOP(OP_AELEM, 0,
					ref(newAVREF($1),OP_RV2AV),
					scalar($3));}
	|	hsh 	%prec '('
			{ $$ = $1; }
	|	ary 	%prec '('
			{ $$ = $1; }
	|	arylen 	%prec '('
			{ $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
	|	scalar '{' expr ';' '}'	%prec '('
			{ $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
			    expect = XOPERATOR; }
	|	term ARROW '{' expr ';' '}'	%prec '('
			{ $$ = newBINOP(OP_HELEM, 0,
					ref(newHVREF($1),OP_RV2HV),
					jmaybe($4));
			    expect = XOPERATOR; }
	|	term '{' expr ';' '}'	%prec '('
			{ assertref($1); $$ = newBINOP(OP_HELEM, 0,
					ref(newHVREF($1),OP_RV2HV),
					jmaybe($3));
			    expect = XOPERATOR; }
	|	'(' expr ')' '[' expr ']'	%prec '('
			{ $$ = newSLICEOP(0, $5, $2); }
	|	'(' ')' '[' expr ']'	%prec '('
			{ $$ = newSLICEOP(0, $4, Nullop); }
	|	ary '[' expr ']'	%prec '('
			{ $$ = prepend_elem(OP_ASLICE,
				newOP(OP_PUSHMARK, 0),
				    newLISTOP(OP_ASLICE, 0,
					list($3),
					ref($1, OP_ASLICE))); }
	|	ary '{' expr ';' '}'	%prec '('
			{ $$ = prepend_elem(OP_HSLICE,
				newOP(OP_PUSHMARK, 0),
				    newLISTOP(OP_HSLICE, 0,
					list($3),
					ref(oopsHV($1), OP_HSLICE)));
			    expect = XOPERATOR; }
	|	THING	%prec '('
			{ $$ = $1; }
	|	amper
			{ $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
	|	amper '(' ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
	|	amper '(' expr ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
			    append_elem(OP_LIST, $3, scalar($1))); }
	|	NOAMP WORD listexpr
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
			    append_elem(OP_LIST, $3, scalar($2))); }
	|	DO term	%prec UNIOP
			{ $$ = newUNOP(OP_DOFILE, 0, scalar($2)); }
	|	DO block	%prec '('
			{ $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
	|	DO WORD '(' ')'
			{ $$ = newUNOP(OP_ENTERSUB,
			    OPf_SPECIAL|OPf_STACKED,
			    prepend_elem(OP_LIST,
				scalar(newCVREF(
				    (OPpENTERSUB_AMPER<<8),
				    scalar($2)
				)),Nullop)); dep();}
	|	DO WORD '(' expr ')'
			{ $$ = newUNOP(OP_ENTERSUB,
			    OPf_SPECIAL|OPf_STACKED,
			    append_elem(OP_LIST,
				$4,
				scalar(newCVREF(
				    (OPpENTERSUB_AMPER<<8),
				    scalar($2)
				)))); dep();}
	|	DO scalar '(' ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
			    prepend_elem(OP_LIST,
				scalar(newCVREF(0,scalar($2))), Nullop)); dep();}
	|	DO scalar '(' expr ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
			    prepend_elem(OP_LIST,
				$4,
				scalar(newCVREF(0,scalar($2))))); dep();}
	|	LOOPEX
			{ $$ = newOP($1, OPf_SPECIAL);
			    hints |= HINT_BLOCK_SCOPE; }
	|	LOOPEX term
			{ $$ = newLOOPEX($1,$2); }
	|	NOTOP argexpr
			{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
	|	UNIOP
			{ $$ = newOP($1, 0); }
	|	UNIOP block
			{ $$ = newUNOP($1, 0, $2); }
	|	UNIOP term
			{ $$ = newUNOP($1, 0, $2); }
	|	UNIOPSUB term
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
			    append_elem(OP_LIST, $2, scalar($1))); }
	|	FUNC0
			{ $$ = newOP($1, 0); }
	|	FUNC0 '(' ')'
			{ $$ = newOP($1, 0); }
	|	FUNC0SUB
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
				scalar($1)); }
	|	FUNC1 '(' ')'
			{ $$ = newOP($1, OPf_SPECIAL); }
	|	FUNC1 '(' expr ')'
			{ $$ = newUNOP($1, 0, $3); }
	|	PMFUNC '(' term ')'
			{ $$ = pmruntime($1, $3, Nullop); }
	|	PMFUNC '(' term ',' term ')'
			{ $$ = pmruntime($1, $3, $5); }
	|	WORD
	|	listop
	;

listexpr:	/* NULL */
			{ $$ = Nullop; }
	|	argexpr
			{ $$ = $1; }
	;

listexprcom:	/* NULL */
			{ $$ = Nullop; }
	|	expr
			{ $$ = $1; }
	|	expr ','
			{ $$ = $1; }
	;

local	:	LOCAL	{ $$ = 0; }
	|	MY	{ $$ = 1; }
	;

my_scalar:	scalar
			{ in_my = 0; $$ = my($1); }
	;

amper	:	'&' indirob
			{ $$ = newCVREF($1,$2); }
	;

scalar	:	'$' indirob
			{ $$ = newSVREF($2); }
	;

ary	:	'@' indirob
			{ $$ = newAVREF($2); }
	;

hsh	:	'%' indirob
			{ $$ = newHVREF($2); }
	;

arylen	:	DOLSHARP indirob
			{ $$ = newAVREF($2); }
	;

star	:	'*' indirob
			{ $$ = newGVREF(0,$2); }
	;

indirob	:	WORD
			{ $$ = scalar($1); }
	|	scalar
			{ $$ = scalar($1);  }
	|	block
			{ $$ = scope($1); }

	|	PRIVATEREF
			{ $$ = $1; }
	;

%% /* PROGRAM */
Commit	Line	Data
a0d0e21e	1	/* perly.y
a687059c	2	*
a0d0e21e	3	* Copyright (c) 1991-1994, Larry Wall
a687059c	4	*
9ef589d8	5	* You may distribute under the terms of either the GNU General Public
9ef589d8	6	* License or the Artistic License, as specified in the README file.
8d063cd8	7	*
a0d0e21e	8	*/
	9
	10	/*
	11	* 'I see,' laughed Strider. 'I look foul and feel fair. Is that it?
	12	* All that is gold does not glitter, not all those that wander are lost.'
8d063cd8	13	*/
	14
	15	%{
79072805	16	#include "EXTERN.h"
8d063cd8	17	#include "perl.h"
378cc40b	18
a0d0e21e	19	static void
	20	dep()
	21	{
	22	deprecate("\"do\" to call subroutines");
	23	}
f0fcb552	24
8d063cd8	25	%}
	26
	27	%start prog
	28
	29	%union {
79072805	30	I32 ival;
	31	char *pval;
	32	OP *opval;
	33	GV *gvval;
8d063cd8	34	}
8d063cd8	35
f0fcb552	36	%token <ival> '{' ')'
f0fcb552	37
a0d0e21e	38	%token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
4633a7c4	39	%token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
79072805	40	%token <pval> LABEL
a0d0e21e	41	%token <ival> FORMAT SUB ANONSUB PACKAGE USE
79072805	42	%token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
79072805	43	%token <ival> LOOPEX DOTDOT
36477c24	44	%token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP
79072805	45	%token <ival> RELOP EQOP MULOP ADDOP
55497cff	46	%token <ival> DOLSHARP DO HASHBRACK NOAMP
55497cff	47	%token LOCAL MY
79072805	48
44a8e56a	49	%type <ival> prog decl local format startsub startanonsub startformsub
28757baa	50	%type <ival> remember mremember '&'
bbce6d69	51	%type <opval> block mblock lineseq line loop cond else
a0d0e21e	52	%type <opval> expr term scalar ary hsh arylen star amper sideff
bbce6d69	53	%type <opval> argexpr nexpr texpr iexpr mexpr mnexpr mtexpr miexpr
44a8e56a	54	%type <opval> listexpr listexprcom indirob listop method
44a8e56a	55	%type <opval> formname subname proto subbody cont my_scalar
79072805	56	%type <pval> label
79072805	57
a0d0e21e	58	%left <ival> OROP
463ee0b2	59	%left ANDOP
c07a80fd	60	%right NOTOP
36477c24	61	%nonassoc LSTOP LSTOPSUB
8d063cd8	62	%left ','
a0d0e21e	63	%right <ival> ASSIGNOP
8d063cd8	64	%right '?' ':'
	65	%nonassoc DOTDOT
	66	%left OROR
	67	%left ANDAND
79072805	68	%left <ival> BITOROP
79072805	69	%left <ival> BITANDOP
a687059c	70	%nonassoc EQOP
a687059c	71	%nonassoc RELOP
36477c24	72	%nonassoc UNIOP UNIOPSUB
79072805	73	%left <ival> SHIFTOP
a687059c	74	%left ADDOP
a687059c	75	%left MULOP
8990e307	76	%left <ival> MATCHOP
79072805	77	%right '!' '~' UMINUS REFGEN
	78	%right <ival> POWOP
	79	%nonassoc PREINC PREDEC POSTINC POSTDEC
8990e307	80	%left ARROW
8d063cd8	81	%left '('
	82
	83	%% /* RULES */
	84
ae986130	85	prog : /* NULL */
	86	{
	87	#if defined(YYDEBUG) && defined(DEBUGGING)
	88	yydebug = (debug & 1);
	89	#endif
8990e307	90	expect = XSTATE;
ae986130	91	}
ae986130	92	/CONTINUED/ lineseq
a0d0e21e	93	{ newPROG($2); }
8d063cd8	94	;
8d063cd8	95
a687059c	96	block : '{' remember lineseq '}'
36477c24	97	{ if (copline > (line_t)$1)
	98	copline = $1;
	99	$$ = block_end($2, $3); }
a0d0e21e	100	;
a0d0e21e	101
55497cff	102	remember: /* NULL / / start a full lexical scope */
	103	{ $$ = block_start(TRUE); }
	104	;
	105
bbce6d69	106	mblock : '{' mremember lineseq '}'
36477c24	107	{ if (copline > (line_t)$1)
	108	copline = $1;
	109	$$ = block_end($2, $3); }
55497cff	110	;
	111
	112	mremember: /* NULL / / start a partial lexical scope */
	113	{ $$ = block_start(FALSE); }
8d063cd8	114	;
	115
	116	lineseq : /* NULL */
79072805	117	{ $$ = Nullop; }
	118	\| lineseq decl
	119	{ $$ = $1; }
8d063cd8	120	\| lineseq line
463ee0b2	121	{ $$ = append_list(OP_LINESEQ,
a0d0e21e	122	(LISTOP)$1, (LISTOP)$2);
a0d0e21e	123	pad_reset_pending = TRUE;
85e6fe83	124	if ($1 && $2) hints \|= HINT_BLOCK_SCOPE; }
8d063cd8	125	;
8d063cd8	126
79072805	127	line : label cond
79072805	128	{ $$ = newSTATEOP(0, $1, $2); }
8d063cd8	129	\| loop /* loops add their own labels */
	130	\| label ';'
	131	{ if ($1 != Nullch) {
79072805	132	$$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
450a55e4	133	}
450a55e4	134	else {
79072805	135	$$ = Nullop;
79072805	136	copline = NOLINE;
32c2e4fb	137	}
8990e307	138	expect = XSTATE; }
8d063cd8	139	\| label sideff ';'
79072805	140	{ $$ = newSTATEOP(0, $1, $2);
8990e307	141	expect = XSTATE; }
8d063cd8	142	;
8d063cd8	143
a687059c	144	sideff : error
79072805	145	{ $$ = Nullop; }
a687059c	146	\| expr
79072805	147	{ $$ = $1; }
a687059c	148	\| expr IF expr
79072805	149	{ $$ = newLOGOP(OP_AND, 0, $3, $1); }
a687059c	150	\| expr UNLESS expr
79072805	151	{ $$ = newLOGOP(OP_OR, 0, $3, $1); }
a687059c	152	\| expr WHILE expr
8990e307	153	{ $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
55497cff	154	\| expr UNTIL iexpr
55497cff	155	{ $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);}
79072805	156	;
	157
	158	else : /* NULL */
	159	{ $$ = Nullop; }
55497cff	160	\| ELSE mblock
79072805	161	{ $$ = scope($2); }
55497cff	162	\| ELSIF '(' mexpr ')' mblock else
79072805	163	{ copline = $1;
bbce6d69	164	$$ = newSTATEOP(0, Nullch,
bbce6d69	165	newCONDOP(0, $3, scope($5), $6));
4633a7c4	166	hints \|= HINT_BLOCK_SCOPE; }
79072805	167	;
79072805	168
55497cff	169	cond : IF '(' remember mexpr ')' mblock else
79072805	170	{ copline = $1;
36477c24	171	$$ = block_end($3,
bbce6d69	172	newCONDOP(0, $4, scope($6), $7)); }
55497cff	173	\| UNLESS '(' remember miexpr ')' mblock else
79072805	174	{ copline = $1;
36477c24	175	$$ = block_end($3,
bbce6d69	176	newCONDOP(0, $4, scope($6), $7)); }
79072805	177	;
	178
	179	cont : /* NULL */
	180	{ $$ = Nullop; }
	181	\| CONTINUE block
	182	{ $$ = scope($2); }
	183	;
	184
55497cff	185	loop : label WHILE '(' remember mtexpr ')' mblock cont
79072805	186	{ copline = $2;
36477c24	187	$$ = block_end($4,
55497cff	188	newSTATEOP(0, $1,
bbce6d69	189	newWHILEOP(0, 1, (LOOP*)Nullop,
bbce6d69	190	$5, $7, $8))); }
55497cff	191	\| label UNTIL '(' remember miexpr ')' mblock cont
79072805	192	{ copline = $2;
36477c24	193	$$ = block_end($4,
55497cff	194	newSTATEOP(0, $1,
bbce6d69	195	newWHILEOP(0, 1, (LOOP*)Nullop,
bbce6d69	196	$5, $7, $8))); }
bbce6d69	197	\| label FOR MY remember my_scalar '(' mexpr ')' mblock cont
36477c24	198	{ $$ = block_end($4,
bbce6d69	199	newFOROP(0, $1, $2, $5, $7, $9, $10)); }
bbce6d69	200	\| label FOR scalar '(' remember mexpr ')' mblock cont
36477c24	201	{ $$ = block_end($5,
bbce6d69	202	newFOROP(0, $1, $2, mod($3, OP_ENTERLOOP),
	203	$6, $8, $9)); }
	204	\| label FOR '(' remember mexpr ')' mblock cont
36477c24	205	{ $$ = block_end($4,
55497cff	206	newFOROP(0, $1, $2, Nullop, $5, $7, $8)); }
bbce6d69	207	\| label FOR '(' remember mnexpr ';' mtexpr ';' mnexpr ')' mblock
8d063cd8	208	/* basically fake up an initialize-while lineseq */
55497cff	209	{ copline = $2;
36477c24	210	$$ = block_end($4,
bbce6d69	211	append_elem(OP_LINESEQ, scalar($5),
	212	newSTATEOP(0, $1,
	213	newWHILEOP(0, 1, (LOOP*)Nullop,
	214	scalar($7),
	215	$11, scalar($9))))); }
79072805	216	\| label block cont /* a block is a loop that happens once */
79072805	217	{ $$ = newSTATEOP(0,
463ee0b2	218	$1, newWHILEOP(0, 1, (LOOP*)Nullop,
463ee0b2	219	Nullop, $2, $3)); }
8d063cd8	220	;
	221
	222	nexpr : /* NULL */
79072805	223	{ $$ = Nullop; }
8d063cd8	224	\| sideff
	225	;
	226
	227	texpr : /* NULL means true */
79072805	228	{ (void)scan_num("1"); $$ = yylval.opval; }
8d063cd8	229	\| expr
	230	;
	231
55497cff	232	iexpr : expr
	233	{ $$ = invert(scalar($1)); }
	234	;
	235
	236	mexpr : expr
bbce6d69	237	{ $$ = $1; intro_my(); }
	238	;
	239
	240	mnexpr : nexpr
	241	{ $$ = $1; intro_my(); }
55497cff	242	;
	243
	244	mtexpr : texpr
bbce6d69	245	{ $$ = $1; intro_my(); }
55497cff	246	;
	247
	248	miexpr : iexpr
bbce6d69	249	{ $$ = $1; intro_my(); }
55497cff	250	;
55497cff	251
8d063cd8	252	label : /* empty */
8d063cd8	253	{ $$ = Nullch; }
32c2e4fb	254	\| LABEL
8d063cd8	255	;
8d063cd8	256
8d063cd8	257	decl : format
	258	{ $$ = 0; }
	259	\| subrout
	260	{ $$ = 0; }
a687059c	261	\| package
a687059c	262	{ $$ = 0; }
a0d0e21e	263	\| use
85e6fe83	264	{ $$ = 0; }
8d063cd8	265	;
8d063cd8	266
44a8e56a	267	format : FORMAT startformsub formname block
a0d0e21e	268	{ newFORM($2, $3, $4); }
44a8e56a	269	;
	270
	271	formname: WORD { $$ = $1; }
	272	\| /* NULL */ { $$ = Nullop; }
8d063cd8	273	;
8d063cd8	274
28757baa	275	subrout : SUB startsub subname proto subbody
4633a7c4	276	{ newSUB($2, $3, $4, $5); }
28757baa	277	;
	278
	279	startsub: /* NULL / / start a subroutine scope */
	280	{ $$ = start_subparse(); }
	281	;
	282
	283	startanonsub: /* NULL / / start an anonymous subroutine scope */
	284	{ $$ = start_subparse();
	285	CvANON_on(compcv); }
	286	;
	287
44a8e56a	288	startformsub: /* NULL / / start a format subroutine scope */
	289	{ $$ = start_subparse();
	290	CvFORMAT_on(compcv); }
	291	;
	292
28757baa	293	subname : WORD { char name = SvPVx(((SVOP)$1)->op_sv, na);
	294	if (strEQ(name, "BEGIN") \|\| strEQ(name, "END"))
	295	CvUNIQUE_on(compcv);
	296	$$ = $1; }
a0d0e21e	297	;
a0d0e21e	298
4633a7c4	299	proto : /* NULL */
	300	{ $$ = Nullop; }
	301	\| THING
	302	;
28757baa	303
	304	subbody : block { $$ = $1; }
	305	\| ';' { $$ = Nullop; expect = XSTATE; }
8d063cd8	306	;
8d063cd8	307
a687059c	308	package : PACKAGE WORD ';'
79072805	309	{ package($2); }
93a17b20	310	\| PACKAGE ';'
93a17b20	311	{ package(Nullop); }
a687059c	312	;
a687059c	313
28757baa	314	use : USE startsub
	315	{ CvUNIQUE_on(compcv); /* It's a BEGIN {} */ }
	316	WORD WORD listexpr ';'
	317	{ utilize($1, $2, $4, $5, $6); }
85e6fe83	318	;
85e6fe83	319
a0d0e21e	320	expr : expr ANDOP expr
	321	{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
	322	\| expr OROP expr
	323	{ $$ = newLOGOP($2, 0, $1, $3); }
a0d0e21e	324	\| argexpr
	325	;
	326
	327	argexpr : argexpr ','
	328	{ $$ = $1; }
	329	\| argexpr ',' term
79072805	330	{ $$ = append_elem(OP_LIST, $1, $3); }
a0d0e21e	331	\| term
8d063cd8	332	;
8d063cd8	333
a0d0e21e	334	listop : LSTOP indirob argexpr
79072805	335	{ $$ = convert($1, OPf_STACKED,
a0d0e21e	336	prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
a0d0e21e	337	\| FUNC '(' indirob expr ')'
79072805	338	{ $$ = convert($1, OPf_STACKED,
a0d0e21e	339	prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
a0d0e21e	340	\| term ARROW method '(' listexprcom ')'
4633a7c4	341	{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
a0d0e21e	342	append_elem(OP_LIST,
55497cff	343	prepend_elem(OP_LIST, scalar($1), $5),
a0d0e21e	344	newUNOP(OP_METHOD, 0, $3))); }
79072805	345	\| METHOD indirob listexpr
4633a7c4	346	{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
a0d0e21e	347	append_elem(OP_LIST,
4633a7c4	348	prepend_elem(OP_LIST, $2, $3),
a0d0e21e	349	newUNOP(OP_METHOD, 0, $1))); }
a0d0e21e	350	\| FUNCMETH indirob '(' listexprcom ')'
4633a7c4	351	{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
a0d0e21e	352	append_elem(OP_LIST,
4633a7c4	353	prepend_elem(OP_LIST, $2, $4),
a0d0e21e	354	newUNOP(OP_METHOD, 0, $1))); }
79072805	355	\| LSTOP listexpr
79072805	356	{ $$ = convert($1, 0, $2); }
a0d0e21e	357	\| FUNC '(' listexprcom ')'
79072805	358	{ $$ = convert($1, 0, $3); }
28757baa	359	\| LSTOPSUB startanonsub block
	360	{ $3 = newANONSUB($2, 0, $3); }
	361	listexpr %prec LSTOP
4633a7c4	362	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
28757baa	363	append_elem(OP_LIST,
28757baa	364	prepend_elem(OP_LIST, $3, $5), $1)); }
a687059c	365	;
a687059c	366
a0d0e21e	367	method : METHOD
	368	\| scalar
	369	;
	370
	371	term : term ASSIGNOP term
	372	{ $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
	373	\| term POWOP term
79072805	374	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	375	\| term MULOP term
79072805	376	{ if ($2 != OP_REPEAT)
	377	scalar($1);
	378	$$ = newBINOP($2, 0, $1, scalar($3)); }
a0d0e21e	379	\| term ADDOP term
79072805	380	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	381	\| term SHIFTOP term
79072805	382	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	383	\| term RELOP term
79072805	384	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	385	\| term EQOP term
79072805	386	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	387	\| term BITANDOP term
79072805	388	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	389	\| term BITOROP term
79072805	390	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	391	\| term DOTDOT term
79072805	392	{ $$ = newRANGE($2, scalar($1), scalar($3));}
a0d0e21e	393	\| term ANDAND term
463ee0b2	394	{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
a0d0e21e	395	\| term OROR term
463ee0b2	396	{ $$ = newLOGOP(OP_OR, 0, $1, $3); }
a0d0e21e	397	\| term '?' term ':' term
79072805	398	{ $$ = newCONDOP(0, $1, $3, $5); }
a0d0e21e	399	\| term MATCHOP term
79072805	400	{ $$ = bind_match($2, $1, $3); }
8d063cd8	401
a0d0e21e	402	\| '-' term %prec UMINUS
79072805	403	{ $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
a687059c	404	\| '+' term %prec UMINUS
a687059c	405	{ $$ = $2; }
8d063cd8	406	\| '!' term
79072805	407	{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
8d063cd8	408	\| '~' term
79072805	409	{ $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
79072805	410	\| REFGEN term
a0d0e21e	411	{ $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
79072805	412	\| term POSTINC
79072805	413	{ $$ = newUNOP(OP_POSTINC, 0,
463ee0b2	414	mod(scalar($1), OP_POSTINC)); }
79072805	415	\| term POSTDEC
79072805	416	{ $$ = newUNOP(OP_POSTDEC, 0,
463ee0b2	417	mod(scalar($1), OP_POSTDEC)); }
79072805	418	\| PREINC term
79072805	419	{ $$ = newUNOP(OP_PREINC, 0,
463ee0b2	420	mod(scalar($2), OP_PREINC)); }
79072805	421	\| PREDEC term
79072805	422	{ $$ = newUNOP(OP_PREDEC, 0,
463ee0b2	423	mod(scalar($2), OP_PREDEC)); }
55497cff	424	\| local term %prec UNIOP
93a17b20	425	{ $$ = localize($2,$1); }
a0d0e21e	426	\| '(' expr ')'
79072805	427	{ $$ = sawparens($2); }
8d063cd8	428	\| '(' ')'
8990e307	429	{ $$ = sawparens(newNULLLIST()); }
a0d0e21e	430	\| '[' expr ']' %prec '('
79072805	431	{ $$ = newANONLIST($2); }
	432	\| '[' ']' %prec '('
	433	{ $$ = newANONLIST(Nullop); }
a0d0e21e	434	\| HASHBRACK expr ';' '}' %prec '('
79072805	435	{ $$ = newANONHASH($2); }
	436	\| HASHBRACK ';' '}' %prec '('
	437	{ $$ = newANONHASH(Nullop); }
28757baa	438	\| ANONSUB startanonsub proto block %prec '('
4633a7c4	439	{ $$ = newANONSUB($2, $3, $4); }
79072805	440	\| scalar %prec '('
8d063cd8	441	{ $$ = $1; }
c07a80fd	442	\| star '{' expr ';' '}'
c07a80fd	443	{ $$ = newBINOP(OP_GELEM, 0, newGVREF(0,$1), $3); }
79072805	444	\| star %prec '('
8d063cd8	445	{ $$ = $1; }
79072805	446	\| scalar '[' expr ']' %prec '('
	447	{ $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
	448	\| term ARROW '[' expr ']' %prec '('
	449	{ $$ = newBINOP(OP_AELEM, 0,
8990e307	450	ref(newAVREF($1),OP_RV2AV),
79072805	451	scalar($4));}
463ee0b2	452	\| term '[' expr ']' %prec '('
a0d0e21e	453	{ assertref($1); $$ = newBINOP(OP_AELEM, 0,
8990e307	454	ref(newAVREF($1),OP_RV2AV),
463ee0b2	455	scalar($3));}
79072805	456	\| hsh %prec '('
8d063cd8	457	{ $$ = $1; }
79072805	458	\| ary %prec '('
8d063cd8	459	{ $$ = $1; }
79072805	460	\| arylen %prec '('
	461	{ $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
	462	\| scalar '{' expr ';' '}' %prec '('
	463	{ $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
	464	expect = XOPERATOR; }
	465	\| term ARROW '{' expr ';' '}' %prec '('
	466	{ $$ = newBINOP(OP_HELEM, 0,
8990e307	467	ref(newHVREF($1),OP_RV2HV),
79072805	468	jmaybe($4));
79072805	469	expect = XOPERATOR; }
463ee0b2	470	\| term '{' expr ';' '}' %prec '('
a0d0e21e	471	{ assertref($1); $$ = newBINOP(OP_HELEM, 0,
8990e307	472	ref(newHVREF($1),OP_RV2HV),
463ee0b2	473	jmaybe($3));
463ee0b2	474	expect = XOPERATOR; }
a0d0e21e	475	\| '(' expr ')' '[' expr ']' %prec '('
79072805	476	{ $$ = newSLICEOP(0, $5, $2); }
	477	\| '(' ')' '[' expr ']' %prec '('
	478	{ $$ = newSLICEOP(0, $4, Nullop); }
	479	\| ary '[' expr ']' %prec '('
	480	{ $$ = prepend_elem(OP_ASLICE,
	481	newOP(OP_PUSHMARK, 0),
79072805	482	newLISTOP(OP_ASLICE, 0,
79072805	483	list($3),
a0d0e21e	484	ref($1, OP_ASLICE))); }
79072805	485	\| ary '{' expr ';' '}' %prec '('
	486	{ $$ = prepend_elem(OP_HSLICE,
	487	newOP(OP_PUSHMARK, 0),
79072805	488	newLISTOP(OP_HSLICE, 0,
79072805	489	list($3),
a0d0e21e	490	ref(oopsHV($1), OP_HSLICE)));
79072805	491	expect = XOPERATOR; }
	492	\| THING %prec '('
	493	{ $$ = $1; }
	494	\| amper
c07a80fd	495	{ $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
79072805	496	\| amper '(' ')'
a0d0e21e	497	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
	498	\| amper '(' expr ')'
	499	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
4633a7c4	500	append_elem(OP_LIST, $3, scalar($1))); }
93a17b20	501	\| NOAMP WORD listexpr
a0d0e21e	502	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
a5f75d66	503	append_elem(OP_LIST, $3, scalar($2))); }
a0d0e21e	504	\| DO term %prec UNIOP
463ee0b2	505	{ $$ = newUNOP(OP_DOFILE, 0, scalar($2)); }
79072805	506	\| DO block %prec '('
79072805	507	{ $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
8d063cd8	508	\| DO WORD '(' ')'
c07a80fd	509	{ $$ = newUNOP(OP_ENTERSUB,
c07a80fd	510	OPf_SPECIAL\|OPf_STACKED,
4633a7c4	511	prepend_elem(OP_LIST,
c07a80fd	512	scalar(newCVREF(
	513	(OPpENTERSUB_AMPER<<8),
	514	scalar($2)
	515	)),Nullop)); dep();}
a0d0e21e	516	\| DO WORD '(' expr ')'
c07a80fd	517	{ $$ = newUNOP(OP_ENTERSUB,
c07a80fd	518	OPf_SPECIAL\|OPf_STACKED,
4633a7c4	519	append_elem(OP_LIST,
a0d0e21e	520	$4,
c07a80fd	521	scalar(newCVREF(
	522	(OPpENTERSUB_AMPER<<8),
	523	scalar($2)
	524	)))); dep();}
79072805	525	\| DO scalar '(' ')'
a0d0e21e	526	{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL\|OPf_STACKED,
4633a7c4	527	prepend_elem(OP_LIST,
c07a80fd	528	scalar(newCVREF(0,scalar($2))), Nullop)); dep();}
a0d0e21e	529	\| DO scalar '(' expr ')'
a0d0e21e	530	{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL\|OPf_STACKED,
4633a7c4	531	prepend_elem(OP_LIST,
a0d0e21e	532	$4,
c07a80fd	533	scalar(newCVREF(0,scalar($2))))); dep();}
8d063cd8	534	\| LOOPEX
85e6fe83	535	{ $$ = newOP($1, OPf_SPECIAL);
85e6fe83	536	hints \|= HINT_BLOCK_SCOPE; }
a0d0e21e	537	\| LOOPEX term
8990e307	538	{ $$ = newLOOPEX($1,$2); }
c07a80fd	539	\| NOTOP argexpr
c07a80fd	540	{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
8d063cd8	541	\| UNIOP
79072805	542	{ $$ = newOP($1, 0); }
f0fcb552	543	\| UNIOP block
79072805	544	{ $$ = newUNOP($1, 0, $2); }
a0d0e21e	545	\| UNIOP term
79072805	546	{ $$ = newUNOP($1, 0, $2); }
4633a7c4	547	\| UNIOPSUB term
	548	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
	549	append_elem(OP_LIST, $2, scalar($1))); }
8d063cd8	550	\| FUNC0
79072805	551	{ $$ = newOP($1, 0); }
ae986130	552	\| FUNC0 '(' ')'
79072805	553	{ $$ = newOP($1, 0); }
4633a7c4	554	\| FUNC0SUB
28757baa	555	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
4633a7c4	556	scalar($1)); }
03a14243	557	\| FUNC1 '(' ')'
79072805	558	{ $$ = newOP($1, OPf_SPECIAL); }
8d063cd8	559	\| FUNC1 '(' expr ')'
79072805	560	{ $$ = newUNOP($1, 0, $3); }
a0d0e21e	561	\| PMFUNC '(' term ')'
79072805	562	{ $$ = pmruntime($1, $3, Nullop); }
a0d0e21e	563	\| PMFUNC '(' term ',' term ')'
79072805	564	{ $$ = pmruntime($1, $3, $5); }
79072805	565	\| WORD
378cc40b	566	\| listop
8d063cd8	567	;
8d063cd8	568
79072805	569	listexpr: /* NULL */
8990e307	570	{ $$ = Nullop; }
a0d0e21e	571	\| argexpr
	572	{ $$ = $1; }
	573	;
	574
	575	listexprcom: /* NULL */
	576	{ $$ = Nullop; }
79072805	577	\| expr
79072805	578	{ $$ = $1; }
a0d0e21e	579	\| expr ','
a0d0e21e	580	{ $$ = $1; }
79072805	581	;
79072805	582
55497cff	583	local : LOCAL { $$ = 0; }
	584	\| MY { $$ = 1; }
	585	;
	586
	587	my_scalar: scalar
	588	{ in_my = 0; $$ = my($1); }
	589	;
	590
79072805	591	amper : '&' indirob
c07a80fd	592	{ $$ = newCVREF($1,$2); }
a687059c	593	;
a687059c	594
79072805	595	scalar : '$' indirob
79072805	596	{ $$ = newSVREF($2); }
a687059c	597	;
a687059c	598
79072805	599	ary : '@' indirob
	600	{ $$ = newAVREF($2); }
	601	;
	602
	603	hsh : '%' indirob
	604	{ $$ = newHVREF($2); }
	605	;
	606
	607	arylen : DOLSHARP indirob
	608	{ $$ = newAVREF($2); }
	609	;
	610
	611	star : '*' indirob
a0d0e21e	612	{ $$ = newGVREF(0,$2); }
79072805	613	;
	614
	615	indirob : WORD
	616	{ $$ = scalar($1); }
	617	\| scalar
463ee0b2	618	{ $$ = scalar($1); }
79072805	619	\| block
a0d0e21e	620	{ $$ = scope($1); }
79072805	621
93a17b20	622	\| PRIVATEREF
93a17b20	623	{ $$ = $1; }
8d063cd8	624	;
	625
	626	%% /* PROGRAM */