[p5sagit/p5-mst-13.2.git] / perly.y

/*    perly.y
 *
 *    Copyright (c) 1991-1994, Larry Wall
 *
 *    You may distribute under the terms of either the GNU General Public
 *    License or the Artistic License, as specified in the README file.
 *
 */

/*
 * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
 * All that is gold does not glitter, not all those that wander are lost.'
 */

%{
#include "EXTERN.h"
#include "perl.h"

static void
dep()
{
    deprecate("\"do\" to call subroutines");
}

%}

%start prog

%union {
    I32	ival;
    char *pval;
    OP *opval;
    GV *gvval;
}

%token <ival> '{' ')'

%token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
%token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
%token <pval> LABEL
%token <ival> FORMAT SUB ANONSUB PACKAGE USE
%token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
%token <ival> LOOPEX DOTDOT
%token <ival> FUNC0 FUNC1 FUNC
%token <ival> RELOP EQOP MULOP ADDOP
%token <ival> DOLSHARP DO LOCAL HASHBRACK NOAMP

%type <ival> prog decl format remember startsub
%type <opval> block lineseq line loop cond nexpr else argexpr
%type <opval> expr term scalar ary hsh arylen star amper sideff
%type <opval> listexpr listexprcom indirob
%type <opval> texpr listop method proto
%type <pval> label
%type <opval> cont

%left <ival> OROP
%left ANDOP
%left NOTOP
%nonassoc <ival> LSTOP
%left ','
%right <ival> ASSIGNOP
%right '?' ':'
%nonassoc DOTDOT
%left OROR
%left ANDAND
%left <ival> BITOROP
%left <ival> BITANDOP
%nonassoc EQOP
%nonassoc RELOP
%nonassoc <ival> UNIOP
%left <ival> SHIFTOP
%left ADDOP
%left MULOP
%left <ival> MATCHOP
%right '!' '~' UMINUS REFGEN
%right <ival> POWOP
%nonassoc PREINC PREDEC POSTINC POSTDEC
%left ARROW
%left '('

%% /* RULES */

prog	:	/* NULL */
		{
#if defined(YYDEBUG) && defined(DEBUGGING)
		    yydebug = (debug & 1);
#endif
		    expect = XSTATE;
		}
	/*CONTINUED*/	lineseq
			{ newPROG($2); }
	;

block	:	'{' remember lineseq '}'
			{ $$ = block_end($1,$2,$3); }
	;

remember:	/* NULL */	/* start a lexical scope */
			{ $$ = block_start(); }
	;

lineseq	:	/* NULL */
			{ $$ = Nullop; }
	|	lineseq decl
			{ $$ = $1; }
	|	lineseq line
			{   $$ = append_list(OP_LINESEQ,
				(LISTOP*)$1, (LISTOP*)$2);
			    pad_reset_pending = TRUE;
			    if ($1 && $2) hints |= HINT_BLOCK_SCOPE; }
	;

line	:	label cond
			{ $$ = newSTATEOP(0, $1, $2); }
	|	loop	/* loops add their own labels */
	|	label ';'
			{ if ($1 != Nullch) {
			      $$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
			    }
			    else {
			      $$ = Nullop;
			      copline = NOLINE;
			    }
			    expect = XSTATE; }
	|	label sideff ';'
			{ $$ = newSTATEOP(0, $1, $2);
			  expect = XSTATE; }
	;

sideff	:	error
			{ $$ = Nullop; }
	|	expr
			{ $$ = $1; }
	|	expr IF expr
			{ $$ = newLOGOP(OP_AND, 0, $3, $1); }
	|	expr UNLESS expr
			{ $$ = newLOGOP(OP_OR, 0, $3, $1); }
	|	expr WHILE expr
			{ $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
	|	expr UNTIL expr
			{ $$ = newLOOPOP(OPf_PARENS, 1, invert(scalar($3)), $1);}
	;

else	:	/* NULL */
			{ $$ = Nullop; }
	|	ELSE block
			{ $$ = scope($2); }
	|	ELSIF '(' expr ')' block else
			{ copline = $1;
			    $$ = newSTATEOP(0, 0,
				newCONDOP(0, $3, scope($5), $6));
			    hints |= HINT_BLOCK_SCOPE; }
	;

cond	:	IF '(' expr ')' block else
			{ copline = $1;
			    $$ = newCONDOP(0, $3, scope($5), $6); }
	|	UNLESS '(' expr ')' block else
			{ copline = $1;
			    $$ = newCONDOP(0,
				invert(scalar($3)), scope($5), $6); }
	|	IF block block else
			{ copline = $1;
			    deprecate("if BLOCK BLOCK");
			    $$ = newCONDOP(0, scope($2), scope($3), $4); }
	|	UNLESS block block else
			{ copline = $1;
			    deprecate("unless BLOCK BLOCK");
			    $$ = newCONDOP(0, invert(scalar(scope($2))),
						scope($3), $4); }
	;

cont	:	/* NULL */
			{ $$ = Nullop; }
	|	CONTINUE block
			{ $$ = scope($2); }
	;

loop	:	label WHILE '(' texpr ')' block cont
			{ copline = $2;
			    $$ = newSTATEOP(0, $1,
				    newWHILEOP(0, 1, (LOOP*)Nullop,
					$4, $6, $7) ); }
	|	label UNTIL '(' expr ')' block cont
			{ copline = $2;
			    $$ = newSTATEOP(0, $1,
				    newWHILEOP(0, 1, (LOOP*)Nullop,
					invert(scalar($4)), $6, $7) ); }
	|	label WHILE block block cont
			{ copline = $2;
			    $$ = newSTATEOP(0, $1,
				    newWHILEOP(0, 1, (LOOP*)Nullop,
					scope($3), $4, $5) ); }
	|	label UNTIL block block cont
			{ copline = $2;
			    $$ = newSTATEOP(0, $1,
				    newWHILEOP(0, 1, (LOOP*)Nullop,
					invert(scalar(scope($3))), $4, $5)); }
	|	label FOR scalar '(' expr ')' block cont
			{ $$ = newFOROP(0, $1, $2, mod($3, OP_ENTERLOOP),
				$5, $7, $8); }
	|	label FOR '(' expr ')' block cont
			{ $$ = newFOROP(0, $1, $2, Nullop, $4, $6, $7); }
	|	label FOR '(' nexpr ';' texpr ';' nexpr ')' block
			/* basically fake up an initialize-while lineseq */
			{  copline = $2;
			    $$ = append_elem(OP_LINESEQ,
				    newSTATEOP(0, $1, scalar($4)),
				    newSTATEOP(0, $1,
					newWHILEOP(0, 1, (LOOP*)Nullop,
					    scalar($6), $10, scalar($8)) )); }
	|	label block cont  /* a block is a loop that happens once */
			{ $$ = newSTATEOP(0,
				$1, newWHILEOP(0, 1, (LOOP*)Nullop,
					Nullop, $2, $3)); }
	;

nexpr	:	/* NULL */
			{ $$ = Nullop; }
	|	sideff
	;

texpr	:	/* NULL means true */
			{ (void)scan_num("1"); $$ = yylval.opval; }
	|	expr
	;

label	:	/* empty */
			{ $$ = Nullch; }
	|	LABEL
	;

decl	:	format
			{ $$ = 0; }
	|	subrout
			{ $$ = 0; }
	|	package
			{ $$ = 0; }
	|	use
			{ $$ = 0; }
	;

format	:	FORMAT startsub WORD block
			{ newFORM($2, $3, $4); }
	|	FORMAT startsub block
			{ newFORM($2, Nullop, $3); }
	;

subrout	:	SUB startsub WORD proto block
			{ newSUB($2, $3, $4, $5); }
	|	SUB startsub WORD proto ';'
			{ newSUB($2, $3, $4, Nullop); expect = XSTATE; }
	;

proto	:	/* NULL */
			{ $$ = Nullop; }
	|	THING
	;
		
startsub:	/* NULL */	/* start a subroutine scope */
			{ $$ = start_subparse(); }
	;

package :	PACKAGE WORD ';'
			{ package($2); }
	|	PACKAGE ';'
			{ package(Nullop); }
	;

use	:	USE WORD listexpr ';'
			{ utilize($1, $2, $3); }
	;

expr	:	expr ANDOP expr
			{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
	|	expr OROP expr
			{ $$ = newLOGOP($2, 0, $1, $3); }
	|	NOTOP expr
			{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
	|	argexpr
	;

argexpr	:	argexpr ','
			{ $$ = $1; }
	|	argexpr ',' term
			{ $$ = append_elem(OP_LIST, $1, $3); }
	|	term
	;

listop	:	LSTOP indirob argexpr
			{ $$ = convert($1, OPf_STACKED,
				prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
	|	FUNC '(' indirob expr ')'
			{ $$ = convert($1, OPf_STACKED,
				prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
	|	term ARROW method '(' listexprcom ')'
			{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
				append_elem(OP_LIST,
				    prepend_elem(OP_LIST, $1, $5),
				    newUNOP(OP_METHOD, 0, $3))); }
	|	METHOD indirob listexpr
			{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
				append_elem(OP_LIST,
				    prepend_elem(OP_LIST, $2, $3),
				    newUNOP(OP_METHOD, 0, $1))); }
	|	FUNCMETH indirob '(' listexprcom ')'
			{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
				append_elem(OP_LIST,
				    prepend_elem(OP_LIST, $2, $4),
				    newUNOP(OP_METHOD, 0, $1))); }
	|	LSTOP listexpr
			{ $$ = convert($1, 0, $2); }
	|	FUNC '(' listexprcom ')'
			{ $$ = convert($1, 0, $3); }
	|	LSTOPSUB startsub block listexpr	%prec LSTOP
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
			    append_elem(OP_LIST,
			      prepend_elem(OP_LIST, newANONSUB($2, 0, $3), $4),
			      $1)); }
	;

method	:	METHOD
	|	scalar
	;

term	:	term ASSIGNOP term
			{ $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
	|	term POWOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term MULOP term
			{   if ($2 != OP_REPEAT)
				scalar($1);
			    $$ = newBINOP($2, 0, $1, scalar($3)); }
	|	term ADDOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term SHIFTOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term RELOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term EQOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term BITANDOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term BITOROP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term DOTDOT term
			{ $$ = newRANGE($2, scalar($1), scalar($3));}
	|	term ANDAND term
			{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
	|	term OROR term
			{ $$ = newLOGOP(OP_OR, 0, $1, $3); }
	|	term '?' term ':' term
			{ $$ = newCONDOP(0, $1, $3, $5); }
	|	term MATCHOP term
			{ $$ = bind_match($2, $1, $3); }

	|	'-' term %prec UMINUS
			{ $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
	|	'+' term %prec UMINUS
			{ $$ = $2; }
	|	'!' term
			{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
	|	'~' term
			{ $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
	|	REFGEN term
			{ $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
	|	term POSTINC
			{ $$ = newUNOP(OP_POSTINC, 0,
					mod(scalar($1), OP_POSTINC)); }
	|	term POSTDEC
			{ $$ = newUNOP(OP_POSTDEC, 0,
					mod(scalar($1), OP_POSTDEC)); }
	|	PREINC term
			{ $$ = newUNOP(OP_PREINC, 0,
					mod(scalar($2), OP_PREINC)); }
	|	PREDEC term
			{ $$ = newUNOP(OP_PREDEC, 0,
					mod(scalar($2), OP_PREDEC)); }
	|	LOCAL term	%prec UNIOP
			{ $$ = localize($2,$1); }
	|	'(' expr ')'
			{ $$ = sawparens($2); }
	|	'(' ')'
			{ $$ = sawparens(newNULLLIST()); }
	|	'[' expr ']'				%prec '('
			{ $$ = newANONLIST($2); }
	|	'[' ']'					%prec '('
			{ $$ = newANONLIST(Nullop); }
	|	HASHBRACK expr ';' '}'			%prec '('
			{ $$ = newANONHASH($2); }
	|	HASHBRACK ';' '}'				%prec '('
			{ $$ = newANONHASH(Nullop); }
	|	ANONSUB startsub proto block			%prec '('
			{ $$ = newANONSUB($2, $3, $4); }
	|	scalar	%prec '('
			{ $$ = $1; }
	|	star	%prec '('
			{ $$ = $1; }
	|	scalar '[' expr ']'	%prec '('
			{ $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
	|	term ARROW '[' expr ']'	%prec '('
			{ $$ = newBINOP(OP_AELEM, 0,
					ref(newAVREF($1),OP_RV2AV),
					scalar($4));}
	|	term '[' expr ']'	%prec '('
			{ assertref($1); $$ = newBINOP(OP_AELEM, 0,
					ref(newAVREF($1),OP_RV2AV),
					scalar($3));}
	|	hsh 	%prec '('
			{ $$ = $1; }
	|	ary 	%prec '('
			{ $$ = $1; }
	|	arylen 	%prec '('
			{ $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
	|	scalar '{' expr ';' '}'	%prec '('
			{ $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
			    expect = XOPERATOR; }
	|	term ARROW '{' expr ';' '}'	%prec '('
			{ $$ = newBINOP(OP_HELEM, 0,
					ref(newHVREF($1),OP_RV2HV),
					jmaybe($4));
			    expect = XOPERATOR; }
	|	term '{' expr ';' '}'	%prec '('
			{ assertref($1); $$ = newBINOP(OP_HELEM, 0,
					ref(newHVREF($1),OP_RV2HV),
					jmaybe($3));
			    expect = XOPERATOR; }
	|	'(' expr ')' '[' expr ']'	%prec '('
			{ $$ = newSLICEOP(0, $5, $2); }
	|	'(' ')' '[' expr ']'	%prec '('
			{ $$ = newSLICEOP(0, $4, Nullop); }
	|	ary '[' expr ']'	%prec '('
			{ $$ = prepend_elem(OP_ASLICE,
				newOP(OP_PUSHMARK, 0),
				    newLISTOP(OP_ASLICE, 0,
					list($3),
					ref($1, OP_ASLICE))); }
	|	ary '{' expr ';' '}'	%prec '('
			{ $$ = prepend_elem(OP_HSLICE,
				newOP(OP_PUSHMARK, 0),
				    newLISTOP(OP_HSLICE, 0,
					list($3),
					ref(oopsHV($1), OP_HSLICE)));
			    expect = XOPERATOR; }
	|	THING	%prec '('
			{ $$ = $1; }
	|	amper
			{ $$ = newUNOP(OP_ENTERSUB, 0,
				scalar($1)); }
	|	amper '(' ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
	|	amper '(' expr ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
			    append_elem(OP_LIST, $3, scalar($1))); }
	|	NOAMP WORD listexpr
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
			    append_elem(OP_LIST,
				$3, newCVREF(scalar($2)))); }
	|	DO term	%prec UNIOP
			{ $$ = newUNOP(OP_DOFILE, 0, scalar($2)); }
	|	DO block	%prec '('
			{ $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
	|	DO WORD '(' ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
			    prepend_elem(OP_LIST,
				scalar(newCVREF(scalar($2))), Nullop)); dep();}
	|	DO WORD '(' expr ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
			    append_elem(OP_LIST,
				$4,
				scalar(newCVREF(scalar($2))))); dep();}
	|	DO scalar '(' ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
			    prepend_elem(OP_LIST,
				scalar(newCVREF(scalar($2))), Nullop)); dep();}
	|	DO scalar '(' expr ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
			    prepend_elem(OP_LIST,
				$4,
				scalar(newCVREF(scalar($2))))); dep();}
	|	LOOPEX
			{ $$ = newOP($1, OPf_SPECIAL);
			    hints |= HINT_BLOCK_SCOPE; }
	|	LOOPEX term
			{ $$ = newLOOPEX($1,$2); }
	|	UNIOP
			{ $$ = newOP($1, 0); }
	|	UNIOP block
			{ $$ = newUNOP($1, 0, $2); }
	|	UNIOP term
			{ $$ = newUNOP($1, 0, $2); }
	|	UNIOPSUB term
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
			    append_elem(OP_LIST, $2, scalar($1))); }
	|	FUNC0
			{ $$ = newOP($1, 0); }
	|	FUNC0 '(' ')'
			{ $$ = newOP($1, 0); }
	|	FUNC0SUB
			{ $$ = newUNOP(OP_ENTERSUB, 0,
				scalar($1)); }
	|	FUNC1 '(' ')'
			{ $$ = newOP($1, OPf_SPECIAL); }
	|	FUNC1 '(' expr ')'
			{ $$ = newUNOP($1, 0, $3); }
	|	PMFUNC '(' term ')'
			{ $$ = pmruntime($1, $3, Nullop); }
	|	PMFUNC '(' term ',' term ')'
			{ $$ = pmruntime($1, $3, $5); }
	|	WORD
	|	listop
	;

listexpr:	/* NULL */
			{ $$ = Nullop; }
	|	argexpr
			{ $$ = $1; }
	;

listexprcom:	/* NULL */
			{ $$ = Nullop; }
	|	expr
			{ $$ = $1; }
	|	expr ','
			{ $$ = $1; }
	;

amper	:	'&' indirob
			{ $$ = newCVREF($2); }
	;

scalar	:	'$' indirob
			{ $$ = newSVREF($2); }
	;

ary	:	'@' indirob
			{ $$ = newAVREF($2); }
	;

hsh	:	'%' indirob
			{ $$ = newHVREF($2); }
	;

arylen	:	DOLSHARP indirob
			{ $$ = newAVREF($2); }
	;

star	:	'*' indirob
			{ $$ = newGVREF(0,$2); }
	;

indirob	:	WORD
			{ $$ = scalar($1); }
	|	scalar
			{ $$ = scalar($1);  }
	|	block
			{ $$ = scope($1); }

	|	PRIVATEREF
			{ $$ = $1; }
	;

%% /* PROGRAM */
Commit	Line	Data
a0d0e21e	1	/* perly.y
a687059c	2	*
a0d0e21e	3	* Copyright (c) 1991-1994, Larry Wall
a687059c	4	*
9ef589d8	5	* You may distribute under the terms of either the GNU General Public
9ef589d8	6	* License or the Artistic License, as specified in the README file.
8d063cd8	7	*
a0d0e21e	8	*/
	9
	10	/*
	11	* 'I see,' laughed Strider. 'I look foul and feel fair. Is that it?
	12	* All that is gold does not glitter, not all those that wander are lost.'
8d063cd8	13	*/
	14
	15	%{
79072805	16	#include "EXTERN.h"
8d063cd8	17	#include "perl.h"
378cc40b	18
a0d0e21e	19	static void
	20	dep()
	21	{
	22	deprecate("\"do\" to call subroutines");
	23	}
f0fcb552	24
8d063cd8	25	%}
	26
	27	%start prog
	28
	29	%union {
79072805	30	I32 ival;
	31	char *pval;
	32	OP *opval;
	33	GV *gvval;
8d063cd8	34	}
8d063cd8	35
f0fcb552	36	%token <ival> '{' ')'
f0fcb552	37
a0d0e21e	38	%token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
4633a7c4	39	%token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
79072805	40	%token <pval> LABEL
a0d0e21e	41	%token <ival> FORMAT SUB ANONSUB PACKAGE USE
79072805	42	%token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
	43	%token <ival> LOOPEX DOTDOT
	44	%token <ival> FUNC0 FUNC1 FUNC
	45	%token <ival> RELOP EQOP MULOP ADDOP
a0d0e21e	46	%token <ival> DOLSHARP DO LOCAL HASHBRACK NOAMP
79072805	47
a0d0e21e	48	%type <ival> prog decl format remember startsub
	49	%type <opval> block lineseq line loop cond nexpr else argexpr
	50	%type <opval> expr term scalar ary hsh arylen star amper sideff
	51	%type <opval> listexpr listexprcom indirob
4633a7c4	52	%type <opval> texpr listop method proto
79072805	53	%type <pval> label
	54	%type <opval> cont
	55
a0d0e21e	56	%left <ival> OROP
463ee0b2	57	%left ANDOP
a0d0e21e	58	%left NOTOP
79072805	59	%nonassoc <ival> LSTOP
8d063cd8	60	%left ','
a0d0e21e	61	%right <ival> ASSIGNOP
8d063cd8	62	%right '?' ':'
	63	%nonassoc DOTDOT
	64	%left OROR
	65	%left ANDAND
79072805	66	%left <ival> BITOROP
79072805	67	%left <ival> BITANDOP
a687059c	68	%nonassoc EQOP
a687059c	69	%nonassoc RELOP
378cc40b	70	%nonassoc <ival> UNIOP
79072805	71	%left <ival> SHIFTOP
a687059c	72	%left ADDOP
a687059c	73	%left MULOP
8990e307	74	%left <ival> MATCHOP
79072805	75	%right '!' '~' UMINUS REFGEN
	76	%right <ival> POWOP
	77	%nonassoc PREINC PREDEC POSTINC POSTDEC
8990e307	78	%left ARROW
8d063cd8	79	%left '('
	80
	81	%% /* RULES */
	82
ae986130	83	prog : /* NULL */
	84	{
	85	#if defined(YYDEBUG) && defined(DEBUGGING)
	86	yydebug = (debug & 1);
	87	#endif
8990e307	88	expect = XSTATE;
ae986130	89	}
ae986130	90	/CONTINUED/ lineseq
a0d0e21e	91	{ newPROG($2); }
8d063cd8	92	;
8d063cd8	93
a687059c	94	block : '{' remember lineseq '}'
a0d0e21e	95	{ $$ = block_end($1,$2,$3); }
	96	;
	97
	98	remember: /* NULL / / start a lexical scope */
	99	{ $$ = block_start(); }
8d063cd8	100	;
	101
	102	lineseq : /* NULL */
79072805	103	{ $$ = Nullop; }
	104	\| lineseq decl
	105	{ $$ = $1; }
8d063cd8	106	\| lineseq line
463ee0b2	107	{ $$ = append_list(OP_LINESEQ,
a0d0e21e	108	(LISTOP)$1, (LISTOP)$2);
a0d0e21e	109	pad_reset_pending = TRUE;
85e6fe83	110	if ($1 && $2) hints \|= HINT_BLOCK_SCOPE; }
8d063cd8	111	;
8d063cd8	112
79072805	113	line : label cond
79072805	114	{ $$ = newSTATEOP(0, $1, $2); }
8d063cd8	115	\| loop /* loops add their own labels */
	116	\| label ';'
	117	{ if ($1 != Nullch) {
79072805	118	$$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
450a55e4	119	}
450a55e4	120	else {
79072805	121	$$ = Nullop;
79072805	122	copline = NOLINE;
32c2e4fb	123	}
8990e307	124	expect = XSTATE; }
8d063cd8	125	\| label sideff ';'
79072805	126	{ $$ = newSTATEOP(0, $1, $2);
8990e307	127	expect = XSTATE; }
8d063cd8	128	;
8d063cd8	129
a687059c	130	sideff : error
79072805	131	{ $$ = Nullop; }
a687059c	132	\| expr
79072805	133	{ $$ = $1; }
a687059c	134	\| expr IF expr
79072805	135	{ $$ = newLOGOP(OP_AND, 0, $3, $1); }
a687059c	136	\| expr UNLESS expr
79072805	137	{ $$ = newLOGOP(OP_OR, 0, $3, $1); }
a687059c	138	\| expr WHILE expr
8990e307	139	{ $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
a687059c	140	\| expr UNTIL expr
8990e307	141	{ $$ = newLOOPOP(OPf_PARENS, 1, invert(scalar($3)), $1);}
79072805	142	;
	143
	144	else : /* NULL */
	145	{ $$ = Nullop; }
	146	\| ELSE block
	147	{ $$ = scope($2); }
	148	\| ELSIF '(' expr ')' block else
	149	{ copline = $1;
85e6fe83	150	$$ = newSTATEOP(0, 0,
4633a7c4	151	newCONDOP(0, $3, scope($5), $6));
4633a7c4	152	hints \|= HINT_BLOCK_SCOPE; }
79072805	153	;
	154
	155	cond : IF '(' expr ')' block else
	156	{ copline = $1;
	157	$$ = newCONDOP(0, $3, scope($5), $6); }
	158	\| UNLESS '(' expr ')' block else
	159	{ copline = $1;
	160	$$ = newCONDOP(0,
	161	invert(scalar($3)), scope($5), $6); }
	162	\| IF block block else
	163	{ copline = $1;
a0d0e21e	164	deprecate("if BLOCK BLOCK");
79072805	165	$$ = newCONDOP(0, scope($2), scope($3), $4); }
	166	\| UNLESS block block else
	167	{ copline = $1;
a0d0e21e	168	deprecate("unless BLOCK BLOCK");
79072805	169	$$ = newCONDOP(0, invert(scalar(scope($2))),
	170	scope($3), $4); }
	171	;
	172
	173	cont : /* NULL */
	174	{ $$ = Nullop; }
	175	\| CONTINUE block
	176	{ $$ = scope($2); }
	177	;
	178
	179	loop : label WHILE '(' texpr ')' block cont
	180	{ copline = $2;
	181	$$ = newSTATEOP(0, $1,
463ee0b2	182	newWHILEOP(0, 1, (LOOP*)Nullop,
463ee0b2	183	$4, $6, $7) ); }
79072805	184	\| label UNTIL '(' expr ')' block cont
	185	{ copline = $2;
	186	$$ = newSTATEOP(0, $1,
463ee0b2	187	newWHILEOP(0, 1, (LOOP*)Nullop,
79072805	188	invert(scalar($4)), $6, $7) ); }
	189	\| label WHILE block block cont
	190	{ copline = $2;
	191	$$ = newSTATEOP(0, $1,
463ee0b2	192	newWHILEOP(0, 1, (LOOP*)Nullop,
79072805	193	scope($3), $4, $5) ); }
	194	\| label UNTIL block block cont
	195	{ copline = $2;
	196	$$ = newSTATEOP(0, $1,
463ee0b2	197	newWHILEOP(0, 1, (LOOP*)Nullop,
79072805	198	invert(scalar(scope($3))), $4, $5)); }
a0d0e21e	199	\| label FOR scalar '(' expr ')' block cont
463ee0b2	200	{ $$ = newFOROP(0, $1, $2, mod($3, OP_ENTERLOOP),
79072805	201	$5, $7, $8); }
a0d0e21e	202	\| label FOR '(' expr ')' block cont
79072805	203	{ $$ = newFOROP(0, $1, $2, Nullop, $4, $6, $7); }
8d063cd8	204	\| label FOR '(' nexpr ';' texpr ';' nexpr ')' block
8d063cd8	205	/* basically fake up an initialize-while lineseq */
79072805	206	{ copline = $2;
	207	$$ = append_elem(OP_LINESEQ,
	208	newSTATEOP(0, $1, scalar($4)),
	209	newSTATEOP(0, $1,
463ee0b2	210	newWHILEOP(0, 1, (LOOP*)Nullop,
79072805	211	scalar($6), $10, scalar($8)) )); }
	212	\| label block cont /* a block is a loop that happens once */
	213	{ $$ = newSTATEOP(0,
463ee0b2	214	$1, newWHILEOP(0, 1, (LOOP*)Nullop,
463ee0b2	215	Nullop, $2, $3)); }
8d063cd8	216	;
	217
	218	nexpr : /* NULL */
79072805	219	{ $$ = Nullop; }
8d063cd8	220	\| sideff
	221	;
	222
	223	texpr : /* NULL means true */
79072805	224	{ (void)scan_num("1"); $$ = yylval.opval; }
8d063cd8	225	\| expr
	226	;
	227
	228	label : /* empty */
	229	{ $$ = Nullch; }
32c2e4fb	230	\| LABEL
8d063cd8	231	;
8d063cd8	232
8d063cd8	233	decl : format
	234	{ $$ = 0; }
	235	\| subrout
	236	{ $$ = 0; }
a687059c	237	\| package
a687059c	238	{ $$ = 0; }
a0d0e21e	239	\| use
85e6fe83	240	{ $$ = 0; }
8d063cd8	241	;
8d063cd8	242
a0d0e21e	243	format : FORMAT startsub WORD block
	244	{ newFORM($2, $3, $4); }
	245	\| FORMAT startsub block
	246	{ newFORM($2, Nullop, $3); }
8d063cd8	247	;
8d063cd8	248
4633a7c4	249	subrout : SUB startsub WORD proto block
	250	{ newSUB($2, $3, $4, $5); }
	251	\| SUB startsub WORD proto ';'
	252	{ newSUB($2, $3, $4, Nullop); expect = XSTATE; }
a0d0e21e	253	;
a0d0e21e	254
4633a7c4	255	proto : /* NULL */
	256	{ $$ = Nullop; }
	257	\| THING
	258	;
	259
a0d0e21e	260	startsub: /* NULL / / start a subroutine scope */
a0d0e21e	261	{ $$ = start_subparse(); }
8d063cd8	262	;
8d063cd8	263
a687059c	264	package : PACKAGE WORD ';'
79072805	265	{ package($2); }
93a17b20	266	\| PACKAGE ';'
93a17b20	267	{ package(Nullop); }
a687059c	268	;
a687059c	269
a0d0e21e	270	use : USE WORD listexpr ';'
a0d0e21e	271	{ utilize($1, $2, $3); }
85e6fe83	272	;
85e6fe83	273
a0d0e21e	274	expr : expr ANDOP expr
	275	{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
	276	\| expr OROP expr
	277	{ $$ = newLOGOP($2, 0, $1, $3); }
	278	\| NOTOP expr
	279	{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
	280	\| argexpr
	281	;
	282
	283	argexpr : argexpr ','
	284	{ $$ = $1; }
	285	\| argexpr ',' term
79072805	286	{ $$ = append_elem(OP_LIST, $1, $3); }
a0d0e21e	287	\| term
8d063cd8	288	;
8d063cd8	289
a0d0e21e	290	listop : LSTOP indirob argexpr
79072805	291	{ $$ = convert($1, OPf_STACKED,
a0d0e21e	292	prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
a0d0e21e	293	\| FUNC '(' indirob expr ')'
79072805	294	{ $$ = convert($1, OPf_STACKED,
a0d0e21e	295	prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
a0d0e21e	296	\| term ARROW method '(' listexprcom ')'
4633a7c4	297	{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
a0d0e21e	298	append_elem(OP_LIST,
4633a7c4	299	prepend_elem(OP_LIST, $1, $5),
a0d0e21e	300	newUNOP(OP_METHOD, 0, $3))); }
79072805	301	\| METHOD indirob listexpr
4633a7c4	302	{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
a0d0e21e	303	append_elem(OP_LIST,
4633a7c4	304	prepend_elem(OP_LIST, $2, $3),
a0d0e21e	305	newUNOP(OP_METHOD, 0, $1))); }
a0d0e21e	306	\| FUNCMETH indirob '(' listexprcom ')'
4633a7c4	307	{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
a0d0e21e	308	append_elem(OP_LIST,
4633a7c4	309	prepend_elem(OP_LIST, $2, $4),
a0d0e21e	310	newUNOP(OP_METHOD, 0, $1))); }
79072805	311	\| LSTOP listexpr
79072805	312	{ $$ = convert($1, 0, $2); }
a0d0e21e	313	\| FUNC '(' listexprcom ')'
79072805	314	{ $$ = convert($1, 0, $3); }
4633a7c4	315	\| LSTOPSUB startsub block listexpr %prec LSTOP
	316	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
	317	append_elem(OP_LIST,
	318	prepend_elem(OP_LIST, newANONSUB($2, 0, $3), $4),
	319	$1)); }
a687059c	320	;
a687059c	321
a0d0e21e	322	method : METHOD
	323	\| scalar
	324	;
	325
	326	term : term ASSIGNOP term
	327	{ $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
	328	\| term POWOP term
79072805	329	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	330	\| term MULOP term
79072805	331	{ if ($2 != OP_REPEAT)
	332	scalar($1);
	333	$$ = newBINOP($2, 0, $1, scalar($3)); }
a0d0e21e	334	\| term ADDOP term
79072805	335	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	336	\| term SHIFTOP term
79072805	337	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	338	\| term RELOP term
79072805	339	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	340	\| term EQOP term
79072805	341	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	342	\| term BITANDOP term
79072805	343	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	344	\| term BITOROP term
79072805	345	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	346	\| term DOTDOT term
79072805	347	{ $$ = newRANGE($2, scalar($1), scalar($3));}
a0d0e21e	348	\| term ANDAND term
463ee0b2	349	{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
a0d0e21e	350	\| term OROR term
463ee0b2	351	{ $$ = newLOGOP(OP_OR, 0, $1, $3); }
a0d0e21e	352	\| term '?' term ':' term
79072805	353	{ $$ = newCONDOP(0, $1, $3, $5); }
a0d0e21e	354	\| term MATCHOP term
79072805	355	{ $$ = bind_match($2, $1, $3); }
8d063cd8	356
a0d0e21e	357	\| '-' term %prec UMINUS
79072805	358	{ $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
a687059c	359	\| '+' term %prec UMINUS
a687059c	360	{ $$ = $2; }
8d063cd8	361	\| '!' term
79072805	362	{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
8d063cd8	363	\| '~' term
79072805	364	{ $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
79072805	365	\| REFGEN term
a0d0e21e	366	{ $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
79072805	367	\| term POSTINC
79072805	368	{ $$ = newUNOP(OP_POSTINC, 0,
463ee0b2	369	mod(scalar($1), OP_POSTINC)); }
79072805	370	\| term POSTDEC
79072805	371	{ $$ = newUNOP(OP_POSTDEC, 0,
463ee0b2	372	mod(scalar($1), OP_POSTDEC)); }
79072805	373	\| PREINC term
79072805	374	{ $$ = newUNOP(OP_PREINC, 0,
463ee0b2	375	mod(scalar($2), OP_PREINC)); }
79072805	376	\| PREDEC term
79072805	377	{ $$ = newUNOP(OP_PREDEC, 0,
463ee0b2	378	mod(scalar($2), OP_PREDEC)); }
a0d0e21e	379	\| LOCAL term %prec UNIOP
93a17b20	380	{ $$ = localize($2,$1); }
a0d0e21e	381	\| '(' expr ')'
79072805	382	{ $$ = sawparens($2); }
8d063cd8	383	\| '(' ')'
8990e307	384	{ $$ = sawparens(newNULLLIST()); }
a0d0e21e	385	\| '[' expr ']' %prec '('
79072805	386	{ $$ = newANONLIST($2); }
	387	\| '[' ']' %prec '('
	388	{ $$ = newANONLIST(Nullop); }
a0d0e21e	389	\| HASHBRACK expr ';' '}' %prec '('
79072805	390	{ $$ = newANONHASH($2); }
	391	\| HASHBRACK ';' '}' %prec '('
	392	{ $$ = newANONHASH(Nullop); }
4633a7c4	393	\| ANONSUB startsub proto block %prec '('
4633a7c4	394	{ $$ = newANONSUB($2, $3, $4); }
79072805	395	\| scalar %prec '('
8d063cd8	396	{ $$ = $1; }
79072805	397	\| star %prec '('
8d063cd8	398	{ $$ = $1; }
79072805	399	\| scalar '[' expr ']' %prec '('
	400	{ $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
	401	\| term ARROW '[' expr ']' %prec '('
	402	{ $$ = newBINOP(OP_AELEM, 0,
8990e307	403	ref(newAVREF($1),OP_RV2AV),
79072805	404	scalar($4));}
463ee0b2	405	\| term '[' expr ']' %prec '('
a0d0e21e	406	{ assertref($1); $$ = newBINOP(OP_AELEM, 0,
8990e307	407	ref(newAVREF($1),OP_RV2AV),
463ee0b2	408	scalar($3));}
79072805	409	\| hsh %prec '('
8d063cd8	410	{ $$ = $1; }
79072805	411	\| ary %prec '('
8d063cd8	412	{ $$ = $1; }
79072805	413	\| arylen %prec '('
	414	{ $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
	415	\| scalar '{' expr ';' '}' %prec '('
	416	{ $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
	417	expect = XOPERATOR; }
	418	\| term ARROW '{' expr ';' '}' %prec '('
	419	{ $$ = newBINOP(OP_HELEM, 0,
8990e307	420	ref(newHVREF($1),OP_RV2HV),
79072805	421	jmaybe($4));
79072805	422	expect = XOPERATOR; }
463ee0b2	423	\| term '{' expr ';' '}' %prec '('
a0d0e21e	424	{ assertref($1); $$ = newBINOP(OP_HELEM, 0,
8990e307	425	ref(newHVREF($1),OP_RV2HV),
463ee0b2	426	jmaybe($3));
463ee0b2	427	expect = XOPERATOR; }
a0d0e21e	428	\| '(' expr ')' '[' expr ']' %prec '('
79072805	429	{ $$ = newSLICEOP(0, $5, $2); }
	430	\| '(' ')' '[' expr ']' %prec '('
	431	{ $$ = newSLICEOP(0, $4, Nullop); }
	432	\| ary '[' expr ']' %prec '('
	433	{ $$ = prepend_elem(OP_ASLICE,
	434	newOP(OP_PUSHMARK, 0),
79072805	435	newLISTOP(OP_ASLICE, 0,
79072805	436	list($3),
a0d0e21e	437	ref($1, OP_ASLICE))); }
79072805	438	\| ary '{' expr ';' '}' %prec '('
	439	{ $$ = prepend_elem(OP_HSLICE,
	440	newOP(OP_PUSHMARK, 0),
79072805	441	newLISTOP(OP_HSLICE, 0,
79072805	442	list($3),
a0d0e21e	443	ref(oopsHV($1), OP_HSLICE)));
79072805	444	expect = XOPERATOR; }
	445	\| THING %prec '('
	446	{ $$ = $1; }
	447	\| amper
a0d0e21e	448	{ $$ = newUNOP(OP_ENTERSUB, 0,
79072805	449	scalar($1)); }
79072805	450	\| amper '(' ')'
a0d0e21e	451	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
	452	\| amper '(' expr ')'
	453	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
4633a7c4	454	append_elem(OP_LIST, $3, scalar($1))); }
93a17b20	455	\| NOAMP WORD listexpr
a0d0e21e	456	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
4633a7c4	457	append_elem(OP_LIST,
4633a7c4	458	$3, newCVREF(scalar($2)))); }
a0d0e21e	459	\| DO term %prec UNIOP
463ee0b2	460	{ $$ = newUNOP(OP_DOFILE, 0, scalar($2)); }
79072805	461	\| DO block %prec '('
79072805	462	{ $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
8d063cd8	463	\| DO WORD '(' ')'
a0d0e21e	464	{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL\|OPf_STACKED,
4633a7c4	465	prepend_elem(OP_LIST,
4633a7c4	466	scalar(newCVREF(scalar($2))), Nullop)); dep();}
a0d0e21e	467	\| DO WORD '(' expr ')'
a0d0e21e	468	{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL\|OPf_STACKED,
4633a7c4	469	append_elem(OP_LIST,
a0d0e21e	470	$4,
4633a7c4	471	scalar(newCVREF(scalar($2))))); dep();}
79072805	472	\| DO scalar '(' ')'
a0d0e21e	473	{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL\|OPf_STACKED,
4633a7c4	474	prepend_elem(OP_LIST,
4633a7c4	475	scalar(newCVREF(scalar($2))), Nullop)); dep();}
a0d0e21e	476	\| DO scalar '(' expr ')'
a0d0e21e	477	{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL\|OPf_STACKED,
4633a7c4	478	prepend_elem(OP_LIST,
a0d0e21e	479	$4,
4633a7c4	480	scalar(newCVREF(scalar($2))))); dep();}
8d063cd8	481	\| LOOPEX
85e6fe83	482	{ $$ = newOP($1, OPf_SPECIAL);
85e6fe83	483	hints \|= HINT_BLOCK_SCOPE; }
a0d0e21e	484	\| LOOPEX term
8990e307	485	{ $$ = newLOOPEX($1,$2); }
8d063cd8	486	\| UNIOP
79072805	487	{ $$ = newOP($1, 0); }
f0fcb552	488	\| UNIOP block
79072805	489	{ $$ = newUNOP($1, 0, $2); }
a0d0e21e	490	\| UNIOP term
79072805	491	{ $$ = newUNOP($1, 0, $2); }
4633a7c4	492	\| UNIOPSUB term
	493	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
	494	append_elem(OP_LIST, $2, scalar($1))); }
8d063cd8	495	\| FUNC0
79072805	496	{ $$ = newOP($1, 0); }
ae986130	497	\| FUNC0 '(' ')'
79072805	498	{ $$ = newOP($1, 0); }
4633a7c4	499	\| FUNC0SUB
	500	{ $$ = newUNOP(OP_ENTERSUB, 0,
	501	scalar($1)); }
03a14243	502	\| FUNC1 '(' ')'
79072805	503	{ $$ = newOP($1, OPf_SPECIAL); }
8d063cd8	504	\| FUNC1 '(' expr ')'
79072805	505	{ $$ = newUNOP($1, 0, $3); }
a0d0e21e	506	\| PMFUNC '(' term ')'
79072805	507	{ $$ = pmruntime($1, $3, Nullop); }
a0d0e21e	508	\| PMFUNC '(' term ',' term ')'
79072805	509	{ $$ = pmruntime($1, $3, $5); }
79072805	510	\| WORD
378cc40b	511	\| listop
8d063cd8	512	;
8d063cd8	513
79072805	514	listexpr: /* NULL */
8990e307	515	{ $$ = Nullop; }
a0d0e21e	516	\| argexpr
	517	{ $$ = $1; }
	518	;
	519
	520	listexprcom: /* NULL */
	521	{ $$ = Nullop; }
79072805	522	\| expr
79072805	523	{ $$ = $1; }
a0d0e21e	524	\| expr ','
a0d0e21e	525	{ $$ = $1; }
79072805	526	;
	527
	528	amper : '&' indirob
	529	{ $$ = newCVREF($2); }
a687059c	530	;
a687059c	531
79072805	532	scalar : '$' indirob
79072805	533	{ $$ = newSVREF($2); }
a687059c	534	;
a687059c	535
79072805	536	ary : '@' indirob
	537	{ $$ = newAVREF($2); }
	538	;
	539
	540	hsh : '%' indirob
	541	{ $$ = newHVREF($2); }
	542	;
	543
	544	arylen : DOLSHARP indirob
	545	{ $$ = newAVREF($2); }
	546	;
	547
	548	star : '*' indirob
a0d0e21e	549	{ $$ = newGVREF(0,$2); }
79072805	550	;
	551
	552	indirob : WORD
	553	{ $$ = scalar($1); }
	554	\| scalar
463ee0b2	555	{ $$ = scalar($1); }
79072805	556	\| block
a0d0e21e	557	{ $$ = scope($1); }
79072805	558
93a17b20	559	\| PRIVATEREF
93a17b20	560	{ $$ = $1; }
8d063cd8	561	;
	562
	563	%% /* PROGRAM */