[p5sagit/p5-mst-13.2.git] / make_ext.pl

#!./miniperl
use strict;
use warnings;
use Config;
use Cwd;

# This script acts as a simple interface for building extensions.

# It's actually a cut and shut of the Unix version ext/utils/makeext and the
# Windows version win32/build_ext.pl hence the two invocation styles.

# On Unix, it primarily used by the perl Makefile one extention at a time:
#
# d_dummy $(dynamic_ext): miniperl preplibrary FORCE
# 	@$(RUN) ./miniperl make_ext.pl --target=dynamic $@ MAKE=$(MAKE) LIBPERL_A=$(LIBPERL)
#
# On Windows or VMS,
# If '--static' is specified, static extensions will be built.
# If '--dynamic' is specified, dynamic (and nonxs) extensions will be built.
# If '--all' is specified, all extensions will be built.
#
#    make_ext.pl "MAKE=make [-make_opts]" --dir=directory [--target=target] [--static|--dynamic|--all] +ext2 !ext1
#
# E.g.
# 
#     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext
# 
#     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext --target=clean
# 
#     make_ext.pl MAKE=dmake --dir=..\ext
# 
#     make_ext.pl MAKE=dmake --dir=..\ext --target=clean
# 
# Will skip building extensions which are marked with an '!' char.
# Mostly because they still not ported to specified platform.
# 
# If any extensions are listed with a '+' char then only those
# extensions will be built, but only if they arent countermanded
# by an '!ext' and are appropriate to the type of building being done.

# It may be deleted in a later release of perl so try to
# avoid using it for other purposes.

my $is_Win32 = $^O eq 'MSWin32';
my $is_VMS = $^O eq 'VMS';
my $is_Unix = !$is_Win32 && !$is_VMS;

require FindExt if $is_Win32;

my (%excl, %incl, %opts, @extspec, @pass_through);

foreach (@ARGV) {
    if (/^!(.*)$/) {
	$excl{$1} = 1;
    } elsif (/^\+(.*)$/) {
	$incl{$1} = 1;
    } elsif (/^--([\w\-]+)$/) {
	$opts{$1} = 1;
    } elsif (/^--([\w\-]+)=(.*)$/) {
	$opts{$1} = $2;
    } elsif (/=/) {
	push @pass_through, $_;
    } elsif (length) {
	push @extspec, $_;
    }
}

my $static = $opts{static} || $opts{all};
my $dynamic = $opts{dynamic} || $opts{all};

# The Perl Makefile.SH will expand all extensions to
#	lib/auto/X/X.a  (or lib/auto/X/Y/Y.a if nested)
# A user wishing to run make_ext might use
#	X (or X/Y or X::Y if nested)

# canonise into X/Y form (pname)

foreach (@extspec) {
    if (s{^lib/auto/}{}) {
	# Remove lib/auto prefix and /*.* suffix
	s{/[^/]+\.[^/]+$}{};
    } elsif (s{^ext/}{}) {
	# Remove ext/ prefix and /pm_to_blib suffix
	s{/pm_to_blib$}{};
	# Targets are given as files on disk, but the extension spec is still
	# written using /s for each ::
	tr!-!/!;
    } elsif (s{::}{\/}g) {
	# Convert :: to /
    } else {
	s/\..*o//;
    }
}

my $makecmd  = shift @pass_through; # Should be something like MAKE=make
unshift @pass_through, 'PERL_CORE=1';

my $dir  = $opts{dir} || 'ext';
my $target   = $opts{target};
$target = 'all' unless defined $target;

# Previously, $make was taken from config.sh.  However, the user might
# instead be running a possibly incompatible make.  This might happen if
# the user types "gmake" instead of a plain "make", for example.  The
# correct current value of MAKE will come through from the main perl
# makefile as MAKE=/whatever/make in $makecmd.  We'll be cautious in
# case third party users of this script (are there any?) don't have the
# MAKE=$(MAKE) argument, which was added after 5.004_03.
unless(defined $makecmd and $makecmd =~ /^MAKE=(.*)$/) {
    die "$0:  WARNING:  Please include MAKE=\$(MAKE) in \@ARGV\n";
}

# This isn't going to cope with anything fancy, such as spaces inside command
# names, but neither did what it replaced. Once there is a use case that needs
# it, please supply patches. Until then, I'm sticking to KISS
my @make = split ' ', $1 || $Config{make} || $ENV{MAKE};
# Using an array of 0 or 1 elements makes the subsequent code simpler.
my @run = $Config{run};
@run = () if not defined $run[0] or $run[0] eq '';


if ($target eq '') {
    die "make_ext: no make target specified (eg all or clean)\n";
} elsif ($target !~ /(?:^all|clean)$/) {
    # for the time being we are strict about what make_ext is used for
    die "$0: unknown make target '$target'\n";
}

if (!@extspec and !$static and !$dynamic)  {
    die "$0: no extension specified\n";
}

my $perl;
my %extra_passthrough;

if ($is_Win32) {
    (my $here = getcwd()) =~ s{/}{\\}g;
    $perl = $^X;
    if ($perl =~ m#^\.\.#) {
	$perl = "$here\\$perl";
    }
    (my $topdir = $perl) =~ s/\\[^\\]+$//;
    # miniperl needs to find perlglob and pl2bat
    $ENV{PATH} = "$topdir;$topdir\\win32\\bin;$ENV{PATH}";
    my $pl2bat = "$topdir\\win32\\bin\\pl2bat";
    unless (-f "$pl2bat.bat") {
	my @args = ($perl, ("$pl2bat.pl") x 2);
	print "@args\n";
	system(@args) unless defined $::Cross::platform;
    }

    print "In ", getcwd();
    chdir($dir) || die "Cannot cd to $dir\n";
    (my $ext = getcwd()) =~ s{/}{\\}g;
    FindExt::scan_ext($ext);
    FindExt::set_static_extensions(split ' ', $Config{static_ext});

    my @ext;
    push @ext, FindExt::static_ext() if $static;
    push @ext, FindExt::dynamic_ext(), FindExt::nonxs_ext() if $dynamic;

    foreach (sort @ext) {
	if (%incl and !exists $incl{$_}) {
	    #warn "Skipping extension $ext\\$_, not in inclusion list\n";
	    next;
	}
	if (exists $excl{$_}) {
	    warn "Skipping extension $ext\\$_, not ported to current platform";
	    next;
	}
	push @extspec, $_;
	if(FindExt::is_static($_)) {
	    push @{$extra_passthrough{$_}}, 'LINKTYPE=static';
	}
    }
    chdir '..'; # now in the Perl build directory
}
elsif ($is_VMS) {
    $perl = $^X;
    push @extspec, (split ' ', $Config{static_ext}) if $static;
    push @extspec, (split ' ', $Config{dynamic_ext}) if $dynamic;
    push @extspec, (split ' ', $Config{nonxs_ext}) if $dynamic;
}

foreach my $spec (@extspec)  {
    my $mname = $spec;
    $mname =~ s!/!::!g;
    my $ext_pathname;
    if (-d "ext/$spec") {
	# Old style ext/Data/Dumper/
	$ext_pathname = "ext/$spec";
    } else {
	# New style ext/Data-Dumper/
	my $copy = $spec;
	$copy =~ tr!/!-!;
	$ext_pathname = "ext/$copy";
    }

    if ($Config{osname} eq 'catamount') {
	# Snowball's chance of building extensions.
	die "This is $Config{osname}, not building $mname, sorry.\n";
    }

    print "\tMaking $mname ($target)\n";

    build_extension($ext_pathname, $perl, $mname,
		    [@pass_through, @{$extra_passthrough{$spec} || []}]);
}

sub build_extension {
    my ($ext_dir, $perl, $mname, $pass_through) = @_;

    my $up = $ext_dir;
    $up =~ s![^/]+!..!g;

    $perl ||= "$up/miniperl";
    my $return_dir = $up;
    my $lib_dir = "$up/lib";
    $ENV{PERL5LIB} = $lib_dir;

    unless (chdir "$ext_dir") {
	warn "Cannot cd to $ext_dir: $!";
	return;
    }
    my $makefile;
    if ($is_VMS) {
	$makefile = 'descrip.mms';
	if ($target =~ /clean$/
	    && !-f $makefile
	    && -f "${makefile}_old") {
	    $makefile = "${makefile}_old";
	}
    } else {
	$makefile = 'Makefile';
    }
    
    if (!-f $makefile) {
	if (!-f 'Makefile.PL') {
	    print "\nCreating Makefile.PL in $ext_dir for $mname\n";
	    # We need to cope well with various possible layouts
	    my @dirs = split /::/, $mname;
	    my $leaf = pop @dirs;
	    my $leafname = "$leaf.pm";
	    my $pathname = join '/', @dirs, $leafname;
	    my @locations = ($leafname, $pathname, "lib/$pathname");
	    my $fromname;
	    foreach (@locations) {
		if (-f $_) {
		    $fromname = $_;
		    last;
		}
	    }

	    unless ($fromname) {
		die "For $mname tried @locations in in $ext_dir but can't find source";
	    }
	    open my $fh, '>', 'Makefile.PL'
		or die "Can't open Makefile.PL for writing: $!";
	    print $fh <<"EOM";
#-*- buffer-read-only: t -*-

# This Makefile.PL was written by $0.
# It will be deleted automatically by make realclean

use strict;
use ExtUtils::MakeMaker;

WriteMakefile(
    NAME          => '$mname',
    VERSION_FROM  => '$fromname',
    ABSTRACT_FROM => '$fromname',
    realclean     => {FILES => 'Makefile.PL'},
);

# ex: set ro:
EOM
	    close $fh or die "Can't close Makefile.PL: $!";
	}
	print "\nRunning Makefile.PL in $ext_dir\n";

	# Presumably this can be simplified
	my @cross;
	if (defined $::Cross::platform) {
	    # Inherited from win32/buildext.pl
	    @cross = "-MCross=$::Cross::platform";
	} elsif ($opts{cross}) {
	    # Inherited from make_ext.pl
	    @cross = '-MCross';
	}
	    
	my @args = (@cross, 'Makefile.PL');
	if ($is_VMS) {
	    my $libd = VMS::Filespec::vmspath($lib_dir);
	    push @args, "INST_LIB=$libd", "INST_ARCHLIB=$libd";
	} else {
	    push @args, 'INSTALLDIRS=perl', 'INSTALLMAN1DIR=none',
		'INSTALLMAN3DIR=none';
	}
	push @args, @$pass_through;
	_quote_args(\@args) if $is_VMS;
	print join(' ', @run, $perl, @args), "\n";
	my $code = system @run, $perl, @args;
	warn "$code from $ext_dir\'s Makefile.PL" if $code;

	# Right. The reason for this little hack is that we're sitting inside
	# a program run by ./miniperl, but there are tasks we need to perform
	# when the 'realclean', 'distclean' or 'veryclean' targets are run.
	# Unfortunately, they can be run *after* 'clean', which deletes
	# ./miniperl
	# So we do our best to leave a set of instructions identical to what
	# we would do if we are run directly as 'realclean' etc
	# Whilst we're perfect, unfortunately the targets we call are not, as
	# some of them rely on a $(PERL) for their own distclean targets.
	# But this always used to be a problem with the old /bin/sh version of
	# this.
	if ($is_Unix) {
	    my $suffix = '.sh';
	    foreach my $clean_target ('realclean', 'veryclean') {
		my $file = "$return_dir/$clean_target$suffix";
		open my $fh, '>>', $file or die "open $file: $!";
		# Quite possible that we're being run in parallel here.
		# Can't use Fcntl this early to get the LOCK_EX
		flock $fh, 2 or warn "flock $file: $!";
		print $fh <<"EOS";
cd $ext_dir
if test ! -f Makefile -a -f Makefile.old; then
    echo "Note: Using Makefile.old"
    make -f Makefile.old $clean_target MAKE='@make' @pass_through
else
    if test ! -f Makefile ; then
	echo "Warning: No Makefile!"
    fi
    make $clean_target MAKE='@make' @pass_through
fi
cd $return_dir
EOS
		close $fh or die "close $file: $!";
	    }
	}
    }

    if (not -f $makefile) {
	print "Warning: No Makefile!\n";
    }

    if ($is_VMS) {
	_macroify_passthrough($pass_through);
	unshift @$pass_through, "/DESCRIPTION=$makefile";
    }

    if (!$target or $target !~ /clean$/) {
	# Give makefile an opportunity to rewrite itself.
	# reassure users that life goes on...
	my @args = ('config', @$pass_through);
	_quote_args(\@args) if $is_VMS;
	system(@run, @make, @args) and print "@run @make @args failed, continuing anyway...\n";
    }
    my @targ = ($target, @$pass_through);
    _quote_args(\@targ) if $is_VMS;
    print "Making $target in $ext_dir\n@run @make @targ\n";
    my $code = system(@run, @make, @targ);
    die "Unsuccessful make($ext_dir): code=$code" if $code != 0;

    chdir $return_dir || die "Cannot cd to $return_dir: $!";
}

sub _quote_args {
    my $args = shift; # must be array reference

    # Do not quote qualifiers that begin with '/'.
    map { if (!/^\//) {
          $_ =~ s/\"/""/g;     # escape C<"> by doubling
          $_ = q(").$_.q(");
        }
    } @{$args}
    ;
}

sub _macroify_passthrough {
    my $passthrough = shift;
    _quote_args($passthrough);
    my $macro = '/MACRO=(' . join(',',@$passthrough) . ')';
    @$passthrough = ();
    @$passthrough[0] = $macro;  
}
Commit	Line	Data
61edc683	1	#!./miniperl
a2f19a19	2	use strict;
a2f19a19	3	use warnings;
b8d39eba	4	use Config;
286d62c2	5	use Cwd;
75f92628	6
a0d0e21e	7	# This script acts as a simple interface for building extensions.
286d62c2	8
	9	# It's actually a cut and shut of the Unix version ext/utils/makeext and the
	10	# Windows version win32/build_ext.pl hence the two invocation styles.
	11
	12	# On Unix, it primarily used by the perl Makefile one extention at a time:
a0d0e21e	13	#
a0d0e21e	14	# d_dummy $(dynamic_ext): miniperl preplibrary FORCE
e2fabae1	15	# @$(RUN) ./miniperl make_ext.pl --target=dynamic $@ MAKE=$(MAKE) LIBPERL_A=$(LIBPERL)
a0d0e21e	16	#
902aaf3e	17	# On Windows or VMS,
286d62c2	18	# If '--static' is specified, static extensions will be built.
	19	# If '--dynamic' is specified, dynamic (and nonxs) extensions will be built.
	20	# If '--all' is specified, all extensions will be built.
	21	#
	22	# make_ext.pl "MAKE=make [-make_opts]" --dir=directory [--target=target] [--static\|--dynamic\|--all] +ext2 !ext1
	23	#
	24	# E.g.
	25	#
	26	# make_ext.pl "MAKE=nmake -nologo" --dir=..\ext
	27	#
	28	# make_ext.pl "MAKE=nmake -nologo" --dir=..\ext --target=clean
	29	#
	30	# make_ext.pl MAKE=dmake --dir=..\ext
	31	#
	32	# make_ext.pl MAKE=dmake --dir=..\ext --target=clean
	33	#
	34	# Will skip building extensions which are marked with an '!' char.
	35	# Mostly because they still not ported to specified platform.
	36	#
	37	# If any extensions are listed with a '+' char then only those
	38	# extensions will be built, but only if they arent countermanded
	39	# by an '!ext' and are appropriate to the type of building being done.
	40
a0d0e21e	41	# It may be deleted in a later release of perl so try to
	42	# avoid using it for other purposes.
	43
e3b84025	44	my $is_Win32 = $^O eq 'MSWin32';
	45	my $is_VMS = $^O eq 'VMS';
	46	my $is_Unix = !$is_Win32 && !$is_VMS;
	47
286d62c2	48	require FindExt if $is_Win32;
286d62c2	49
fc678412	50	my (%excl, %incl, %opts, @extspec, @pass_through);
97a26ad9	51
	52	foreach (@ARGV) {
	53	if (/^!(.*)$/) {
	54	$excl{$1} = 1;
	55	} elsif (/^\+(.*)$/) {
	56	$incl{$1} = 1;
	57	} elsif (/^--([\w\-]+)$/) {
	58	$opts{$1} = 1;
e2fabae1	59	} elsif (/^--([\w\-]+)=(.*)$/) {
e2fabae1	60	$opts{$1} = $2;
e2fabae1	61	} elsif (/=/) {
fc678412	62	push @pass_through, $_;
ca5de986	63	} elsif (length) {
e2fabae1	64	push @extspec, $_;
97a26ad9	65	}
	66	}
	67
286d62c2	68	my $static = $opts{static} \|\| $opts{all};
	69	my $dynamic = $opts{dynamic} \|\| $opts{all};
	70
ca5de986	71	# The Perl Makefile.SH will expand all extensions to
	72	# lib/auto/X/X.a (or lib/auto/X/Y/Y.a if nested)
	73	# A user wishing to run make_ext might use
	74	# X (or X/Y or X::Y if nested)
	75
	76	# canonise into X/Y form (pname)
	77
	78	foreach (@extspec) {
7ad017a8	79	if (s{^lib/auto/}{}) {
ca5de986	80	# Remove lib/auto prefix and /. suffix
c5aac6ab	81	s{/[^/]+\.[^/]+$}{};
7ad017a8	82	} elsif (s{^ext/}{}) {
ca5de986	83	# Remove ext/ prefix and /pm_to_blib suffix
ca5de986	84	s{/pm_to_blib$}{};
57df1c46	85	# Targets are given as files on disk, but the extension spec is still
	86	# written using /s for each ::
	87	tr!-!/!;
7ad017a8	88	} elsif (s{::}{\/}g) {
ca5de986	89	# Convert :: to /
7ad017a8	90	} else {
ca5de986	91	s/\..*o//;
	92	}
	93	}
	94
fc678412	95	my $makecmd = shift @pass_through; # Should be something like MAKE=make
	96	unshift @pass_through, 'PERL_CORE=1';
	97
286d62c2	98	my $dir = $opts{dir} \|\| 'ext';
e2fabae1	99	my $target = $opts{target};
07f3cc2a	100	$target = 'all' unless defined $target;
a0d0e21e	101
fb73857a	102	# Previously, $make was taken from config.sh. However, the user might
	103	# instead be running a possibly incompatible make. This might happen if
	104	# the user types "gmake" instead of a plain "make", for example. The
	105	# correct current value of MAKE will come through from the main perl
	106	# makefile as MAKE=/whatever/make in $makecmd. We'll be cautious in
	107	# case third party users of this script (are there any?) don't have the
	108	# MAKE=$(MAKE) argument, which was added after 5.004_03.
ca5de986	109	unless(defined $makecmd and $makecmd =~ /^MAKE=(.*)$/) {
ca5de986	110	die "$0: WARNING: Please include MAKE=\$(MAKE) in \@ARGV\n";
a2f19a19	111	}
a2f19a19	112
eb1f8df7	113	# This isn't going to cope with anything fancy, such as spaces inside command
	114	# names, but neither did what it replaced. Once there is a use case that needs
	115	# it, please supply patches. Until then, I'm sticking to KISS
	116	my @make = split ' ', $1 \|\| $Config{make} \|\| $ENV{MAKE};
ca5de986	117	# Using an array of 0 or 1 elements makes the subsequent code simpler.
fc678412	118	my @run = $Config{run};
fc678412	119	@run = () if not defined $run[0] or $run[0] eq '';
a2f19a19	120
a0d0e21e	121
07f3cc2a	122	if ($target eq '') {
ca5de986	123	die "make_ext: no make target specified (eg all or clean)\n";
	124	} elsif ($target !~ /(?:^all\|clean)$/) {
	125	# for the time being we are strict about what make_ext is used for
	126	die "$0: unknown make target '$target'\n";
a2f19a19	127	}
a2f19a19	128
286d62c2	129	if (!@extspec and !$static and !$dynamic) {
	130	die "$0: no extension specified\n";
	131	}
	132
	133	my $perl;
	134	my %extra_passthrough;
	135
	136	if ($is_Win32) {
	137	(my $here = getcwd()) =~ s{/}{\\}g;
	138	$perl = $^X;
	139	if ($perl =~ m#^\.\.#) {
	140	$perl = "$here\\$perl";
	141	}
	142	(my $topdir = $perl) =~ s/\\[^\\]+$//;
	143	# miniperl needs to find perlglob and pl2bat
	144	$ENV{PATH} = "$topdir;$topdir\\win32\\bin;$ENV{PATH}";
	145	my $pl2bat = "$topdir\\win32\\bin\\pl2bat";
	146	unless (-f "$pl2bat.bat") {
	147	my @args = ($perl, ("$pl2bat.pl") x 2);
	148	print "@args\n";
	149	system(@args) unless defined $::Cross::platform;
	150	}
	151
	152	print "In ", getcwd();
	153	chdir($dir) \|\| die "Cannot cd to $dir\n";
	154	(my $ext = getcwd()) =~ s{/}{\\}g;
	155	FindExt::scan_ext($ext);
	156	FindExt::set_static_extensions(split ' ', $Config{static_ext});
	157
	158	my @ext;
	159	push @ext, FindExt::static_ext() if $static;
	160	push @ext, FindExt::dynamic_ext(), FindExt::nonxs_ext() if $dynamic;
	161
	162	foreach (sort @ext) {
	163	if (%incl and !exists $incl{$_}) {
	164	#warn "Skipping extension $ext\\$_, not in inclusion list\n";
	165	next;
	166	}
	167	if (exists $excl{$_}) {
	168	warn "Skipping extension $ext\\$_, not ported to current platform";
	169	next;
	170	}
	171	push @extspec, $_;
	172	if(FindExt::is_static($_)) {
	173	push @{$extra_passthrough{$_}}, 'LINKTYPE=static';
	174	}
	175	}
	176	chdir '..'; # now in the Perl build directory
	177	}
902aaf3e	178	elsif ($is_VMS) {
	179	$perl = $^X;
	180	push @extspec, (split ' ', $Config{static_ext}) if $static;
	181	push @extspec, (split ' ', $Config{dynamic_ext}) if $dynamic;
d1ce36d7	182	push @extspec, (split ' ', $Config{nonxs_ext}) if $dynamic;
902aaf3e	183	}
286d62c2	184
e08c66ce	185	foreach my $spec (@extspec) {
e08c66ce	186	my $mname = $spec;
ca5de986	187	$mname =~ s!/!::!g;
238a6851	188	my $ext_pathname;
	189	if (-d "ext/$spec") {
	190	# Old style ext/Data/Dumper/
	191	$ext_pathname = "ext/$spec";
	192	} else {
	193	# New style ext/Data-Dumper/
	194	my $copy = $spec;
	195	$copy =~ tr!/!-!;
	196	$ext_pathname = "ext/$copy";
	197	}
a2f19a19	198
ca5de986	199	if ($Config{osname} eq 'catamount') {
a2f19a19	200	# Snowball's chance of building extensions.
ca5de986	201	die "This is $Config{osname}, not building $mname, sorry.\n";
ca5de986	202	}
a2f19a19	203
ca5de986	204	print "\tMaking $mname ($target)\n";
a2f19a19	205
acb65a20	206	build_extension($ext_pathname, $perl, $mname,
e08c66ce	207	[@pass_through, @{$extra_passthrough{$spec} \|\| []}]);
ca5de986	208	}
a0d0e21e	209
fc678412	210	sub build_extension {
acb65a20	211	my ($ext_dir, $perl, $mname, $pass_through) = @_;
	212
	213	my $up = $ext_dir;
	214	$up =~ s![^/]+!..!g;
	215
	216	$perl \|\|= "$up/miniperl";
	217	my $return_dir = $up;
	218	my $lib_dir = "$up/lib";
73402eba	219	$ENV{PERL5LIB} = $lib_dir;
acb65a20	220
fc678412	221	unless (chdir "$ext_dir") {
	222	warn "Cannot cd to $ext_dir: $!";
	223	return;
	224	}
902aaf3e	225	my $makefile;
	226	if ($is_VMS) {
	227	$makefile = 'descrip.mms';
	228	if ($target =~ /clean$/
	229	&& !-f $makefile
	230	&& -f "${makefile}_old") {
	231	$makefile = "${makefile}_old";
	232	}
	233	} else {
	234	$makefile = 'Makefile';
	235	}
fc678412	236
902aaf3e	237	if (!-f $makefile) {
e74f76b2	238	if (!-f 'Makefile.PL') {
	239	print "\nCreating Makefile.PL in $ext_dir for $mname\n";
	240	# We need to cope well with various possible layouts
	241	my @dirs = split /::/, $mname;
	242	my $leaf = pop @dirs;
	243	my $leafname = "$leaf.pm";
	244	my $pathname = join '/', @dirs, $leafname;
	245	my @locations = ($leafname, $pathname, "lib/$pathname");
	246	my $fromname;
	247	foreach (@locations) {
	248	if (-f $_) {
	249	$fromname = $_;
	250	last;
	251	}
	252	}
	253
	254	unless ($fromname) {
	255	die "For $mname tried @locations in in $ext_dir but can't find source";
	256	}
	257	open my $fh, '>', 'Makefile.PL'
	258	or die "Can't open Makefile.PL for writing: $!";
	259	print $fh <<"EOM";
	260	#-- buffer-read-only: t --
	261
	262	# This Makefile.PL was written by $0.
	263	# It will be deleted automatically by make realclean
	264
	265	use strict;
	266	use ExtUtils::MakeMaker;
	267
	268	WriteMakefile(
	269	NAME => '$mname',
	270	VERSION_FROM => '$fromname',
	271	ABSTRACT_FROM => '$fromname',
	272	realclean => {FILES => 'Makefile.PL'},
	273	);
	274
	275	# ex: set ro:
	276	EOM
	277	close $fh or die "Can't close Makefile.PL: $!";
	278	}
fc678412	279	print "\nRunning Makefile.PL in $ext_dir\n";
	280
	281	# Presumably this can be simplified
	282	my @cross;
	283	if (defined $::Cross::platform) {
	284	# Inherited from win32/buildext.pl
	285	@cross = "-MCross=$::Cross::platform";
	286	} elsif ($opts{cross}) {
	287	# Inherited from make_ext.pl
	288	@cross = '-MCross';
a2f19a19	289	}
fc678412	290
73402eba	291	my @args = (@cross, 'Makefile.PL');
902aaf3e	292	if ($is_VMS) {
	293	my $libd = VMS::Filespec::vmspath($lib_dir);
	294	push @args, "INST_LIB=$libd", "INST_ARCHLIB=$libd";
	295	} else {
a2b175af	296	push @args, 'INSTALLDIRS=perl', 'INSTALLMAN1DIR=none',
a2b175af	297	'INSTALLMAN3DIR=none';
902aaf3e	298	}
	299	push @args, @$pass_through;
	300	_quote_args(\@args) if $is_VMS;
	301	print join(' ', @run, $perl, @args), "\n";
	302	my $code = system @run, $perl, @args;
fc678412	303	warn "$code from $ext_dir\'s Makefile.PL" if $code;
fc678412	304
61edc683	305	# Right. The reason for this little hack is that we're sitting inside
	306	# a program run by ./miniperl, but there are tasks we need to perform
	307	# when the 'realclean', 'distclean' or 'veryclean' targets are run.
	308	# Unfortunately, they can be run after 'clean', which deletes
	309	# ./miniperl
	310	# So we do our best to leave a set of instructions identical to what
	311	# we would do if we are run directly as 'realclean' etc
	312	# Whilst we're perfect, unfortunately the targets we call are not, as
	313	# some of them rely on a $(PERL) for their own distclean targets.
	314	# But this always used to be a problem with the old /bin/sh version of
	315	# this.
e3b84025	316	if ($is_Unix) {
fc678412	317	my $suffix = '.sh';
fc678412	318	foreach my $clean_target ('realclean', 'veryclean') {
ca5de986	319	my $file = "$return_dir/$clean_target$suffix";
fc678412	320	open my $fh, '>>', $file or die "open $file: $!";
	321	# Quite possible that we're being run in parallel here.
	322	# Can't use Fcntl this early to get the LOCK_EX
	323	flock $fh, 2 or warn "flock $file: $!";
	324	print $fh <<"EOS";
	325	cd $ext_dir
	326	if test ! -f Makefile -a -f Makefile.old; then
61edc683	327	echo "Note: Using Makefile.old"
eb1f8df7	328	make -f Makefile.old $clean_target MAKE='@make' @pass_through
61edc683	329	else
fc678412	330	if test ! -f Makefile ; then
61edc683	331	echo "Warning: No Makefile!"
61edc683	332	fi
eb1f8df7	333	make $clean_target MAKE='@make' @pass_through
61edc683	334	fi
fc678412	335	cd $return_dir
61edc683	336	EOS
fc678412	337	close $fh or die "close $file: $!";
fc678412	338	}
61edc683	339	}
fc678412	340	}
a2f19a19	341
902aaf3e	342	if (not -f $makefile) {
a2f19a19	343	print "Warning: No Makefile!\n";
fc678412	344	}
a2f19a19	345
902aaf3e	346	if ($is_VMS) {
	347	_macroify_passthrough($pass_through);
	348	unshift @$pass_through, "/DESCRIPTION=$makefile";
	349	}
	350
fc678412	351	if (!$target or $target !~ /clean$/) {
a2f19a19	352	# Give makefile an opportunity to rewrite itself.
75f92628	353	# reassure users that life goes on...
902aaf3e	354	my @args = ('config', @$pass_through);
	355	_quote_args(\@args) if $is_VMS;
	356	system(@run, @make, @args) and print "@run @make @args failed, continuing anyway...\n";
fc678412	357	}
902aaf3e	358	my @targ = ($target, @$pass_through);
	359	_quote_args(\@targ) if $is_VMS;
	360	print "Making $target in $ext_dir\n@run @make @targ\n";
	361	my $code = system(@run, @make, @targ);
fc678412	362	die "Unsuccessful make($ext_dir): code=$code" if $code != 0;
a2f19a19	363
fc678412	364	chdir $return_dir \|\| die "Cannot cd to $return_dir: $!";
fc678412	365	}
902aaf3e	366
	367	sub _quote_args {
	368	my $args = shift; # must be array reference
	369
	370	# Do not quote qualifiers that begin with '/'.
	371	map { if (!/^\//) {
	372	$_ =~ s/\"/""/g; # escape C<"> by doubling
	373	$_ = q(").$_.q(");
	374	}
	375	} @{$args}
	376	;
	377	}
	378
	379	sub _macroify_passthrough {
	380	my $passthrough = shift;
	381	_quote_args($passthrough);
	382	my $macro = '/MACRO=(' . join(',',@$passthrough) . ')';
	383	@$passthrough = ();
	384	@$passthrough[0] = $macro;
	385	}