[p5sagit/p5-mst-13.2.git] / lib / utf8_heavy.pl

package utf8;
use strict;
use warnings;

sub DEBUG () { 0 }

sub DESTROY {}

my %Cache;

our (%PropertyAlias, %PA_reverse, %PropValueAlias, %PVA_reverse, %PVA_abbr_map);

sub croak { require Carp; Carp::croak(@_) }

##
## "SWASH" == "SWATCH HASH". A "swatch" is a swatch of the Unicode landscape.
## It's a data structure that encodes a set of Unicode characters.
##

sub SWASHNEW {
    my ($class, $type, $list, $minbits, $none) = @_;
    local $^D = 0 if $^D;

    print STDERR "SWASHNEW @_\n" if DEBUG;

    ##
    ## Get the list of codepoints for the type.
    ## Called from swash_init (see utf8.c) or SWASHNEW itself.
    ##
    ## Callers of swash_init:
    ##     op.c:pmtrans             -- for tr/// and y///
    ##     regexec.c:regclass_swash -- for /[]/, \p, and \P
    ##     utf8.c:is_utf8_common    -- for common Unicode properties
    ##     utf8.c:to_utf8_case      -- for lc, uc, ucfirst, etc. and //i
    ##
    ## Given a $type, our goal is to fill $list with the set of codepoint
    ## ranges. If $type is false, $list passed is used.
    ##
    ## $minbits:
    ##     For binary properties, $minbits must be 1.
    ##     For character mappings (case and transliteration), $minbits must
    ##     be a number except 1.
    ##
    ## $list (or that filled according to $type):
    ##     Refer to perlunicode.pod, "User-Defined Character Properties."
    ##     
    ##     For binary properties, only characters with the property value
    ##     of True should be listed. The 3rd column, if any, will be ignored.
    ##
    ## To make the parsing of $type clear, this code takes the a rather
    ## unorthodox approach of last'ing out of the block once we have the
    ## info we need. Were this to be a subroutine, the 'last' would just
    ## be a 'return'.
    ##
    my $file; ## file to load data from, and also part of the %Cache key.
    my $ListSorted = 0;

    if ($type)
    {
        $type =~ s/^\s+//;
        $type =~ s/\s+$//;

        print STDERR "type = $type\n" if DEBUG;

      GETFILE:
        {
	    ##
	    ## It could be a user-defined property.
	    ##

	    my $caller1 = $type =~ s/(.+)::// ? $1 : caller(1);

	    if (defined $caller1 && $type =~ /^(?:\w+)$/) {
		my $prop = "${caller1}::$type";
		if (exists &{$prop}) {
		    no strict 'refs';
		    
		    $list = &{$prop};
		    last GETFILE;
		}
	    }

            my $wasIs;

            ($wasIs = $type =~ s/^Is(?:\s+|[-_])?//i)
              or
            $type =~ s/^(?:(?:General(?:\s+|_)?)?Category|gc)\s*[:=]\s*//i
              or
            $type =~ s/^(?:Script|sc)\s*[:=]\s*//i
              or
            $type =~ s/^Block\s*[:=]\s*/In/i;


	    ##
	    ## See if it's in some enumeration.
	    ##
	    require "unicore/PVA.pl";
	    if ($type =~ /^([\w\s]+)[:=]\s*(.*)/) {
		my ($enum, $val) = (lc $1, lc $2);
		$enum =~ tr/ _-//d;
		$val =~ tr/ _-//d;

		my $pa = $PropertyAlias{$enum} ? $enum : $PA_reverse{$enum};
		my $f = $PropValueAlias{$pa}{$val} ? $val : $PVA_reverse{$pa}{lc $val};

		if ($pa and $f) {
		    $pa = "gc_sc" if $pa eq "gc" or $pa eq "sc";
		    $file = "unicore/lib/$pa/$PVA_abbr_map{$pa}{lc $f}.pl";
		    last GETFILE;
		}
	    }
	    else {
		my $t = lc $type;
		$t =~ tr/ _-//d;

		if ($PropValueAlias{gc}{$t} or $PropValueAlias{sc}{$t}) {
		    $file = "unicore/lib/gc_sc/$PVA_abbr_map{gc_sc}{$t}.pl";
		    last GETFILE;
		}
	    }

            ##
            ## See if it's in the direct mapping table.
            ##
            require "unicore/Exact.pl";
            if (my $base = $utf8::Exact{$type}) {
                $file = "unicore/lib/gc_sc/$base.pl";
                last GETFILE;
            }

            ##
            ## If not there exactly, try the canonical form. The canonical
            ## form is lowercased, with any separators (\s+|[-_]) removed.
            ##
            my $canonical = lc $type;
            $canonical =~ s/(?<=[a-z\d])(?:\s+|[-_])(?=[a-z\d])//g;
            print STDERR "canonical = $canonical\n" if DEBUG;

            require "unicore/Canonical.pl";
	    { no warnings "uninitialized";
            if (my $base = ($utf8::Canonical{$canonical} || $utf8::Canonical{ lc $utf8::PropertyAlias{$canonical} })) {
                $file = "unicore/lib/gc_sc/$base.pl";
                last GETFILE;
            }
            }

	    ##
	    ## See if it's a user-level "To".
	    ##

	    my $caller0 = caller(0);

	    if (defined $caller0 && $type =~ /^To(?:\w+)$/) {
		my $map = $caller0 . "::" . $type;

		if (exists &{$map}) {
		    no strict 'refs';
		    
		    $list = &{$map};
		    last GETFILE;
		}
	    }

            ##
            ## Last attempt -- see if it's a standard "To" name
	    ## (e.g. "ToLower")  ToTitle is used by ucfirst().
	    ## The user-level way to access ToDigit() and ToFold()
	    ## is to use Unicode::UCD.
            ##
            if ($type =~ /^To(Digit|Fold|Lower|Title|Upper)$/) {
                $file = "unicore/To/$1.pl";
                ## would like to test to see if $file actually exists....
                last GETFILE;
            }

            ##
            ## If we reach this line, it's because we couldn't figure
            ## out what to do with $type. Ouch.
            ##

            return $type;
        }

	if (defined $file) {
	    print STDERR "found it (file='$file')\n" if DEBUG;

	    ##
	    ## If we reach here, it was due to a 'last GETFILE' above
	    ## (exception: user-defined properties and mappings), so we
	    ## have a filename, so now we load it if we haven't already.
	    ## If we have, return the cached results. The cache key is the
	    ## class and file to load.
	    ##
	    my $found = $Cache{$class, $file};
	    if ($found and ref($found) eq $class) {
		print STDERR "Returning cached '$file' for \\p{$type}\n" if DEBUG;
		return $found;
	    }

	    local $@;
	    local $!;
	    $list = do $file; die $@ if $@;
	}

        $ListSorted = 1; ## we know that these lists are sorted
    }

    my $extras;
    my $bits = $minbits;

    my $ORIG = $list;
    if ($list) {
	my @tmp = split(/^/m, $list);
	my %seen;
	no warnings;
	$extras = join '', grep /^[^0-9a-fA-F]/, @tmp;
	$list = join '',
	    map  { $_->[1] }
	    sort { $a->[0] <=> $b->[0] }
	    map  { /^([0-9a-fA-F]+)/; [ CORE::hex($1), $_ ] }
	    grep { /^([0-9a-fA-F]+)/ and not $seen{$1}++ } @tmp; # XXX doesn't do ranges right
    }

    if ($none) {
	my $hextra = sprintf "%04x", $none + 1;
	$list =~ s/\tXXXX$/\t$hextra/mg;
    }

    if ($minbits != 1 && $minbits < 32) { # not binary property
	my $top = 0;
	while ($list =~ /^([0-9a-fA-F]+)(?:[\t]([0-9a-fA-F]+)?)(?:[ \t]([0-9a-fA-F]+))?/mg) {
	    my $min = CORE::hex $1;
	    my $max = defined $2 ? CORE::hex $2 : $min;
	    my $val = defined $3 ? CORE::hex $3 : 0;
	    $val += $max - $min if defined $3;
	    $top = $val if $val > $top;
	}
	my $topbits =
	    $top > 0xffff ? 32 :
	    $top > 0xff ? 16 : 8;
	$bits = $topbits if $bits < $topbits;
    }

    my @extras;
    for my $x ($extras) {
	pos $x = 0;
	while ($x =~ /^([^0-9a-fA-F\n])(.*)/mg) {
	    my $char = $1;
	    my $name = $2;
	    print STDERR "$1 => $2\n" if DEBUG;
	    if ($char =~ /[-+!&]/) {
		my ($c,$t) = split(/::/, $name, 2);	# bogus use of ::, really
		my $subobj;
		if ($c eq 'utf8') {
		    $subobj = utf8->SWASHNEW($t, "", $minbits, 0);
		}
		elsif (exists &$name) {
		    $subobj = utf8->SWASHNEW($name, "", $minbits, 0);
		}
		elsif ($c =~ /^([0-9a-fA-F]+)/) {
		    $subobj = utf8->SWASHNEW("", $c, $minbits, 0);
		}
		return $subobj unless ref $subobj;
		push @extras, $name => $subobj;
		$bits = $subobj->{BITS} if $bits < $subobj->{BITS};
	    }
	}
    }

    print STDERR "CLASS = $class, TYPE => $type, BITS => $bits, NONE => $none\nEXTRAS =>\n$extras\nLIST =>\n$list\n" if DEBUG;

    my $SWASH = bless {
	TYPE => $type,
	BITS => $bits,
	EXTRAS => $extras,
	LIST => $list,
	NONE => $none,
	@extras,
    } => $class;

    if ($file) {
        $Cache{$class, $file} = $SWASH;
    }

    return $SWASH;
}

# Now SWASHGET is recasted into a C function S_swash_get (see utf8.c).

1;
Commit	Line	Data
a0ed51b3	1	package utf8;
cf25bb62	2	use strict;
cf25bb62	3	use warnings;
a0ed51b3	4
15732964	5	sub DEBUG () { 0 }
a0ed51b3	6
	7	sub DESTROY {}
	8
5beb625e	9	my %Cache;
5beb625e	10
12ac2576	11	our (%PropertyAlias, %PA_reverse, %PropValueAlias, %PVA_reverse, %PVA_abbr_map);
12ac2576	12
86916d66	13	sub croak { require Carp; Carp::croak(@_) }
86916d66	14
5beb625e	15	##
3a2263fe	16	## "SWASH" == "SWATCH HASH". A "swatch" is a swatch of the Unicode landscape.
3a2263fe	17	## It's a data structure that encodes a set of Unicode characters.
5beb625e	18	##
5beb625e	19
a0ed51b3	20	sub SWASHNEW {
	21	my ($class, $type, $list, $minbits, $none) = @_;
	22	local $^D = 0 if $^D;
15732964	23
	24	print STDERR "SWASHNEW @_\n" if DEBUG;
	25
cf25bb62	26	##
cf25bb62	27	## Get the list of codepoints for the type.
711a919c	28	## Called from swash_init (see utf8.c) or SWASHNEW itself.
	29	##
	30	## Callers of swash_init:
	31	## op.c:pmtrans -- for tr/// and y///
	32	## regexec.c:regclass_swash -- for /[]/, \p, and \P
	33	## utf8.c:is_utf8_common -- for common Unicode properties
	34	## utf8.c:to_utf8_case -- for lc, uc, ucfirst, etc. and //i
cf25bb62	35	##
cf25bb62	36	## Given a $type, our goal is to fill $list with the set of codepoint
711a919c	37	## ranges. If $type is false, $list passed is used.
	38	##
	39	## $minbits:
	40	## For binary properties, $minbits must be 1.
	41	## For character mappings (case and transliteration), $minbits must
	42	## be a number except 1.
	43	##
	44	## $list (or that filled according to $type):
	45	## Refer to perlunicode.pod, "User-Defined Character Properties."
	46	##
	47	## For binary properties, only characters with the property value
	48	## of True should be listed. The 3rd column, if any, will be ignored.
cf25bb62	49	##
cf25bb62	50	## To make the parsing of $type clear, this code takes the a rather
2d92f8a0	51	## unorthodox approach of last'ing out of the block once we have the
cf25bb62	52	## info we need. Were this to be a subroutine, the 'last' would just
	53	## be a 'return'.
	54	##
5beb625e	55	my $file; ## file to load data from, and also part of the %Cache key.
	56	my $ListSorted = 0;
	57
cf25bb62	58	if ($type)
	59	{
	60	$type =~ s/^\s+//;
	61	$type =~ s/\s+$//;
	62
711a919c	63	print STDERR "type = $type\n" if DEBUG;
cf25bb62	64
cf25bb62	65	GETFILE:
cf25bb62	66	{
12ac2576	67	##
	68	## It could be a user-defined property.
	69	##
	70
	71	my $caller1 = $type =~ s/(.+)::// ? $1 : caller(1);
	72
	73	if (defined $caller1 && $type =~ /^(?:\w+)$/) {
	74	my $prop = "${caller1}::$type";
	75	if (exists &{$prop}) {
	76	no strict 'refs';
	77
	78	$list = &{$prop};
	79	last GETFILE;
	80	}
	81	}
	82
2d92f8a0	83	my $wasIs;
	84
	85	($wasIs = $type =~ s/^Is(?:\s+\|[-_])?//i)
5beb625e	86	or
12ac2576	87	$type =~ s/^(?:(?:General(?:\s+\|_)?)?Category\|gc)\s[:=]\s//i
5beb625e	88	or
12ac2576	89	$type =~ s/^(?:Script\|sc)\s[:=]\s//i
5beb625e	90	or
12ac2576	91	$type =~ s/^Block\s[:=]\s/In/i;
	92
	93
	94	##
	95	## See if it's in some enumeration.
	96	##
7ebf06b3	97	require "unicore/PVA.pl";
12ac2576	98	if ($type =~ /^([\w\s]+)[:=]\s(.)/) {
12ac2576	99	my ($enum, $val) = (lc $1, lc $2);
	100	$enum =~ tr/ _-//d;
	101	$val =~ tr/ _-//d;
	102
	103	my $pa = $PropertyAlias{$enum} ? $enum : $PA_reverse{$enum};
	104	my $f = $PropValueAlias{$pa}{$val} ? $val : $PVA_reverse{$pa}{lc $val};
	105
	106	if ($pa and $f) {
	107	$pa = "gc_sc" if $pa eq "gc" or $pa eq "sc";
	108	$file = "unicore/lib/$pa/$PVA_abbr_map{$pa}{lc $f}.pl";
	109	last GETFILE;
	110	}
	111	}
	112	else {
	113	my $t = lc $type;
	114	$t =~ tr/ _-//d;
	115
	116	if ($PropValueAlias{gc}{$t} or $PropValueAlias{sc}{$t}) {
	117	$file = "unicore/lib/gc_sc/$PVA_abbr_map{gc_sc}{$t}.pl";
	118	last GETFILE;
	119	}
	120	}
cf25bb62	121
5beb625e	122	##
	123	## See if it's in the direct mapping table.
	124	##
	125	require "unicore/Exact.pl";
	126	if (my $base = $utf8::Exact{$type}) {
12ac2576	127	$file = "unicore/lib/gc_sc/$base.pl";
5beb625e	128	last GETFILE;
cf25bb62	129	}
	130
	131	##
5beb625e	132	## If not there exactly, try the canonical form. The canonical
5beb625e	133	## form is lowercased, with any separators (\s+\|[-_]) removed.
cf25bb62	134	##
5beb625e	135	my $canonical = lc $type;
5beb625e	136	$canonical =~ s/(?<=[a-z\d])(?:\s+\|[-_])(?=[a-z\d])//g;
711a919c	137	print STDERR "canonical = $canonical\n" if DEBUG;
cf25bb62	138
5beb625e	139	require "unicore/Canonical.pl";
0a0ffbce	140	{ no warnings "uninitialized";
12ac2576	141	if (my $base = ($utf8::Canonical{$canonical} \|\| $utf8::Canonical{ lc $utf8::PropertyAlias{$canonical} })) {
12ac2576	142	$file = "unicore/lib/gc_sc/$base.pl";
5beb625e	143	last GETFILE;
cf25bb62	144	}
0a0ffbce	145	}
cf25bb62	146
491fd90a	147	##
3a2263fe	148	## See if it's a user-level "To".
	149	##
	150
	151	my $caller0 = caller(0);
	152
	153	if (defined $caller0 && $type =~ /^To(?:\w+)$/) {
	154	my $map = $caller0 . "::" . $type;
09e0265a	155
3a2263fe	156	if (exists &{$map}) {
	157	no strict 'refs';
	158
	159	$list = &{$map};
	160	last GETFILE;
	161	}
	162	}
	163
cf25bb62	164	##
3a2263fe	165	## Last attempt -- see if it's a standard "To" name
	166	## (e.g. "ToLower") ToTitle is used by ucfirst().
	167	## The user-level way to access ToDigit() and ToFold()
	168	## is to use Unicode::UCD.
cf25bb62	169	##
711a919c	170	if ($type =~ /^To(Digit\|Fold\|Lower\|Title\|Upper)$/) {
cf25bb62	171	$file = "unicore/To/$1.pl";
	172	## would like to test to see if $file actually exists....
	173	last GETFILE;
	174	}
	175
	176	##
	177	## If we reach this line, it's because we couldn't figure
	178	## out what to do with $type. Ouch.
	179	##
bc45ce41	180
bc45ce41	181	return $type;
cf25bb62	182	}
cf25bb62	183
491fd90a	184	if (defined $file) {
711a919c	185	print STDERR "found it (file='$file')\n" if DEBUG;
491fd90a	186
	187	##
	188	## If we reach here, it was due to a 'last GETFILE' above
3a2263fe	189	## (exception: user-defined properties and mappings), so we
491fd90a	190	## have a filename, so now we load it if we haven't already.
491fd90a	191	## If we have, return the cached results. The cache key is the
c49d5ed7	192	## class and file to load.
491fd90a	193	##
c49d5ed7	194	my $found = $Cache{$class, $file};
c49d5ed7	195	if ($found and ref($found) eq $class) {
711a919c	196	print STDERR "Returning cached '$file' for \\p{$type}\n" if DEBUG;
c49d5ed7	197	return $found;
491fd90a	198	}
491fd90a	199
2096afc4	200	local $@;
2096afc4	201	local $!;
e81465be	202	$list = do $file; die $@ if $@;
491fd90a	203	}
5beb625e	204
5beb625e	205	$ListSorted = 1; ## we know that these lists are sorted
886ba366	206	}
a0ed51b3	207
15732964	208	my $extras;
711a919c	209	my $bits = $minbits;
cf25bb62	210
5beb625e	211	my $ORIG = $list;
a0ed51b3	212	if ($list) {
	213	my @tmp = split(/^/m, $list);
	214	my %seen;
db376a24	215	no warnings;
a0ed51b3	216	$extras = join '', grep /^[^0-9a-fA-F]/, @tmp;
a0ed51b3	217	$list = join '',
df68b396	218	map { $_->[1] }
df68b396	219	sort { $a->[0] <=> $b->[0] }
075d4edd	220	map { /^([0-9a-fA-F]+)/; [ CORE::hex($1), $_ ] }
df68b396	221	grep { /^([0-9a-fA-F]+)/ and not $seen{$1}++ } @tmp; # XXX doesn't do ranges right
a0ed51b3	222	}
	223
	224	if ($none) {
	225	my $hextra = sprintf "%04x", $none + 1;
	226	$list =~ s/\tXXXX$/\t$hextra/mg;
	227	}
	228
711a919c	229	if ($minbits != 1 && $minbits < 32) { # not binary property
a0ed51b3	230	my $top = 0;
3a2263fe	231	while ($list =~ /^([0-9a-fA-F]+)(?:[\t]([0-9a-fA-F]+)?)(?:[ \t]([0-9a-fA-F]+))?/mg) {
075d4edd	232	my $min = CORE::hex $1;
	233	my $max = defined $2 ? CORE::hex $2 : $min;
	234	my $val = defined $3 ? CORE::hex $3 : 0;
a0ed51b3	235	$val += $max - $min if defined $3;
	236	$top = $val if $val > $top;
	237	}
711a919c	238	my $topbits =
a0ed51b3	239	$top > 0xffff ? 32 :
711a919c	240	$top > 0xff ? 16 : 8;
711a919c	241	$bits = $topbits if $bits < $topbits;
a0ed51b3	242	}
a0ed51b3	243
	244	my @extras;
	245	for my $x ($extras) {
	246	pos $x = 0;
1fef36c7	247	while ($x =~ /^([^0-9a-fA-F\n])(.*)/mg) {
a0ed51b3	248	my $char = $1;
a0ed51b3	249	my $name = $2;
6d6ae962	250	print STDERR "$1 => $2\n" if DEBUG;
09e0265a	251	if ($char =~ /[-+!&]/) {
a0ed51b3	252	my ($c,$t) = split(/::/, $name, 2); # bogus use of ::, really
11ef8fdd	253	my $subobj;
11ef8fdd	254	if ($c eq 'utf8') {
711a919c	255	$subobj = utf8->SWASHNEW($t, "", $minbits, 0);
09e0265a	256	}
09e0265a	257	elsif (exists &$name) {
711a919c	258	$subobj = utf8->SWASHNEW($name, "", $minbits, 0);
11ef8fdd	259	}
11ef8fdd	260	elsif ($c =~ /^([0-9a-fA-F]+)/) {
711a919c	261	$subobj = utf8->SWASHNEW("", $c, $minbits, 0);
11ef8fdd	262	}
bc45ce41	263	return $subobj unless ref $subobj;
a0ed51b3	264	push @extras, $name => $subobj;
	265	$bits = $subobj->{BITS} if $bits < $subobj->{BITS};
	266	}
	267	}
	268	}
	269
15732964	270	print STDERR "CLASS = $class, TYPE => $type, BITS => $bits, NONE => $none\nEXTRAS =>\n$extras\nLIST =>\n$list\n" if DEBUG;
a0ed51b3	271
5beb625e	272	my $SWASH = bless {
a0ed51b3	273	TYPE => $type,
	274	BITS => $bits,
	275	EXTRAS => $extras,
	276	LIST => $list,
	277	NONE => $none,
	278	@extras,
	279	} => $class;
5beb625e	280
	281	if ($file) {
	282	$Cache{$class, $file} = $SWASH;
	283	}
	284
	285	return $SWASH;
a0ed51b3	286	}
a0ed51b3	287
979f2922	288	# Now SWASHGET is recasted into a C function S_swash_get (see utf8.c).
a0ed51b3	289
a0ed51b3	290	1;