Commit | Line | Data |
b5cc15f7 |
1 | use strict; |
2 | use warnings; |
3 | |
4 | package local::lib; |
5 | |
387f8022 |
6 | use 5.006; |
b5cc15f7 |
7 | |
8 | use File::Spec (); |
b5cc15f7 |
9 | use Config; |
10 | |
7c0e6b54 |
11 | our $VERSION = '1.008026'; # 1.8.26 |
d04dfa50 |
12 | $VERSION = eval $VERSION; |
1f8043c8 |
13 | |
15f79556 |
14 | our @KNOWN_FLAGS = qw(--self-contained --deactivate --deactivate-all); |
15 | |
16 | sub DEACTIVATE_ONE () { 1 } |
17 | sub DEACTIVATE_ALL () { 2 } |
b5cc15f7 |
18 | |
3939a7ae |
19 | sub INTERPOLATE_ENV () { 1 } |
20 | sub LITERAL_ENV () { 0 } |
21 | |
b5cc15f7 |
22 | sub import { |
0fb70b9a |
23 | my ($class, @args) = @_; |
24 | |
e4892f2b |
25 | # Remember what PERL5LIB was when we started |
ea0824e7 |
26 | my $perl5lib = $ENV{PERL5LIB} || ''; |
e4892f2b |
27 | |
b9c94c15 |
28 | my %arg_store; |
29 | for my $arg (@args) { |
30 | # check for lethal dash first to stop processing before causing problems |
5eff9c24 |
31 | # the fancy dash is U+2212 or \xE2\x88\x92 |
32 | if ($arg =~ /\xE2\x88\x92/ or $arg =~ /−/) { |
d4dbe584 |
33 | die <<'DEATH'; |
34 | WHOA THERE! It looks like you've got some fancy dashes in your commandline! |
35 | These are *not* the traditional -- dashes that software recognizes. You |
36 | probably got these by copy-pasting from the perldoc for this module as |
37 | rendered by a UTF8-capable formatter. This most typically happens on an OS X |
38 | terminal, but can happen elsewhere too. Please try again after replacing the |
39 | dashes with normal minus signs. |
40 | DEATH |
b9c94c15 |
41 | } |
42 | elsif(grep { $arg eq $_ } @KNOWN_FLAGS) { |
43 | (my $flag = $arg) =~ s/--//; |
44 | $arg_store{$flag} = 1; |
45 | } |
46 | elsif($arg =~ /^--/) { |
47 | die "Unknown import argument: $arg"; |
48 | } |
49 | else { |
50 | # assume that what's left is a path |
51 | $arg_store{path} = $arg; |
52 | } |
d4dbe584 |
53 | } |
b9c94c15 |
54 | |
b10fc4d4 |
55 | if($arg_store{'self-contained'}) { |
1f8043c8 |
56 | die "FATAL: The local::lib --self-contained flag has never worked reliably and the original author, Mark Stosberg, was unable or unwilling to maintain it. As such, this flag has been removed from the local::lib codebase in order to prevent misunderstandings and potentially broken builds. The local::lib authors recommend that you look at the lib::core::only module shipped with this distribution in order to create a more robust environment that is equivalent to what --self-contained provided (although quite possibly not what you originally thought it provided due to the poor quality of the documentation, for which we apologise).\n"; |
0fb70b9a |
57 | } |
b9c94c15 |
58 | |
15f79556 |
59 | my $deactivating = 0; |
60 | if ($arg_store{deactivate}) { |
61 | $deactivating = DEACTIVATE_ONE; |
62 | } |
63 | if ($arg_store{'deactivate-all'}) { |
64 | $deactivating = DEACTIVATE_ALL; |
65 | } |
66 | |
b9c94c15 |
67 | $arg_store{path} = $class->resolve_path($arg_store{path}); |
15f79556 |
68 | $class->setup_local_lib_for($arg_store{path}, $deactivating); |
0fb70b9a |
69 | |
6e5079df |
70 | for (@INC) { # Untaint @INC |
71 | next if ref; # Skip entry if it is an ARRAY, CODE, blessed, etc. |
72 | m/(.*)/ and $_ = $1; |
73 | } |
b5cc15f7 |
74 | } |
75 | |
5b94dce5 |
76 | sub pipeline; |
b5cc15f7 |
77 | |
5b94dce5 |
78 | sub pipeline { |
b5cc15f7 |
79 | my @methods = @_; |
80 | my $last = pop(@methods); |
81 | if (@methods) { |
82 | \sub { |
83 | my ($obj, @args) = @_; |
5b94dce5 |
84 | $obj->${pipeline @methods}( |
b5cc15f7 |
85 | $obj->$last(@args) |
86 | ); |
87 | }; |
88 | } else { |
89 | \sub { |
90 | shift->$last(@_); |
91 | }; |
92 | } |
93 | } |
94 | |
275c9dae |
95 | =begin testing |
96 | |
97 | #:: test pipeline |
b5cc15f7 |
98 | |
99 | package local::lib; |
100 | |
101 | { package Foo; sub foo { -$_[1] } sub bar { $_[1]+2 } sub baz { $_[1]+3 } } |
8522f4d5 |
102 | my $foo = bless({}, 'Foo'); |
4c375968 |
103 | Test::More::ok($foo->${pipeline qw(foo bar baz)}(10) == -15); |
b5cc15f7 |
104 | |
275c9dae |
105 | =end testing |
106 | |
b5cc15f7 |
107 | =cut |
108 | |
a9489cb0 |
109 | sub _uniq { |
110 | my %seen; |
111 | grep { ! $seen{$_}++ } @_; |
112 | } |
113 | |
b5cc15f7 |
114 | sub resolve_path { |
115 | my ($class, $path) = @_; |
5b94dce5 |
116 | $class->${pipeline qw( |
b5cc15f7 |
117 | resolve_relative_path |
118 | resolve_home_path |
119 | resolve_empty_path |
120 | )}($path); |
121 | } |
122 | |
123 | sub resolve_empty_path { |
124 | my ($class, $path) = @_; |
125 | if (defined $path) { |
126 | $path; |
127 | } else { |
128 | '~/perl5'; |
129 | } |
130 | } |
131 | |
275c9dae |
132 | =begin testing |
133 | |
134 | #:: test classmethod setup |
b5cc15f7 |
135 | |
136 | my $c = 'local::lib'; |
137 | |
275c9dae |
138 | =end testing |
139 | |
140 | =begin testing |
b5cc15f7 |
141 | |
275c9dae |
142 | #:: test classmethod |
b5cc15f7 |
143 | |
144 | is($c->resolve_empty_path, '~/perl5'); |
145 | is($c->resolve_empty_path('foo'), 'foo'); |
146 | |
275c9dae |
147 | =end testing |
148 | |
b5cc15f7 |
149 | =cut |
150 | |
151 | sub resolve_home_path { |
152 | my ($class, $path) = @_; |
153 | return $path unless ($path =~ /^~/); |
154 | my ($user) = ($path =~ /^~([^\/]+)/); # can assume ^~ so undef for 'us' |
b5cc15f7 |
155 | my $homedir = do { |
5c957a4b |
156 | if (!defined $user && defined $ENV{HOME}) { |
157 | $ENV{HOME} |
158 | } |
159 | else { |
160 | require File::Glob; |
161 | File::Glob::bsd_glob("~$user", File::Glob::GLOB_TILDE()); |
b5cc15f7 |
162 | } |
163 | }; |
164 | unless (defined $homedir) { |
cd3eb741 |
165 | require Carp; |
b5cc15f7 |
166 | Carp::croak( |
167 | "Couldn't resolve homedir for " |
168 | .(defined $user ? $user : 'current user') |
b5cc15f7 |
169 | ); |
170 | } |
171 | $path =~ s/^~[^\/]*/$homedir/; |
172 | $path; |
173 | } |
174 | |
175 | sub resolve_relative_path { |
176 | my ($class, $path) = @_; |
53699c99 |
177 | $path = File::Spec->rel2abs($path); |
b5cc15f7 |
178 | } |
179 | |
275c9dae |
180 | =begin testing |
181 | |
182 | #:: test classmethod |
b5cc15f7 |
183 | |
184 | local *File::Spec::rel2abs = sub { shift; 'FOO'.shift; }; |
185 | is($c->resolve_relative_path('bar'),'FOObar'); |
186 | |
275c9dae |
187 | =end testing |
188 | |
b5cc15f7 |
189 | =cut |
190 | |
191 | sub setup_local_lib_for { |
4c718913 |
192 | my ($class, $path, $deactivating) = @_; |
3939a7ae |
193 | |
194 | my $interpolate = LITERAL_ENV; |
195 | my @active_lls = $class->active_paths; |
196 | |
f22d40d7 |
197 | $class->ensure_dir_structure_for($path) |
198 | unless $deactivating; |
c1ed5f4b |
199 | |
200 | # On Win32 directories often contain spaces. But some parts of the CPAN |
201 | # toolchain don't like that. To avoid this, GetShortPathName() gives us |
202 | # an alternate representation that has none. |
203 | # This only works if the directory already exists. |
204 | $path = Win32::GetShortPathName($path) if $^O eq 'MSWin32'; |
82efaec7 |
205 | |
3939a7ae |
206 | if (! $deactivating) { |
a27f7456 |
207 | if (@active_lls && $active_lls[0] eq $path) { |
3939a7ae |
208 | exit 0 if $0 eq '-'; |
209 | return; # Asked to add what's already at the top of the stack |
210 | } elsif (grep { $_ eq $path} @active_lls) { |
211 | # Asked to add a dir that's lower in the stack -- so we remove it from |
212 | # where it is, and then add it back at the top. |
213 | $class->setup_env_hash_for($path, DEACTIVATE_ONE); |
214 | # Which means we can no longer output "PERL5LIB=...:$PERL5LIB" stuff |
215 | # anymore because we're taking something *out*. |
216 | $interpolate = INTERPOLATE_ENV; |
217 | } |
218 | } |
219 | |
b5cc15f7 |
220 | if ($0 eq '-') { |
3939a7ae |
221 | $class->print_environment_vars_for($path, $deactivating, $interpolate); |
b5cc15f7 |
222 | exit 0; |
223 | } else { |
4c718913 |
224 | $class->setup_env_hash_for($path, $deactivating); |
cdd450c5 |
225 | my $arch_dir = $Config{archname}; |
226 | @INC = _uniq( |
c50d554b |
227 | ( |
228 | # Inject $path/$archname for each path in PERL5LIB |
229 | map { ( File::Spec->catdir($_, $arch_dir), $_ ) } |
230 | split($Config{path_sep}, $ENV{PERL5LIB}) |
231 | ), |
232 | @INC |
cdd450c5 |
233 | ); |
b5cc15f7 |
234 | } |
235 | } |
236 | |
b5cc15f7 |
237 | sub install_base_bin_path { |
238 | my ($class, $path) = @_; |
239 | File::Spec->catdir($path, 'bin'); |
240 | } |
241 | |
242 | sub install_base_perl_path { |
243 | my ($class, $path) = @_; |
244 | File::Spec->catdir($path, 'lib', 'perl5'); |
245 | } |
246 | |
247 | sub install_base_arch_path { |
248 | my ($class, $path) = @_; |
249 | File::Spec->catdir($class->install_base_perl_path($path), $Config{archname}); |
250 | } |
251 | |
252 | sub ensure_dir_structure_for { |
253 | my ($class, $path) = @_; |
254 | unless (-d $path) { |
255 | warn "Attempting to create directory ${path}\n"; |
256 | } |
5c957a4b |
257 | require File::Basename; |
258 | my @dirs; |
259 | while(!-d $path) { |
260 | push @dirs, $path; |
261 | $path = File::Basename::dirname($path); |
262 | } |
263 | mkdir $_ for reverse @dirs; |
264 | return; |
b5cc15f7 |
265 | } |
266 | |
c4e3c83b |
267 | sub guess_shelltype { |
0353dbc0 |
268 | my $shellbin = 'sh'; |
269 | if(defined $ENV{'SHELL'}) { |
270 | my @shell_bin_path_parts = File::Spec->splitpath($ENV{'SHELL'}); |
271 | $shellbin = $shell_bin_path_parts[-1]; |
272 | } |
1bc71e56 |
273 | my $shelltype = do { |
274 | local $_ = $shellbin; |
b42496e0 |
275 | if(/csh/) { |
1bc71e56 |
276 | 'csh' |
b42496e0 |
277 | } else { |
1bc71e56 |
278 | 'bourne' |
279 | } |
280 | }; |
281 | |
f58534b1 |
282 | # Both Win32 and Cygwin have $ENV{COMSPEC} set. |
283 | if (defined $ENV{'COMSPEC'} && $^O ne 'cygwin') { |
53699c99 |
284 | my @shell_bin_path_parts = File::Spec->splitpath($ENV{'COMSPEC'}); |
285 | $shellbin = $shell_bin_path_parts[-1]; |
286 | $shelltype = do { |
287 | local $_ = $shellbin; |
288 | if(/command\.com/) { |
289 | 'win32' |
290 | } elsif(/cmd\.exe/) { |
291 | 'win32' |
292 | } elsif(/4nt\.exe/) { |
293 | 'win32' |
294 | } else { |
295 | $shelltype |
296 | } |
297 | }; |
298 | } |
c4e3c83b |
299 | return $shelltype; |
300 | } |
301 | |
302 | sub print_environment_vars_for { |
3939a7ae |
303 | my ($class, $path, $deactivating, $interpolate) = @_; |
304 | print $class->environment_vars_string_for($path, $deactivating, $interpolate); |
8cc924b8 |
305 | } |
306 | |
307 | sub environment_vars_string_for { |
3939a7ae |
308 | my ($class, $path, $deactivating, $interpolate) = @_; |
309 | my @envs = $class->build_environment_vars_for($path, $deactivating, $interpolate); |
c4e3c83b |
310 | my $out = ''; |
311 | |
312 | # rather basic csh detection, goes on the assumption that something won't |
313 | # call itself csh unless it really is. also, default to bourne in the |
314 | # pathological situation where a user doesn't have $ENV{SHELL} defined. |
315 | # note also that shells with funny names, like zoid, are assumed to be |
316 | # bourne. |
317 | |
318 | my $shelltype = $class->guess_shelltype; |
53699c99 |
319 | |
b5cc15f7 |
320 | while (@envs) { |
321 | my ($name, $value) = (shift(@envs), shift(@envs)); |
4c718913 |
322 | $value =~ s/(\\")/\\$1/g if defined $value; |
1bc71e56 |
323 | $out .= $class->${\"build_${shelltype}_env_declaration"}($name, $value); |
b5cc15f7 |
324 | } |
8cc924b8 |
325 | return $out; |
b5cc15f7 |
326 | } |
327 | |
1bc71e56 |
328 | # simple routines that take two arguments: an %ENV key and a value. return |
329 | # strings that are suitable for passing directly to the relevant shell to set |
330 | # said key to said value. |
331 | sub build_bourne_env_declaration { |
332 | my $class = shift; |
333 | my($name, $value) = @_; |
4c718913 |
334 | return defined($value) ? qq{export ${name}="${value}";\n} : qq{unset ${name};\n}; |
1bc71e56 |
335 | } |
336 | |
337 | sub build_csh_env_declaration { |
338 | my $class = shift; |
339 | my($name, $value) = @_; |
2d98051c |
340 | return defined($value) ? qq{setenv ${name} "${value}";\n} : qq{unsetenv ${name};\n}; |
1bc71e56 |
341 | } |
342 | |
53699c99 |
343 | sub build_win32_env_declaration { |
344 | my $class = shift; |
345 | my($name, $value) = @_; |
4c718913 |
346 | return defined($value) ? qq{set ${name}=${value}\n} : qq{set ${name}=\n}; |
53699c99 |
347 | } |
348 | |
b5cc15f7 |
349 | sub setup_env_hash_for { |
4c718913 |
350 | my ($class, $path, $deactivating) = @_; |
351 | my %envs = $class->build_environment_vars_for($path, $deactivating, INTERPOLATE_ENV); |
b5cc15f7 |
352 | @ENV{keys %envs} = values %envs; |
353 | } |
354 | |
355 | sub build_environment_vars_for { |
4c718913 |
356 | my ($class, $path, $deactivating, $interpolate) = @_; |
357 | |
ee0e1840 |
358 | if ($deactivating && $deactivating == DEACTIVATE_ONE) { |
4c718913 |
359 | return $class->build_deactivate_environment_vars_for($path, $interpolate); |
ee0e1840 |
360 | } elsif ($deactivating && $deactivating == DEACTIVATE_ALL) { |
15f79556 |
361 | return $class->build_deact_all_environment_vars_for($path, $interpolate); |
4c718913 |
362 | } else { |
363 | return $class->build_activate_environment_vars_for($path, $interpolate); |
364 | } |
365 | } |
366 | |
1bf7d892 |
367 | # Build an environment value for a variable like PATH from a list of paths. |
368 | # References to existing variables are given as references to the variable name. |
369 | # Duplicates are removed. |
370 | # |
371 | # options: |
372 | # - interpolate: INTERPOLATE_ENV/LITERAL_ENV |
373 | # - exists: paths are included only if they exist (default: interpolate == INTERPOLATE_ENV) |
374 | # - filter: function to apply to each path do decide if it must be included |
375 | # - empty: the value to return in the case of empty value |
f878d9c1 |
376 | my %ENV_LIST_VALUE_DEFAULTS = ( |
1bf7d892 |
377 | interpolate => INTERPOLATE_ENV, |
378 | exists => undef, |
379 | filter => sub { 1 }, |
380 | empty => undef, |
381 | ); |
48eb676f |
382 | sub _env_list_value { |
1bf7d892 |
383 | my $options = shift; |
384 | die(sprintf "unknown option '$_' at %s line %u\n", (caller)[1..2]) |
f878d9c1 |
385 | for grep { !exists $ENV_LIST_VALUE_DEFAULTS{$_} } keys %$options; |
386 | my %options = (%ENV_LIST_VALUE_DEFAULTS, %{ $options }); |
1bf7d892 |
387 | $options{exists} = $options{interpolate} == INTERPOLATE_ENV |
388 | unless defined $options{exists}; |
389 | |
390 | my %seen; |
391 | |
392 | my $value = join($Config{path_sep}, map { |
393 | ref $_ ? ($^O eq 'MSWin32' ? "%${$_}%" : "\$${$_}") : $_ |
394 | } grep { |
395 | ref $_ || (defined $_ |
396 | && length($_) > 0 |
397 | && !$seen{$_}++ |
398 | && $options{filter}->($_) |
399 | && (!$options{exists} || -e $_)) |
400 | } map { |
401 | if (ref $_ eq 'SCALAR' && $options{interpolate} == INTERPOLATE_ENV) { |
373b3c18 |
402 | defined $ENV{${$_}} ? (split /\Q$Config{path_sep}/, $ENV{${$_}}) : () |
1bf7d892 |
403 | } else { |
404 | $_ |
405 | } |
406 | } @_); |
407 | return length($value) ? $value : $options{empty}; |
408 | } |
409 | |
4c718913 |
410 | sub build_activate_environment_vars_for { |
b5cc15f7 |
411 | my ($class, $path, $interpolate) = @_; |
412 | return ( |
1bf7d892 |
413 | PERL_LOCAL_LIB_ROOT => |
414 | _env_list_value( |
415 | { interpolate => $interpolate, exists => 0, empty => '' }, |
1bf7d892 |
416 | $path, |
a27f7456 |
417 | \'PERL_LOCAL_LIB_ROOT', |
393c618d |
418 | ), |
93b577b5 |
419 | PERL_MB_OPT => "--install_base " . _mb_escape_path($path), |
420 | PERL_MM_OPT => "INSTALL_BASE=" . _mm_escape_path($path), |
1bf7d892 |
421 | PERL5LIB => |
422 | _env_list_value( |
423 | { interpolate => $interpolate, exists => 0, empty => '' }, |
1bf7d892 |
424 | $class->install_base_perl_path($path), |
425 | \'PERL5LIB', |
426 | ), |
427 | PATH => _env_list_value( |
428 | { interpolate => $interpolate, exists => 0, empty => '' }, |
c50d554b |
429 | $class->install_base_bin_path($path), |
1bf7d892 |
430 | \'PATH', |
431 | ), |
b5cc15f7 |
432 | ) |
433 | } |
434 | |
93b577b5 |
435 | sub _mm_escape_path { |
436 | my $path = shift; |
437 | $path =~ s/\\/\\\\\\\\/g; |
438 | if ($path =~ s/ /\\ /g) { |
439 | $path = qq{"\\"$path\\""}; |
440 | } |
441 | return $path; |
442 | } |
443 | |
444 | sub _mb_escape_path { |
445 | my $path = shift; |
446 | $path =~ s/\\/\\\\/g; |
447 | return qq{"$path"}; |
448 | } |
449 | |
29500601 |
450 | sub active_paths { |
451 | my ($class) = @_; |
452 | |
453 | return () unless defined $ENV{PERL_LOCAL_LIB_ROOT}; |
24351831 |
454 | |
455 | return grep { |
456 | # screen out entries that aren't actually reflected in @INC |
457 | my $active_ll = $class->install_base_perl_path($_); |
458 | grep { $_ eq $active_ll } @INC |
459 | } |
460 | grep { $_ ne '' } |
461 | split /\Q$Config{path_sep}\E/, $ENV{PERL_LOCAL_LIB_ROOT}; |
29500601 |
462 | } |
463 | |
4c718913 |
464 | sub build_deactivate_environment_vars_for { |
465 | my ($class, $path, $interpolate) = @_; |
466 | |
29500601 |
467 | my @active_lls = $class->active_paths; |
4c718913 |
468 | |
469 | if (!grep { $_ eq $path } @active_lls) { |
470 | warn "Tried to deactivate inactive local::lib '$path'\n"; |
471 | return (); |
472 | } |
473 | |
1bf7d892 |
474 | my $perl_path = $class->install_base_perl_path($path); |
475 | my $arch_path = $class->install_base_arch_path($path); |
476 | my $bin_path = $class->install_base_bin_path($path); |
477 | |
4c718913 |
478 | |
479 | my %env = ( |
1bf7d892 |
480 | PERL_LOCAL_LIB_ROOT => _env_list_value( |
481 | { |
482 | exists => 0, |
483 | }, |
484 | grep { $_ ne $path } @active_lls |
4c718913 |
485 | ), |
1bf7d892 |
486 | PERL5LIB => _env_list_value( |
487 | { |
488 | exists => 0, |
489 | filter => sub { |
490 | $_ ne $perl_path && $_ ne $arch_path |
491 | }, |
492 | }, |
493 | \'PERL5LIB', |
4c718913 |
494 | ), |
1bf7d892 |
495 | PATH => _env_list_value( |
496 | { |
497 | exists => 0, |
498 | filter => sub { $_ ne $bin_path }, |
499 | }, |
500 | \'PATH', |
4c718913 |
501 | ), |
502 | ); |
503 | |
504 | # If removing ourselves from the "top of the stack", set install paths to |
505 | # correspond with the new top of stack. |
a27f7456 |
506 | if ($active_lls[0] eq $path) { |
507 | my $new_top = $active_lls[1]; |
93b577b5 |
508 | $env{PERL_MB_OPT} = defined($new_top) ? "--install_base "._mb_escape_path($new_top) : undef; |
509 | $env{PERL_MM_OPT} = defined($new_top) ? "INSTALL_BASE="._mm_escape_path($new_top) : undef; |
4c718913 |
510 | } |
511 | |
512 | return %env; |
513 | } |
514 | |
15f79556 |
515 | sub build_deact_all_environment_vars_for { |
516 | my ($class, $path, $interpolate) = @_; |
517 | |
29500601 |
518 | my @active_lls = $class->active_paths; |
15f79556 |
519 | |
1bf7d892 |
520 | my %perl_paths = map { ( |
521 | $class->install_base_perl_path($_) => 1, |
522 | $class->install_base_arch_path($_) => 1 |
523 | ) } @active_lls; |
524 | my %bin_paths = map { ( |
525 | $class->install_base_bin_path($_) => 1, |
526 | ) } @active_lls; |
15f79556 |
527 | |
528 | my %env = ( |
529 | PERL_LOCAL_LIB_ROOT => undef, |
530 | PERL_MM_OPT => undef, |
531 | PERL_MB_OPT => undef, |
1bf7d892 |
532 | PERL5LIB => _env_list_value( |
533 | { |
534 | exists => 0, |
535 | filter => sub { |
536 | ! scalar grep { exists $perl_paths{$_} } $_[0] |
537 | }, |
538 | }, |
539 | \'PERL5LIB' |
540 | ), |
541 | PATH => _env_list_value( |
542 | { |
543 | exists => 0, |
544 | filter => sub { |
545 | ! scalar grep { exists $bin_paths{$_} } $_[0] |
546 | }, |
547 | }, |
548 | \'PATH' |
15f79556 |
549 | ), |
15f79556 |
550 | ); |
551 | |
552 | return %env; |
553 | } |
554 | |
275c9dae |
555 | =begin testing |
556 | |
557 | #:: test classmethod |
b5cc15f7 |
558 | |
559 | File::Path::rmtree('t/var/splat'); |
560 | |
4c375968 |
561 | $c->ensure_dir_structure_for('t/var/splat'); |
b5cc15f7 |
562 | |
563 | ok(-d 't/var/splat'); |
564 | |
275c9dae |
565 | =end testing |
566 | |
898f36cf |
567 | =encoding utf8 |
568 | |
b5cc15f7 |
569 | =head1 NAME |
570 | |
571 | local::lib - create and use a local lib/ for perl modules with PERL5LIB |
572 | |
573 | =head1 SYNOPSIS |
574 | |
575 | In code - |
576 | |
577 | use local::lib; # sets up a local lib at ~/perl5 |
578 | |
579 | use local::lib '~/foo'; # same, but ~/foo |
580 | |
1bc71e56 |
581 | # Or... |
582 | use FindBin; |
583 | use local::lib "$FindBin::Bin/../support"; # app-local support library |
584 | |
b5cc15f7 |
585 | From the shell - |
586 | |
359329d3 |
587 | # Install LWP and its missing dependencies to the '~/perl5' directory |
588 | perl -MCPAN -Mlocal::lib -e 'CPAN::install(LWP)' |
0fb70b9a |
589 | |
0fb70b9a |
590 | # Just print out useful shell commands |
b5cc15f7 |
591 | $ perl -Mlocal::lib |
e322149f |
592 | export PERL_MB_OPT='--install_base /home/username/perl5' |
c4e3c83b |
593 | export PERL_MM_OPT='INSTALL_BASE=/home/username/perl5' |
594 | export PERL5LIB='/home/username/perl5/lib/perl5/i386-linux:/home/username/perl5/lib/perl5' |
595 | export PATH="/home/username/perl5/bin:$PATH" |
b5cc15f7 |
596 | |
322b0a0d |
597 | =head2 The bootstrapping technique |
bc30e1d5 |
598 | |
730f5dda |
599 | A typical way to install local::lib is using what is known as the |
600 | "bootstrapping" technique. You would do this if your system administrator |
601 | hasn't already installed local::lib. In this case, you'll need to install |
8522f4d5 |
602 | local::lib in your home directory. |
898f36cf |
603 | |
0ad9f83d |
604 | Even if you do have administrative privileges, you will still want to set up your |
898f36cf |
605 | environment variables, as discussed in step 4. Without this, you would still |
606 | install the modules into the system CPAN installation and also your Perl scripts |
607 | will not use the lib/ path you bootstrapped with local::lib. |
608 | |
04f8efde |
609 | By default local::lib installs itself and the CPAN modules into ~/perl5. |
610 | |
898f36cf |
611 | Windows users must also see L</Differences when using this module under Win32>. |
715c31a0 |
612 | |
730f5dda |
613 | 1. Download and unpack the local::lib tarball from CPAN (search for "Download" |
614 | on the CPAN page about local::lib). Do this as an ordinary user, not as root |
615 | or administrator. Unpack the file in your home directory or in any other |
616 | convenient location. |
715c31a0 |
617 | |
730f5dda |
618 | 2. Run this: |
715c31a0 |
619 | |
730f5dda |
620 | perl Makefile.PL --bootstrap |
715c31a0 |
621 | |
730f5dda |
622 | If the system asks you whether it should automatically configure as much |
623 | as possible, you would typically answer yes. |
624 | |
04f8efde |
625 | In order to install local::lib into a directory other than the default, you need |
626 | to specify the name of the directory when you call bootstrap, as follows: |
898f36cf |
627 | |
628 | perl Makefile.PL --bootstrap=~/foo |
629 | |
630 | 3. Run this: (local::lib assumes you have make installed on your system) |
730f5dda |
631 | |
632 | make test && make install |
633 | |
8522f4d5 |
634 | 4. Now we need to setup the appropriate environment variables, so that Perl |
898f36cf |
635 | starts using our newly generated lib/ directory. If you are using bash or |
636 | any other Bourne shells, you can add this to your shell startup script this |
637 | way: |
730f5dda |
638 | |
639 | echo 'eval $(perl -I$HOME/perl5/lib/perl5 -Mlocal::lib)' >>~/.bashrc |
640 | |
641 | If you are using C shell, you can do this as follows: |
642 | |
643 | /bin/csh |
644 | echo $SHELL |
618272fe |
645 | /bin/csh |
730f5dda |
646 | perl -I$HOME/perl5/lib/perl5 -Mlocal::lib >> ~/.cshrc |
dc8ddd06 |
647 | |
8522f4d5 |
648 | If you passed to bootstrap a directory other than default, you also need to give that as |
898f36cf |
649 | import parameter to the call of the local::lib module like this way: |
8b1e8e69 |
650 | |
730f5dda |
651 | echo 'eval $(perl -I$HOME/foo/lib/perl5 -Mlocal::lib=$HOME/foo)' >>~/.bashrc |
618272fe |
652 | |
aab64481 |
653 | After writing your shell configuration file, be sure to re-read it to get the |
8522f4d5 |
654 | changed settings into your current shell's environment. Bourne shells use |
898f36cf |
655 | C<. ~/.bashrc> for this, whereas C shells use C<source ~/.cshrc>. |
aab64481 |
656 | |
b9c94c15 |
657 | If you're on a slower machine, or are operating under draconian disk space |
658 | limitations, you can disable the automatic generation of manpages from POD when |
659 | installing modules by using the C<--no-manpages> argument when bootstrapping: |
660 | |
730f5dda |
661 | perl Makefile.PL --bootstrap --no-manpages |
b9c94c15 |
662 | |
8522f4d5 |
663 | To avoid doing several bootstrap for several Perl module environments on the |
664 | same account, for example if you use it for several different deployed |
665 | applications independently, you can use one bootstrapped local::lib |
898f36cf |
666 | installation to install modules in different directories directly this way: |
977a9ca3 |
667 | |
730f5dda |
668 | cd ~/mydir1 |
669 | perl -Mlocal::lib=./ |
670 | eval $(perl -Mlocal::lib=./) ### To set the environment for this shell alone |
898f36cf |
671 | printenv ### You will see that ~/mydir1 is in the PERL5LIB |
730f5dda |
672 | perl -MCPAN -e install ... ### whatever modules you want |
673 | cd ../mydir2 |
674 | ... REPEAT ... |
675 | |
480534a8 |
676 | If you are working with several C<local::lib> environments, you may want to |
677 | remove some of them from the current environment without disturbing the others. |
678 | You can deactivate one environment like this (using bourne sh): |
679 | |
680 | eval $(perl -Mlocal::lib=--deactivate,~/path) |
681 | |
682 | which will generate and run the commands needed to remove C<~/path> from your |
683 | various search paths. Whichever environment was B<activated most recently> will |
684 | remain the target for module installations. That is, if you activate |
685 | C<~/path_A> and then you activate C<~/path_B>, new modules you install will go |
686 | in C<~/path_B>. If you deactivate C<~/path_B> then modules will be installed |
687 | into C<~/pathA> -- but if you deactivate C<~/path_A> then they will still be |
688 | installed in C<~/pathB> because pathB was activated later. |
689 | |
690 | You can also ask C<local::lib> to clean itself completely out of the current |
691 | shell's environment with the C<--deactivate-all> option. |
730f5dda |
692 | For multiple environments for multiple apps you may need to include a modified |
693 | version of the C<< use FindBin >> instructions in the "In code" sample above. |
694 | If you did something like the above, you have a set of Perl modules at C<< |
695 | ~/mydir1/lib >>. If you have a script at C<< ~/mydir1/scripts/myscript.pl >>, |
696 | you need to tell it where to find the modules you installed for it at C<< |
697 | ~/mydir1/lib >>. |
977a9ca3 |
698 | |
699 | In C<< ~/mydir1/scripts/myscript.pl >>: |
700 | |
730f5dda |
701 | use strict; |
702 | use warnings; |
703 | use local::lib "$FindBin::Bin/.."; ### points to ~/mydir1 and local::lib finds lib |
704 | use lib "$FindBin::Bin/../lib"; ### points to ~/mydir1/lib |
977a9ca3 |
705 | |
706 | Put this before any BEGIN { ... } blocks that require the modules you installed. |
707 | |
53699c99 |
708 | =head2 Differences when using this module under Win32 |
709 | |
76f30678 |
710 | To set up the proper environment variables for your current session of |
711 | C<CMD.exe>, you can use this: |
712 | |
730f5dda |
713 | C:\>perl -Mlocal::lib |
e322149f |
714 | set PERL_MB_OPT=--install_base C:\DOCUME~1\ADMINI~1\perl5 |
730f5dda |
715 | set PERL_MM_OPT=INSTALL_BASE=C:\DOCUME~1\ADMINI~1\perl5 |
716 | set PERL5LIB=C:\DOCUME~1\ADMINI~1\perl5\lib\perl5;C:\DOCUME~1\ADMINI~1\perl5\lib\perl5\MSWin32-x86-multi-thread |
717 | set PATH=C:\DOCUME~1\ADMINI~1\perl5\bin;%PATH% |
8522f4d5 |
718 | |
898f36cf |
719 | ### To set the environment for this shell alone |
d4ccf2ea |
720 | C:\>perl -Mlocal::lib > %TEMP%\tmp.bat && %TEMP%\tmp.bat && del %TEMP%\tmp.bat |
730f5dda |
721 | ### instead of $(perl -Mlocal::lib=./) |
53699c99 |
722 | |
723 | If you want the environment entries to persist, you'll need to add then to the |
76f30678 |
724 | Control Panel's System applet yourself or use L<App::local::lib::Win32Helper>. |
53699c99 |
725 | |
726 | The "~" is translated to the user's profile directory (the directory named for |
727 | the user under "Documents and Settings" (Windows XP or earlier) or "Users" |
9bc0788f |
728 | (Windows Vista or later)) unless $ENV{HOME} exists. After that, the home |
53699c99 |
729 | directory is translated to a short name (which means the directory must exist) |
730 | and the subdirectories are created. |
731 | |
730f5dda |
732 | =head1 RATIONALE |
733 | |
734 | The version of a Perl package on your machine is not always the version you |
735 | need. Obviously, the best thing to do would be to update to the version you |
736 | need. However, you might be in a situation where you're prevented from doing |
737 | this. Perhaps you don't have system administrator privileges; or perhaps you |
738 | are using a package management system such as Debian, and nobody has yet gotten |
739 | around to packaging up the version you need. |
740 | |
741 | local::lib solves this problem by allowing you to create your own directory of |
742 | Perl packages downloaded from CPAN (in a multi-user system, this would typically |
743 | be within your own home directory). The existing system Perl installation is |
744 | not affected; you simply invoke Perl with special options so that Perl uses the |
745 | packages in your own local package directory rather than the system packages. |
746 | local::lib arranges things so that your locally installed version of the Perl |
747 | packages takes precedence over the system installation. |
748 | |
749 | If you are using a package management system (such as Debian), you don't need to |
750 | worry about Debian and CPAN stepping on each other's toes. Your local version |
751 | of the packages will be written to an entirely separate directory from those |
8522f4d5 |
752 | installed by Debian. |
730f5dda |
753 | |
618272fe |
754 | =head1 DESCRIPTION |
755 | |
756 | This module provides a quick, convenient way of bootstrapping a user-local Perl |
757 | module library located within the user's home directory. It also constructs and |
758 | prints out for the user the list of environment variables using the syntax |
759 | appropriate for the user's current shell (as specified by the C<SHELL> |
730f5dda |
760 | environment variable), suitable for directly adding to one's shell |
761 | configuration file. |
762 | |
763 | More generally, local::lib allows for the bootstrapping and usage of a |
764 | directory containing Perl modules outside of Perl's C<@INC>. This makes it |
765 | easier to ship an application with an app-specific copy of a Perl module, or |
766 | collection of modules. Useful in cases like when an upstream maintainer hasn't |
767 | applied a patch to a module of theirs that you need for your application. |
1bc71e56 |
768 | |
769 | On import, local::lib sets the following environment variables to appropriate |
770 | values: |
771 | |
772 | =over 4 |
773 | |
e322149f |
774 | =item PERL_MB_OPT |
1bc71e56 |
775 | |
776 | =item PERL_MM_OPT |
777 | |
778 | =item PERL5LIB |
779 | |
780 | =item PATH |
781 | |
782 | PATH is appended to, rather than clobbered. |
783 | |
784 | =back |
785 | |
786 | These values are then available for reference by any code after import. |
787 | |
b0c48f8e |
788 | =head1 CREATING A SELF-CONTAINED SET OF MODULES |
789 | |
a949ebcd |
790 | See L<lib::core::only> for one way to do this - but note that |
d8b1a404 |
791 | there are a number of caveats, and the best approach is always to perform a |
792 | build against a clean perl (i.e. site and vendor as close to empty as possible). |
b0c48f8e |
793 | |
480534a8 |
794 | =head1 OPTIONS |
795 | |
796 | Options are values that can be passed to the C<local::lib> import besides the |
797 | directory to use. They are specified as C<use local::lib '--option'[, path];> |
798 | or C<perl -Mlocal::lib=--option[,path]>. |
799 | |
800 | =head2 --deactivate |
801 | |
802 | Remove the chosen path (or the default path) from the module search paths if it |
803 | was added by C<local::lib>, instead of adding it. |
804 | |
805 | =head2 --deactivate-all |
806 | |
807 | Remove all directories that were added to search paths by C<local::lib> from the |
808 | search paths. |
809 | |
480e6e85 |
810 | =head1 METHODS |
811 | |
a949ebcd |
812 | =head2 ensure_dir_structure_for |
480e6e85 |
813 | |
814 | =over 4 |
815 | |
a949ebcd |
816 | =item Arguments: $path |
817 | |
818 | =item Return value: None |
480e6e85 |
819 | |
820 | =back |
821 | |
822 | Attempts to create the given path, and all required parent directories. Throws |
823 | an exception on failure. |
824 | |
825 | =head2 print_environment_vars_for |
826 | |
827 | =over 4 |
828 | |
a949ebcd |
829 | =item Arguments: $path |
830 | |
831 | =item Return value: None |
480e6e85 |
832 | |
833 | =back |
834 | |
835 | Prints to standard output the variables listed above, properly set to use the |
836 | given path as the base directory. |
837 | |
a949ebcd |
838 | =head2 build_environment_vars_for |
839 | |
840 | =over 4 |
841 | |
842 | =item Arguments: $path, $interpolate |
843 | |
844 | =item Return value: \%environment_vars |
845 | |
846 | =back |
847 | |
291b5a3a |
848 | Returns a hash with the variables listed above, properly set to use the |
849 | given path as the base directory. |
850 | |
480e6e85 |
851 | =head2 setup_env_hash_for |
852 | |
853 | =over 4 |
854 | |
a949ebcd |
855 | =item Arguments: $path |
856 | |
857 | =item Return value: None |
480e6e85 |
858 | |
859 | =back |
860 | |
861 | Constructs the C<%ENV> keys for the given path, by calling |
a949ebcd |
862 | L</build_environment_vars_for>. |
480e6e85 |
863 | |
5a63c13e |
864 | =head2 active_paths |
865 | |
866 | =over 4 |
867 | |
868 | =item Arguments: None |
869 | |
870 | =item Return value: @paths |
871 | |
872 | =back |
873 | |
874 | Returns a list of active C<local::lib> paths, according to the |
24351831 |
875 | C<PERL_LOCAL_LIB_ROOT> environment variable and verified against |
876 | what is really in C<@INC>. |
5a63c13e |
877 | |
480e6e85 |
878 | =head2 install_base_perl_path |
879 | |
880 | =over 4 |
881 | |
a949ebcd |
882 | =item Arguments: $path |
883 | |
884 | =item Return value: $install_base_perl_path |
480e6e85 |
885 | |
886 | =back |
887 | |
888 | Returns a path describing where to install the Perl modules for this local |
889 | library installation. Appends the directories C<lib> and C<perl5> to the given |
890 | path. |
891 | |
892 | =head2 install_base_arch_path |
893 | |
894 | =over 4 |
895 | |
a949ebcd |
896 | =item Arguments: $path |
897 | |
898 | =item Return value: $install_base_arch_path |
480e6e85 |
899 | |
900 | =back |
901 | |
902 | Returns a path describing where to install the architecture-specific Perl |
903 | modules for this local library installation. Based on the |
904 | L</install_base_perl_path> method's return value, and appends the value of |
905 | C<$Config{archname}>. |
906 | |
907 | =head2 install_base_bin_path |
908 | |
909 | =over 4 |
910 | |
a949ebcd |
911 | =item Arguments: $path |
912 | |
913 | =item Return value: $install_base_bin_path |
480e6e85 |
914 | |
915 | =back |
916 | |
917 | Returns a path describing where to install the executable programs for this |
918 | local library installation. Based on the L</install_base_perl_path> method's |
919 | return value, and appends the directory C<bin>. |
920 | |
480e6e85 |
921 | =head2 resolve_empty_path |
922 | |
923 | =over 4 |
924 | |
a949ebcd |
925 | =item Arguments: $path |
926 | |
927 | =item Return value: $base_path |
480e6e85 |
928 | |
929 | =back |
930 | |
931 | Builds and returns the base path into which to set up the local module |
932 | installation. Defaults to C<~/perl5>. |
933 | |
934 | =head2 resolve_home_path |
935 | |
936 | =over 4 |
937 | |
a949ebcd |
938 | =item Arguments: $path |
939 | |
940 | =item Return value: $home_path |
480e6e85 |
941 | |
942 | =back |
943 | |
944 | Attempts to find the user's home directory. If installed, uses C<File::HomeDir> |
945 | for this purpose. If no definite answer is available, throws an exception. |
946 | |
947 | =head2 resolve_relative_path |
948 | |
949 | =over 4 |
950 | |
a949ebcd |
951 | =item Arguments: $path |
952 | |
953 | =item Return value: $absolute_path |
480e6e85 |
954 | |
955 | =back |
956 | |
957 | Translates the given path into an absolute path. |
958 | |
959 | =head2 resolve_path |
960 | |
961 | =over 4 |
962 | |
a949ebcd |
963 | =item Arguments: $path |
964 | |
965 | =item Return value: $absolute_path |
480e6e85 |
966 | |
967 | =back |
968 | |
969 | Calls the following in a pipeline, passing the result from the previous to the |
970 | next, in an attempt to find where to configure the environment for a local |
971 | library installation: L</resolve_empty_path>, L</resolve_home_path>, |
972 | L</resolve_relative_path>. Passes the given path argument to |
973 | L</resolve_empty_path> which then returns a result that is passed to |
974 | L</resolve_home_path>, which then has its result passed to |
975 | L</resolve_relative_path>. The result of this final call is returned from |
976 | L</resolve_path>. |
977 | |
0fb70b9a |
978 | =head1 A WARNING ABOUT UNINST=1 |
979 | |
980 | Be careful about using local::lib in combination with "make install UNINST=1". |
981 | The idea of this feature is that will uninstall an old version of a module |
982 | before installing a new one. However it lacks a safety check that the old |
983 | version and the new version will go in the same directory. Used in combination |
984 | with local::lib, you can potentially delete a globally accessible version of a |
381738d7 |
985 | module while installing the new version in a local place. Only combine "make |
0fb70b9a |
986 | install UNINST=1" and local::lib if you understand these possible consequences. |
987 | |
dc8ddd06 |
988 | =head1 LIMITATIONS |
989 | |
788ea146 |
990 | =over 4 |
991 | |
992 | =item * The perl toolchain is unable to handle directory names with spaces in it, |
469251c5 |
993 | so you can't put your local::lib bootstrap into a directory with spaces. What |
a8e981cf |
994 | you can do is moving your local::lib to a directory with spaces B<after> you |
995 | installed all modules inside your local::lib bootstrap. But be aware that you |
469251c5 |
996 | can't update or install CPAN modules after the move. |
47e70ca1 |
997 | |
788ea146 |
998 | =item * Rather basic shell detection. Right now anything with csh in its name is |
618272fe |
999 | assumed to be a C shell or something compatible, and everything else is assumed |
53699c99 |
1000 | to be Bourne, except on Win32 systems. If the C<SHELL> environment variable is |
1001 | not set, a Bourne-compatible shell is assumed. |
dc8ddd06 |
1002 | |
788ea146 |
1003 | =item * Bootstrap is a hack and will use CPAN.pm for ExtUtils::MakeMaker even if you |
dc8ddd06 |
1004 | have CPANPLUS installed. |
1005 | |
788ea146 |
1006 | =item * Kills any existing PERL5LIB, PERL_MM_OPT or PERL_MB_OPT. |
dc8ddd06 |
1007 | |
788ea146 |
1008 | =item * Should probably auto-fixup CPAN config if not already done. |
1009 | |
1010 | =back |
e423efce |
1011 | |
dc8ddd06 |
1012 | Patches very much welcome for any of the above. |
bc30e1d5 |
1013 | |
788ea146 |
1014 | =over 4 |
1015 | |
1016 | =item * On Win32 systems, does not have a way to write the created environment variables |
53699c99 |
1017 | to the registry, so that they can persist through a reboot. |
1018 | |
788ea146 |
1019 | =back |
1020 | |
9a021b2b |
1021 | =head1 TROUBLESHOOTING |
1022 | |
1023 | If you've configured local::lib to install CPAN modules somewhere in to your |
1024 | home directory, and at some point later you try to install a module with C<cpan |
1025 | -i Foo::Bar>, but it fails with an error like: C<Warning: You do not have |
1026 | permissions to install into /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux at |
1027 | /usr/lib64/perl5/5.8.8/Foo/Bar.pm> and buried within the install log is an |
1028 | error saying C<'INSTALL_BASE' is not a known MakeMaker parameter name>, then |
1029 | you've somehow lost your updated ExtUtils::MakeMaker module. |
1030 | |
1031 | To remedy this situation, rerun the bootstrapping procedure documented above. |
1032 | |
1033 | Then, run C<rm -r ~/.cpan/build/Foo-Bar*> |
1034 | |
1035 | Finally, re-run C<cpan -i Foo::Bar> and it should install without problems. |
1036 | |
618272fe |
1037 | =head1 ENVIRONMENT |
1038 | |
1039 | =over 4 |
1040 | |
1041 | =item SHELL |
1042 | |
53699c99 |
1043 | =item COMSPEC |
1044 | |
618272fe |
1045 | local::lib looks at the user's C<SHELL> environment variable when printing out |
1046 | commands to add to the shell configuration file. |
1047 | |
53699c99 |
1048 | On Win32 systems, C<COMSPEC> is also examined. |
1049 | |
618272fe |
1050 | =back |
1051 | |
163f162c |
1052 | =head1 SEE ALSO |
1053 | |
1054 | =over 4 |
1055 | |
1056 | =item * L<Perl Advent article, 2011|http://perladvent.org/2011/2011-12-01.html> |
1057 | |
1058 | =back |
1059 | |
cc19e8d4 |
1060 | =head1 SUPPORT |
1061 | |
1062 | IRC: |
1063 | |
1064 | Join #local-lib on irc.perl.org. |
1065 | |
b5cc15f7 |
1066 | =head1 AUTHOR |
1067 | |
1068 | Matt S Trout <mst@shadowcat.co.uk> http://www.shadowcat.co.uk/ |
1069 | |
d6b71a2d |
1070 | auto_install fixes kindly sponsored by http://www.takkle.com/ |
1071 | |
b5c1154d |
1072 | =head1 CONTRIBUTORS |
1073 | |
1074 | Patches to correctly output commands for csh style shells, as well as some |
1075 | documentation additions, contributed by Christopher Nehren <apeiron@cpan.org>. |
1076 | |
cc19e8d4 |
1077 | Doc patches for a custom local::lib directory, more cleanups in the english |
a949ebcd |
1078 | documentation and a L<german documentation|POD2::DE::local::lib> contributed by Torsten Raudssus |
8b1e8e69 |
1079 | <torsten@raudssus.de>. |
1080 | |
be160790 |
1081 | Hans Dieter Pearcey <hdp@cpan.org> sent in some additional tests for ensuring |
9a021b2b |
1082 | things will install properly, submitted a fix for the bug causing problems with |
1083 | writing Makefiles during bootstrapping, contributed an example program, and |
1084 | submitted yet another fix to ensure that local::lib can install and bootstrap |
1085 | properly. Many, many thanks! |
1086 | |
1087 | pattern of Freenode IRC contributed the beginnings of the Troubleshooting |
1088 | section. Many thanks! |
be160790 |
1089 | |
53699c99 |
1090 | Patch to add Win32 support contributed by Curtis Jewell <csjewell@cpan.org>. |
1091 | |
03b91976 |
1092 | Warnings for missing PATH/PERL5LIB (as when not running interactively) silenced |
1093 | by a patch from Marco Emilio Poleggi. |
1094 | |
1f8043c8 |
1095 | Mark Stosberg <mark@summersault.com> provided the code for the now deleted |
1096 | '--self-contained' option. |
1097 | |
76f30678 |
1098 | Documentation patches to make win32 usage clearer by |
1099 | David Mertens <dcmertens.perl@gmail.com> (run4flat). |
1100 | |
a949ebcd |
1101 | Brazilian L<portuguese translation|POD2::PT_BR::local::lib> and minor doc patches contributed by Breno |
ccf362c0 |
1102 | G. de Oliveira <garu@cpan.org>. |
1103 | |
a0b3d98a |
1104 | Improvements to stacking multiple local::lib dirs and removing them from the |
1105 | environment later on contributed by Andrew Rodland <arodland@cpan.org>. |
1106 | |
cd3eb741 |
1107 | Patch for Carp version mismatch contributed by Hakim Cassimally <osfameron@cpan.org>. |
1108 | |
7c0db165 |
1109 | =head1 COPYRIGHT |
1110 | |
cc19e8d4 |
1111 | Copyright (c) 2007 - 2010 the local::lib L</AUTHOR> and L</CONTRIBUTORS> as |
7c0db165 |
1112 | listed above. |
1113 | |
b5cc15f7 |
1114 | =head1 LICENSE |
1115 | |
73c9a8ad |
1116 | This is free software; you can redistribute it and/or modify it under |
1117 | the same terms as the Perl 5 programming language system itself. |
b5cc15f7 |
1118 | |
1119 | =cut |
1120 | |
1121 | 1; |