Commit | Line | Data |
54310121 |
1 | package constant; |
2 | |
83763826 |
3 | use strict; |
b0d6893f |
4 | use 5.006_00; |
d3a7d8c7 |
5 | use warnings::register; |
17f410f9 |
6 | |
7 | our($VERSION, %declared); |
e040ff70 |
8 | $VERSION = '1.07'; |
83763826 |
9 | |
10 | #======================================================================= |
11 | |
83763826 |
12 | # Some names are evil choices. |
7d30b5c4 |
13 | my %keywords = map +($_, 1), qw{ BEGIN INIT CHECK END DESTROY AUTOLOAD }; |
83763826 |
14 | |
15 | my %forced_into_main = map +($_, 1), |
16 | qw{ STDIN STDOUT STDERR ARGV ARGVOUT ENV INC SIG }; |
17 | |
18 | my %forbidden = (%keywords, %forced_into_main); |
19 | |
20 | #======================================================================= |
21 | # import() - import symbols into user's namespace |
22 | # |
23 | # What we actually do is define a function in the caller's namespace |
24 | # which returns the value. The function we create will normally |
25 | # be inlined as a constant, thereby avoiding further sub calling |
26 | # overhead. |
27 | #======================================================================= |
28 | sub import { |
29 | my $class = shift; |
30 | return unless @_; # Ignore 'use constant;' |
b35226bb |
31 | my $constants; |
3cb88d13 |
32 | my $multiple = ref $_[0]; |
39a108ce |
33 | my $pkg = caller; |
e040ff70 |
34 | my $symtab; |
35 | |
36 | if ($] > 5.009002) { |
37 | no strict 'refs'; |
38 | $symtab = \%{$pkg . '::'}; |
39 | }; |
3cb88d13 |
40 | |
41 | if ( $multiple ) { |
42 | if (ref $_[0] ne 'HASH') { |
43 | require Carp; |
44 | Carp::croak("Invalid reference type '".ref(shift)."' not 'HASH'"); |
45 | } |
b35226bb |
46 | $constants = shift; |
3cb88d13 |
47 | } else { |
b35226bb |
48 | $constants->{+shift} = undef; |
83763826 |
49 | } |
3cb88d13 |
50 | |
b35226bb |
51 | foreach my $name ( keys %$constants ) { |
3cb88d13 |
52 | unless (defined $name) { |
53 | require Carp; |
54 | Carp::croak("Can't use undef as constant name"); |
55 | } |
3cb88d13 |
56 | |
57 | # Normal constant name |
58 | if ($name =~ /^_?[^\W_0-9]\w*\z/ and !$forbidden{$name}) { |
59 | # Everything is okay |
60 | |
61 | # Name forced into main, but we're not in main. Fatal. |
62 | } elsif ($forced_into_main{$name} and $pkg ne 'main') { |
63 | require Carp; |
64 | Carp::croak("Constant name '$name' is forced into main::"); |
65 | |
66 | # Starts with double underscore. Fatal. |
67 | } elsif ($name =~ /^__/) { |
68 | require Carp; |
69 | Carp::croak("Constant name '$name' begins with '__'"); |
70 | |
71 | # Maybe the name is tolerable |
72 | } elsif ($name =~ /^[A-Za-z_]\w*\z/) { |
73 | # Then we'll warn only if you've asked for warnings |
74 | if (warnings::enabled()) { |
75 | if ($keywords{$name}) { |
76 | warnings::warn("Constant name '$name' is a Perl keyword"); |
77 | } elsif ($forced_into_main{$name}) { |
78 | warnings::warn("Constant name '$name' is " . |
79 | "forced into package main::"); |
3cb88d13 |
80 | } |
81 | } |
82 | |
83 | # Looks like a boolean |
84 | # use constant FRED == fred; |
85 | } elsif ($name =~ /^[01]?\z/) { |
86 | require Carp; |
87 | if (@_) { |
88 | Carp::croak("Constant name '$name' is invalid"); |
83763826 |
89 | } else { |
3cb88d13 |
90 | Carp::croak("Constant name looks like boolean value"); |
83763826 |
91 | } |
83763826 |
92 | |
83763826 |
93 | } else { |
3cb88d13 |
94 | # Must have bad characters |
95 | require Carp; |
96 | Carp::croak("Constant name '$name' has invalid characters"); |
83763826 |
97 | } |
98 | |
3cb88d13 |
99 | { |
100 | no strict 'refs'; |
101 | my $full_name = "${pkg}::$name"; |
102 | $declared{$full_name}++; |
e040ff70 |
103 | if ($multiple || @_ == 1) { |
104 | my $scalar = $multiple ? $constants->{$name} : $_[0]; |
105 | if ($symtab && !exists $symtab->{$name}) { |
106 | # No typeglob yet, so we can use a reference as space- |
107 | # efficient proxy for a constant subroutine |
108 | # The check in Perl_ck_rvconst knows that inlinable |
109 | # constants from cv_const_sv are read only. So we have to: |
110 | Internals::SvREADONLY($scalar, 1); |
111 | $symtab->{$name} = \$scalar; |
3cb88d13 |
112 | } else { |
e040ff70 |
113 | if(!exists $symtab->{$name}) { |
114 | print STDERR "$name $scalar\n"; |
115 | } |
116 | *$full_name = sub () { $scalar }; |
3cb88d13 |
117 | } |
e040ff70 |
118 | } elsif (@_) { |
119 | my @list = @_; |
120 | *$full_name = sub () { @list }; |
121 | } else { |
122 | *$full_name = sub () { }; |
3cb88d13 |
123 | } |
83763826 |
124 | } |
125 | } |
83763826 |
126 | } |
127 | |
128 | 1; |
129 | |
130 | __END__ |
54310121 |
131 | |
132 | =head1 NAME |
133 | |
134 | constant - Perl pragma to declare constants |
135 | |
136 | =head1 SYNOPSIS |
137 | |
a747501d |
138 | use constant PI => 4 * atan2(1, 1); |
139 | use constant DEBUG => 0; |
140 | |
141 | print "Pi equals ", PI, "...\n" if DEBUG; |
142 | |
3cb88d13 |
143 | use constant { |
a747501d |
144 | SEC => 0, |
145 | MIN => 1, |
146 | HOUR => 2, |
147 | MDAY => 3, |
148 | MON => 4, |
149 | YEAR => 5, |
150 | WDAY => 6, |
151 | YDAY => 7, |
152 | ISDST => 8, |
3cb88d13 |
153 | }; |
154 | |
a747501d |
155 | use constant WEEKDAYS => qw( |
156 | Sunday Monday Tuesday Wednesday Thursday Friday Saturday |
157 | ); |
158 | |
159 | print "Today is ", (WEEKDAYS)[ (localtime)[WDAY] ], ".\n"; |
160 | |
54310121 |
161 | =head1 DESCRIPTION |
162 | |
a747501d |
163 | This will declare a symbol to be a constant with the given value. |
54310121 |
164 | |
165 | When you declare a constant such as C<PI> using the method shown |
166 | above, each machine your script runs upon can have as many digits |
167 | of accuracy as it can use. Also, your program will be easier to |
168 | read, more likely to be maintained (and maintained correctly), and |
169 | far less likely to send a space probe to the wrong planet because |
170 | nobody noticed the one equation in which you wrote C<3.14195>. |
171 | |
a747501d |
172 | When a constant is used in an expression, perl replaces it with its |
173 | value at compile time, and may then optimize the expression further. |
174 | In particular, any code in an C<if (CONSTANT)> block will be optimized |
175 | away if the constant is false. |
176 | |
54310121 |
177 | =head1 NOTES |
178 | |
a747501d |
179 | As with all C<use> directives, defining a constant happens at |
180 | compile time. Thus, it's probably not correct to put a constant |
181 | declaration inside of a conditional statement (like C<if ($foo) |
182 | { use constant ... }>). |
54310121 |
183 | |
a747501d |
184 | Constants defined using this module cannot be interpolated into |
185 | strings like variables. However, concatenation works just fine: |
54310121 |
186 | |
a747501d |
187 | print "Pi equals PI...\n"; # WRONG: does not expand "PI" |
188 | print "Pi equals ".PI."...\n"; # right |
54310121 |
189 | |
a747501d |
190 | Even though a reference may be declared as a constant, the reference may |
191 | point to data which may be changed, as this code shows. |
192 | |
193 | use constant ARRAY => [ 1,2,3,4 ]; |
194 | print ARRAY->[1]; |
195 | ARRAY->[1] = " be changed"; |
196 | print ARRAY->[1]; |
197 | |
198 | Dereferencing constant references incorrectly (such as using an array |
199 | subscript on a constant hash reference, or vice versa) will be trapped at |
200 | compile time. |
54310121 |
201 | |
a747501d |
202 | Constants belong to the package they are defined in. To refer to a |
203 | constant defined in another package, specify the full package name, as |
204 | in C<Some::Package::CONSTANT>. Constants may be exported by modules, |
205 | and may also be called as either class or instance methods, that is, |
206 | as C<< Some::Package->CONSTANT >> or as C<< $obj->CONSTANT >> where |
207 | C<$obj> is an instance of C<Some::Package>. Subclasses may define |
208 | their own constants to override those in their base class. |
54310121 |
209 | |
210 | The use of all caps for constant names is merely a convention, |
211 | although it is recommended in order to make constants stand out |
212 | and to help avoid collisions with other barewords, keywords, and |
83763826 |
213 | subroutine names. Constant names must begin with a letter or |
214 | underscore. Names beginning with a double underscore are reserved. Some |
215 | poor choices for names will generate warnings, if warnings are enabled at |
216 | compile time. |
54310121 |
217 | |
a747501d |
218 | =head2 List constants |
54310121 |
219 | |
a747501d |
220 | Constants may be lists of more (or less) than one value. A constant |
221 | with no values evaluates to C<undef> in scalar context. Note that |
222 | constants with more than one value do I<not> return their last value in |
223 | scalar context as one might expect. They currently return the number |
224 | of values, but B<this may change in the future>. Do not use constants |
225 | with multiple values in scalar context. |
3cb88d13 |
226 | |
a747501d |
227 | B<NOTE:> This implies that the expression defining the value of a |
228 | constant is evaluated in list context. This may produce surprises: |
54310121 |
229 | |
a747501d |
230 | use constant TIMESTAMP => localtime; # WRONG! |
231 | use constant TIMESTAMP => scalar localtime; # right |
54310121 |
232 | |
a747501d |
233 | The first line above defines C<TIMESTAMP> as a 9-element list, as |
234 | returned by localtime() in list context. To set it to the string |
235 | returned by localtime() in scalar context, an explicit C<scalar> |
236 | keyword is required. |
54310121 |
237 | |
a747501d |
238 | List constants are lists, not arrays. To index or slice them, they |
239 | must be placed in parentheses. |
54310121 |
240 | |
a747501d |
241 | my @workdays = WEEKDAYS[1 .. 5]; # WRONG! |
242 | my @workdays = (WEEKDAYS)[1 .. 5]; # right |
b0d6893f |
243 | |
a747501d |
244 | =head2 Defining multiple constants at once |
b0d6893f |
245 | |
a747501d |
246 | Instead of writing multiple C<use constant> statements, you may define |
247 | multiple constants in a single statement by giving, instead of the |
248 | constant name, a reference to a hash where the keys are the names of |
249 | the constants to be defined. Obviously, all constants defined using |
250 | this method must have a single value. |
251 | |
252 | use constant { |
253 | FOO => "A single value", |
254 | BAR => "This", "won't", "work!", # Error! |
255 | }; |
256 | |
257 | This is a fundamental limitation of the way hashes are constructed in |
258 | Perl. The error messages produced when this happens will often be |
259 | quite cryptic -- in the worst case there may be none at all, and |
260 | you'll only later find that something is broken. |
261 | |
262 | When defining multiple constants, you cannot use the values of other |
263 | constants defined in the same declaration. This is because the |
264 | calling package doesn't know about any constant within that group |
265 | until I<after> the C<use> statement is finished. |
266 | |
267 | use constant { |
268 | BITMASK => 0xAFBAEBA8, |
269 | NEGMASK => ~BITMASK, # Error! |
270 | }; |
271 | |
272 | =head2 Magic constants |
b0d6893f |
273 | |
274 | Magical values and references can be made into constants at compile |
275 | time, allowing for way cool stuff like this. (These error numbers |
276 | aren't totally portable, alas.) |
54310121 |
277 | |
278 | use constant E2BIG => ($! = 7); |
a747501d |
279 | print E2BIG, "\n"; # something like "Arg list too long" |
280 | print 0+E2BIG, "\n"; # "7" |
54310121 |
281 | |
b0d6893f |
282 | You can't produce a tied constant by giving a tied scalar as the |
283 | value. References to tied variables, however, can be used as |
284 | constants without any problems. |
285 | |
a747501d |
286 | =head1 TECHNICAL NOTES |
b0d6893f |
287 | |
a747501d |
288 | In the current implementation, scalar constants are actually |
289 | inlinable subroutines. As of version 5.004 of Perl, the appropriate |
290 | scalar constant is inserted directly in place of some subroutine |
291 | calls, thereby saving the overhead of a subroutine call. See |
292 | L<perlsub/"Constant Functions"> for details about how and when this |
293 | happens. |
3cb88d13 |
294 | |
83763826 |
295 | In the rare case in which you need to discover at run time whether a |
296 | particular constant has been declared via this module, you may use |
297 | this function to examine the hash C<%constant::declared>. If the given |
298 | constant name does not include a package name, the current package is |
299 | used. |
300 | |
301 | sub declared ($) { |
a747501d |
302 | use constant 1.01; # don't omit this! |
303 | my $name = shift; |
304 | $name =~ s/^::/main::/; |
305 | my $pkg = caller; |
306 | my $full_name = $name =~ /::/ ? $name : "${pkg}::$name"; |
307 | $constant::declared{$full_name}; |
83763826 |
308 | } |
779c5bc9 |
309 | |
54310121 |
310 | =head1 BUGS |
311 | |
312 | In the current version of Perl, list constants are not inlined |
313 | and some symbols may be redefined without generating a warning. |
314 | |
a747501d |
315 | It is not possible to have a subroutine or a keyword with the same |
83763826 |
316 | name as a constant in the same package. This is probably a Good Thing. |
317 | |
318 | A constant with a name in the list C<STDIN STDOUT STDERR ARGV ARGVOUT |
319 | ENV INC SIG> is not allowed anywhere but in package C<main::>, for |
320 | technical reasons. |
321 | |
54310121 |
322 | Unlike constants in some languages, these cannot be overridden |
323 | on the command line or via environment variables. |
324 | |
a3cb178b |
325 | You can get into trouble if you use constants in a context which |
326 | automatically quotes barewords (as is true for any subroutine call). |
327 | For example, you can't say C<$hash{CONSTANT}> because C<CONSTANT> will |
328 | be interpreted as a string. Use C<$hash{CONSTANT()}> or |
329 | C<$hash{+CONSTANT}> to prevent the bareword quoting mechanism from |
a747501d |
330 | kicking in. Similarly, since the C<< => >> operator quotes a bareword |
331 | immediately to its left, you have to say C<< CONSTANT() => 'value' >> |
83763826 |
332 | (or simply use a comma in place of the big arrow) instead of |
a747501d |
333 | C<< CONSTANT => 'value' >>. |
a3cb178b |
334 | |
54310121 |
335 | =head1 AUTHOR |
336 | |
83763826 |
337 | Tom Phoenix, E<lt>F<rootbeer@redcat.com>E<gt>, with help from |
54310121 |
338 | many other folks. |
339 | |
e1e60e72 |
340 | Multiple constant declarations at once added by Casey West, |
341 | E<lt>F<casey@geeknest.com>E<gt>. |
3cb88d13 |
342 | |
a747501d |
343 | Documentation mostly rewritten by Ilmari Karonen, |
b0d6893f |
344 | E<lt>F<perl@itz.pp.sci.fi>E<gt>. |
345 | |
54310121 |
346 | =head1 COPYRIGHT |
347 | |
83763826 |
348 | Copyright (C) 1997, 1999 Tom Phoenix |
54310121 |
349 | |
350 | This module is free software; you can redistribute it or modify it |
351 | under the same terms as Perl itself. |
352 | |
353 | =cut |